Überschreiben einer Prozedur

[MTornau]

Moin zusammen !

Ich habe folgendes angestellt:

Ich habe ein TStringGrid erstellt und initialisiert.
Zur Laufzeit füttere ich jetzt dieses Grid mit Daten, also z.b.
Spalte,Zeile=0,1 steht eine Zahl
Spalte,Zeile=1,1 steht ein String,
usw. ...
Das wiederholt sich für ca. 30 Zeilen. Ich habe also eine Durchnummerierung von 1 bis 30 und dahinter in der Spalte steht jedesmal ein String.

Zusätzlich wird jetzt bei einem Klick auf ein bestimmtes TEdit ein PopUpMenü geladen, daß die Namen aus dem TStringGrid 1,1 als Menüitems enthält. Gleichzeitig erhält jedes Menüitem-Tag den fortlaufenden Zahlenwert aus 0,1.

Was ich jetzt erreichen möchte ist folgendes:
Bei einem Klick auf die zur Laufzeit generierten PopUpMenüeinträge soll jetzt der zur vorher gesetzte Zahlenwert im Tag in das TEdit Eingabefeld übernommen werden.

Dazu habe ich folgendes gemacht:
Zuerst erstelle ich meine eigene Klasse (Grid, etc ist alles fertig und mit Testdaten gefüttert)

type
TMyMenuItem = class (TMenuItem)
public
procedure Click(); override;
end;

procedure TMyMenuItem.Click ();
begin
//So, Aufruf durch Klick auf Menüitem, jetzt den dazugehörigen Tag an das TEDit Eingabe übergeben
// ..... aber Wie ?
end;

procedure TBedienfeld.Edit_Soll_IndexClick(Sender: TObject);
var i:byte;
var AItem : TMyMenuItem;
begin
// Vorherigen belegten Speicher wieder freigeben
Main.PopUp_Tabelle.Items.Clear;

for i:=1 to Main.Grid_Tab.RowCount-1 do
begin
AItem := TMyMenuItem.Create(self);
AItem.Caption := Main.Grid_Tab.cells[0,i] + ' - ' + Main.Grid_Tab.cells[1,i];
AItem.Tag := i;
Main.PopUp_Tab.Items.Add(AItem);
end;

//Positionieren
// ... weggelassen ...
end;


Es scheitert momentan daran, daß ich nicht weiss, wie ich jetzt an die Tags komme ... Definiere ich die Prozedur mit VIRTUAL, so kommt eine Fehlermeldung vom Typ: "Methode "Click" verbirgt virtuelle Methode vom Basistyp, also wird die Prozedur zur Laufzeit nicht aufgerufen.

Hast recht. Das AItem gehört da nicht hin ...

[s-off]

Hallo,

lese mir das jetzt net alles durch (benutze Formatierungen, also hier Delphi-Tags für Deinen Code), aber auf Basis des Titels und des Schlusssatzes kann ich Dir folgendes sagen:

Du kannst Methoden, die als 'virtual' deklariert sind in einer Ableitung mit 'override' überschreiben.

Vielleicht passt das ja zu Deinem Problem.

=======================

Edit:
Ok, habe es mir jetzt mal angeschaut:
Das Problem fängt bereits damit an, dass Deine Implementierung der Prozedur 'Click' anders ist, als sie deklariert wurde (AItem gibt es da nicht!).
Greife auf das Item mit 'Self' zu.

Hier ein Beispiel:

Delphi-Quellcode:

Unit Unit1;

Interface

Uses
   Windows,
   Messages,
   SysUtils,
   Variants,
   Classes,
   Graphics,
   Controls,
   Forms,
   Dialogs,
   Menus,
   StdCtrls;

Type
   TMyMenuItem = Class(TMenuItem)
      Procedure Click; override;
   End;

   TForm1 = Class(TForm)
      Button1: TButton;
      PopupMenu1: TPopupMenu;
      Edit1: TEdit;
      Procedure Button1Click(Sender: TObject);
   private
      { Private-Deklarationen }
   public
      { Public-Deklarationen }
   End;

Var
   Form1: TForm1;

Implementation

{$R *.dfm}

Procedure TForm1.Button1Click(Sender: TObject);
Var
   MI: TMyMenuItem;
Begin
   MI := TMyMenuItem.Create(self);
   MI.Tag := 99;
   MI.Caption := 'Testcaption';
   PopupMenu1.Items.Add(MI);
End;

{ TMyMenuItem }

Procedure TMyMenuItem.Click;
Begin
   Inherited;
   Form1.Edit1.Text := IntToStr(Self.Tag);
End;

End.

Und denke nächstes Mal bitte an die Delphi-Tags ;)

[MTornau]

Die Lösung des Problems war doch einfacher als gedacht. Der Hinweis von dir war wunderbar:

Form1.Edit1.Text := IntToStr(Self.Tag);

Danke !! :-D