Nur zahlen im string

[Gehstock]

Delphi-Quellcode:

l := ListView1.Items.Add; 
  l.Caption := 'Eigene Nummer';
  l.SubItems.Add(ReadNumber);
  Edit7.Text:=ReadNumber;

Delphi-Quellcode:

function ReadNumber:String;
begin
  s:= 'AT+CPBS=ON';
  Form1.SendCMD;
  Memo1.Lines.clear;
  s:= 'AT+CPBR=1';
  SendCMD;
  Memo1.Lines.Add(sReadData);
  result:=memo1.Lines[1];
  delete(result,1,10);
  delete(result,12,16);
end;

das sich die ausgelesenen daten(telefonnummern) in der länge unterscheiden soll sichergestellt werden das nur Zahlen eingetragen werden

edit habs mal so versucht geht aber net

Delphi-Quellcode:

function ReadNumber:String;
var
z:Integer;
s:string;
begin
  s:= 'AT+CPBS=ON';
  SendCMD;
  Memo1.Lines.clear;
  s:= 'AT+CPBR=1';
  SendCMD;
  Memo1.Lines.Add(sReadData);
  result:=memo1.Lines[1];
  delete(result,1,10);
  while z = ['0'..'9'] do
  s:= s+result[z]
  result:=s;
  end;

[bttb930]

und wo ist da jetzt eine frage? oder einfach nur mal so was posten?

um ehrlich zu sein: hab lange nicht mehr sowas wirres gelesen...

[Gehstock]

Hehe danke nee ich weiß ein paar stellen kann man besser machen

aber im result von funktion ReadNumber ist geplant das nur telefonnummern ala 0172344565563 drinstehen wenn sie kürzer sind sieht das result so aus 017254545&§ das soll vermieden werden

[TBx]

Dennoch wird mir Deine Frage irgendwie immer noch nicht klar.
Was Du da in Deinem Code machst ist nicht so ganz durchschaubar.

Was brauchst Du nun?

• Eine Funktion, die überprüft, ob ein String nur aus den Ziffern 0..9 besteht?
• eine Möglichkeit, zu verhindern, dass unerwünschte Zeichen in ein Editfeld eingegeben werden können?
• Oder womöglich was ganz anderes?

Versuch uns da doch bitte mal zu erhellen, denn im Gegensatz zu einigen anderen habe ich keine Glaskugel, die gerade in Reparatur sein könnte ;-)

Gruß

Thomas

[Edit]Dreckfuhler[/Edit]

[Gehstock]

Die Funktion ReadNumber soll nur Zahlen an den ListView übergeben
also am ehestens Auswahl 2. deines Postings nur das es ein String ist und kein TEdit.text

[TBx]

Willst Du nur alle Numerischen Anteile des Strings zurückbekommen, oder soll die Annahme des Strings einfach verweigert werden, wenn da was anderes als Ziffern drin gefunden wird?

Für den ersten Fall kannst DU sowas machen:

Delphi-Quellcode:

function CopyNumericOnly(s: string): string;
var
  i, l : integer;
begin
  Result := '';
  i := 1;
  l := Length (s) + 1;
  while i < l do
  begin
    if pos (s [i], '0123456789') > 0 then
    begin
      Result := Result + S [i];
    end;
    inc (i);
  end;
end;

Für den zweiten Fall sowas:

Delphi-Quellcode:

function IsNumeric(s: string): Boolean;
var
  i : integer;
begin
  Result := True;
  i := Length (s);
  while (Result and (i > 0)) do
  begin
    Result := (pos (copy (s, i, 1), '0123456789') > 0);
    dec (i);
  end;
end;

quick and dirty, sollte aber funktionieren

Hope it helps

Thomas

[Luckie]

Na dann debug deine while-Schlife doch einfach mal und guck, was er macht, wenn keine Ziffer in z steht.

@onlinekater: Stringoperationen sind immer sehr langsam. Besser:

Delphi-Quellcode:

function ExtractNumbers(s: String): String;
var
  i: Integer;
begin
  for i := 1 to length(s) do
  begin
    if s[i] in ['0'..'9'] then
      result := Result + s[i];
  end;
end;

const
  FOOBAR = 'hgt546zu3426dh4536';

begin
  Writeln(ExtractNumbers(FOOBAR));
  Readln;
end.

[marabu]

Hallo Michael,

du solltest Result zuerst initialisieren.

Hier noch eine Alternative:

Delphi-Quellcode:

function ExtractDigits(s: string): string;
var
  i, iLength: Integer;
begin
  iLength := 0;
  for i := 1 to Length(s) do
  begin
    if s[i] in ['0'..'9'] then
    begin
      Inc(iLength);
      if iLength <> i then
        s[iLength] := s[i];
    end;
  end;
  Result := Copy(s, 1, iLength);
end;

Freundliche Grüße

[angos]

Hi marabu,

hätte zu dem Thema auch noch eine kurze Frage: Gibt es einen Grund deinen Code dem von Luckie vorzuziehen? Ist das Konstrukt schneller oder hat es nur mehr Code :D? Sorry für die Fragerei, aber hatte das bisher auch immer auf die Weise wie Luckie gemacht und will nicht unbedingt zuviel code haben ;)

[alzaimar]

Der Code von Luckie hängt jede Ziffer an das Resultat an. Das kostet Zeit, zumal bei der Konkaterierung der alte String freigegeben und neuer Speicher angefordert wird.

Der Code von marabu führt nur eine Speicheralloziierung durch, nämlich am Ende. Falls der String nur aus Ziffern besteht, passiert (so gut wie) nichts in seinem Code.

Unterm Strich ist marabus Code dem von Luckie vorzuziehen.

[marabu]

Hallo Ansgar,

ExtractDigits() läuft mit FOOBAR etwas mehr als sieben mal so schnell wie ExtractNumbers(). Ich habe den Code aber bewusst als Alternative und nicht als Verbesserung bereit gestellt.

Freundliche Grüße

[angos]

Hallo Achim,
Hallo alzaimar,


vielen Dank für die Erklärungen. Leuchtet mir ein. Für mich ist dieser Code als Verbesserung zu sehen, da ich aus Erfahrung sagen kann, das die Geschwindkeit eines Programmes sehr häufig ein KO - Kriterium für mögliche Kunden ist. Somit sind optimierte Routinen für mich Gold wert. Also besten dank für den Code, er wird Verwendung finden ;)


[Edit]: Ich möchte euch dann auch meinen erweiterten Vorschlag nicht vorenthalten ;). So ist die Funktion recht allgmein:

Delphi-Quellcode:

type
  TCharSet = set of Char;

//------------------------------------------------------------------------------
// RemoveChars
// Wenn KeepCharSet = False, werden die in CharSet übergebenen Zeichen aus
// dem String s entfernt, ansonsten werden alle anderen Zeichen entfernt
//------------------------------------------------------------------------------
function RemoveChars(s: String; CharSet: TCharSet;
  KeepCharSet: Boolean): String;
var
  i, iLength: Integer;
  bAddChar: Boolean;
begin
  iLength := 0;
  for i := 1 to Length(s) do
  begin
    if (((KeepCharSet) and (s[i] in CharSet))
      or ((KeepCharSet = False) and not (s[i] in CharSet))) then      
    begin
      Inc(iLength);
      if iLength <> i then
        s[iLength] := s[i];
    end;
  end;

  Result := Copy(s, 1, iLength);
end;                                                              // RemoveChars


// Für das hier benötigte Ergebnis die Funktion folgendermassen aufrufen:
Edit1.Text := RemoveChars(Edit1.Text, ['0'..'9'], True);

Grüße

[Billa]

Hmm...sehr schön, nur eine kleine ästhetische Anmerkung vielleicht:

Die Funktion heißt "RemoveChars", der zweite Parameter enthält aber die zu erhaltenen Zeichen.
Auf den ersten Blick sieht der Aufruf so aus, als sollten die Zeichen 0..9 entfernt werden.
Ich fände "KeepChars" intuitiver....

[angos]

Hallo Billa,

ich kann je nachdem ob KeepChrSet True oder False ist bestimmen, ob die Chars entfernt werden, oder weiterhin bestehen bleiben. Da die Funktion aber in 99% der Fälle aus dem String Zeichen entfernt (welche auch immer) habe ich mich für diesen Namen entschieden ;)


Gruß

[Billa]

Habe ich durchaus verstanden. Aber würde ich diesen Aufruf in einem Quelltext lesen, den ich nicht kenne, wäre mein erster Gedanke: "Aha, hier werden aus dem String die Zeichen 0..9 entfernt...."

[Gehstock]

Danke an alle hab den Code von marabu genommen

Delphi-Quellcode:

function ReadNumber:String;
var
  i, iLength: Integer;
begin
  Form1.Memo1.Lines.clear;
  s:= 'AT+CPBS=ON';
  Form1.SendCMD;
  Form1.Memo1.Lines.clear;
  s:= 'AT+CPBR=1';
  Form1.SendCMD;
  Form1.Memo1.Lines.Add(sReadData);
  result:=Form1.memo1.Lines[1];
  delete(result,1,10);
  delete(result,13,19);
  iLength := 0;
  for i := 1 to Length(result) do
  begin
    if result[i] in ['0'..'9'] then
    begin
      Inc(iLength); 
      if iLength <> i then 
        result[iLength] := result[i];
    end;
  end;
  Result := Copy(result, 1, iLength);
end;

Danke nochmal

[marabu]

Matthäus 7,6

[Gehstock]

Bin grad nicht so Bibelfest aber glaub das ging so

Zitat:

Gebt das, was euch heilig ist, nicht Menschen preis, die es nicht achten. Und was euch kostbar ist, verschleudert nicht an solche, die seinen Wert nicht erkennen. Sie werden sonst euern Glauben in den Dreck zerren und euch hinterher auch noch angreifen.

[marabu]

Nimm es mir bitte nicht übel, aber ich bemühe mich immer um Code mit einem Fünkchen Wiederverwendbarkeit. Ich war spontan geschockt, als ich sah, wie du den Code aus seinem schönen Funktionskorsett herausgeschnitten hast. Aber egal - de gustibus non est disputandum.

Freundliche Grüße

[Gehstock]

Ok du hast recht die Funktion könnte im Programm öfters verwendung finden habs also wieder separiert