Bild über TSocket senden

[F.Art]

Ich habe nun seit mehreren Tagen versucht ein Bild über TSocketServer zum Client zu senden, leider ohne erfolg. Ich hoffe mal das hier Leute mir helfen es zu schaffen. Es soll soetwas ähnliches wie VNC werden. Mit dem folgenden Code mache ich ein Screenshot was in ein Stream geladen werden soll und vom SocketServer zum Client gesendet werden soll. Und in ein Image eingeladen werden soll.

Delphi-Quellcode:

procedure Screenshot(Quality: Integer);
type  
  TJPEGQualityRange = 1..100;
var
   DeskWnd: HWnd;
   DeskDC: HDC;
   DeskCv: TCanvas;
   R: TRect;
   W, H: Integer;
   Jpg: TJpegImage;
   BMP: TBitmap;
begin
DeskWnd := GetDesktopWindow;
DeskDC := GetWindowDC(DeskWnd);
DeskCv := TCanvas.Create;
DeskCv.Handle := DeskDC;
W := Screen.Width;
H := Screen.Height;
R := Bounds(0, 0, W, H);
BMP := TBitmap.Create;
Jpg := TJpegImage.Create;
try
   BMP.HandleType := bmDIB;
   BMP.PixelFormat := pf24Bit;
   BMP.Width := W;
   BMP.Height := H;
   BMP.Canvas.CopyMode := cmSrcCopy;
   BMP.Canvas.CopyRect(R, DeskCv, R);
   Jpg.CompressionQuality := Quality;
   Jpg.Assign(BMP);
   Jpg.SaveToFile('bild.jpg');
   finally
   BMP.Free;
   Jpg.Free;
   DeskCv.Free;
   ReleaseDC(DeskWnd, DeskDC);
   end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
Screenshot(80);
end;

Das Bild muss nun erst in ein Stream geladen werden anstatt als Datei abgelegt werden.
Dann an den Client gesendet und dort in das Image eingeladen werden.
Und alle 5 sec ein neuer Screenshot versendet werden.

[Luckie]

Lass Screenshot doch einen MemoryStream zurück geben, den du dann einfach verschickst.

[F.Art]

Das mit dem Stream werde ich mal testen, aber mein Hauptproblem ist,
wie sende ich das dann über Socket?
Daran bin ich gerade am verzweifeln.

[Luckie]

Ergo heißt dein Probelm auch nicht "Bilder mittels TSocket verschicken" sondern: "Wie verschicke ich einen Stream mit der TSocket Komponente".

[Chris1986]

Hi F.Art,
habe die Sockets schon lange nichtmehr installiert und auch damals nur wenig mit ihnen gearbeitet, aber wahrscheinlich musst du den Memorystream zunächst in mehere Teile zerlegen (jedes Teil sollte so um die 10-20kb groß sein), dann das 1. Teil in den Buffer der Sockets schreiben und anschließend senden. Die anderen Teile verarbeitest du analog. Die Daten musst du am Server sammeln und Stück für Stück wieder zu einem Stream zusammensetzen.
Um zu garantieren, dass der Stream auch richtig wieder zusammengesetzt wird solltest du dir zusätzlich einige Methoden überlegen, mit denen zunächst die Anzahl der Pakete und die Gesamtgröße übermittelt wird. Ausserdem solltest du die Pakete in irgendeiner Art und Weise nummerieren. Es kann leicht passieren, das sich Pakete auf dem Weg zum Server "überholen".

Gruß
Christian

[F.Art]

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, JPEG, ExtCtrls, ExtDlgs;

type
  TForm1 = class(TForm)
    Button1: TButton;
    Image1: TImage;
    procedure Button1Click(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;
  ScreenStream: TMemoryStream;

implementation

{$R *.dfm}

procedure Screenshot(Quality: Integer);
type  
  TJPEGQualityRange = 1..100;
var
   DeskWnd: HWnd;
   DeskDC: HDC;
   DeskCv: TCanvas;
   R: TRect;
   W, H: Integer;
   Jpg: TJpegImage;
   BMP: TBitmap;
begin
DeskWnd := GetDesktopWindow;
DeskDC := GetWindowDC(DeskWnd);
DeskCv := TCanvas.Create;
DeskCv.Handle := DeskDC;
W := Screen.Width;
H := Screen.Height;
R := Bounds(0, 0, W, H);
BMP := TBitmap.Create;
Jpg := TJpegImage.Create;
try
   BMP.HandleType := bmDIB;
   BMP.PixelFormat := pf24Bit;
   BMP.Width := W;
   BMP.Height := H;
   BMP.Canvas.CopyMode := cmSrcCopy;
   BMP.Canvas.CopyRect(R, DeskCv, R);
   Jpg.CompressionQuality := Quality;
   Jpg.Assign(BMP);
   Jpg.SaveToStream(ScreenStream);
   finally
   BMP.Free;
   Jpg.Free;
   DeskCv.Free;
   ReleaseDC(DeskWnd, DeskDC);
   end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
ScreenStream:=TMemoryStream.Create;
Screenshot(80);
try
   Image1.Picture.Bitmap.LoadFromStream(ScreenStream);
  except
   ScreenStream.Free;
  end;  
end;

Jetzt habe ich ein Problem mit dem Stream. Wie müsste es sein das er den Screenshot in das Image einwirft? Ist die umsetzung mit dem Stream richtig?

Ich könnte Codes zu Socket gebrauchen, da ich nicht weis wie das geht.

[Chris1986]

Habs netterweise mal ausprobiert.
Folgendes ist falsch:
TBitmap.LoadfromStream erwartet einen Stream, der mit einem Bitmap gefüllt ist. JPEG scheint nicht zu gehen. Desweiteren musst du die Position, von der an im Stream gelesen wird, wieder auf 0 setzen. Als letztes ist noch der try except Block falsch.
Wenn keine Exception auftritt wird Screenstream nicht wieder freigegeben. Was du wahrscheinlich meinst ist ein try finally Block.

Gute Nacht
Christian

[Highway]

Was ist denn genau dein Problem?

Hast du ein Problem mit dem Screenshot oder mit der Übertragung?

Wenn du ein Problem mit dem Screenshot hast würde ich dir vorschlagen erst einmal eine normale binärdatei zu übertragen. Einen Fallstrick gibt es aber auch noch dort: Du musst die Binärdaten umkodieren, beispielsweise in Code64 (findest du als Indy Komponente) oder ähnliches. Die Gegenseite muss natürlich auch wieder decodieren. Unter PHP bespielsweise gibt es eine entsprechende Funktion. Wenn die Gegenseite auch eine Delphi-Applikation ist kannst du wieder eine Indy-Komponente verwenden.

Grüße,

Highway

[F.Art]

Wie bekomme ich nun ein JPG Stream in das Image rein?
JPG kann man als File laden, also denke ich mal das es doch bestimmt irgendwie als Stream auch geht.

Der Server soll halt ein Screenshot machen und in JPG umwandeln und über Socket an den Client senden,
wo er in einem Image angezeigt werden soll.

[ManuMF]

Dann würde ich die JPEG-Datei als Datei versenden: Beispiel mit den INDYs.

Gruß,
ManuMF

[bladecs]

oder so :

Delphi-Quellcode:

procedure ScreenShot(const Bitmap: TBitmap);
var
  DesktopDC: HDC;
begin
  DesktopDC := CreateDC('DISPLAY', nil, nil, nil);
  try
    Bitmap.PixelFormat := pfDevice;
    Bitmap.Width := Screen.Width;
    Bitmap.Height := Screen.Height;
    BitBlt(Bitmap.Canvas.Handle, 0, 0, Screen.Width, Screen.Height, DesktopDC, 0, 0, SRCCOPY);
  finally
    DeleteDC(DesktopDC);
  end;
end;
////////////////////////////////////////////////////////////////////////////


// Für den Client: /////////////////////////////////////////////////////////
var
Rec: Boolean=false;
rM: TMemoryStream;
rSize: Int64;

procedure TForm1.ClientSocket1Read(Sender: TObject;
  Socket: TCustomWinSocket);
var
rL : Integer;
Pic: TJpegimage;
begin
rL := Socket.ReceiveLength;
If rL = 0 then Exit;
If Rec then begin
   Socket.ReceiveBuf(Pointer(Int64(rM.Memory) + rM.Position)^, rL);
   rM.Position := rM.Position + rL;
   ProgressBar1.Position:=round(rm.position/rsize*100);   //Fortschritt anzeigen lassen
        If rM.Position = rSize then begin
        ProgressBar1.Position:=100;                       //Fortschritt anzeigen lassen
        rM.Position := 0;
        Pic := TJpegimage.Create;
            try
            Pic.LoadFromStream(rM);
            Image1.Picture.Assign(Pic);
            Image1.Refresh;
            finally
            Pic.Free;
            end;
        FreeAndNil(rM);
        Rec := False;
        end;
end
else begin
    rSize := StrToInt(Socket.ReceiveText);
    rM := TMemoryStream.Create;
    rM.SetSize(rSize);
    rM.Position := 0;
    Rec := True;
    Socket.SendText('ok');
    end;
end;
// Ende der Clientprocedure  ////////////////////////////////////////////////


// Für den Server:  /////////////////////////////////////////////////////////
var
sM : TMemoryStream;

procedure TForm1.ServerSocket1ClientRead(Sender: TObject;
  Socket: TCustomWinSocket);
var
Bmp : TBitmap;
Jpeg : TJpegimage;
empfangen:string;
begin
empfangen:=socket.ReceiveText;

if leftstr(empfangen,length('Screenshot'))='Screenshot' then begin
    FreeAndNil(sM);
    Bmp:=TBitmap.Create;
    Jpeg:=TJpegImage.Create;
    sM:=TMemoryStream.Create;
        try
        ScreenShot(bmp);
       Jpeg.CompressionQuality:=strtoint(rightstr(empfangen,length(empfangen)-length('Screenshot'))); 
        Jpeg.Assign(Bmp);
        Jpeg.SaveToStream(sM);
        finally
        Jpeg.Free;
        Bmp.Free;
        end;
    Socket.SendText(IntToStr(sM.Size));
end;

// Empfänger hat Größe erhalten, das senden der Datei wird durchgeführt
If empfangen='ok' then begin
Socket.SendBuf(sM.Memory^, sM.Size);   
end;
end;
// Ende der Serverprocedure ///////////////////////////////////////////////////




// Screenshot anfordern
procedure TForm1.Button1Click(Sender: TObject);
begin
if ClientSocket1.Active then begin
ClientSocket1.Socket.SendText('Screenshot'+inttostr(scrollbar1.Position)); //Über die Scrollbar stell ich die Screenshot Qualität ein
end;
end;

[F.Art]

Folgende Fehlermeldungen kommen noch bei dem letzigen Code.

[Fehler] Unit1.pas(57): Undefinierter Bezeichner: 'leftstr'
[Fehler] Unit1.pas(64): Undefinierter Bezeichner: 'rightstr'

[bladecs]

Delphi-Quellcode:

uses ..,strutils;

[F.Art]

Das läuft so wunderbar.