Checkboxen machen mich wahnsinnig!

[sonicfire]

Servus und Hallo!

Schon wieder ein Problemchen *seufz*.

Wie erkläre ich es am besten ... nun...

Ich habe ein Fenster mit 16 Checkboxen und TEdit-Feldern. Beim Start des Programmes ist in diesem Fenster nur die erste(!) Checkbox markiert bzw. gewählt (checked). Die erste Checkbox ist grundsätzlich checked UND disabled. (enabled := false). Alle anderen CheckBoxen (2 - 16) sind per Default nicht checked aber alle enabled.

Wenn ich nun z.b. auf die 10te CheckBox klicke - so soll diese Checked sein UND gleichzeitig auch Enabled. (Geht.)
Und: Von der zweiten bis zur neunten Checkbox soll jeweils Enabled := False UND gleichzeitig checked gesetzt sein. (Geht ebenfalls).

Nun aber zum Problem. Wenn ich jetzt WIEDER auf diese 10te Checkbox klicke, soll das Häkchen weggehen (tut es ja auch so oder so) aber gleichezeitig sollen alle bis dahin marktierten Checkboxen (2 - 9) wieder "Enabled := True" und "Checked := False" sein - und genau da haut es nicht hin und ich weiss nicht wieso ...

Ich habe es mit einem Array of TCheckBox versucht und mit folgendem:

Delphi-Quellcode:

If (Sender is TCheckBox) then
begin
    begin
    if VeloLayers = (Sender as TCheckBox).Tag then
    begin
        For i:=1 to VeloLayers-1 do
        begin
           BoxToCheck[i].Enabled := True;
           BoxToCheck[i].Checked := False;
        end
    end
    else
    begin
        For i:=1 to ((Sender as TCheckBox).Tag-1) do
        begin
            BoxToCheck[i].Enabled := False;
            BoxToCheck[i].Checked := True;
        end;
        VeloLayers := (Sender as TCheckBox).Tag;
        end;
    end;
    end;
end;

In die jeweiligen CheckBoxen habe ich der Reihenfolge nach korrekte Tag-Werte geschrieben, eben einfach 1 bis 16...

Ich weiss einfach nicht, wieso er dann nur zum TEIL die Checkboxen wieder auf "NICHT checked" setzt. Das sieht fast so aus als würde er immer Zweiersprünge machen. Das ist zum Haareraufen! :wall: :gruebel:

[DGL-luke]

Checkboxen sin dafür da, mehrere Optionen GLEICHZEITG auszuwählen.

Radiobuttons sind dafür da, nur EINE Option AUS MEHREREN auszuwählen.

Wenn du da jetzt rummurkst, machst dur dir erstens einen Haufen Arbeit und baust zweitens einen Designfehler ein.

EDIT: Ich sehe, du strebst was anderes an... lass mich mal drüber nachdenken. :gruebel:

[Neutral General]

Hab grade versucht das Problem zu lösen aber genau wie du sagst ist das Problem das sobald man Checked ändert wird die OnClick Procedure ausgeführt -.-^^
Bin grad ne Lösung am suchen...

EDIT: Probiers ma ungefähr so:

Delphi-Quellcode:

var
  Form1: TForm1;
  Checks: Array[0..9] of TCheckbox;
  a: Boolean = false; //*

implementation

{$R *.dfm}

procedure TForm1.CheckBoxenClick(Sender: TObject);
var i: Integer;
begin
 if not a then begin //*
  a:= true;         //*
  for i:= TCheckBox(Sender).Tag to 9 do
  begin
   Checks[i].Enabled := true;
   Checks[i].Checked := false;
  end;
  for i:= TCheckBox(Sender).Tag-1 downto 0 do
  begin
   Checks[i].Enabled := false;
   Checks[i].Checked := true;
  end;
  TCheckBox(Sender).Checked := true;
  a := false; // *
 end;
 //*) Verhindert das OnClick nochmals während dem OnClick ausgeführt wird
end;

procedure TForm1.FormCreate(Sender: TObject);
var i: Integer;
begin
 for i:= 0 to 9 do
 begin
  Checks[i] := TCheckBox.Create(Self);
  Checks[i].Parent := Self;
  Checks[i].Left := 10;
  Checks[i].Top := i*20;
  Checks[i].Caption := 'Checkbox' + IntToStr(i);
  Checks[i].OnClick := CheckBoxenClick;
  Checks[i].Tag := i;
 end;
end;

Ich glaube das ist nicht 100% das was du willst aber es beantwortet deine Frage :)

Gruß
Neutral General

[DGL-luke]

also ich würde einfach ein value-edit machen, und da dann eben "anzahl der layer" eingeben lassen.

[Neutral General]

Zitat:

Zitat von DGL-luke

also ich würde einfach ein value-edit machen, und da dann eben "anzahl der layer" eingeben lassen.

Ne ich schätze das ist so der Fall das es Optionen werden sollen und das wenn man die 4. Option aktiviert das dann die ersten drei (zwangsweise) auch mitaktiviert werden weil die in der vierten Option praktisch mitdrin ist. Verstehst du?^^

[DGL-luke]

Nein.

Option 1 ist imemr aktiv. wenn 2-9 aktiviert ist, sind alle vorherigen auch aktiv - wenn 4 aktiv, dann auch 2 und 3. also nichts anderes als "wie viele optionen?".

[Neutral General]

Ja aber wie umständlich ist das bitte für den Benutzer wenn er in einem Spinedit eingeben muss wie viele Optionen aktiviert werden sollen... Da ist es halt wirklich einfacher so wie sonicfire es vorhat und so ist es auch normalerweise üblich :gruebel:

[hoika]

Hallo,

ich verstehe zwar nicht ganz, was der Code bezwecken soll
habe bei CheckBox 10 aufgehört zu zählen,
aber viell. hilft ja folgendes

Delphi-Quellcode:

procedure CheckBox_SetCheck(theCheckBox: TCheckBox; bCheck: Boolean);
var
  TempProc: procedure (Sender: TObject) of object;
begin
  if theCheckBox<>NIL then
  begin
    TempProc:= theCheckBox.OnClick;
    theCheckBox.OnClick:= NIL;
    theCheckBox.Checked:= bCheck;
    theCheckBox.OnClick:= TempProc;
  end
end;

Damit wird das OnClick temporär deaktiviert und stört nicht,
wenn man an den Checkboxen manuell rumfummelt.


Heiko

[KrasserChecker]

Zitat:

Zitat von Neutral General

Hab grade versucht das Problem zu lösen aber genau wie du sagst ist das Problem das sobald man Checked ändert wird die OnClick Procedure ausgeführt -.-^^

Stimmt, daher müsste es doch auch eigentlich reichen, wenn Du die erste Schleife umdrehst.

Also statt

Delphi-Quellcode:

...
if VeloLayers = (Sender as TCheckBox).Tag then
    begin
        For i:=1 to VeloLayers-1 do
        begin
           BoxToCheck[i].Enabled := True;
           BoxToCheck[i].Checked := False;
        end
    end 
...

einfach

Delphi-Quellcode:

...
if VeloLayers = (Sender as TCheckBox).Tag then
    begin
        For i:=VeloLayers-1 downto 1 do
        begin
           BoxToCheck[i].Enabled := True;
           BoxToCheck[i].Checked := False;
        end
    end 
...

[sonicfire]

Zitat:

Zitat von KrasserChecker

Zitat:

Zitat von Neutral General

Hab grade versucht das Problem zu lösen aber genau wie du sagst ist das Problem das sobald man Checked ändert wird die OnClick Procedure ausgeführt -.-^^

Stimmt, daher müsste es doch auch eigentlich reichen, wenn Du die erste Schleife umdrehst.

Also statt

Delphi-Quellcode:

...
if VeloLayers = (Sender as TCheckBox).Tag then
    begin
        For i:=1 to VeloLayers-1 do
        begin
           BoxToCheck[i].Enabled := True;
           BoxToCheck[i].Checked := False;
        end
    end 
...

einfach

Delphi-Quellcode:

...
if VeloLayers = (Sender as TCheckBox).Tag then
    begin
        For i:=VeloLayers-1 downto 1 do
        begin
           BoxToCheck[i].Enabled := True;
           BoxToCheck[i].Checked := False;
        end
    end 
...

Bist ECHT ein krasser Checker!! :shock: Ich glaubs nicht - so geht es!! :spin2:
Danke auch an alle anderen! :)

[raiguen]

Moin :-)
Auch wenn das Problem gelöst scheint, so darf ich dennoch eine kleine Anmerkung machen !?
Wie bereits gesagt, löst das Setzen von Checked immer das Ereignis OnClick aus...soweit, so dumm *gg*
Es gibt aber eine einfache Lösung (sogar mit Delphi-Boardmitteln ;-) ). Hierzu ein kleines Beispielmit 3 Checkboxen:

Delphi-Quellcode:

procedure TForm.CheckBox1MouseUp(Sender: TObject;
  Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
begin
   CheckBoxStatus(Sender as TCheckBox);
end;

{zum 'Abfangen' der Leertaste, welche auch den Status setzen kann }
procedure TForm1.CheckBox1KeyUp(Sender: TObject; var Key: Word;
  Shift: TShiftState);
begin
  if Key = ORD(#32) then CheckBoxStatus(Sender as TCheckBox);
end;
{ allg. Proc für die Checkboxen}
procedure TForm1.CheckBoxStatus(Sender: TcheckBox);
begin
   if Sender.Name = 'CheckBox1' then
   begin
     Checkbox2.State := cbUnchecked; //--setzen des Status auf unchecked
     Checkbox3.State := cbUnchecked;
  end;
  if Sender.Name = 'CheckBox2' then
   begin
     Checkbox1.State := cbUnchecked;
     Checkbox3.State := cbUnchecked;
  end;
  if Sender.Name = 'CheckBox3' then
   begin
     Checkbox1.State := cbUnchecked;
     Checkbox2.State := cbUnchecked;
  end;   
end;

Interessant ist hier Checkboxe.State, dessen Eigenschaft man durchaus zur Laufzeit setzen kann...entweder im MouseUp- oder wie hier 'weitergeleitet' an die Prozedure CheckBoxStatus. Somit umgeht man das Auslösen des OnClick-Ereignisses..
Eine Checkbos erhält automatisch den Status cbChecked, sobald sie angeklickt oder (sofern per Tab focusiert wurde) die Leertaste gedrückt wurde.
Sollen andere Checkboxen in Abhängigkeit einer bestimmten Checkbox den Status cbChecked erhalten, so löst man das elegant wiederum über

Code:

Checkbox.State := cbChecked

;-)

Ob eine Checkbox markiert ist, lässt sich zum einen ja über

Code:

if CheckBox.Checked then..

oder über

Code:

if Checkbox.State=cbChecked

ermitteln; für den häkchenfreien Zustand dann entsprechend so:

Code:

if not CheckBox.Checked then..

bzw

Code:

if Checkbox.State=cbUnChecked

..

Zu diesem Problem gibt es hier Abhängigkeiten mehrerer Checkboxen noch etwas mehr Codebeispiel.
...