Sekündlich wechselnde MAC Adresse!?

[EConvertError]

Hallo!

Ich schreibe gerade einen Netzwerk Traffic Monitor. Um den Adapter zu identifizieren benutze ich die MAC-Adresse. Allerdings bekomme ich jedesmal wenn ich mir neue Daten von der IPHlpApi hole (ich benutze die Header vom JEDI Project) eine andere MAC Addresse.

Hier mein Code:

Delphi-Quellcode:

procedure TTraffic.ProcessNetworkData(Sender: TObject);
var
  Size: ULONG;
  pIfTable: PMibIfTable;
begin
  { Get IfTableMIB... }
  Size := 0;
  // First call: Get memsize needed
  if not GetIfTable(nil, Size, True) = ERROR_BUFFER_OVERFLOW then
    Exit;

  try
    pIfTable := AllocMem(Size);
    if GetIfTable(pIfTable, Size, True) = ERROR_SUCCESS then
      UpdateAdaptersList(pIfTable);
  finally
    FreeMem(pIfTable);
  end;

end;

procedure TTraffic.UpdateAdaptersList(var pIfTable: PMibIfTable);
var
  I: Integer;
  Adapter: TAdapter;
begin
  { Check which TAdapter-Objects are to delete... }
  for I := 0 to FAdapters.Count -1 do
    if not IsIndexValid(TAdapter(FAdapters[I]).AdapterIndex, pIfTable) then
    begin
      { OnAdapterDelete event }
      if Assigned(FOnAdapterDelete) then
        FOnAdapterDelete(FAdapters[I] as TAdapter);
      { Delete adapter... }
      FAdapters.Delete(I);
    end;

  { Check which TAdapter-Objects are to add and update existing adapters... }
  { pIfTable^.table[x] = TMibIfRow }
  for I := 0 to pIfTable^.dwNumEntries - 1 do
  begin^
    // HIER IST DAS PROBLEM: bPhysAddr HAT IMMER EINEN ANDEREN WERT!
    Adapter := GetAdapterByMACAddr(TMACAddress(pIfTable^.table[I].bPhysAddr),
       pIfTable^.table[I].dwPhysAddrLen);
    if Adapter <> nil then
      Adapter.FeedWithData(pIfTable^.table[I])
    else
      RegisterNewAdapter(pIfTable^.table[I]);
  end

function TTraffic.GetAdapterByMACAddr(const MACAddr: TMACAddress;
   const MACAddrLen: Cardinal): TAdapter;
var
  I: Integer;
begin
  { Return adapter with given MAC-address }
  Result := nil;
  for I := 0 to FAdapters.Count -1 do
  begin
    if (TAdapter.MacAddrToStr(MACAddr, MACAddrLen)) = (TAdapter(FAdapters[I]).MACAddr) then
    begin
      Result := FAdapters[I] as TAdapter;
      Exit;
    end;
  end;
end;

FAdapters ist eine TObjectList. Der Fehler liegt garantiert nicht bei der class function MacAddrToStr.

Das Problem ist: pIfTable^.table[I].bPhysAddr hat immer einen anderen Wert. Allerdings halte ich es für ein Gerücht, dass sich meine MAC-Adresse sekündlich ändert.

Hoffentlich kann mir jemand helfen...

Vielen Dank für eure Hilfe,
Andreas

[moritz]

Moin!

Ich vermute mal, da sitzt irgendein Pointer an der falschen Stelle. Die Mac-Adresse ändert sich im normalfall eigentlich gar nicht.

Gruß

[himitsu]

Schon mal versucht die MAC-Adresse anders auszulesen?
Diese sollte ja dann identisch du der sein, die derzeit bei dir gefunden wird, ansonsten is die Funktion zum ermitteln der MAC-Adresse defekt ^^

z.B. MAC Adresse

[s.h.a.r.k]

also normalerweise kann und darf sich die MAC-Adresse nicht ändern :mrgreen: wäre schlecht für Windows, könnte ja keine Komponenten mehr ansprechen... :zwinker:

[Lasse2002]

Also in der Annahme daß MacAddrToStr korrekt ist, müsste ich dir schreiben, daß deine Funktion richtig arbeitet. Bei mir tut sie das nämlich.

Ansonsten würde ich vermuten, daß MacAddrToStr die Länge nicht richtig auswertet, weil die letzten beiden Stellen Zufallswerte enthalten, wenn die MAC-Adresse (wie bei mir) nur 6 und nicht die Maximallänge von 8 Bytes hat.

[tommie-lie]

Zitat:

Zitat von s.h.a.r.k

also normalerweise kann und darf sich die MAC-Adresse nicht ändern

Unter Linux als root:

Code:

ifconfig ethN hw ether xx:xx:xx:xx:xx:xx

Mit ethN als gewünschte Netzwerk-Device und xx als Wert zwischen 00 und FF.

Zitat:

Zitat von s.h.a.r.k

wäre schlecht für Windows, könnte ja keine Komponenten mehr ansprechen... :zwinker:

Ich wüsste nicht, warum sich das Betriebssystem für eine MAC-Adresse interessieren sollte, von Kontrollzwecken wie zum Beispiel Windows' Product Activation mal abgesehen (soll jetzt nicht heißen, daß die MAC-Adresse in den PA-Key einwandert, ob dem so ist weiß ich nicht).

[Daniel Schuhmann]

Zitat:

Zitat von tommie-lie

Ich wüsste nicht, warum sich das Betriebssystem für eine MAC-Adresse interessieren sollte[...]

Zumindest der TCP/IP-Stack benötigt sie für das ARP-Protokoll, sonst würde die Umsetzung MAC <-> IP gar nicht funktionieren können.

ipconfig /all zeigt übrigens auch die MAC-Adressen an.

[tommie-lie]

Zitat:

Zitat von Daniel Schuhmann

Zumindest der TCP/IP-Stack benötigt sie für das ARP-Protokoll

Stimmt, habe ich nicht dran gedacht. Benötigt wird's aber auch nur für den tatsächlichen Netzwerkverkehr, ansprechen kann Windows die Karte auch so, nur eben nicht mit sinnvollem Netzwerktraffic.

Edit: Echt nicht mein Tag, diese Woche...

[EConvertError]

Danke erstmal für eure tatkräftige Hilfe!

Dass sich die MAC-Adresse (normalerweise) nicht ändern kann, ist mir klar. :wink:

Vielleicht liegt der Fehler doch in der MacAddrToStr function, deshalb hier der Code:

Delphi-Quellcode:

type
  TMacAddress = array [0..MAXLEN_PHYSADDR - 1] of Byte;

class function TAdapter.MacAddrToStr(const MacAddr: TMacAddress; AddrLen: Cardinal): String;
var
  I: Integer;
begin
  { Convert MAC-Address to string for display purposes... }
  Result := '';
  if AddrLen = 0 then
  begin
    Result := '00-00-00-00-00-00';
    Exit;
  end;
  for I := 1 to AddrLen do
    Result := Result + IntToHex(MacAddr[I], 2) + '-';
  Delete(Result, Length(Result), 1);
end;

Warum ich nicht glaube, dass dort der Fehler liegt?

Delphi-Quellcode:

{ Siehe mein bereits geposteter Code }
Adapter := GetAdapterByMACAddr(TMACAddress(pIfTable^.table[I].bPhysAddr), 
       pIfTable^.table[I].dwPhysAddrLen);

Weil in diesem Code bPhysAddr immer einen anderen Wert hat. Es ändert sich meinem Debugger zufolge immer der vorletzte Block, also z.B. 0,0,33,232,166,94,X,130, wobei sich immer X ändert. Das Programm wurde auch schon auf einem anderen Rechner getestet (dort stand mir allerdings kein Debugger zur Verfügung), auch dort "erkannte" mein Programm neue Netzwerkkarten, die sich nur in der MAC-Adresse unterschieden.

Da mir das Problem aber schon schlaflose Nächte bereitet, habe ich beschlossen den ganzen Code meines Projektes zur Verfügung zu stellen - vielleicht findet ihr ja den Fehler. Ich weiß echt nicht mehr weiter.

Falls ihr anderere Verbesserungen für mein Programm (es ist sicherlich unschwer festzustellen, dass es noch nicht fertig ist) habt, dann heraus damit, denn ich programmiere Delphi um zu lernen!

Danke,
Andreas

[Luckie]

Ohne diese Units: IPHlpApi, IpTypes, IpExport, IpRtrMib, IpIfConst wird das nichts mit dem Debuggen.

[EConvertError]

Verzeihung, diese Units gibt hier: ftp://delphi-jedi.org/api/IPHlpAPI.zip

Andreas

[Lasse2002]

Versuchs mal damit:

Delphi-Quellcode:

class function TAdapter.MacAddrToStr(const MacAddr: TMacAddress; AddrLen: Cardinal): String;
var
  I: Integer;
begin
  { Convert MAC-Address to string for display purposes... }
  Result := '';
  if AddrLen = 0 then
  begin
    Result := '00-00-00-00-00-00';
    Exit;
  end;
  for I := 0 to AddrLen-1 do  // <-- hier sollte man besser von 0 bis AddrLen-1 zählen
    Result := Result + IntToHex(MacAddr[I], 2) + '-';
  Delete(Result, Length(Result), 1);
end;

[himitsu]

Oder eine dieser beiden Varianten, wobei ich Letztere bevorzugen würde ^^

Und das der Index bei 0 beginnt, daß hat Lasse2002 schon versucht zu sagen ;)

Delphi-Quellcode:

TMacAddress = array [0..MAXLEN_PHYSADDR - 1] of Byte;

Delphi-Quellcode:

class function TAdapter.MacAddrToStr(const MacAddr: TMacAddress; AddrLen: Cardinal): String;
var
  I: Integer;
begin
  { Convert MAC-Address to string for display purposes... }
  if AddrLen = 0 then
  begin
    Result := '00-00-00-00-00-00';
    Exit;
  end;
  Result := IntToHex(MacAddr[0], 2);
  for I := 1 to AddrLen - 1 do
    Result := Result + '-' + IntToHex(MacAddr[I], 2);
end;

Delphi-Quellcode:

class function TAdapter.MacAddrToStr(const MacAddr: TMacAddress; AddrLen: Cardinal): String;
var
  I: Integer;
begin
  { Convert MAC-Address to string for display purposes... }
  if AddrLen > 0 then
  begin
    Result := IntToHex(MacAddr[0], 2);
    for I := 1 to AddrLen - 1 do
      Result := Result + '-' + IntToHex(MacAddr[I], 2);
  end
  else
    Result := '00-00-00-00-00-00';
end;

Allerdings dürfte sich, auf Grund des Indexfehlers, nur die letzte Zahl verändern und nicht die vorletzte, also wird es demnach noch ein weiteres Problem geben. :gruebel:

[EConvertError]

Ich kann mir das nicht logisch erklären, aber durch ersetzen der MacAddrToString Funktion funktioniert es, obwohl sich die MAC-Adresse in dem Array, der MacAddrToString übergeben wird, ändert (eben die vorletzte Zahl). Trotzdem kommt jetzt immer die selbe MAC-Adresse heraus, folglich bin ich glücklich!

Vielen Dank für eure Hilfe,
Andreas

[himitsu]

Bekommst du 'ne 4-stellige MAC raus?
Wenn ja, dann kann sich ruhig die vorletzte Stelle ändern, da sie ja nicht in den String einfließt ... ich dachte die vorletzte Stelle ändert sich in dem String und nicht im Array, folglich ist es OK, da die letzten 2 Stellen nicht definiert sind :)

[EConvertError]

Nein, ich habe eine 6 stellige MAC Adresse, aber die ersten beiden Zahlen sind "00-00".
Ja, die Adresse hat sich im Array schon geändert.

Aber jetzt funktioniert ja Alles.