Canvas mit Handle auf Bitmap.Canvas

[igel457]

Hallo,

in meiner 2D Engine habe ich mir selbst eine Klasse von TCanvas abgeleitet:

Delphi-Quellcode:

TSurfaceCanvas = class(TCanvas)
  private
    FBitmap:TBitmap;
  public
    constructor Create;
end;

Nun möchte ich dass alle Zeichenbefehle die auf dem Canvas ausgeführt werden auf dem Bitmap erfolgen.
Also habe ich einfach...

Delphi-Quellcode:

constructor TSurfaceCanvas.Create;
begin
  inherited Create;
  Handle := FBitmap.Canvas.Handle;
end;

...geschrieben, was aber (wie ihr euch sicherlich denken könnt) nicht geht.
Wie bringe ich das zum laufen? Es wäre klasse wenn es mit dem Bitmap gehen würde, damit erspare ich mir nämlich einigen Ärger.

Danke,
Igel457

[Sunlight7]

Hallo,

so spontan würd' ich mal fragen, setzt Du irgendwo die größe des Bitmaps?

Denn das funkt:

Kompo:

Delphi-Quellcode:

constructor TSurfaceCanvas.Create;
begin
  inherited Create;
  FBitmap:=TBitmap.Create;
  FBitmap.Width:=80;
  FBitmap.Height:=80;
  Handle:=FBitmap.Canvas.Handle;
end;

procedure TSurfaceCanvas.Save;
begin
   FBitmap.SaveToFile('Test.bmp');
end;

Ausführen:

Delphi-Quellcode:

procedure TForm1.FormCreate(Sender: TObject);
   var sc:TSurfaceCanvas;
begin
   sc:=TSurfaceCanvas.Create;
   sc.TextOut(0, 0, 'Text');
   sc.Save;
end;

Grüßle!

[igel457]

Du hast recht...
Problem ist, dass ich nach einer Größenänderung das Handle neu zuweisen muss...
In einer kleinen Konsolenanwendung läuft es bei mir jetzt auch. Aber irgendwo muss ich noch einen Fehler haben.

Schonmal Danke!

[Sunlight7]

Bitte.

Kannst Dich ja nochmal melden, wenns wo hackt.

[igel457]

Ich bin jetz mal einen Schritt weiter:
Es funktioniert nur (warum auch immer), wenn ich mein Canvas innerhalb einer Prozedur erstelle und damit Arbeite.
Sobald ich das Canvas z.B. in "Form-Create" erstelle und in "Button1-Click" damit arbeite geht es nicht, die Ausgabe bleibt einfach weiß.

Kann ich dieses Problem irgendwie umgehen, ohne jedes mal mein Canvas neu erstellen zu müssen? Woran liegt dies überhaupt?

Schonmal Danke,
Igel457

[jbg]

Zitat:

Zitat von igel457

Woran liegt dies überhaupt?

Die VCL räumt nach jeder Window-Message alle DCs der Controls und alle Bitmap-DCs auf um GDI Resourcen zu sparen. Dem unterliegt natürlich auch dein Bitmap.

[igel457]

OK. Das hört sich logisch an. Kann ich das DC irgendwie sperren? Oder muss ich jedes mal ein neues erzeugen?

[Sunlight7]

Selber eins machen, dann müßts IMHO erhalten bleiben.

Aus genau den von jbg genannten Gründen hab ich mir ne eigene Bitmap Kompo gemacht, weil mir das Handle gewechsle aufn Zeiger ging.

[jbg]

Du musst ein neues erzeugen und das Bitmap-Handle dort selektieren, damit in das Bitmap gezeichnet wird

Delphi-Quellcode:

type
  TSurfaceCanvas = class(TCanvas)
  private
    FBmp: TBitmap;
    FOldBitmapHandle: HBITMAP;
    FOldPaletteHandle: HPALETTE;
  protected
    procedure CreateHandle; override;
  public
    constructor Create(AWidth, AHeight: Integer);
    destructor Destroy; override;

    property Bitmap: TBitmap read FBmp;
  end;

{ TSurfaceCanvas }

constructor TSurfaceCanvas.Create(AWidth, AHeight: Integer);
begin
  Assert(AWidth * AHeight > 0);
  inherited Create;
  FBmp := TBitmap.Create;
  FBmp.Width := AWidth;
  FBmp.Height := AHeight;
end;

procedure TSurfaceCanvas.CreateHandle;
begin
  Handle := CreateCompatibleDC(0);
  FOldBitmapHandle := SelectObject(Handle, FBmp.Handle);
  if not FBmp.IgnorePalette then
  begin
    FOldPaletteHandle := SelectObject(Handle, FBmp.Palette);
    // RealizePalette(FBmp.Palette); FALSCH
    RealizePalette(Handle);  // RICHTIG
  end;
end;

destructor TSurfaceCanvas.Destroy;
var
  DC: HDC;
begin
  if Handle <> 0 then
  begin
    SelectObject(Handle, FOldBitmapHandle);
    if FOldPaletteHandle <> 0 then
      SelectObject(Handle, FOldPaletteHandle);
    DC := Handle;
    Handle := 0;
    DeleteDC(DC);
  end;
  FBmp.Free;
  inherited Destroy;
end;

[DGL-luke]

Wie wärs, wenn du gleich auf NonVCL gehst? Unter torry.net gibts ne schöne GDI+-Kapselung...

[igel457]

@jbg
Danke für deine Lösung, ich werde mir das mal anschauen.

Guten Rutsch ins neue Jahr,
Igel457

[jbg]

Da ist mir gestern Nacht doch glatt ein Tippfehler unterlaufen:

Zitat:

// RealizePalette(FBmp.Palette); FALSCH
RealizePalette(Handle); // RICHTIG

[turboPASCAL]

Hab da mal ne Zwischenfrage, wozu ist das nun gut ?
Ich mein, ich würde die Ausgaben gleichch auf ein Bitmap machen etc.

[igel457]

Zitat:

Zitat von turboPASCAL

Hab da mal ne Zwischenfrage, wozu ist das nun gut ?
Ich mein, ich würde die Ausgaben gleichch auf ein Bitmap machen etc.

Eigentlich hast du recht. Allerding möchte oder wollte ich, dass man auf meine Oberfläche ganz "Normal" Zeichnen kann ohne zu bemerken, dass es eigentlich auf ein Bitmap gezeichnet wird. Außerdem möchte/wollte ich möglichst Kompatibel zu DelphiX bleiben. Doch vermutlich kommt das ganze jetzt doch nicht rein, weil es einfach zu langsam ist. Wer etwas über ein Canvas zeichnen will, der erstelle sich selbst eine Textur, zeichne da ein Bitmap drauf und verwende dieses.

[turboPASCAL]

Nunja, die Idee ist schon klar aber ein BitmapCanvas ist genausogut wie ein normaler Canvas.
Schlieslich ist TBitmap davon abgeleited.

Was ich mal gemacht habe ist eine Art SwapBitmap ala OpenGl bzw. DirectX.
Halt eine Miniversion.

Und zwar, zwei gleiche Bitmaps erstellt eins wird angezeigt und auf dem anderen gezeichnet.
Ist das Zeichnen fertig werden die Bitmaps getauscht.
Leider ist mir der Code durch meine eigene Schult verloren gegangen.