[RTTI] setzen von klasseneigenschaften

[_frank_]

Hallo,
weis jemand, wie ich per rtti spezial (Klassen)-Eigenschaften setzen kann (Binär [TImage.bitmap], stringlist [TMemo.Lines],integerlist [TStringgrid.ColWidths],tcollection [TStatusbar.panels]) ?

Gruß Frank

[dataspider]

Hallo Frank,

unter Uses TypInfo mit aufnehmen und dann mit SetObjectProp das Property setzen.
Allerdings muss das Property Published sein.

Cu, Frank

[_frank_]

getObjectProp gibt es unter D3 nicht, für normale klassen hab ich da SetOrdProp genommen, jedoch muss ja bei den oben genannten Eigenschaften so eine art Assign gemacht erden und nicht nur der pointer gesetzt werden wie das bei anderen Klassen-Eigenschaften der fall ist
hast du ein funktionierendes Beispiel (für D3)?

Gruß Frank

[Hawkeye219]

Hallo Frank,

beim Lesen von Eigenschaftswerten hat es doch mit einem TypeCast funktioniert (klick). Kannst du beim Setzen nicht einen ähnlichen Weg einschlagen?

Delphi-Quellcode:

SetOrdProp(...,Integer(Objektvariable));

Gruß Hawkeye

[dataspider]

Zitat:

Zitat von _frank_

getObjectProp gibt es unter D3 nicht, für normale klassen hab ich da SetOrdProp genommen, jedoch muss ja bei den oben genannten Eigenschaften so eine art Assign gemacht erden und nicht nur der pointer gesetzt werden wie das bei anderen Klassen-Eigenschaften der fall ist
hast du ein funktionierendes Beispiel (für D3)?

Gruß Frank

Sorry, ich habe kein D3.
Du kannst auch kein Assign per RTTI machen. Du kannst dir aber das Object holen und dann damit weiterarbeiten.
Kannst du mal konkret schildern, was du erreichen willst?

D7 macht bei SetObjectProp auch am Ende ein SetOrdProp:

Delphi-Quellcode:

procedure SetObjectProp(Instance: TObject; PropInfo: PPropInfo;
  Value: TObject; ValidateClass: Boolean);
begin
  if (Value = nil) or
     (not ValidateClass) or
     (Value is GetObjectPropClass(PropInfo)) then
    SetOrdProp(Instance, PropInfo, Integer(Value));
end;

Cu, Frank

[_frank_]

bisher hab ich bei klassenproperties nur Pointer nach integer gecasted und diese per setOrdProp gesetzt bzw. diese per getordprop ausgelesen und nach TObject gecasted.
Kurz ich habe nur mit pointern gearbeitet.
beim setzen dieser properties müssen aber die daten kopiert werden, bzw. das ursprungsobjekt freigegeben werden und mit dem vorhandenen ersetzt werden (dadurch können aber evtl. Eigenschaften verloren gehen).

Hoffe, ich hab mich verständlich ausgedrückt...

Gruß Frank

[dataspider]

Also erst mal ein Beispiel, wie man eine Bitmap z.B. per RTTI lädt:

Delphi-Quellcode:

...
// nur bei Delphi < D5
function GetObjectProp(Instance: TObject; const PropName: string): TObject;

function IsPublishedProp(Instance: TObject; const PropName: string): Boolean;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.BitBtn1Click(Sender: TObject);
begin
  LoadBitmapPerRTTI(Image1);
end;

procedure TForm1.LoadBitmapPerRTTI(AObject: TObject);
Var
  ATmpObj: TObject;
  ABitMap: TBitMap;
begin
  ATmpObj := nil;
  ABitMap := nil;

  if IsPublishedProp(AObject, 'Picture') then
    ATmpObj := GetObjectProp(AObject, 'Picture');
  if Assigned(ATmpObj) and (ATmpObj is TPicture) then
    ABitMap := TPicture(ATmpObj).Bitmap;
  ABitMap.LoadFromFile('d:\buffer\uts1.bmp');


end;

function IsPublishedProp(Instance: TObject; const PropName: string): Boolean;
begin
  Result := GetPropInfo(Instance.ClassInfo, PropName) <> nil;
end;

function GetObjectProp(Instance: TObject; const PropName: string): TObject;
var
  PropInfo: PPropInfo;
begin
  Result := nil;
  PropInfo := TypInfo.GetPropInfo(Instance.ClassInfo, PropName);
  if (PropInfo <> nil) and (PropInfo^.PropType^.Kind = tkClass) then
    Result := TObject(GetOrdProp(Instance, PropInfo));
end;

Das Setzen von Eigenschaften wie z.B. ein Propertie vom Typ TStrings
auf eine selbsterstellte Stringliste halte ich für gefährlich.
Man sollte so etwas wirklich am konkreten Beispiel diskutieren. Da gerade die Methode Assign sehr unterschiedlich bis gar nicht implementiert ist, muss m an dann entscheiden, ob man diese benutzt oder in einer abgeleiteten Kalsse neu implementiert.

Frank

[_frank_]

Zitat:

Zitat von dataspider

Also erst mal ein Beispiel, wie man eine Bitmap z.B. per RTTI lädt:

Delphi-Quellcode:

...
procedure TForm1.LoadBitmapPerRTTI(AObject: TObject);
Var
  ATmpObj: TObject;
  ABitMap: TBitMap;
begin
  ATmpObj := nil;
  ABitMap := nil;

  if IsPublishedProp(AObject, 'Picture') then
    ATmpObj := GetObjectProp(AObject, 'Picture');
  if Assigned(ATmpObj) and (ATmpObj is TPicture) then
    ABitMap := TPicture(ATmpObj).Bitmap;
  ABitMap.LoadFromFile('d:\buffer\uts1.bmp');


end;

du machst letztendlich auch nur reine Pointeraktionen. Holst den pointer castest den nach TPicture und weist das bitmap zu...beim setzen ist das nicht so einfach...da das Quellobjekt nicht das zielobjekt ist (bei mir).
//edit: soll das Loadfromfile nicht saveToFile heisen? weil so wäre die ganze Procedure sinnlos, da immer aus der datei gelesen würde.

aber da man eh prüfen muss, von welchem typ das ziel ist, kann man doch auch folgendes machen, oder:

Delphi-Quellcode:

...
if Assigned(ATmpObj) then
begin
  if (ATmpObj is TPicture) then
    TPicture(ATmpObj).Bitmap.assign(ABitMap) else
  if (ATmpObj is TBitmap) then
    TBitmap(ATmpObj).assign(ABitMap) else
  if (ATmpObj is TStrings) then
    TStrings(ATmpObj).assign(AStringlist) else
...
end;
...
das geht aber nicht bei t-collections...weil der grundtyp kapselt nicht die jeweiligen objecteigenschaften, daher komme ich mit assign nicht weiter.

Zitat:

Zitat von dataspider

Das Setzen von Eigenschaften wie z.B. ein Propertie vom Typ TStrings
auf eine selbsterstellte Stringliste halte ich für gefährlich.
Man sollte so etwas wirklich am konkreten Beispiel diskutieren. Da gerade die Methode Assign sehr unterschiedlich bis gar nicht implementiert ist, muss m an dann entscheiden, ob man diese benutzt oder in einer abgeleiteten Kalsse neu implementiert.

Frank

bei typen wie tstrings dürfte sich nicht viel ändern, da ich zum editieren nur ein memo habe hat man da z.B. keine sondereigenschaften wie z.B. in TRichedit.

Gruß Frank

[Hawkeye219]

Frank, du mußt doch eigentlich nur eine in deinem Delphi 3 nicht vorhandene Routine "nachbauen", die Vorlage dazu hat dataspider in seinem Beitrag geliefert. In der Routine 'SetOrdProp' wird eine eventuell vorhandene Setter-Methode des übergeordneten Objekts aufgerufen, welche für das eigentliche Kopieren der Daten zuständig ist. Die Setter-Methode verfügt über alle notwendigen Informationen und kann auch das Zielobjekt freigeben, falls dies erforderlich ist. Bei den VCL-Komponenten (TMemo etc.) ist diese Funktionalität bereits implementiert.

Gruß Hawkeye

[_frank_]

versteh ich dich richtig, dass setOrdProp nicht den Pointer kopiert sondern die Daten?

Gruß Frank

[Hawkeye219]

Kleines Beispiel:

Delphi-Quellcode:

type
  TMyObject = class
  private
    FProp1 : Integer;
    FProp2 : TBitmap;
    procedure SetProp2 (Value: TBitmap);
  published
    property Prop1: Integer read FProp1 write FProp1;
    property Prop2: TBitmap read FProp2 write SetProp2;
  end;

Bei Prop1 wird der Wert direkt gelesen und geschrieben. Bei Prop2 wird direkt gelesen und mit der Routine SetProp2 geschrieben. Diese Setter-Routine wird beim Zugriff über 'SetOrdProp' bzw. 'SetObjectProp' automatisch aufgerufen, sie sollte dann die Daten kopieren:

Delphi-Quellcode:

procedure TMyObject.SetProp2 (Value: TBitmap);
begin
  FProp2.Assign(Value);
end;

Gruß Hawkeye

[_frank_]

Zitat:

Zitat von Hawkeye219

Bei Prop1 wird der Wert direkt gelesen und geschrieben. Bei Prop2 wird direkt gelesen und mit der Routine SetProp2 geschrieben. Diese Setter-Routine wird beim Zugriff über 'SetOrdProp' bzw. 'SetObjectProp' automatisch aufgerufen, sie sollte dann die Daten kopieren.

ahja, dachte die RTTI-Funktionen arbeiten auf niedrigerer Ebene...gut, werde mal versuchen es einzubauen...danke dir erstmal

Gruß Frank

[_frank_]

Hallo,
also ich hab mal das versucht umzusetzen, jedoch bekomme ich bei meinen Versuchen immer eine AV...

hier mal mein code:

Delphi-Quellcode:

procedure TForm1.Button2Click(Sender: TObject);
var ti:PTypeinfo;
    pi:PPropinfo;
begin
  ti:=Typeinfo(TMemo);
  pi:=GetPropInfo(ti,'Lines');
  setOrdProp(memo2.lines,pi,integer(@memo1.lines));
end;

das ganze soll nur ein beispiel sein um memo1.lines nach memo2.lines zu kopieren...später ist natürlich alles variabel...

Hoffe jemand kann mir helfen...

Gruß Frank

[Hawkeye219]

Hallo Frank,

versuche es einmal so:

Delphi-Quellcode:

procedure TForm1.Button2Click(Sender: TObject);
var ti:PTypeinfo;
    pi:PPropinfo;
begin
  ti:=Typeinfo(TMemo);
  pi:=GetPropInfo(ti,'Lines');
  setOrdProp(memo2,pi,integer(memo1.lines));  // <-- geändert
end;

Die Property-Informationen zu Lines hast du ja schon in der Variablen pi vorliegen, der erste Parameter von SetOrdProp muß also eine Referenz auf das Control sein.
Beim dritten Parameter ist der Adreßoperator falsch, memo1.lines ist bereits eine Referenz auf ein TStrings-Objekt.

Gruß Hawkeye

[_frank_]

danke so funktioniert es...
das mit dem @ war mein 2. Versuch...hatte es auch erst ohne probiert, weils ja schon ein Pointer ist, aber der eigentliche Fehler war das Property als ersten Parameter direkt anzugeben...

Dank dir... (hab dich auch schon in die credits des DFMedit aufgenommen)