Message innerhalb einer Klasse ???

[ustra]

Hallo,

ich schreibe mir gerade eine einfache Klasse, mit der ich einen Hotkey einrichte. Dazu brauche ich die Message

Delphi-Quellcode:

procedure WMHotKey(var Msg: TWMHotKey); message WM_HOTKEY;

Wenn ich die Message in einem Formular mache, funktioniert das wunderbar. Ich würde das gerne innerhalb meiner Klasse erledigen. Geht das überhaupt so in Delphi, oder muss ich die Message im Formular implementieren und dann an die Klasse bzw. dann an das Objekt weiterleiten? Ich vermute letzteres.

Besten Dank

Ulrich

PS: Ops, jetzt ist das Thema im falschen Forum gelandet. @Admins, bitte nach VCL-Komponenten und Controls verschieben

[Speedmaster]

Formular ist auch nur eine klasse...

[shmia]

Vielleicht willst du die Message lieber zentral für die gesamte Anwendung abfangen und bearbeiten??
Dann kannst du einen Eventhandler für Application.OnMessage schreiben.

Delphi-Quellcode:

procedure THauptform.HandleOnMessage(var Msg: TMsg; var Handled: Boolean);
begin
   case Msg.message of

      WM_HOTKEY:
      begin
         ; // irgendwas tun
         handled := True;
      end;
   end;
end;

[ustra]

Hi,

ich möchte es nach Möglichkeit nicht im Formular machen, sondern in meiner eigenen Klasse. So sieht die momentan aus:

Delphi-Quellcode:

unit UHotKey;

interface

uses messages, Windows, classes;

const
  MOD_CONTROL = 2;
                      
type THotkeyEvent = procedure of object;
type THotKey = class (TComponent)
  private
    FOnHotKey: THotkeyEvent;
    iHotkeyID: Integer; 
    procedure SetOnHotKey(Value: THotkeyEvent);
  public
    constructor create(sName, sKey : String; AOwner : TComponent);
    destructor destroy;
    procedure WMHotKey(var Msg: TWMHotKey); message WM_HOTKEY;  
  published
      property onHotKeyEvent: THotKeyEvent read FOnHotKey write SetOnHotKey;

end;

implementation

{ THotKey }

//Registriere Hotkey (nur in Verbindung STRG + Key)
constructor THotKey.create(sName, sKey: String; AOwner : TComponent);
begin                     
  Inherited Create(AOwner);
  iHotKeyID := GlobalAddAtom(PChar(sName));
  RegisterHotKey(0, iHotKeyID, MOD_CONTROL, Ord(sKey[1]));
end;

//Deregistriert den HotKey
destructor THotKey.destroy;
begin
  UnRegisterHotKey(0, iHotKeyID);  
  Inherited Destroy;
end;

//Beim Laden wird eine Methode zum Ereignis festgelegt
procedure THotKey.SetOnHotKey(Value: THotkeyEvent);
begin
  FOnHotKey := Value;
end;

//Message, die Nachricht bekommt, dass der HotKey gedrückt wurde und diese löst
//dann das Ereignis aus.
procedure THotKey.WMHotKey(var Msg: TWMHotKey);
begin
  if Msg.HotKey = iHotkeyId
  then
    if Assigned(FOnHotKey)
    then FOnHotKey;
end;

end.

Momentan passiert halt nichts, wenn ich die entsprechende Tastenkombination drücke.

@shmia: Das wäre die Lösung, die ich nehmen würde, wenn es nur über das Formular geht.

Kann mir jemand sagen, ob das so geht, wie ich es mir vorstelle?

Ulrich

[Dax]

Leite deine Klasse von TWinControl ab und es sollte funktionieren ;)

[teebee]

Zitat:

Zitat von Dax

Leite deine Klasse von TWinControl ab und es sollte funktionieren

Wenn Du bei RegisterHotkey Dein Handle angibst statt 0...

Gruß, teebee

[ustra]

Den Fehler habe ich auch gerade entdeckt. Anstelle der 0 habe ich jetzt

Delphi-Quellcode:

self.handle

geschrieben. Trotzdem läuft es nicht.

Woran könnte es noch liegen? Er geht auf jedenfall nicht in die Message, egal, welche Tasten ich drücke.

Danke

[DP-Maintenance]

Dieses Thema wurde von "Christian Seehase" von "Windows API" nach "VCL-Komponenten und Controls" verschoben.
Auf Wunsch von Ustra verschoben

[Christian Seehase]

Moin Ustra,

Du solltest mal prüfen, ob Dein RegisterHotKey überhaupt funktioniert hat.
Wenn die Tastenkombination bereits registriert wurde, schlägt der Aufruf fehl, da hier die Regel gilt: Wer zuerst kommt, mahlt zuerst.

[ustra]

Ich habe gerade das Objekt in einer kompletten leeren Anwendung implementiert und dort kommt dann die Meldung: Element hat kein übergeordnetes Fenster.

Hilft das weiter?

Nachtrag: 2 Minuten zu spät. Unabhängig vom obigen Text: Ich habe das einmal direkt in ein Formular geschrieben und dann funktionierte es auch => Die Tastenkombination ist nicht belegt.

[teebee]

Diese Fehlemeldung kriegt man, wenn man zu früh auf das Handle zugreifen will. In Create hat man das noch nicht. (Weil der Parent noch keins hat, dessen Parent noch keins hat, usw.) Überschreibe mal CreateWnd und registriere den HotKey dort nach dem inherited.
Parent setzen nicht vergessen, wenn Du die Komponente selbst erzeugst.

Gruß, teebee

[ustra]

Habe jetzt

Delphi-Quellcode:

procedure THotKey.CreateWnd;
begin
  inherited CreateWnd;
  iHotKeyID := GlobalAddAtom(PChar(sName));
  RegisterHotKey(self.handle, iHotKeyID, MOD_CONTROL, Ord(sKey[1]));
end;

eingefügt mit einem override hinter der Methodendeklaration:

Delphi-Quellcode:

procedure CreateWnd; override;

Trotzdem funzt es nicht. Habe die Codezeilen mit Haltepunkten versehen, aber die werden ignoriert.

[teebee]

Geht es nicht oder kommt die gleiche Fehlermeldung?

[ustra]

So,

ich habe es jetzt hinbekommen. Lag daran, dass ich zwei Variablen mit den WErten nicht richtig gespeichert hatte umd demzufolge die Registrierung fehl schlug. Danke für Deine Hilfe und den anderen.

[teebee]

Mir ist noch etwas aufgefallen:

1. Das Atom musst Du auch wieder löschen, wenn Du es nicht mehr brauchst.
2. CreateWnd kann während der Lebenszeit der Komponente mehrfach aufgerufen werden:
Mit Deinem jetzigen Code erhöhst Du den Referenzzähler für Dein Atom unkontrollierbar. Also am besten das GlobalAddAtom ins Create, ins Destroy ein GlobalDeleteAtom und im CreateWnd nur das RegisterHotkey, das schlägt ja bei einer Wiederholung eh fehl (oder Du baust noch ein Flag ein, das nur einen einmaligen Aufruf gestattet).

Gruß, teebee

[generic]

poste doch bitte nochmal die ganze lösung.

danke

[ustra]

Hier der Code, wie ich diesen momentan benutze:

Delphi-Quellcode:

unit UHotKey;

interface

uses messages, Windows, classes, controls;

const
  MOD_CONTROL = 2;
                      
type THotkeyEvent = procedure of object;
type THotKey = class (TWinControl)
  private
    FOnHotKey: THotkeyEvent;
    iHotkeyID: Integer;
    sName1, sKey1 : String;
    procedure SetOnHotKey(Value: THotkeyEvent);
  public
    constructor create(sName, sKey : String; AOwner : TComponent);
    destructor destroy;
    procedure WMHotKey(var Msg: TWMHotKey); message WM_HOTKEY;   
    procedure CreateWnd; override;
  published
      property onHotKeyEvent: THotKeyEvent read FOnHotKey write SetOnHotKey;

end;

implementation

{ THotKey }

//speichert die Werte
constructor THotKey.create(sName, sKey: String; AOwner : TComponent);
begin
  Inherited Create(AOwner);
  sName1 := sName;
  sKey1 := sKey;
end;

//Registriere Hotkey (nur in Verbindung STRG + Key)
procedure THotKey.CreateWnd;
begin
  inherited CreateWnd;
  iHotKeyID := GlobalAddAtom(PChar(sName1));
  RegisterHotKey(self.handle, iHotKeyID, MOD_CONTROL, Ord(sKey1[1]));
end;

//Deregistriert den HotKey
destructor THotKey.destroy;
begin
  UnRegisterHotKey(self.handle, iHotKeyID);     
  Inherited Destroy;
end;


//Beim Laden wird eine Methode zum Ereignis festgelegt
procedure THotKey.SetOnHotKey(Value: THotkeyEvent);
begin
  FOnHotKey := Value;
end;

//Message, die Nachricht bekommt, dass der HotKey gedrückt wurde und diese löst
//dann das Ereignis aus.
procedure THotKey.WMHotKey(var Msg: TWMHotKey);
begin
  if Msg.HotKey = iHotkeyId
  then
    if Assigned(FOnHotKey)
    then FOnHotKey;
end;

end.

[teebee]

Schau Dir besser nochmal mein Posting von oben an...

Gruß, teebee

[ustra]

So, habe Deine Tipps beachtet und eingepflegt.

Besten Dank