OnCreate wird nur einmal nach Programmstart ausgeführt

[Svenkan]

Ich hab ein ziemlich großes Problem!
Nachdem ich die versch. 'Forms' aus meinem Menü nicht mehr über eine definierte Funktion, sondern .ShowModal aufrufe, wird auch jeweilige FormCreate nur beim ersten Aufrufen ausgeführt.
Das komische ist auch: wenn ich etwas geändert hab, wird dies nicht verworfen, sondern ist beim nächsten Aufruf immer noch genauso erhalten.
Wie kann ich das verhindern bzw. es wieder vernünftig ans Laufen bringen?

[mkinzler]

Die Formulare werden auch nicht freigegeben sonder nur ausgeblendet.

[Christian Seehase]

Moin Svenkan,

also so ganz schlau werde ich aus Deinem Posting nicht.
Wenn Du die Formulare in der Projektdatei erzeugen lässt, wird OnCreate natürlich nur einmal aufgerufen, ansonsten müsstest Du die Formulare dynamisch erzeugen.
Bei den zu Programmstart erzeugten Formularen bewirkt ein Close lediglich ein visible := false

Wenn die Formulare immer wieder gleich aussehen sollen, könntest Du sie im OnShow entsprechend initialisieren.

[Svenkan]

Vorher habe ich das ganze über eine Prozedur geöffnet:

Delphi-Quellcode:

procedure ShowGeneralSettings;
begin
  with TGrundeinstellungen.Create(Application) do
  try
    ShowModal;
  finally
    Free;
  end;
end;

Also müsste ich das Ganze dementsprechend auch irgendwie wieder freigeben können.
Mit .Free oder FreeAndNil meckert der Compiler aber rum und ich bekomm nen Zugriffsfehler.

[Christian Seehase]

Moin Svenkan,

Zitat:

Zitat von Svenkan

Vorher habe ich das ganze über eine Prozedur geöffnet:

Delphi-Quellcode:

procedure ShowGeneralSettings;
begin
  with TGrundeinstellungen.Create(Application) do
  try
    ShowModal;
  finally
    Free;
  end;
end;

Also müsste ich das Ganze dementsprechend auch irgendwie wieder freigeben können.
Mit .Free oder FreeAndNil meckert der Compiler aber rum und ich bekomm nen Zugriffsfehler.

Wenn Du uns zeigst, wie Du es bisher gemacht hast, und nicht, wie jetzt, wird es aber etwas schwierig einen Fehler zu finden ;-)
Ausserdem könnte es auch hilfreich sein zu erfahren, was der Compiler anmeckert.

[Svenkan]

Öffnen:

Delphi-Quellcode:

procedure THauptform.Grundeinstellungen1Click(Sender: TObject);
begin
  Grundeinstellungen.ShowModal;  // Fenster grundeinstellungen öffnen 
  IF Grundeinstellungen.ModalResult = mrOK then
    Datenneuladen1.OnClick(Datenneuladen1);
end;

Im OnClose:

Delphi-Quellcode:

FreeAndNil(Grundeinstellungen);

Fehlermeldung beim Schließen der Form siehe Anhang.

[Christian Seehase]

Moin Svenkan,

wird das Formular irgendwo dynamisch erzeugt?
Wenn nicht sollte es auch nicht freigegeben werden, wenn ja:
Das OnClose-Ereignis hat den Parameter Action. Um das Formular im OnClose freizugeben, müsstest Du den dort auf caFree setzen.

[Svenkan]

Also ich hab nix an der Erstellung geändert.
Dementsprechend werden die wohl alle autom. beim Programmstart erzeugt.

[semo]

ich würde das automatische erstellen der forms aus dem projekt herausnehmen und
dann in deinem onclick event des hauptforms
folgendes machen:

Delphi-Quellcode:

  with TGrundeinstellungen.Create(Self) do
  try
    ShowModal;
  finally
    Free;
  end;

wüsste nicht wo da das problem liegen soll.

[SirThornberry]

im OnClose das ganze frei zu geben knallt natürlich. Das OnClose wird vom Formular selbst ausgelöst. Du musst dir das ungefähr so vorstellen
· rufe OnClose auf wenn Procedure zugewiesen ist
· Du machst irgendwas im OnClose (im schlimmsten Fall frei geben
· prüfen ob im OnClose das Action geändert wurde und dann das Formular verstecken, frei geben, nichts machen etc. => ups, jetzt knallt es weil du das Formular während der Abarbeitung aus dem Speicher geschmissen hast

Wenn du im OnClose frei geben willst setzte "Action" auf caFree aber gebe nicht selbst das Formular frei während es mit der Abarbeitung von Events (OnClose) etc. beschäftigt ist.

Zu deiner Frage im Allgemeinen:
- "OnCreate" heißt in etwa "beim Kreieren/Erstellen"
- "OnClose" heißt "beim Schließen"
- "OnDestroy" heißt "beim zerstören/freigeben"
- "OnShow" heißt "beim anzeigen"
dementsprechend ist auch klar das OnCreate nur einmal (beim kreieren) augelöst wird und nicht beim anzeigen was ja ein Show wäre.

[Svenkan]

Wie bekomm ich denn nu folgende Anweisung richtig hin?:

Delphi-Quellcode:

 with TGrundeinstellungen.Create(Self) do 
  try 
    ShowModal;
  
  if Grundeinstellungen.ModalResult = mrOK then
    Datenneuladen1.OnClick(Datenneuladen1);

  finally 
    Free; 
  end;

Er gibt mir bei der if-Anweisung einen Zugriffsverletzung aus. Also direkt nachm Close der Form.

[SirThornberry]

ist auch klar, du rufst zwar

Delphi-Quellcode:

TGrundeinstellungen.Create(Self)

auf, weißt dies aber nirgendwo der Variablen "Grundeinstellungen" zu. Um es dir zu verdeutlichen:

Delphi-Quellcode:

with TGrundeinstellungen.Create(Self) do 
  try 
    ShowModal; 
  
  if EtwasNichtErzeugtesBzwEineVariableDerNichtsZugewiesenWurde.ModalResult = mrOk then
    Datenneuladen1.OnClick(Datenneuladen1); 

  finally 
    Free; 
  end;

wenn dann

Delphi-Quellcode:

with TGrundeinstellungen.Create(Self) do 
  try 
    ShowModal; 
  
  if ModalResult = mrOK then 
    Datenneuladen1.OnClick(Datenneuladen1); 

  finally 
    Free; 
  end;

oder

Delphi-Quellcode:

with TGrundeinstellungen.Create(Self) do 
  try 
    if ShowModal = mrOk then
      Datenneuladen1.OnClick(Datenneuladen1); 

  finally 
    Free; 
  end;

oder

Delphi-Quellcode:

var
  lFormInstance: TGrundeinstellungen;
begin
  lFormInstance := TGrundeinstellungen.Create(Self); 
  try 
    lFormInstance.ShowModal; 
  
    if lFormInstance.ModalResult = mrOK then 
      Datenneuladen1.OnClick(Datenneuladen1);  

  finally 
    lFormInstance.Free; 
  end;

[Svenkan]

Argh!
Nicht denken, sondern nachdenken. :duck:
Dankeschön. Funktioniert jetzt natürlich perfekt. :)