Welcher ToolButton ruft PopupMenu auf?

[Kroko1999]

Ich habe eine TToolbar mit mehreren Buttons, u.a. zwei die per Style auf tbsDropDown gesetzt werden und beide das gleiche PopupMenu aufrufen. Wie bekomme ich nun heraus,welcher TToolButton der Auslöser ist, denn PopupMenu.PopupComponent liefert nur die Toolbar zurück?

[chrisw]

der Auslöser steht im Object Sender !

Delphi-Quellcode:

with Sender as TToolButton do Showmessage(name)

[Kroko1999]

nein, in diesem Fall steht dort TMenuItem als Sender!

[Legolas]

Hallo Kroko1999,

in dem Ereignis OnPopup des PopupMenu schreibst du:

Delphi-Quellcode:

SenderPopup:=TPopupMenu(Sender).PopupComponent;

SenderPopup mu0t du als TObject in deinem Projekt an entsprecher Stelle deklarieren.

Jetzt kannst du z.B. so die TAG Eigenschaft des jeweilihen TToolbutton auswerten:

Delphi-Quellcode:

...
If TToolbutton(SenderPopUp).Tag = 1 then
...

[teebee]

Ein schmutziger Trick:
Frage im OnPopup die aktuelle Mausposition ab und bestimme daraus den gedrückten Button, ist zwar alles andere als elegant, sollte aber gehen.

@Legolas: In PopupComponent steht die ToolBar nicht der ToolButton

Gruß, teebee

[Legolas]

Hi teebee,

ja ich weiß, ein sehr schnutziger Trick. :-D

Es funktioniert aber 100%ig und der Zweck heiligt dochdie mittel, oder?

[teebee]

Zitat:

Zitat von Legolas

Es funktioniert aber 100%ig und der Zweck heiligt dochdie mittel, oder?

Falls Du Deinen Vorschlag mit PopupComponent meinst, das funktioniert leider nicht, weil in PopupComponent die ToolBar steht und nicht der ToolButton.

Mit schmutzig meinte ich eigentlich meinen Vorschlag :wink:

Gruß, teebee

[Legolas]

Hi teebee,

probiere meinen Vorschlag einfach aus, es funktioniert. Zumindest tut es das bei mir... Habe es getestet...

Wer lesen kann ist klar im Vorteil. Dann hätte ich gemerkt das du deinen Trick meinst. :oops: Sorry...

[teebee]

Also bei mir gehts nicht...

Delphi-Quellcode:

procedure TForm1.PopupMenu1Popup(Sender: TObject);
begin
 ShowMessage(PopupMenu1.PopupComponent.Name+' '+(Sender As TComponent).Name+' '+TToolButton((Sender As TPopupMenu).PopupComponent).Name);
end;

Ich komme nicht an den ToolButton heran, auch der Cast zieht nicht (wie sollte er auch, TToolButton hat ja vererbungstechnisch nix mit TToolBar zu tun).

Gruß, teebee

[Ultimator]

Du könntest den Code im ToolButtonClick in eine eigene Funktion auslagern, die als Ergebnis den Namen des ToolButtons zurückgibt, und diese Funktion dann im eigentlichen OnClick auslösen ;)

[Kroko1999]

@teebee: Bir mir auch nicht!

@Ultimator
geht nicht, die Buttons haben alle dieselbe Proc. als OnClick, ich werte .Tag aus!

[Legolas]

@Kroko1999,

hast du das Popup der TToolbar oder dem TToolbutton zugewiesen?

Du weißt jedem TToolbutton dein PopupMenu zu und schreibst folgendes:

Delphi-Quellcode:

var
  Form1: TForm1;
  SenderPopup: TObject;

implementation

{$R *.DFM}

procedure TForm1.PopupMenu1Popup(Sender: TObject);
begin
  SenderPopup:=TPopupMenu(Sender).PopupComponent;
end;

procedure TForm1.Test1Click(Sender: TObject);
begin
  if TToolButton(SenderPopup).Name='ToolButton4' then Label1.Caption:='OK';
end;

Also bei mir funktioniert das 100%ig.

Oder habe ich falsch verstanden was du machen´willst ???

[Ultimator]

Zitat:

Zitat von Kroko1999

@teebee: Bir mir auch nicht!

@Ultimator
geht nicht, die Buttons haben alle dieselbe Proc. als OnClick, ich werte .Tag aus!

:shock: Wenn alle Buttons das gleiche tun, warum sinds dann verschiedene?

[teebee]

Zitat:

Zitat von Legolas

Oder habe ich falsch verstanden was du machen´willst ???

Ich fürchte, wir reden aneinander vorbei. Wenn man einem ToolButton den Style tbsDropDown zuweist, dann muss das Popupmenu in DropdownMenu und nicht in PopupMenu stehen, damit der Button bei einem Linksclick auf den Pfeil des Buttons das PopupMenu anzeigt. Wenn Du das Menu der Eigenschaft PopupMenu des ToolButtons zuweist, dann musst Du rechts klicken, was hier nicht gewünscht ist.
Und bei diesem Vorgehen steht in PopupComponent leider nicht der Toolbutton sondern die ganze Toolbar...

Gruß, teebee

[Kroko1999]

@legolas
ich habe zwei TToolbuttons in einer TToolbar und ich weise den Buttons.DropDownMenu das Popupmenu zu!

@ultimator
weil außer einer zuweisung, die von Button abhängt, das jeweilige PopupMenu gleich ist,
also Button1 = integer Button2 = real und im Menu die Zahlen von 1 bis 10, und je nach Button möchte ich Integer oder real rechnen, daher die Frage!

[chrisw]

Ich hab das mal so gelöst :
(keine "Schöne Lösung", aber es funzt !)

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  Menus, ComCtrls, ToolWin;

type
  TForm1 = class(TForm)
    ToolBar1: TToolBar;
    ToolButton1: TToolButton;
    ToolButton2: TToolButton;
    ToolButton3: TToolButton;
    PopupMenu1: TPopupMenu;
    MenuItem11: TMenuItem;
    procedure MenuItem11Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure ToolButton3MouseMove(Sender: TObject; Shift: TShiftState; X,
      Y: Integer);
  private
    { Private declarations }
    LastSender : TToolButton;
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.DFM}

procedure TForm1.MenuItem11Click(Sender: TObject);
begin
  showmessage(LastSender.Name);  //oder was auch immer mit dem Object machen
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  LastSender := TToolButton.Create(self);
end;

procedure TForm1.ToolButton3MouseMove(Sender: TObject; Shift: TShiftState;   //im OnMouseMove aller Buttons
  X, Y: Integer);
begin
  LastSender :=Sender as TToolButton;
end;

end.

[Khabarakh]

Wieso erstellst du denn LastSender im OnCreate?
Lieber so:

Delphi-Quellcode:

procedure TForm1.MenuItem11Click(Sender: TObject);
begin
  if Assigned(LastSender) then
    Showmessage(LastSender.Name);  //oder was auch immer mit dem Object machen
end;

[teebee]

Habe jetzt in den Tiefen der API-Doku eine Möglichkeit gefunden, die das ganze ziemlich solide macht (ohne Mausposition oder MouseOver).

Delphi-Quellcode:

 type
  TForm1 = class(TForm)
   ...
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
    DropButton: Integer;
    Procedure WMNotify(Var Msg: TWMNotify); message WM_NOTIFY;
end;

...

Procedure TForm1.WMNotify(Var Msg: TWMNotify);
Begin
  If Msg.NMHdr^.code=TBN_DROPDOWN Then
    DropButton := PNMTOOLBAR(Msg.NMHdr)^.iItem;
  inherited;
End;

procedure TForm1.PopupMenu1Popup(Sender: TObject);
begin
  ShowMessage('Gedrückt von: '+ToolBar1.Buttons[DropButton].Name); // hier wahlweise auch Tag-Auswertung :-)
end;

Gruß, teebee

[Kroko1999]

Thx , klappt alles prächtig!