Datei bzw. Verzeichnis lässt sich nicht löschen

[wolle72]

Hallo,

ich bin blutiger Anfänger in Delphi und versuche mich mit einem kleinen CMD-Tool.

Ich will alle Dateien im Tempverzeichnis löschen die älter als 3 Tage sind. Das klappt leider nur zur Hälfte. Mein Tool sagt in vielen Fällen "Zugriff verweigert", allerdings hat Windows nach meinem Ermessen nicht die "Finger" drauf. Mit dem Explorer lassen sich diese problemlos löschen, warum dann nicht mit meinem Code ?

Delphi-Quellcode:

//Delete all files/dirs in TempDir which ones are older than x days

program TempCleaner;

{$APPTYPE CONSOLE}

uses Windows,SysUtils;


//Function
Function MyRemoveDir(sDir : String; OlderThanDays : Integer) : Boolean;
var
         iIndex    : Integer;
         SearchRec : TSearchRec;
         sFileName,sErrMess : String;
         dtFileDirDate,dtNow : TDateTime;

begin
         Result := False;
         sDir   := sDir + '\*.*';
         iIndex := FindFirst(sDir, faAnyFile, SearchRec);
         dtNow  := Date;

         while iIndex = 0 do begin
               sFileName := ExtractFileDir(sDir)+'\'+SearchRec.Name;
               dtFileDirDate := FileDateToDateTime(SearchRec.Time);
               if trunc(dtNow - dtFileDirDate) + 1 > OlderThanDays then
               begin
                  if SearchRec.Attr = faDirectory then begin
                      if (SearchRec.Name <> '' )  and
                         (SearchRec.Name <> '.')  and
                         (SearchRec.Name <> '..') then
                          MyRemoveDir(sFileName,OlderThanDays);
                      end else begin
                      //if SearchRec.Attr <> faArchive then
                      //   FileSetAttr(sFileName, faArchive);
                      if NOT DeleteFile(sFileName) then
                        sErrMess := SysErrorMessage(GetLastError);
                        writeln('Could NOT delete ' + sFileName + ' Error: ' + sErrMess);
                  end;
               end;
               iIndex := FindNext(SearchRec);
         end;

         FindClose(SearchRec);

         RemoveDir(ExtractFileDir(sDir));
         Result := True;
end;



//Mainproggi

var
    temp_dir : string;

begin
   temp_dir := SysUtils.GetEnvironmentVariable('temp');
   //writeln(temp_dir);
   //MyRemoveDir('D:\Temp\test\test', 3);
   MyRemoveDir(temp_dir, 3);
end.

Kann mir dabei jemand helfen ?

Wolle

[taaktaak]

Moin, Moin Wolle,
ohne auf die Frage direkt zu antworten: Wenn du gezielt Dateien aus einem dir bekannten Verzeichnis löschen willst und dessen Namen auch an deine Rouine übergibts - wozu erfolgt dann innerhalb dieser Prozedur eine rekursiver Aufruf derselben????
Gruß Ralph

[wolle72]

Zitat:

Zitat von taaktaak

ohne auf die Frage direkt zu antworten: Wenn du gezielt Dateien aus einem dir bekannten Verzeichnis löschen willst und dessen Namen auch an deine Rouine übergibts - wozu erfolgt dann innerhalb dieser Prozedur eine rekursiver Aufruf derselben????

Hallo Ralph,
Das ganze soll rekursiv alles in dem befindlichen Verzeichnis inklusive allen Unterverzeichnissen löschen.
Viele Grüsse
Wolle

[taaktaak]

Moin Wolle,
da habe ich "zu kurz" gedacht - bringt dich aber natürlich auch nicht weiter, sorry. Gibt es denn irgendwelche "Regelmäßigkeiten" oder "Merkmale" welche Dateien sich nicht löschen lassen?
Gruß Ralph

[Nuclear-Ping]

Delphi-Quellcode:

                  if SearchRec.Attr = faDirectory then begin
                      if (SearchRec.Name <> '' )  and
                         (SearchRec.Name <> '.')  and
                         (SearchRec.Name <> '..') then
                          MyRemoveDir(sFileName,OlderThanDays);
                      end else begin
                      //if SearchRec.Attr <> faArchive then
                      //   FileSetAttr(sFileName, faArchive);
                      if NOT DeleteFile(sFileName) then
                        sErrMess := SysErrorMessage(GetLastError);
                        writeln('Could NOT delete ' + sFileName + ' Error: ' + sErrMess);
                  end;

Delphi-Quellcode:

                      if NOT DeleteFile(sFileName) then
                        sErrMess := SysErrorMessage(GetLastError);
                        writeln('Could NOT delete ' + sFileName + ' Error: ' + sErrMess);

Wer hier den Fehler findet, darf ihn korrigieren.

[Tom]

Zitat:

Zitat von Nuclear-Ping

Delphi-Quellcode:

                      if NOT DeleteFile(sFileName) then
                        sErrMess := SysErrorMessage(GetLastError);
                        writeln('Could NOT delete ' + sFileName + ' Error: ' + sErrMess);

Wer hier den Fehler findet, darf ihn korrigieren.

Es fehlt wohl ein begin und ein end ...

[Nuclear-Ping]

Yo, und deswegen ...

Zitat:

Zitat von wolle72

[...] Mein Tool sagt in vielen Fällen "Zugriff verweigert", [...]

[wolle72]

Danke soweit mal für den Tipp. :-D Das scheint auf alle Fälle logisch zu klingen. Sieht bis dato aber so aus, wie wenn da einiges ned ganz mit dem begin...end stimmt. Momentan bekomme ich es leider nicht mal mehr fehlerfrei kompiliert - hab wohl an der falschen Schraube gedreht. :(

[wolle72]

So ich denke jetzt müsste es passen. Allerdings bekomme ich immer noch die selbe Fehlermeldung. Hier der aktuelle Code.

Delphi-Quellcode:

//Delete all files/dirs in TempDir which ones are older than x days

program TempCleaner;

{$APPTYPE CONSOLE}

uses Windows,SysUtils;


//Function
Function MyRemoveDir(TargetDir : String; OlderThanDays : Integer) : Boolean;
var
         iIndex    : Integer;
         SearchRec : TSearchRec;
         FoundName,ErrMess : String;
         DateFileDirDate,DateNow : TDateTime;

begin
         Result := False;
         TargetDir := TargetDir + '\*.*';
         iIndex := FindFirst(TargetDir, faAnyFile, SearchRec);
         DateNow := Date;

         while iIndex = 0 do
         begin
           FoundName := ExtractFileDir(TargetDir)+'\'+SearchRec.Name;
           DateFileDirDate := FileDateToDateTime(SearchRec.Time);
           if trunc(DateNow - DateFileDirDate) + 1 > OlderThanDays then
           begin
             if SearchRec.Attr = faDirectory then
             begin
               if (SearchRec.Name <> '' ) and (SearchRec.Name <> '.') and (SearchRec.Name <> '..') then
               begin
                 MyRemoveDir(FoundName,OlderThanDays);
               end;
             end else
             begin
               if NOT DeleteFile(FoundName) then
               begin
                 ErrMess := SysErrorMessage(GetLastError);
                 writeln('Could NOT delete ' + FoundName + ' Error: ' + ErrMess);
               end;
             end;
           end;
         iIndex := FindNext(SearchRec);
         end;
         FindClose(SearchRec);
         RemoveDir(ExtractFileDir(TargetDir));
         Result := True;
end;


//Mainproggi
var
    temp_dir : string;

begin
   temp_dir := SysUtils.GetEnvironmentVariable('temp');
   //writeln(temp_dir);
   //MyRemoveDir('D:\Temp\test\test', 1);
   MyRemoveDir(temp_dir, 3);
end.

Habe ich doch noch was vergessen ?

[DeddyH]

Schlecht:

Delphi-Quellcode:

if SearchRec.Attr = faDirectory then

Besser:

Delphi-Quellcode:

if (SearchRec.Attr and faDirectory) = faDirectory then