TList, Vererbung und Aufräumen beim Free

[Bbommel]

Hallo zusammen,

irgendwie bin ich gerade etwas verwirrt und zweifel an mir selbst, ob ich wohl die Objektorientierung nicht verstanden habe. Was mich wundern würde, weil meine Programme, in denen ich mit Vererbung und Co. rumspiele, eigentlich immer machen, was sie sollen, nur in diesem Fall nicht.

Die Situation: Ich erstelle eine Klasse, die von TList abstammt und die ich mit Objekten einer anderen Klaase fülle. Damit das ganze beim Freigeben der Liste wieder sauber aufgeräumt wird, überschreibe ich das Delete von TList und gebe dann dort das entsprechende Objekt frei (bitte jetzt keine Diskussion, ob eine TObjectList nicht sinnvoller wäre, darum gehts mir gerade nicht, sondern um ein Verständnisproblem :)).

Problem: Obwohl das Destroy von TList ein Clear aufruft und dieses wiederum ein Delete, wird mein Delete nie ausgeführt und entsprechend auch das Objekt nie freigegeben. Noch schlimmer: Es wird noch nicht mal das Clear von TList ausgeführt.

Hier mal ein Beispiel-Code, der bei mir dieses Verhalten zeigt und somit zu einem Speicherleck führt:

Delphi-Quellcode:

program listenleeren;

{$APPTYPE CONSOLE}

uses
  SysUtils, classes;

type
  TSomeElement = class
    randomNumber: integer;
  end;

  TSomeElementList = class(TList)
    procedure Delete (index: integer);
    procedure Fill (amount: integer);
    procedure Write;
  end;


// **********************************************

procedure TSomeElementList.Delete(index:integer);
begin
  TSomeElement(items[index]).Free;

  inherited;
end;

// **********************************************

procedure TSomeElementList.Fill(amount:integer);

var i: integer;
    newElem: TSomeElement;

begin
  for I := 0 to amount - 1 do begin
    newElem:=TSomeElement.Create;
    newElem.randomNumber:=random(1000);
    add(newElem);
  end;
end;

// **********************************************

procedure TsomeElementList.Write;

var i: integer;

begin
  for I := 0 to Count - 1 do
    writeln(TSomeElement(items[i]).randomNumber);
end;

// **********************************************

var SomeList: TSomeElementList;

begin
  randomize;
  RandSeed:=80;

  SomeList:=TSomeElementList.Create;
  SomeList.Fill(30);
  SomeList.Write;
  SomeList.Free;
end.

Irgendwas verstehe ich doch offenbar falsch, oder? Warum wird beim Aufruf von SomeList.Free kein Clear für die Liste durchgeführt?

Hoffe verzweifelt auf Tipps. :)

Bis denn
Bommel

[Muetze1]

Du hast nur ein Problem und darauf begründet sich das ganze Verhalten:

Zitat:

Zitat von Bbommel

..., überschreibe ich das Delete von TList und gebe dann dort das entsprechende Objekt frei

Du hast kein Delete() überschrieben sondern das Original versteckt. Da Delete() in TList nicht virtuell bzw. dynamisch ist, kannst du diese Methode gar nicht überschreiben. Du kannst nur ein neues Delete() einführen und somit das alte verdecken. In TList.Clear wird Delete() von TList aufgerufen und da es nicht virtuell ist, kannst/hast du es nicht überschrieben. Dein Delete() ist ein komplett neues Delete und TList weiss nichts von deiner abgeleiteten Klasse.

Mach es doch wie TObjectList: TList implementiert eine Notify() Methode (virtuell) und dort kommt er mit jedem Item durch, wenn es hinzugefügt, entfernt oder extrahiert wird. Genau dort setzt auch TObjectList an um die Einträge freizugeben.

[Bbommel]

Ah! Alles klar! Klar, jetzt hab ichs kapiert. Kann es zwar gerade nicht testen, aber ich gehe mal davon aus, dass genau das mein Problem löst. Vielen Dank für die Hilfe.

Bis denn
Bommel

[grenzgaenger]

im übrigen, wenn du schon deine eigene objectlist zusammen basteln willst, solltest du darauf achten, dass auch noch die standardfunktionalitäten funktionieren, sonnst bekommste ganz obscure ergebnisse... ;-)

also, beim sortieren, exchange, insert, etc. pp. auch das object mit verschieben...

[Bbommel]

Nabend,

wollen tue ich das gar nicht unbedingt. Ich hatte hier in ein paar älteren Projekten noch aus Unwissendheit TList statt TObjectList und bin jetzt, weil ich etwasmit FastMM rumgespielt habe, über diesen Fehler gestolpert, den ich zunächst nicht verstanden habe.

Wobei: Sortiert wird dort in diesen Projekten bspw. teilweise auch und auch eingefügt. Warum sollte ich bei diesen Operationen aber auch die Objekte verschieben? Die dürfen im Speicher ruhig liegenbleiben wo sie sind und um das Versxchieben der Pointer auf die Objekte kümmert sich ja Delphi selbst. Klappte immer wunderbar.

Oder hab ich dich irgendwie falsch verstanden?

Bis denn
Bommel