If-Schleifen-Haufen zusammenfassen

[XeRo]

Also meine If Schleifen sehen im Moment etwa derartig aus:

Delphi-Quellcode:

if(s='avi')or
(s='mpg')or
(s='mpeg')or
(s='wmf')or
(s=.....)...

Wie kann ich das vernünftiger machen?

[Zacherl]

Hi,

erstmal: if ist kein Schleifen Befehl :wink: ...

Du könntest alle Dateiendungen in einem Array speichern und dann mit dem Operator IN abfragen, ob die Endung enthalten ist.

Florian

[Interceptor]

nen array mit den dateiendungen bauen, danach mit ner for-schleife drübergehn & abfragen?

[leddl]

Zitat:

Zitat von Florian Bernd

Du könntest alle Dateiendungen in einem Array speichern und dann mit dem Operator IN abfragen, ob die Endung enthalten ist.

:shock: Seit wann geht das mit Arrays? :gruebel: AFAIK funktioniert IN nur mit Sets (und die funktionieren AFAIK nicht mit Strings ;)).

[Klaus01]

Zitat:

Zitat von XeRo

Also meine If Schleifen sehen im Moment etwa derartig aus:

Delphi-Quellcode:

if(s='avi')or
(s='mpg')or
(s='mpeg')or
(s='wmf')or
(s=.....)...

Wie kann ich das vernünftiger machen?

Vielleicht so?

Delphi-Quellcode:

var
  FileTypes : set of ['avi','mpg','mpeg','wmf']


if s in FileTypes then
 ...

Grüße
Klaus

[Neutral General]

Sowas geht nicht weil das kein Ordinaltyp ist wie ich letztens auch vom Compiler zu hören bekommen hab-.-^^

[Klaus01]

Danke,

so sollte es aber funktionieren.

Delphi-Quellcode:

var 
  FileTypes : set of (avi, mpg, mpeg, wmf) 


if s in FileTypes then 
...

sorry geht auch so nicht.




Grüße
Klaus

[leddl]

Zitat:

Zitat von Klaus01

so sollte es aber funktionieren.

Delphi-Quellcode:

var 
  FileTypes : set of (avi, mpg, mpeg, wmf) 
if s in FileTypes then

Dann müßte er aber aus seinem String erstmal den Datentyp machen, wofür er wieder ein if braucht ;)

[Die Muhkuh]

Schau dir mal AnsiIndexText an.

Edit:

Kleines Beispiel:

Delphi-Quellcode:

const
  FileTypes: array [0..4] of string = ('avi', 'mpg', 'mpeg', 'wmf', 'wmv');

procedure Blabla(Ext: String);
begin
  if AnsiIndexText(Ext, FileTypes) > - 1 then
  begin
    // MAch was mit mir :)
  end;
end;

[Neutral General]

Also ich glaube nicht das sowas geht. Wenn es doch ohne großen Aufwand geht dann sagt mir Bescheid. Das wäre für mich eine kleine Sensation :) :firejump:

[Klaus01]

Delphi-Quellcode:

const
  FileType ='avi_mpg_mpeg_wmf';

if pos(s,FileType) <> 0 then
  ...

mein letzter Versuch.

Einen schönen Feierabend.

Grüße
Klaus

[XeRo]

Wow danke für die extrem schnellen antworten!
Besonders Letzte methode gefällt mir!
Vielen dank!

[Die Muhkuh]

Zitat:

Zitat von XeRo

Besonders Letzte methode gefällt mir!

Klaus' oder meine?

[dino]

kann man sich nicht ne boolean Prozedur schreiben, der man den Vergleichswert mit allen Möglichkeiten übergibt ( :kotz: genau), und true rauskriegt, wenn einer der Möglichkeiten= dem Vergleichswert sind...

[Die Muhkuh]

Hi dino,

das sollte wohl kein Problem darstellen:

Delphi-Quellcode:

function InArray(What: String; const Values: Array of String): Boolean;
begin
  Result := AnsiIndexText(What, Values) > - 1;
end;

[Cöster]

Zitat:

Zitat von Klaus01

Delphi-Quellcode:

const
  FileType ='avi_mpg_mpeg_wmf';

if pos(s,FileType) <> 0 then
  ...

Hm, und wenn s = 'i_m'? Ich wage aber zu bezweifeln, dass das schneller ist, als die Methode mit den if-Abfragen. Im Gegenteil. So wie du es mit den if's machst, ist es schon das Beste, alternativ mit der Funktion à la Dino.

[semo]

AnsiIndexText gibts aber noch nicht in delphi5 ...

alternativ erstelle man sich ein array of integer und
eine funktion die man mit dem suchwort füttert, die dann das array durchläuft und den index bw true oder false zurückliefert.

[malo]

Zitat:

Zitat von computer-glossar.de

AnsiIndexText gibts aber noch nicht in delphi5 ...

Dann halt der Haudrauf-Weg.

Delphi-Quellcode:

function InArray(s: string; const StrArray: array of string): boolean;
var i: integer;
begin
result := false;
for i := 0 to high(StrArray)-1 do
begin
  if s=StrArray[i] then
  begin
    result := true;
    break;
  end;
end;

Aufruf wäre etwa so:

Delphi-Quellcode:

const
  FileTypes: array [0..4] of string = ('avi', 'mpg', 'mpeg', 'wmf', 'wmv'); 
//...
if InArray(s, FileTypes) then DoSomething;

Ist jetzt grob zusammen gezimmert ;)

[Lannes]

Hallo,

oder die Extensionen in eine Stringlist schreiben und dann mit IndexOf prüfen.

[semo]

Delphi-Quellcode:

function InArray(s: string; const StrArray: array of string): boolean;
var 
  i: integer;
begin
  result := false;
  for i := 0 to high(StrArray)-1 do
  begin
    if s=StrArray[i] then
    begin
      result := true;
      break;
    end;
  end;
end;

würd ich immer über ne while schleife lösen,
weil break sind nen "no go"
also:

Delphi-Quellcode:

function InArray(s: string; const StrArray: array of string): boolean;
var 
  i: integer;
begin
  result := false;
  i      := 0;
  while (not Result) and (i < to high(StrArray)) do
  begin
    result := s=StrArray[i];
    Inc(i);
  end;
end;

und das ganze könnte man dann ja noch um die möglichkeit erweitern auf groß/kleinschreibung zu achten oder nicht

Delphi-Quellcode:

function InArray(s: string; const StrArray: array of string; bCaseSensitiv: Boolean = false): boolean;
var 
  i: integer;
begin
  result := false;

  if not bCaseSensitiv then  
    s := AnsiUpperCase(s);

  i      := 0;
  while (not Result) and (i < to high(StrArray)) do
  begin
    if bCaseSensitiv then
      result := s=StrArray[i]
    else 
      result := s=AnsiUpperCase(StrArray[i]);

    Inc(i);
  end;
end;

[Hawkeye219]

Zitat:

Zitat von computer-glossar.de

[...]weil break sind nen "no go"

Die Anweisung BREAK ist ein sinnvolles Sprachelement, welches - sparsam eingesetzt - zu durchaus lesbarem Code führen kann.

Delphi-Quellcode:

function InArray (const s: string; 
                  const A: array of string;
                  CaseSensitive: Boolean = False): Boolean;
var
  i    : integer;
  Same : function (const s1, s2: string): Boolean;
begin
  if CaseSensitive then
    Same := AnsiSameStr
  else
    Same := AnsiSameText;

  Result := False;

  for i := 0 to High(A) do
    if Same(s, A[i]) then
      begin
        Result := True;
        Break;
      end;
end;

Gruß Hawkeye