Pagecontrolproplem

[Adrian112]

Hallo,

ich würde gerne für meine Textverarbeitung TexEdit ein Pagecontrol verwenden,
um mehrere dokumente gleichzeitig zu öffnen. Das mit neuen Seiten erstellen klappt schon,
doch wie soll ich dann ein Richedit einfügen. Und wie kann ich dafür sorgen, dass
wenn man zumbeispiel die Schriftart ändert das nur für das gerade aktive Richedit
gemacht wird?

[DP-Maintenance]

Dieses Thema wurde von "SirThornberry" von "Sonstige Fragen zu Delphi" nach "VCL / WinForms / Controls" verschoben.

[CCRDude]

1. Der Link in Deiner Signatur ist kaputt (fehlt wohl ein ":")
2. Bei TexEdit denke ich immer an TeX, dabei erwähnst Du ausgerechnet das nicht ;)

Ok, ich schweife ab. Die Lösung lautet, die einzelne TTabSheet mit den Elementen darauf dynamisch zu erstellen, also etwa:

Delphi-Quellcode:

var tabNew: TTabSheet;
begin
   tabNew := TTabSheet.Create(pcMain);
   tabNew.Parent := pcMain;
   tabNew.PageControl := pcMain;
   // hier das TRichEdit und weitere Komponenten erzeugen
end;

Damit Änderungen sich nur auf das aktuelle auswirken, schaust Du pcMain.ActivePage nach, enumerierst dort alle Controls (Eigenschaften "Controls", "ControlCount"), und wenn eines der TRichEdit ist ("is TRichEdit"), dann wendest Du deine Formatierung auf dessen Inhalt an.

[Adrian112]

Danke für den Tipp, und wo genau fehlt ein ':'?

[CCRDude]

Also einen Link prüfen darf doch nicht so schwer sein :P
Geh einfach mit der Maus über den Link, dann wirst Du sehen daß er als:

Zitat:

http://http//www......

erscheint. Offensichtlich fehlt der also an Position 5, und da das http// somit nicht als Protokoll angesehen wird, setzt der Browser noch ein http:// davor.

[Adrian112]

Aha, hab ich ganz übesehen :oops:

[Adrian112]

Funktioniert das auch mit Pagecontrol?

[CCRDude]

pcMain oben IST ein TPageControl. Aber die Unterseiten eines TPageControls sind nun TTabSheets ;)

[Adrian112]

Oh man, bin ich blöd!!! :wall:

[Adrian112]

Ich hab jetzt den Quelltext mal getestet, und das mit den TabSheets erstellen funkt
schon mal. aber das mit der einzelveränderung funkt noch nicht.

Delphi-Quellcode:

PageControl1.ActivePage.Controls[RichEdit1.Selattributes.Size:=StrToInt(ComboBox1.Text)];

wie könnte es anders gehen?

[uwewo]

Nur so als Anregung, warum versuchst Du das ganze nicht mit MDIChilds zu lösen?

[Jens Schumann]

Hallo,
hier ein kleines Beispiel

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls, ComCtrls, ExtCtrls;

type
  TForm1 = class(TForm)
    PageCtrl: TPageControl;
    btnNew: TButton;
    btnDelete: TButton;
    edtText: TEdit;
    procedure btnNewClick(Sender: TObject);
    procedure btnDeleteClick(Sender: TObject);
    procedure edtTextKeyPress(Sender: TObject; var Key: Char);
  private
    { Private-Deklarationen }
    function NewTabSheet(pc : TPageControl; aCaption : TCaption) : TTabSheet;
    function DeleteTabSheet(pc : TPageControl) : Boolean;
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.DFM}

{ TForm1 }

function TForm1.NewTabSheet(pc: TPageControl; aCaption : TCaption): TTabSheet;
var
  Panel    : TPanel;
  RichEdit : TRichEdit;
begin
  Result:=TTabSheet.Create(Self);
  Result.Parent:=pc;
  Result.PageControl:=pc;
  Result.Caption:=aCaption;
  Panel:=TPanel.Create(Result);
  Panel.Parent:=Result;
  Panel.Align:=alClient;
  Panel.BevelInner:=bvNone;
  Panel.BevelOuter:=bvNone;
  Panel.BorderWidth:=2;
  RichEdit:=TRichEdit.Create(Result);
  RichEdit.Parent:=Panel;
  RichEdit.Align:=alClient;

  Result.Tag:=Integer(RichEdit); // Hier Zeiger auf TRichEdit merken.
end;

procedure TForm1.btnNewClick(Sender: TObject);
begin
  NewTabSheet(PageCtrl,'Tab '+IntToStr(PageCtrl.PageCount));
  btnDelete.Enabled:=True;
end;

function TForm1.DeleteTabSheet(pc: TPageControl): Boolean;
var
  aTabSheet : TTabSheet;
begin
  Result:=True;
  Try
    aTabSheet:=pc.ActivePage;
    FreeAndNil(aTabSheet);
  Except
    Result:=False;
    end;
end;

procedure TForm1.btnDeleteClick(Sender: TObject);
begin
  If Not DeleteTabSheet(PageCtrl) then
    ShowMessage('Fehler');
end;

procedure TForm1.edtTextKeyPress(Sender: TObject; var Key: Char);
var
  aTabSheet : TTabSheet;
  aRichEdit : TRichEdit;
begin
  aTabSheet:=PageCtrl.ActivePage;
  If aTabSheet<>Nil then
    begin
    aRichEdit:=TRichEdit(aTabSheet.Tag);
    If (aRichEdit<>Nil) and (Key=#13) then
      aRichEdit.Lines.Add(edtText.Text);
    end;
end;

end.

[Adrian112]

Danke für den Quelltext! Ich werde ihn sobald wie möglich testen.

[Adrian112]

Es funktioniert!!!