Timer Problem

[Darksniper]

Hi

Ich bin gerade dabei einen timer zu bauen
http://img35.picoodle.com/img/img35/...em_f881e6f.png

Label5 dient nur zum speichern der sekunden und ist unsichtbar
bei Timer1 steht Enable auf false und Intervall auf 1000
Button3 ist nicht anwählbar
und das hier ist der wichtige Teil des code

Delphi-Quellcode:

procedure TForm3.Button1Click(Sender: TObject);
var H,M,S,SZ:Integer;
begin
H:= 60*60*StrtoInt(Edit1.Text);  
M:= 60*StrtoInt(Edit2.Text);    
S:= StrtoInt(Edit3.Text);       
SZ:=H+M+S;                       
Label5.Caption:=IntToStr(SZ);    
Timer1.Enabled := true;          
Button1.Enabled:=false;          
Button3.Enabled:=true;           
end;

procedure TForm3.Timer1Timer(Sender: TObject);
var sekunden,minuten,Stunden :Real;
    S1,EM,ES,EH,H,M,S: Integer;
begin                                         
S:=StrtoInt(Label5.caption)-1;  //hier kommt das 
Label5.caption:=InttoStr(S1);   //wo ich mir nicht ganz
S1:=StrtoInt(Label5.caption);   //sicher bin ob das geht
Stunden:=(S1)/60/60;
minuten:=(stunden-Trunc(stunden))*60;
sekunden:=(minuten-Trunc(minuten))*60;
EH:=trunc(Stunden);
EM:=Trunc(MInuten);
ES:=Trunc(Sekunden);
Label1.caption:=InttoStr(EH)+':'+InttoStr(EM)+':'+InttoStr(ES);
end;

procedure TForm3.Button3Click(Sender: TObject);
begin
Button1.Enabled:=true;
Button3.Enabled:=false;
Timer1.Enabled:=false;
Label5.Caption:='00:00:00';
Edit1.Text:='00';
Edit2.Text:='00';
Edit3.Text:='00';
end;

procedure TForm3.Button2Click(Sender: TObject);
begin
if Timer1.Enabled=true then
   Timer1.Enabled:=false;
if Timer1.Enabled=false then
   Timer1.Enabled:=true;
end;

mein Problem ist,dass das Label1 immer 0:0:0 anzeigt

[SirThornberry]

könntest du das bild bitte in den Anhang packen :)

Delphi-Quellcode:

S:=StrtoInt(Label5.caption)-1;  //Zeile1 
Label5.caption:=InttoStr(S1);   //Zeile2

Welchen Wert hat denn S1 zu diesem Zeitpunkt in Zeile2? :wink:

[sirius]

Du solltest die Zeit nicht in Label5 speichern sondern in der gesamten Klasse als Variable. Diese Variablen kannst du (auf gleiche Weise wie lokale Variablen) direkt unter den Abschnitt private bei TForm3 schreiben. Und damit brauchst du kein Label5, dein Problem verschwindet (wo ich auch nicht weis, was du machst, ausser das es falsch ist; S1 ist nicht initialisiert und keine Ahnung was du damit willst). du greifst einfach von jeder Methode auf diese Variable zu (das ist ja der Sinn der OOP).

Btw: Es ist günstig, wenn du deinen Komponenten auch schönere Namen gibst als Button1, Button2,... Dasselbe gilt für Variablen.

[angos]

Hi,

hab mal ein paar Kommentare eingefügt.

Zitat:

Zitat von Darksniper

Delphi-Quellcode:

procedure TForm3.Button1Click(Sender: TObject);
var H,M,S,SZ:Integer;
begin
H:= 60*60*StrtoInt(Edit1.Text); // Wann wird Edit1.Text gefüllt??? Setze hier doch mal einen Haltepunkt und schau dir an was passiert
M:= 60*StrtoInt(Edit2.Text); // Wann wird Edit2.Text gefüllt??? 
S:= StrtoInt(Edit3.Text); // Wann wird Edit3.Text gefüllt???     
SZ:=H+M+S;                       
Label5.Caption:=IntToStr(SZ);  // Wenn die Edit´s nicht gefüllt werden, steht Label5 immer auf 0   
Timer1.Enabled := true;          
Button1.Enabled:=false;          
Button3.Enabled:=true;           
end;

procedure TForm3.Timer1Timer(Sender: TObject);
var sekunden,minuten,Stunden :Real;
    S1,EM,ES,EH,H,M,S: Integer;
begin                                         
S:=StrtoInt(Label5.caption)-1;  //hier kommt das 
Label5.caption:=InttoStr(S1);   //wo ich mir nicht ganz
S1:=StrtoInt(Label5.caption);   //sicher bin ob das geht
Stunden:=(S1)/60/60;
minuten:=(stunden-Trunc(stunden))*60;
sekunden:=(minuten-Trunc(minuten))*60;
EH:=trunc(Stunden);
EM:=Trunc(MInuten);
ES:=Trunc(Sekunden);
Label1.caption:=InttoStr(EH)+':'+InttoStr(EM)+':'+InttoStr(ES); 
end;

procedure TForm3.Button3Click(Sender: TObject);
begin
Button1.Enabled:=true;
Button3.Enabled:=false;
Timer1.Enabled:=false;
Label5.Caption:='00:00:00';
Edit1.Text:='00';
Edit2.Text:='00';
Edit3.Text:='00';
end;

procedure TForm3.Button2Click(Sender: TObject);
begin
if Timer1.Enabled=true then
   Timer1.Enabled:=false;
if Timer1.Enabled=false then
   Timer1.Enabled:=true;
end;

Es wäre auch noch schön zu wissen, was überhaupt im Timer passiert ;)
Und was verdammt viel hilft ist eine ordentliche Sourcecodeformatierung -> Styleguide :D

Grüße

[Darksniper]

:wall: :wall: :wall: :wall: :wall: :wall: :wall: :wall:

Delphi-Quellcode:

S:=StrtoInt(Label5.caption)-1; 
Label5.caption:=InttoStr(S1);

=Falsch
:wall: :wall: :wall: :wall: :wall: :wall: :wall: :wall:

Delphi-Quellcode:

S:=StrtoInt(Label5.caption)-1;
Label5.caption:=InttoStr(S);

=Richtig
:wall: :wall: :wall: :wall: :wall: :wall: :wall: :wall:


aber es ist ein neues problem aufgetreten

der timer funktioniert aber das label kommt nicht nach mit dem aktualisieren

[Darksniper]

Zitat:

Zitat von angos

Es wäre auch noch schön zu wissen, was überhaupt im Timer passiert ;)
Und was verdammt viel hilft ist eine ordentliche Sourcecodeformatierung -> Styleguide :D

Grüße

hast du das auch auf deutsch
Englisch ist nicht gerade meine Stärke

[Darksniper]

das problem kann man schlecht erklähren.

für die dies nachbauen wollen.
das Bild habt ihr ja.

der Timer funktioniert
das sieht mann wenn man Label5 sichtbar macht

Delphi-Quellcode:

unit Unit3;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, Borland.Vcl.ExtCtrls, Borland.Vcl.StdCtrls, System.ComponentModel;

type
  TForm3 = class(TForm)
    Edit1: TEdit;
    Edit2: TEdit;
    Edit3: TEdit;
    Label1: TLabel;
    Button1: TButton;
    Button2: TButton;
    Label2: TLabel;
    Label3: TLabel;
    Label4: TLabel;
    Button3: TButton;
    Timer1: TTimer;
    Label5: TLabel;
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form3: TForm3;

implementation

{$R *.nfm}

procedure TForm3.Button1Click(Sender: TObject);
var H,M,S,SZ:Integer;
begin
H:= 60*60*StrtoInt(Edit1.Text);
M:= 60*StrtoInt(Edit2.Text);
S:= StrtoInt(Edit3.Text);
SZ:=H+M+S;
Label5.Caption:=IntToStr(SZ);
Timer1.Enabled := true;
Button1.Enabled:=false;
Button3.Enabled:=true;
end;

procedure TForm3.Timer1Timer(Sender: TObject);
var sekunden,minuten,Stunden :Real;
    S1,EM,ES,EH,H,M,S: Integer;
begin
S:=StrtoInt(Label5.caption)-1;
Label5.caption:=InttoStr(S);
S1:=StrtoInt(Label5.caption);
Stunden:=(S1)/60/60;
minuten:=(stunden-Trunc(stunden))*60;
sekunden:=(minuten-Trunc(minuten))*60;
EH:=trunc(Stunden);
EM:=Trunc(MInuten);
ES:=Trunc(Sekunden);
Label1.caption:=InttoStr(EH)+':'+InttoStr(EM)+':'+InttoStr(ES);
end;

procedure TForm3.Button3Click(Sender: TObject);
begin
Button1.Enabled:=true;
Button3.Enabled:=false;
Timer1.Enabled:=false;
Label5.Caption:='00:00:00';
Edit1.Text:='00';
Edit2.Text:='00';
Edit3.Text:='00';
end;

procedure TForm3.Button2Click(Sender: TObject);
begin
if Timer1.Enabled=true then
   Timer1.Enabled:=false;
if Timer1.Enabled=false then
   Timer1.Enabled:=true;
end;

end.

[Klaus01]

Delphi-Quellcode:

procedure TForm3.Timer1Timer(Sender: TObject); 
var sekunden,minuten,Stunden :Real; 
    S1,EM,ES,EH,H,M,S: Integer; 
begin 
  S:=StrtoInt(Label5.caption)-1; 
  Label5.caption:=InttoStr(S); 
  S1:=StrtoInt(Label5.caption); 
  Stunden:=(S1)/60/60; 
  minuten:=(stunden-Trunc(stunden))*60; 
  sekunden:=(minuten-Trunc(minuten))*60; 
  EH:=trunc(Stunden); 
  EM:=Trunc(MInuten); 
  ES:=Trunc(Sekunden); 
  Label1.caption:=InttoStr(EH)+':'+InttoStr(EM)+':'+InttoStr(ES); 
  Label1.repaint;
end;

Ein Label1.repaint hilft auch nicht?

Grüße
Klaus

[Darksniper]

nein
hilft leider nicht

wenn ich repaint einbaue hängt label5 sogar noch stärker als label1

[sirius]

Alle Zeilen in denen ich was verändert habe sind auskommentiert, bzw. es ist so ein Pfeil dran, wenn ich etwas eingefügt habe.
Label5 kannst du rausschmeissen.

Delphi-Quellcode:

procedure TForm3.Button1Click(Sender: TObject);
var H,M,S{,SZ}:Integer;
begin
  H:= 60*60*StrtoInt(Edit1.Text);
  M:= 60*StrtoInt(Edit2.Text);
  S:= StrtoInt(Edit3.Text);
  SZ:=H+M+S;
  {Label5.Caption:=IntToStr(SZ);}
  Timer1.Enabled := true;
  Button1.Enabled:=false;
  Button3.Enabled:=true;
end;

procedure TForm3.Timer1Timer(Sender: TObject);
var sekunden,minuten,Stunden :Real;
    {S1,}EM,ES,EH,H,M{,S}: Integer;
begin
  {S:=StrtoInt(Label5.caption)-1;
  Label5.caption:=InttoStr(S1);
  S1:=StrtoInt(Label5.caption);   }

  //hier sollte noch ne Abfrage rein, wenn SZ=0 dann Ende

  dec(SZ); //<-----
  Stunden:=({S1}SZ)/60/60;
  minuten:=(stunden-Trunc(stunden))*60;
  sekunden:=(minuten-Trunc(minuten))*60;
  EH:=trunc(Stunden);
  EM:=Trunc(MInuten);
  ES:=Trunc(Sekunden);
  //Label1.caption:=InttoStr(EH)+':'+InttoStr(EM)+':'+InttoStr(ES); //nicht falsch
  label1.Caption:=format('%2d:%2d:%2d',[EH,EM,ES]);  //aber so gefällts mir besser
end;

procedure TForm3.Button3Click(Sender: TObject);
begin
  Button1.Enabled:=true;
  Button3.Enabled:=false;
  Timer1.Enabled:=false;
  //Label5.Caption:='00:00:00';
  Edit1.Text:='00';
  Edit2.Text:='00';
  Edit3.Text:='00';
end;

procedure TForm3.Button2Click(Sender: TObject);
begin
{if Timer1.Enabled=true then
   Timer1.Enabled:=false;
if Timer1.Enabled=false then
   Timer1.Enabled:=true;}
  timer1.Enabled:=not timer1.Enabled;
end;

Edit: Naja, ich sollte auch den Teil mitliefern, da habe ich auch eine Zeile eingefügt:

Delphi-Quellcode:

type
  TForm3 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Edit1: TEdit;
    Edit2: TEdit;
    Edit3: TEdit;
    Button3: TButton;
    Label1: TLabel;
    Timer1: TTimer;
    procedure Timer1Timer(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
  private
    { Private-Deklarationen }
    SZ:integer;     ///<-----
  public
    { Public-Deklarationen }
  end;

[Darksniper]

danke für die mühe

aber das problem besteht weiterhin

wenn ich zb 1Min eingebe dann zählt das Label so runter

00:00:58
00:00:56
00:00:54
00:00:52
...
...
...
..
.

[Darksniper]

:?: Weis denn hier keiner eine Lösung für dieses Problem? :?:

[sirius]

Zitat:

Zitat von Darksniper

der timer funktioniert aber das label kommt nicht nach mit dem aktualisieren

Eine exakte Fehlerbeschreibung ist alles!

Es ist nicht das Label, was nicht nachkommt, sondern dein algo ist falsch. Darauf kommt man in dem man bemerkt, dass nicht jede zweite Zahl ausgelassen wird (oder eine willkürliche), sondern immer wieder dieselben.

Delphi-Quellcode:

procedure TForm3.Timer1Timer(Sender: TObject);
var
    EM,ES,EH: Integer;
begin

  if SZ=0 then //diese Abfrage noch als Ergänzung
    Button3click(self)
  else
  begin
    dec(SZ);
    EH:=SZ div 3600;
    EM:=(SZ div 60) mod 60;
    ES:=SZ mod 60;
    label1.Caption:=format('%2d:%2d:%2d',[EH,EM,ES]);
  end;
end;

[scrat1979]

Habe mir erst vor ein paar Tagen auch einen Countdown gebastelt. WEnn ich nachher Zeit habe werde ich mein Source mal posten. Falls ich es vergesse -> PN schicken.

SCRaT

[scrat1979]

Danke für Deine Erinnerungs-Mail. Habe Dir gerade mal einen Mini-Countdown gebastelt. Das Prinzip ist folgendes:

• Man hat 3 Edit-Felder für STunden, Minuten und Sekunden.
• Beim Klick auf Start wird der aktuelle Zeitstempel in Form eines TDateTimes eingelesen
• Über IncHour, IncMinute und IncSecond wird der Zeitstempel des Countdown-Endes berechnet
• Im OnTimer-Ereignis wird der jeweils aktuelle Zeitstempel mit dem "Endzeitstempel" verglichen
  und die ausstehenden Stunden, Minuten und Sekunden in einem Label ausgegeben

Hier mal mein kompletter Source-Code. Ach so, nicht vergessen, die Unit "DateUtils" einzubinden!!!!

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, DateUtils, StdCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    Edit_STunden: TEdit;
    Edit_Minuten: TEdit;
    Edit_Sekunden: TEdit;
    Label1: TLabel;
    Label2: TLabel;
    Button1: TButton;
    Label_CountDown: TLabel;
    Timer: TTimer;
    Button2: TButton;
    procedure Button2Click(Sender: TObject);
    procedure TimerTimer(Sender: TObject);
    procedure Button1Click(Sender: TObject);
  private
    { Private-Deklarationen }
    DateTimeEnd : TDateTime;
    procedure UpdateCountDown;
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Button1Click(Sender: TObject);
var DateTimeNow : TDateTime;
begin
  // Aktueller Zeitstempel
  DateTimeNow := now;

  { Zu aktuellem Zeitstempel Stunden, Minuten und Sekunden
    dazuzählen um Zeitstempel des Countdownendes zu ermitteln }
  DateTimeEnd := inchour(DateTimeNow, strtoint(edit_stunden.Text));
  DateTimeEnd := incminute(DateTimeEnd, strtoint(edit_minuten.Text));
  DateTimeEnd := incsecond(DateTimeEnd, strtoint(edit_sekunden.Text));

  { Timer starten... }
  Timer.Enabled := True;
end;

procedure TForm1.Button2Click(Sender: TObject);
begin
  Label_Countdown.Caption := 'Inaktiv';
  Timer.Enabled := False;
end;

procedure TForm1.TimerTimer(Sender: TObject);
begin
  // Falls aktueller Zeitstempel >= Ende dann Timer beenden
  if now >= DateTimeEnd then Begin;
    { hier können dann Aktionen ausgeführt werden... }
    timer.Enabled := False;
    Showmessage('Countdown beendet!');
  end Else
  { Countdown aktualisieren }
  UpdateCountDown
end;

procedure Tform1.UpdateCountDown;
var h, m, s      : integer;
    hs, ms, ss   : String;
    DateTimeTemp : TDateTime;
begin
  { Aktueller Zeitstempel }
  DateTimeTemp := Now;

  { Zeitspanne ausrechnen }
  { Stunden }
  h  := HoursBetween(DateTimeTemp, DateTimeEnd);
  hs := InttoStr(h);
  if Length(hs) = 1 then hs := '0' + hs;
  DateTimeTemp := IncHour(DateTimeTemp, h);

  { Minuten }
  m  := MinutesBetween(DateTimeTemp, DateTimeEnd);
  ms := InttoStr(m);
  if Length(ms) = 1 then ms := '0' + ms;
  DateTimeTemp := IncMinute(DateTimeTemp, m);

  { Sekunden }
  s  := SecondsBetween(DateTimeTemp, DateTimeEnd);
  ss := InttoStr(s);
  if Length(ss) = 1 then ss := '0' + ss;

  { Label ausgeben }
  LabeL_CountDown.Caption := Format('%s:%s:%s', [hs, ms, ss]);
end;

end.

- getest und funktioniert!

Grüße,
SCRAT