Stringrid

[RafNix]

Hallo Leute

Habe folgende Problemchen mit meinem StringGrid: :coder2:

Übertrage Messwerte in ein StringGrid. Nachdem ich dieses speichere und wieder aufrufe sollen neue Werte dazu kommen.
Jetzt sollen diese natürlich an die nächste Stelle der Grids angehängt werden.
Mein Quelltext fügt diese aber an das Ende des Grids das mit 100 vorgegeben ist hinzu.

Delphi-Quellcode:

procedure TForm1.bestehendenAuftragladen1Click(Sender: TObject);
          var
          n          : integer;
          f          : textfile;
          zeile,pfad,verz,datei      : string;
          laufwerk:                  char;
          MyStringList: TstringList;

          begin
          MyStringList := TStringList.Create;
          StringGrid1.Rowcount := 100;

          if
          OpenDialog1.Execute

          then begin
          try
          pfad := opendialog1.filename;
          ProcessPath(pfad,laufwerk,verz,datei);
          assignfile(f,opendialog1.filename);
          MyStringList.CommaText := ChangeFileExt(datei,'');

          Panel2.Caption := MyStringList[0];
          Panel7.Caption := MyStringList[1];
          finally
          FreeAndNil(MyStringList);
          end;
          opendialog1.filename;



          reset(f);
          for n := 1 to 100 do begin
          readln(f,zeile);
          StringGrid1.cells[1,n] := zeile;
          readln(f,zeile);
          StringGrid1.cells[2,n] := zeile;
          readln(f,zeile);
          StringGrid1.cells[3,n] := zeile;
          readln(f,zeile);
          StringGrid1.cells[4,n] := zeile;

          end;
          closefile(f);

          end;
end;

Wäre auch nicht schlecht wenn Ich die Größe des Feldes nicht vorgeben müsste,
sondern diese sich nach der größe der Datei/Grids richtet.

Hab diese Sachen schon mit der eoF- funktion versucht. Komme aber auf keinen grünen Zweig!! :wall:

Danke im Vorraus!

[mkinzler]

Ersetzte mal

Delphi-Quellcode:

for n := 1 to 100 do begin

mit

Delphi-Quellcode:

While not Eof( f) do

. Du liest auch 100 Zeilen ein, egal wieviele Einträge gespeichert sind. Wenn mehr als 100 DS in Textdatei steht, wederden dann auch nur 100 geladen.

[RafNix]

:(
Funzt net!
Erstellt mir ein neues Feld und fügt mir die neuen Werte hinzu.
Lädt aber mein altes Grid nicht!

[marabu]

Herzlich willkommen in der Delphi-PRAXiS, RafNix.

Das Laden eines StringGrid aus einer CSV-Datei ist sehr einfach:

Delphi-Quellcode:

procedure LoadFromFile(sg: TStringGrid; csv: TFileName);
var
  sRows, sCols: TStrings;
  i: Integer;
begin
  sRows := TStringList.Create;
  sRows.LoadFromFile(csv);
  sCols := TStringList.Create;
  sCols.CommaText := sRows[0];
  sG.ColCount := sCols.Count;
  sCols.Free;
  SG.RowCount := sRows.Count;
  for i := 0 to Pred(sRows.Count) do
    SG.Rows[i].CommaText := sRows[i];
  sRows.Free;
end;

procedure TDemoForm.LoadButtonClick(Sender: TObject);
begin
  LoadFromFile(SG, 'C:\daten\messdaten.csv');
end;

Dabei wird das Grid schon optimal dimensioniert. Wenn du dann später neue Werte eintragen willst und diese in einer CSV-Zeile bereit stellst, dann geht das Anhängen so:

Delphi-Quellcode:

procedure AddRow(sg: TStringGrid; row: String);
var
  iCol, iRow: Integer;
begin
  iRow := SG.RowCount;
  SG.RowCount := Succ(iRow);
  for iCol := 0 to Pred(SG.ColCount) do
    SG.Rows[iRow].CommaText := row;
end;

procedure TDemoForm.AddButtonClick(Sender: TObject);
var
  s: TStrings;
begin
  s := TStringList.Create;
  if InputRow(s) then
    AddRow(sg, s.CommText);
  s.Free;
end;

InputRow() ist eine Funktion, welche eine neue Zeile mit Messwerten im CSV-Format bereit stellt.

Freundliche Grüße vom marabu

[DieFliege]

Hallo zusammen,

ja ich weiß, das Thema ist alt, dennoch habe ich genau hier wieder mal ein Problem.

Mein Ziel ist es, eine CSV-Datei in ein StringGrid einzulesen. Dazu habe ich die Funktion von marabu verwendet (und nichts daran geändert). Über eine Google Tabelle habe ich nun eine Adressliste erstellt und diese als CSV heruntergeladen und möchte sie einlesen. Dabei erhalte ich dieses Ergebnis:

Quelle Google:
Anhang 55798

So sieht es nach dem Importieren im StringGrid aus:
Anhang 55799

Die Felder der Tabelle in Google werden hier teilweise berücksichtigt, das Leerzeichen dient hier scheinbar als "Separator" zu dienen. In Excel selbst, werden die Tabellenfelder der Google-CSV-Datei wie in der Google-Tabelle dargestellt:
Anhang 55800


Da es mit keine Ruhe gelassen hat, habe ich mir eine CSV-Datei über Excel 2000 erstellt und dort das Semikolon als Separator verwendet:
Anhang 55801

So sieht es dann im StringGrid nach dem Importieren aus:
Anhang 55802

Immer scheint Delphi (Version 10.2) das Leerzeichen als Separator zu verwenden. Vermeide ich die Leerzeichen, wird alles korrekt importiert. Was genau mache ich falsch, bzw. wo ist mein Denkfehler? Über etwas Hilfe wäre ich dankbar :-)

LG DieFliege

[DeddyH]

Versuch doch mal, StrictDelimiter der Stringliste auf true zu setzen, bevor Du importierst.

[dummzeuch]

Ohne mir den Code jetzt explizit angesehen zu haben, vermute ich, dass da irgendwo eine Stringlist mit CommaText verwendet wird. Stattdessen sollte man StringList mit StrictDelimter = True, Delimiter = ',' und DelimitedText verwenden.

Ich bin mir gerade nicht sicher, ob StrictDelimiter=True auch für CommaText funktioniert.

[Alallart]

Das ist korrekt, so steht es übrigens auch in der Delphi-Hilfe. Delphi betrachtet das Komma und Leerzeichen als Trenner.

Code:

String 1, String 2, String 3,String4

wird so zerlegt

Code:

String
1
String
2
String
3
String4

Es gibt hier zwei Lösungen. Die erste: du setzt die Felder in Anführungszeichen:

Code:

"String 1", "String 2", "String 3","String4"

wird so zerlegt

Code:

String 1
String 2
String 3
String4

Die zweite Möglichkeit ist StrictDelimiter (habe ich mal gelesen). Allerdings noch nie damit gearbeitet, da ich noch eine etwas ältere Delphi-Version habe.

Falls jemand den Code der Methode hat, könnte er eventuell hier veröffentlichen, zu Studierzwecken.

[jaenicke]

Zitat:

Zitat von Alallart (Beitrag 1518323)

Allerdings noch nie damit gearbeitet, da ich noch eine etwas ältere Delphi-Version habe.

Falls jemand den Code der Methode hat, könnte er eventuell hier veröffentlichen, zu Studierzwecken.

Hol dir doch einfach die aktuelle Community Edition und schau selbst hinein. ;-)

[DieFliege]

Hallo :-)

Erst mal vielen Dank - Ich werde es mir anschauen und gucken ob ich da was finde. Zur Info noch, dies ist der bisher verwendete Code:

Delphi-Quellcode:

//##############################################################################
//############################# CSV-Datei einlesen #############################
procedure LoadGrid(grid: TStringGrid; csv: TFileName);
var
  sRows : TStrings;
  sCols : TStrings;
  i     : Integer;
begin
  sRows := TStringList.Create;
  sRows.LoadFromFile(csv);
  sCols := TStringList.Create;
  sCols.CommaText := sRows[0];
  grid.ColCount := sCols.Count;
  sCols.Free;
  grid.RowCount := sRows.Count;
  for i := 0 to Pred(sRows.Count) do
    grid.Rows[i].CommaText := sRows[i];
  sRows.Free;
end;

procedure TForm1.btn_google_csvClick(Sender: TObject);
begin
  LoadGrid(StringGrid1, 'adressen_google_csv.csv');
end;
//##############################################################################

LG DieFliege

[DieFliege]

Hallo,

leider komme ich mit "StrictDelimiter := True", "Delimiter = ','" und "DelimitedText" nicht weiter - Vermutlich denke ich auch einfach zu kompliziert :-(

Nun habe ich es erst mal mit

Code:

"String 1", "String 2", "String 3", "String 4"

gelöst. Irgendwie habe ich das Gefühl, dass dies eher die "Dummy-Lösung" ist. Vielleicht komme ich ja noch auf eine bessere Lösung - Trotzdem erst mal Danke!

LG DieFliege

[himitsu]

Im Prinzip war das schon immer ein Bug (besch*** Verhalten), welcher durch StrictDelimiter gefuxt wurde.

https://docwiki.embarcadero.com/Libr...trictDelimiter

[shebang]

Falls du XE4 verwendest wird dir diese Lösung wahrscheinlich nicht helfen, da sie Generics und TStringHelper verwendet. Ich möchte sie der Vollständigkeit halber trotzdem posten.

Delphi-Quellcode:

procedure LoadGrid(grid: TStringGrid; csv: string);
var
  lines, values : TArray<string>;
begin
  lines := TFile.ReadAllLines(csv);

   grid.RowCount := Length(lines);
   for var i := 0 to High(lines) do 
   begin
      values := lines[i].Split([',']);
      for var j := 0 to High(values) do 
      begin
        grid.Cells[j, i] := values[j];
      end
   end;
end;

Das Setzen von ColCount hab ich hier weggelassen, da die Anzahl an Spalten normalerweise vorher bekannt sein dürfte. Falls nicht, sollte sich der Code leicht anpassen lassen.

[Alallart]

Da mich das Thema selbst interessiert hat, und das StrictDelimiter bei mir nicht funktioniert hat, zumindest bei Lazarus, habe ich paar Funktionen geschrieben, die das Leerzeichen ignorieren. Wobei ich hier eigentlich den vorhandenen Code etwas angepasst habe (das meiste ist also nicht von mir). Auf die Idee hat mich himitsu gebracht, als er von einem Bug sprach. Ich weiß nicht ob das ein Bug ist, aber die erste Funktion zerlegt beliebige DelimiterText'e nun korrekt und ignoriert das Leerzeichen. Die zweite Funktion erstellt aus Werten in TStringList einen beliebigen DelimiterText. Die dritte Funktion konvertiert beliebigen DelimiterText in ein CommaText.

Delphi-Quellcode:

{Funktion zerlegt den CommaText, bzw. DelimiterText vom Typ:
 'Bernd "Doc.",Maitre ,Schönfließer Str. 2 ,10439,"Berlin",25.10.1974'
 in Einzelteile. Im Gegensatz zum CommaText, bzw. DelimiterText von TStringList
 werden hier die Leerzeichen ignoriert, sind also keine Trennzeichen.
 Das Ergebnis von Value-String wird in List-TStringList zurückgegeben.
 Result gibt den Count, also Anzahl der Datensätze zurück.
}
function DelimitedTextFunc(List: TStringList; const Value: string;
  Delimiter: Char = ','; QuoteChar: Char = '"'): Integer;
var
  S: string;
  P, P1: PChar;
begin
  List.Clear;

  P := PChar(Value);

  while P^ in [#1..' '] do
    P := CharNext(P);

  while P^ <> #0 do
  begin
    if P^ = QuoteChar then
      S := AnsiExtractQuotedStr(P, QuoteChar)
    else
    begin
      P1 := P;
      while (P^ <> Delimiter) and (P^ <> #0) do
        P := CharNext(P);

      SetString(S, P1, P - P1);
    end;
    List.Add(S);

    while P^ in [#1..' '] do
      P := CharNext(P);

    if P^ = Delimiter then
    begin
      P1 := P;
      if CharNext(P1)^ = #0 then
        List.Add('');

      repeat
        P := CharNext(P);
      until not (P^ in [#1..' ']);
    end;
  end;

  Result := List.Count;
end;

{Funktion erstellt aus Werten einer TStringListe, ein Coma-, bzw. DelimiteText
}
function CommaTextFunc(List: TStringList; Delimiter: Char = ',';
  QuoteChar: Char = '"'): string;
var
  S: string;
  P: PChar;
  I, Count: Integer;
begin
  Count := List.Count;
  if (Count = 1) and (List[0] = '') then
    Result := QuoteChar + QuoteChar
  else
  begin
    Result := '';
    for I := 0 to Count - 1 do
    begin
      S := List[I];
      P := PChar(S);
      while not (P^ in [#0..' ', QuoteChar, Delimiter]) do
        P := CharNext(P);

      if (P^ <> #0) then
        S := AnsiQuotedStr(S, QuoteChar);
      Result := Result + S + Delimiter;
    end;
    System.Delete(Result, Length(Result), 1);
  end;
end;

{Funkion konvertiert einen beliebigen DelimiterText, mit beliebigen Delimiter
 und QuoteChar, in ein CommaText mit Komma und Anführungszeichen.
 Vorsicht! Value muss mit dem angegbenem Delimiter und QuoteChar getrennt sein,
 sonst wird falsch getrennt. Rückgabe ist immer mit Komma getrennt und in
 Anführungszeichen gesetzt.

 Noch nicht aufführlich getestet!!!
}
function DelimiterTextToCommaText(const Value: string; Delimiter: Char = ',';
  QuoteChar: Char = '"'): string;
var
  sl: TStringList;
  i: Integer;
begin
  sl := TStringList.Create;
  try
    DelimitedTextFunc(sl, Value, Delimiter, QuoteChar);

    for i := 0 to sl.Count - 1 do
    begin
      //Result := Result + '"' + sl.Strings[i] + '"';

      Result := Result + AnsiQuotedStr(sl.Strings[i], '"');
      if i < (sl.Count - 1) then
        Result := Result + ',';
    end;
  finally
    sl.Free;
  end;
end;

Zum Testen:

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var
  sl: TStringList;
  s: string;
begin
  //s := '"Sebastian" ,"Kopetzky" ,"Hofer Str. 15 A" ,"95189","Köditz","03.07.1957"';
  //s := 'Johannes ,Wagner ,Erich- Weinert- Straße 8 ,1774,Pretzschendorf,27.11.1983';
  //s := 'Bernd "Doc.",Maitre ,Schönfließer Str. 2 ,10439,Berlin,25.10.1974';
  s := '"Boris ""Bobele""","Becker" ,"Hauptstr. 1" ,"10458","Berlin","22.11.1967"';
  //s := '"Stri,ng 1","Stri""ng 2","String 3",String4';
  //s := '"Stri,ng 1", "Stri""ng 2" , String 3,String4';
  //s := '"Abcd ef", ghijk, lmn';

  sl := TStringList.Create;
  try
    DelimitedTextFunc(sl, s);

    ShowMessage(sl.Text);
    ShowMessage('Count: ' + IntToStr(sl.Count));
    ShowMessage(CommaTextFunc(sl));
  finally
    sl.Free;
  end;
end;