Überprüfen ob alle Zeilen vorhanden sind

[horst]

Hallo...

Ich habe eine Datei in der steht am Anfang immer das Datum dann die Uhrzeit und noch mehr steht. Nun möchte ich überprüfen, anhand der fortlaufenden Uhrzeit, ob alle Zeilen vorhanden sind. Evt die fehlenden Zeilennummern in einem LOG speichern.

Hat jemand eine Idee wie ich das machen/anfangen kann?


Ein Beispiel:

Code:

05.07.2006 00:00:00  - >hier kann dann noch alles mögliche stehen
05.07.2006 00:00:01  - >hier kann dann noch alles mögliche stehen 
05.07.2006 00:00:02  - >hier kann dann noch alles mögliche stehen
05.07.2006 00:00:03  - >hier kann dann noch alles mögliche stehen
05.07.2006 00:00:04  - >hier kann dann noch alles mögliche stehen
05.07.2006 00:00:05  - >hier kann dann noch alles mögliche stehen
05.07.2006 00:00:06  - >hier kann dann noch alles mögliche stehen
05.07.2006 00:00:07  - >hier kann dann noch alles mögliche stehen
usw...immer 1 TAG

Grüße Horst

[mkinzler]

Muß pro Sekunde ein Eintrag vorhanden sien oder wie erkennst du das eine Zeile fehlt?

[horst]

Genau...anhand der Zeit bzw. pro Sekunde ein Eintrag.

[mkinzler]

Da der Timestamp immer das gleiche Format besitzt, dürfte das Parsen kein Problem darstellen.

[horst]

mhm..Parsen.
Und wie würdest du das anfangen?

[mkinzler]

Parsen ist vielleicht übertrieben. Du kannst den Datum/Zeit-Eintrag mit Hilfe von StrToDateTime()
in einen Datetime wandeln, den du dann jeweils mit dem erwarteten Wert vergleichst.

[horst]

Hallo,

danke erstmal.

Zitat:

Zitat von mkinzler

den du dann jeweils mit dem erwarteten Wert vergleichst.

Genau das ist mein Problem. Irgendwo einen Vergleich haben, nur wie.

Gruß, Horst

[mkinzler]

So in etwa:

Delphi-Quellcode:

erwTimeStamp := EncodeDate( Jahr, Monat, Tag) + EncodeTime( Stunde, Minute, Sekunde, Msekunde);
logTimeStamp := StrToDateTime( Copy( logZeile, 1, 19));

[horst]

Stimmt, mal sehen wie weit ich komme :)
Danke.

[mkinzler]

Du kannst natürlich auch die Zeitspanne zwischen 2 aufeinanderfolgende Werte berechnen.

[Neon-chan]

Über die Zeitspanne würde ich es auch machen...TTime ist ja nichts anderes als ne real-Zahl

Mach dir am Anfang eine Vergleichsvariabel zB check := strtoTime('00:00:01') dann musst du zum überprüfen nurnoch abfragen ob Timestamp aktuelle Zeile - Timestamp vorherige zeile = check

[horst]

Ist es dann egal ob noch andere Zahlen im Text stehen?
Irgendwie blick ich das mit dem auslesen nicht.

[mquadrat]

Du musst als erstes mal die Uhrzeiten aus deinen Zeilen isolieren. Da du ein festes Format hast, kannst du das direkt per Copy() machen. Dann hast du einen String, der nur noch die Uhrzeit enthält und kannst die Vergleiche mittels StrToDateTime machen, wie oben schon beschrieben.

[Hawkeye219]

Hallo Horst,

hier ist ein Ansatz:

Delphi-Quellcode:

procedure CheckLog (const aFilename: string);
  var DT          : TDateTime;
      F           : TextFile;
      i           : Integer;
      LastSeconds : Integer;
      Line        : string;
      NewSeconds  : Integer;
begin
  AssignFile (F, aFilename);
  Reset (F);
  LastSeconds := -1;
  while not Eof(F) do
    begin
      ReadLn (F, Line);
      DT := StrToDateTime(Copy(Line, 1, 19));
      // Uhrzeit in Sekunden umrechen
      NewSeconds := Round(86400 * Frac(DT));
      // bei der ersten Zeile erfolgt keine Prüfung
      if (LastSeconds >= 0) then
        for i := LastSeconds + 1 to NewSeconds - 1 do
          ShowMessage (Format('Zeile %d fehlt', [i]));
      LastSeconds := NewSeconds;
    end;
  CloseFile (F);
end;

Es ist keine vollständige Lösung, es fehlen beispielsweise ein paar Absicherungen gegen fehlerhafte Daten. Falls die Datei ein Protokoll über mehrere Tage enthält, wirst du weitere Abfragen einbauen müssen. Die Routine erwartet nach Uhrzeit aufsteigend sortierte Einträge.

Gruß Hawkeye

[horst]

@Hawkeye219
vielen Dank, damit kann ich auf jeden Fall was anfangen.
Nur noch die doppelten Zeilen herausfinden.
Gruß
Horst

[capo]

hi
ich hab ein ähnliches problem, ich lese nur kein datum aus.
ich hab auch noch ein problem mit den doppelten zeilen, auch wie ich das problem mit den leerzeilen umgehen kann,
da gibts immer fehler?

gruss, capo

[marabu]

Herzlich willkommen in der Delphi-PRAXiS, capo.

Die Prüfung auf doppelte (aufeinander folgende) oder leere Zeilen funktioniert vom Prinzip her so:

Delphi-Quellcode:

procedure CheckText(fn: TFileName);
var
  tf: TextFile;
  index, lineCount: Integer;
  lines: array [0..1] of String;
begin
  lines[0] := '';
  lines[1] := '';
  lineCount := 0;
  index := 0;
  AssignFile(tf, fn);
  Reset(tf);
  while not Eof(tf) do
  begin
    Inc(lineCount);
    ReadLn(tf, lines[index]);
    // Test auf Leere
    if line[index] = '' then
      DoEmptyLine(lineCount) else
    // Test auf Gleichheit
    if lines[0] = lines[1] then
      DoSameLine(lineCount, lines[index])
    // Sonst
      DoLine(lineCount, lines[index]);
    index := 1 - index;
  end;
  CloseFile(tf);
end;

Freundliche Grüße vom marabu

[capo]

hi marabu :-D

danke.
ich hab doch nochmal einige fragen, wieso wird in deinem beispiel ein

Delphi-Quellcode:

lines: array [0..1] of String;

verwendet und in dem von horst
ein string für line(s) ?

ich hatte das so gemacht, funktioniert aber nicht

Delphi-Quellcode:

 // Eine Zeile doppelt vorhanden?
if (NewSeconds = LastSeconds) then
Form1.ListBox1.Items.Add('    ' + TimeToStr(SecondsToTime(i - 1)) + '    ' + '---------------> Zeile doppelt vorhanden');

capo

[marabu]

Hi Capo,

ich hatte nicht verstanden, dass am Beginn deiner Zeilen eine Zeitangabe steht, deshalb ist mein Lösungsansatz etwas generisch. Du kannst ihn aber etwa so an deine Bedürfnisse anpassen:

Delphi-Quellcode:

procedure TDemoForm.DoLine(lineCount: Integer; line: String);
begin
  KeepMemo.Lines.Add(line);
end;

procedure TDemoForm.DoEmptyLine(lineCount: Integer);
begin
  LogMemo.Lines.Add(Format('Zeile %d ist leer', [lineCount]));
end;

procedure TDemoForm.DoSameLine(lineCount: Integer; line: String);
begin
  LogMemo.Lines.Add(Format('Zeile %d ist doppelt: %s', [lineCount, line]));
end;

procedure TDemoForm.CheckText(fn: TFileName);
var
  tf: TextFile;
  index, lineCount: Integer;
  lines: array [0..1] of String;
begin
  lines[0] := '';
  lines[1] := '';
  lineCount := 0;
  index := 0;
  KeepMemo.Clear;
  LogMemo.Clear;
  AssignFile(tf, fn);
  Reset(tf);
  while not Eof(tf) do
  begin
    Inc(lineCount);
    ReadLn(tf, lines[index]);
    // Test auf Leere
    if line[index] = '' then
      DoEmptyLine(lineCount) else
    // Test auf Gleichheit
    if Copy(lines[0], 1, 8) = Copy(lines[1], 1, 8) then
      DoSameLine(lineCount, lines[index]) else
    // Sonst
      DoLine(lineCount, lines[index]);
    index := 1 - index;
  end;
  CloseFile(tf);
end;

Der Ansatz unterscheidet sich geringfügig von Hawkeyes Ansatz.

Besser du findest die Bedeutung des lines array selbst heraus - andernfalls wird dir sicher noch geholfen.

Gute Nacht
marabu

Edit: Fehlendes ELSE eingefügt - danke Hawkeye

[capo]

hallo marabu
dein beispiel funktioniert super.

ich komme damit an einem punkt nicht weiter und zwar mit der uhrzeit.
im beispiel von Hawkeye bekomme ich noch die fehlenden uhrzeiten angezeigt

Zitat:

03:15:03
03:15:05
03:15:07
03:15:08

ich habe versucht dein beispiel mit dem beispiel von Hawkeye zu kombinieren, aber irgendwie will es nicht so wie ich will.


gute nacht
capo

[Jelly]

Zitat:

Zitat von horst

Nur noch die doppelten Zeilen herausfinden.

Davon war bislang nie die Rede.

Was willst Du denn eigentlich erreichen. Muss wirklich für jede Sekunde ein Eintrag stehen, auch wenn Du keinen Text hintendran schreibst.

[capo]

hallo Jelly

Zitat:

Davon war bislang nie die Rede.

das stimmt, wenn ich das beispiel von Hawkeye hätte anpassen können wäre ich auch nicht in die situation gekommen danach zu fragen.

Zitat:

Muss wirklich für jede Sekunde ein Eintrag stehen,

ja das ich mir wirklich wichtig.

Zitat:

auch wenn Du keinen Text hintendran schreibst.

darum geht es nicht, es geht um die fehleneden uhrzeiten, egal was dahinter oder davor steht.

ich bekomm das nicht in marabus's beispiel integriert:

Delphi-Quellcode:

    DT := StrToDateTime(Copy(Line, 1, 19));
      // Uhrzeit in Sekunden umrechen
      NewSeconds := Round(86400 * Frac(DT));
      // bei der ersten Zeile erfolgt keine Prüfung
      if (LastSeconds >= 0) then
        for i := LastSeconds + 1 to NewSeconds - 1 do
          ShowMessage (Format('Zeile %d fehlt', [i]));

gruss, capo

[Hawkeye219]

Hallo capo,

es ist ohne weiteres möglich, meinen und marabus Code zusammenzuführen. Die Routine DoLine erhält alle gültigen Zeilen der Eingabedatei. Hier kann also die Überprüfung auf fehlende Zeilen vorgenommen werden. Die notwendige Variable LastSeconds aus meinem Code bringst du am besten im private-Abschnitt des Formulars unter, die Initialisierung der Variablen in der Methode FormCreate.

Zwei kleine Änderungen würde ich an marabus Code noch vornehmen. Das fehlende "else" hast du wahrscheinlich schon entdeckt, die Umschaltung der Variablen index sollte meiner Meinung nach nur nach einer gültigen Zeile vorgenommen werden. Ansonsten erscheinen mehrfache doppelte Zeilen, die durch Leerzeilen unterbrochen werden, mehrfach im Ausgabeprotokoll.

Delphi-Quellcode:

type
  TDemoForm = class (TForm)
    :
  private
    LastSeconds : Integer;
  end;

procedure TDemoForm.FormCreate(Sender: TObject);
begin
  LastSeconds := -1;
end;

procedure TDemoForm.CheckForMissingLines (line: String);
var
  DT : TDateTime;
  NewSeconds : Integer;
  i : Integer;
begin
  DT := StrToTime(Copy(line, 1, 8));
  NewSeconds := Round(86400 * DT);
  if (LastSeconds >= 0) then
    for i := LastSeconds + 1 to NewSeconds - 1 do
      LogMemo.Lines.Add(Format('Eintrag für Uhrzeit %s fehlt', [TimeToStr(i / 86400)]));
  LastSeconds := NewSeconds;
end;

procedure TDemoForm.DoLine(lineCount: Integer; line: String);
begin
  CheckForMissingLines (line);
  KeepMemo.Lines.Add(line);
end;

procedure TDemoForm.DoEmptyLine(lineCount: Integer);
begin
  LogMemo.Lines.Add(Format('Zeile %d ist leer', [lineCount]));
end;

procedure TDemoForm.DoSameLine(lineCount: Integer; line: String);
begin
  LogMemo.Lines.Add(Format('Zeile %d ist doppelt: %s', [lineCount, line]));
end;

procedure TDemoForm.CheckText(fn: TFileName);
var
  tf: TextFile;
  index, lineCount: Integer;
  lines: array [0..1] of String;
begin
  lines[0] := '';
  lines[1] := '';
  lineCount := 0;
  index := 0;
  KeepMemo.Clear;
  LogMemo.Clear;
  AssignFile(tf, fn);
  Reset(tf);
  while not Eof(tf) do
  begin
    Inc(lineCount);
    ReadLn(tf, lines[index]);
    // Test auf Leere
    if lines[index] = '' then
      DoEmptyLine(lineCount) else
    // Test auf Gleichheit
    if Copy(lines[0], 1, 8) = Copy(lines[1], 1, 8) then
      DoSameLine(lineCount, lines[index])
    // Sonst
    else // <<-- dieses else fehlte
      begin
        DoLine(lineCount, lines[index]);
        index := 1 - index; // <<-- Umschaltung nur nach gültigen Zeilen
      end;
  end;
  CloseFile(tf);
end;

Gruß Hawkeye

[capo]

hallo
dankeschön für die wahnsinns hilfe.

ich trau mich schon fast nicht mehr zu fragen.
CheckForMissingLines (line); funktioniert irgendwie nicht. Es werden keine fehlenden Zeiten angezeigt.
ich kann nirgends einen fehler sehen.

capo

[marabu]

Hi Capo,

der von Hawkeye angepasste Code tut es einwandfrei. Wie sehen deine Daten aus?

Grüße vom marabu

[capo]

hi marabu

stimmt dein beispiel funktioniert.

eine zeile sieht von der struktur so aus

Zitat:

1.1 10:00:08 test test test test test
1.1 10:00:09 test test test test test
1.1 10:00:10 test test test test test

gruss, capo

[marabu]

Wir gingen bisher davon aus, dass die Uhrzeit am Anfang der Zeile steht. Damit deine Beispielzeilen korrekt verarbeitet werden, müsstest du in der Prozedur CheckForMissingLines() folgende Zeile ändern:

Delphi-Quellcode:

// DT := StrToTime(Copy(line, 1, 8));
DT := Between(line, ' ', ' ');

Die Funktion Between() könnte so aussehen:

Delphi-Quellcode:

function Between(const s, sLeft, sRight: String): String;
var
  iLeft, iRight: Integer;
begin
  iLeft := Pos(sLeft, s);
  if iLeft > 0 then
  begin
    Inc(iLeft, Length(sLeft));
    iRight := PosEx(sRight, s, iLeft);
    if iRight > 0
      then Result := Copy(s, iLeft, iRight - iLeft)
      else Result := ''
  end else Result := '';
end;

Auch die Funktion PosEx() findest du hier im Forum, falls du sie nicht in der Unit StrUtils hast. Du solltest vielleicht deine Delphi-Version in dein DP-Profil eintragen.

Ganz allgemein gilt, dass du ein Muster in deinen Daten erkennen und den Code zur Extraktion der Zeitangaben entsprechend anpassen musst. Und vergiss nicht, dass es Probleme beim Tagwechsel geben wird, wenn du keine Vorkehrungen triffst.

marabu

[capo]

weißt du was ich nicht verstehe.
wieso kopiert

Delphi-Quellcode:

 DT := StrToTime(Copy(line, 5, 12));

nicht die uhrzeit heraus egal was davor oder dahinter steht?
in dem beispiel für horst steht ja auch noch etwas davor.

so sieht der text aus

Zitat:

1.1 10:00:08 test test test test test
1.1 10:00:09 test test test test test
1.1 10:00:10 test test test test test

Delphi-Quellcode:

---------------------------
Benachrichtigung über Debugger-Exception
---------------------------
Im Projekt Demo.exe ist eine Exception der Klasse EConvertError aufgetreten. Meldung: ''10:00:08 tes' ist keine gültige Uhrzeit'. Prozess wurde angehalten. Mit Einzelne Anweisung oder Start fortsetzen.
---------------------------
OK   Hilfe   
---------------------------

mensch ist das schwer.

capo

[marabu]

Die zwölf als zweites Argument im Aufruf von Copy() ist etwas reichlich bemessen - Copy(line, 5, 8) würde reichen und wahrscheinlich auch ein besseres Ergebnis liefern. Schau doch mal in die Online-Hilfe ...

marabu

[capo]

okay das klappt nun *puhh*
danke

capo

[Sir Rufo]

Wen es interessiert ... hier eine Between-Funktion, die auch mit geschachtelten Variablen zurechtkommt.
Der Aufruf Between( '{{Variable}}', '{', '}' ) ergibt in dieser Funktion '{Variable}'
in der Funktion von marabu erhält man '{Variable'

Delphi-Quellcode:

function Between(const S : string; const Start, Stop : char): string;
var
  sp,
  il,
  ir : integer;
begin
  sp := Pos( Start, S );
  if ( sp > 0 )
  then begin
    inc( sp );
    il := sp;
    ir := sp;
    repeat
      ir := PosEx( Stop, S, ir );
      il := PosEx( Start, S, il );
      if (il = 0) or ( il > ir )
      then
        il := 0
      else begin
        il := il + 1;
        ir := ir + 1;
      end;
    until (il = 0) or (ir = 0);
    RESULT := copy(S, sp, ir - sp );
  end
  else
    RESULT := '';
end;

War nur so als Zeitvertreib gedacht :mrgreen: