AV mit TStringList-Methode Add()

[Mackhack]

Hi,

warum kracht es hier denn mit einer AV in der Files.Add(...) Zeile? Files ist vom Typ TStringList

Delphi-Quellcode:

...
repeat
  if (wfd.dwFileAttributes and FILE_ATTRIBUTE_DIRECTORY <> FILE_ATTRIBUTE_DIRECTORY ) then
    if ( IsLanguageFile(aRoot + wfd.cFileName, '<Languages>') ) then
      Files.Add(aRoot + wfd.cFileName);
until FindNextFile(hFile, wfd) = False;
...

[mkinzler]

Ist schon eine Instanz der Stringliste erzeugt?

[Mordilion]

Wie mein vorschreiber schon erwähnte, wäre es gut zu wissen ob du eine Instanz erzeugst.

Wenn nicht hilft das vielleciht weiter? ;)

Delphi-Quellcode:

  // Dann erzeugen wir mal die Instanz
  Files := TStringList.Create;
  try
    {...}
    repeat
      if (wfd.dwFileAttributes and FILE_ATTRIBUTE_DIRECTORY <> FILE_ATTRIBUTE_DIRECTORY ) then
        if ( IsLanguageFile(aRoot + wfd.cFileName, '<Languages>') ) then
          Files.Add(aRoot + wfd.cFileName);
    until FindNextFile(hFile, wfd) = False; 
    {...}
  finally
    // Wenn man was erzeugt, muss es auch weider freigegeben werden!
    // Aber erst nachdem man die Daten verarbeitet hat, da sie sonst weg sind!
    Files.Free
  end;

Gruß
Mordi

[Mackhack]

Hab vergessen ne Instanz zu erzeugen.

Danke euch!

[Mackhack]

Hab nochmal ne Frage dazu hier:

Warum ist denn das Files.Count immer 0 und somit kommt nix im TestMemo an?

Delphi-Quellcode:

var
  I : Integer;
  Files : TStringList;
begin
  Memo1.Clear;
  Files := TStringList.Create;
  FindFile.SearchFiles('c:\', Files, '*.xml', False);
  for I := 0 to Files.Count - 1 do
    Memo1.Lines.Add(Files[I])
end;

[Luckie]

Zitat:

Zitat von Mackhack

Hab nochmal ne Frage dazu hier:

Warum ist denn das Files.Count immer 0 und somit kommt nix im TestMemo an?

Delphi-Quellcode:

var
  I : Integer;
  Files : TStringList;
begin
  Memo1.Clear;
  Files := TStringList.Create;
  FindFile.SearchFiles('c:\', Files, '*.xml', False);
  for I := 0 to Files.Count - 1 do
    Memo1.Lines.Add(Files[I])
end;

Weil die Methode SearchFiles von der Klasse FindFiles keine Dateien in die StringListe schreibt? :?

[Mackhack]

Und warum tut sie das nicht?

Geht eigentlich sauber durch den code und erkennt auch die Datei!

[SirThornberry]

warum sie das nicht tut wissen wir nicht wenn du uns die Funktion nicht vollständig postest (das wollte dir Luckie damit sagen, wir können es nicht wissen wenn wir nicht wissen wie dein quelltext aussieht)

[Mackhack]

Zitat:

Zitat von Mordilion

Wie mein vorschreiber schon erwähnte, wäre es gut zu wissen ob du eine Instanz erzeugst.

Wenn nicht hilft das vielleciht weiter? ;)

Delphi-Quellcode:

  // Dann erzeugen wir mal die Instanz
  Files := TStringList.Create;
  try
    {...}
    repeat
      if (wfd.dwFileAttributes and FILE_ATTRIBUTE_DIRECTORY <> FILE_ATTRIBUTE_DIRECTORY ) then
        if ( IsLanguageFile(aRoot + wfd.cFileName, '<Languages>') ) then
          Files.Add(aRoot + wfd.cFileName);
    until FindNextFile(hFile, wfd) = False; 
    {...}
  finally
    // Wenn man was erzeugt, muss es auch weider freigegeben werden!
    // Aber erst nachdem man die Daten verarbeitet hat, da sie sonst weg sind!
    Files.Free
  end;

Gruß
Mordi

Es ist das Files.Free das mir die TStringList leer raeumt. Aber wo sonst sollte denn das Files.Free hin wenn nicht an das Ende der Procedure?

Ich habe das ganze jetzt mal in eine Function gepackt mit dem Rueckgabewert TStringList. Jedoch sieht das irgendwie nicht wirklich richtig aus wenns auch funktioniert.

Delphi-Quellcode:

var
  I: Integer;
begin
  for I := 0 to FindFile.SearchFiles('c:\', '*.xml', False).Count - 1 do
    Memo1.Lines.Add(FindFile.SearchFiles('c:\', '*.xml', False)[I])
end;

[Christian Seehase]

Moin Mackhack,

wenn Du die Stringlist als Parameter an die Routine übergibst, die die Liste füllen soll, dann muss sie schon vor der Übergabe erzeug t worden sein.
Die aufgerufene Routine schreibt dann nur noch ihre Daten da rein, erzeugt sie nicht, und gibt sie nicht frei.
(in der Hoffnung Dein Problem richtig verstanden zu haben)

[Mackhack]

So hier ist meine Funktion. Ich weis nur leider nicht wie ich die Eintraege aus der TStringList nun in mein TestMemo bekomme und schaeme mich dafuer schonmal :(

Delphi-Quellcode:

function TFindFile.SearchFiles(aRoot: String; Mask: String = '*.xml'; Recursive : Boolean = False): TStringList;

  function IsLanguageFile(aFileName: String; aSearchString: String): Boolean;
  const
    MAX_BUFFER_SIZE = 10240;
  var
    FileStream: TFileStream;
    BufferSize: Integer;
    I: Integer;
    StrLength: Integer;
    Buffer: String;
    Found: Integer;
    ReadBytes: Integer;
  begin
    Result := False;

    if ( aSearchString = '' ) then
      Exit;

    aSearchString := AnsiLowerCase(aSearchString);
    FileStream := TFileStream.Create(aFileName, fmOpenRead or fmShareDenyWrite);
    try
      StrLength := Length(aSearchString);
      if ( FileStream.Size <= MAX_BUFFER_SIZE ) then
        BufferSize := FileStream.Size
      else
        BufferSize := MAX_BUFFER_SIZE * StrLength;
        SetLength(Buffer, BufferSize);
        repeat
          ReadBytes := FileStream.Read(Buffer[1], BufferSize);
          if ( ReadBytes = 0 ) then
            Exit;
          Buffer := AnsiLowerCase(Buffer);
          Found := 0;
          for I := 1 to ReadBytes - 1 do
          begin
            if ( BufferSize - (I - 1) >= StrLength ) then
            while (Buffer[I + Found] = aSearchString[Found + 1]) do
            begin
              Inc(Found);
              if ( Found = StrLength ) then
              begin
                Result := True;
                Exit;
              end;
            end;
          end;
        until ( FileStream.Position <= FileStream.Size );
    finally
      FileStream.Free;
      SetLength(Buffer, 0);
    end;
  end;

var
  wfd : TWin32FindData;
  hFile : THandle;
begin
  if ( AnsiLastChar(aRoot)^ <> '\' ) then
    aRoot := aRoot + '\';
  if Recursive then
  begin
    hFile := FindFirstFile(PChar(aRoot + '*.xml'), wfd);
    if ( hFile <> INVALID_HANDLE_VALUE ) then
    try
      repeat
        if ( wfd.dwFileAttributes and FILE_ATTRIBUTE_DIRECTORY = FILE_ATTRIBUTE_DIRECTORY ) then
          if ( (String(wfd.cFileName) <> '.') and (String(wfd.cFileName) <> '..') ) then
            SearchFiles(aRoot + wfd.cFileName, Mask, Recursive);
      until FindNextFile(hFile, wfd) = False;
    finally
      Windows.FindClose(hFile);
    end;
  end;
  hFile := FindFirstFile(PChar(aRoot + '*.xml'), wfd);
  if ( hFile <> INVALID_HANDLE_VALUE ) then
  Result := TStringList.Create;
  try
    repeat
      if (wfd.dwFileAttributes and FILE_ATTRIBUTE_DIRECTORY <> FILE_ATTRIBUTE_DIRECTORY ) then
        if ( IsLanguageFile(aRoot + wfd.cFileName, '<Languages>') ) then
          Result.Add(aRoot + wfd.cFileName);
    until FindNextFile(hFile, wfd) = False;
  finally
    Windows.FindClose(hFile);
  end;
end;

Jedoch weis ich immer noch net wo ich das Files.Free hinparken muss!

[Christian Seehase]

Moin Mackhack,

ich habe mal die Änderungen bezüglich des Ergebnisses so eingebaut, wie ich es machen würde.

Delphi-Quellcode:

// Geändert
procedure TFindFile.SearchFiles(aRoot: String; const AslResult : TStringList;Mask: String = '*.xml';Recursive : Boolean = false);

//...

var
  wfd : TWin32FindData;
  hFile : THandle;
begin
  if ( AnsiLastChar(aRoot)^ <> '\' ) then
    aRoot := aRoot + '\';
  if Recursive then
  begin
    hFile := FindFirstFile(PChar(aRoot + '*.xml'), wfd);
    if ( hFile <> INVALID_HANDLE_VALUE ) then
    try
      repeat
        if ( wfd.dwFileAttributes and FILE_ATTRIBUTE_DIRECTORY = FILE_ATTRIBUTE_DIRECTORY ) then
          if ( (String(wfd.cFileName) <> '.') and (String(wfd.cFileName) <> '..') ) then
            SearchFiles(aRoot + wfd.cFileName,AslResult, Mask, Recursive); // Geändert
      until FindNextFile(hFile, wfd) = False;
    finally
      Windows.FindClose(hFile);
    end;
  end;
  hFile := FindFirstFile(PChar(aRoot + '*.xml'), wfd);
  if ( hFile <> INVALID_HANDLE_VALUE ) then
  // Zeile weggelassen
  try
    repeat
      if (wfd.dwFileAttributes and FILE_ATTRIBUTE_DIRECTORY <> FILE_ATTRIBUTE_DIRECTORY ) then
        if ( IsLanguageFile(aRoot + wfd.cFileName, '<Languages>') ) then
          AslResult.Add(aRoot + wfd.cFileName); // Geändert
    until FindNextFile(hFile, wfd) = False;
  finally
    Windows.FindClose(hFile);
  end;
end;

Der Ablauf wäre also:

• StringListe erzeugen
• Prozedure (Methode) aufrufen
• StringListe (Ergebnis) verarbeiten
• StringListe freigeben

[EDIT]
Statt extra eine StringListe zu erzeugen, könntest Du den Ergebnisparameter als TStrings deklarieren, und gleich die Memo.Lines als Parameter übergeben.
[/EDIT]

[Mackhack]

Ja aber so hatte ich es bereits als Procedure und ich bekam ne AV weil ich keine Instanz angelegt habe von der TStringList.

Sehr seltsam. Ich habe nun einfach meine urspruengliche Procedure genommen und nicht die Function und habe einfach nur das Files.Free ganz unten weggelassen was mir jemand hier empfohlen hat und es tut mit folgendem Aufruf.

Delphi-Quellcode:

var
  I: Integer;
  Files: TStringList;
begin
  Memo1.Clear;
  Files := TStringList.Create;
  FindFile.SearchFiles('c:\', Files, '*.xml', False);
  for I := 0 to Files.Count - 1 do
    Memo1.Lines.Add(Files[I]);
  Files.Free;
end;

Jedoch hab ich jetzt noch eine Frage... Rein zum Verstaendnis.

Wenn ich hier in der Aufrufenden Methode die TStringList genauso benenne wie die TStringList in der Procedure funktioniert das ganze, wenn ich aber sagen wir hier oben das Files in Datei : TStringList umbenenne funktioniert das ganze nicht mehr. Warum aber nicht? Warum ist sozusagen das Files hier mit dem Files aus der Procedure gleichgestellt?

[Christian Seehase]

Moin Mackhack,

z.B. so:

Delphi-Quellcode:

SearchFiles('c:\temp',Memo1.Lines);

(Vorausgesetzt, der Parametertyp wird auf TStrings geändert)

oder so:

Delphi-Quellcode:

var
  sl : TStringList;

begin
  sl := TStringList.Create;
  try
    SearchFiles('c:\temp',sl);
    // Mach was mit der StringListe
  finally
    FreeAndNil(sl);
  end;

[EDIT]
Ist zwar ungetestet, sollte aber stimmen.
[/EDIT]