FindFirstFile: Wie suche ich auch in Unterordnern?

[Pseudemys Nelsoni]

siehe titel. Mit werden immer nur die dateien in dem hauptordner den ich der funktion übergebe angezeigt, nicht aber die dateien dessen unterordner. Wie mache ich das?

[mirage228]

Zitat:

Zitat von Pseudemys Nelsoni

siehe titel. Mit werden immer nur die dateien in dem hauptordner den ich der funktion übergebe angezeigt, nicht aber die dateien dessen unterordner. Wie mache ich das?

Hi,

da musst Du rekursiv alle Unterordner dursuchen.

Einen enstsprechenden Code findest Du in der Library. Du musst ihn nur geringfügig ändern (einfach ne Abfrage nach Deinem Dateinamen einbauen).

mfG
mirage228

[Pseudemys Nelsoni]

moin Mirage,

ich muss noch erwähnen das ich nicht die VCL version FindFirst meine, sondern die API funktion FindFirstFile und einen code finde ich in der cod lib nicht. ich weiss derzeit nicht wie ich überhaupt an die ordner komme.

[mirage228]

Hi,

hier ist der Code:
http://www.delphipraxis.net/internal...ect.php?t=2464

Das nach nonVCL umzubauen sollte aber kein Problem darstellen (hoffe ich :mrgreen: ) - im Prinzip ist beides das selbe.

mfG
mirage228

[Pseudemys Nelsoni]

hallo mirage,

leider hilft mir das nicht :oops: FindFirst hat da einen parameter den ich bei FindFirstFile nicht habe und zwar:

Zitat:

if FindFirst(RootFolder + '*.*', faAnyFile, SR) = 0 then

[kalmi01]

Hi,
so kann man es machen, läuft mit ShellAPI:

Delphi-Quellcode:

  interface
    procedure DirSearch(SearchDir,   SearchFile : string;
                        var DirList, FileList   : TStringList);


  implementation
    procedure DirSearch(SearchDir,   SearchFile : string;
                        var DirList, FileList   : TStringList);
      var
        i         : Integer;
        SearchRec : TSearchRec;
      begin
        if SearchDir[Length(SearchDir)] <> '\' then SearchDir := SearchDir + '\';
        i := FindFirst(SearchDir + SearchFile, faDirectory, SearchRec);

        if DirectoryExists(SearchDir)
        then DirList.Add(Copy(SearchDir, 0, Length(SearchDir) -1));

        while i = 0
        do begin
             if (SearchRec.Name <> '.')
                and
                (SearchRec.Name <> '..')
             then begin
                    if DirectoryExists(SearchDir + SearchRec.Name)
                    then DirList.Add(SearchDir + SearchRec.Name);

                    if FileExists(SearchDir + SearchRec.Name)
                    then FileList.Add(SearchDir + SearchRec.Name);

                    SearchRec.Name := SearchDir + SearchRec.Name;
                    DirSearch(SearchRec.Name, SearchFile, DirList, FileList);
                  end;

             i := FindNext(SearchRec);
           end;
        FindClose(SearchRec);
      end;

Der Parameter fa.... gibt den Filetyp an, also z.B. alle Files (faAnyFile) oder nur Dir's (faDirectory).

Ich hoffe geholfen zu haben.
Gruß Michael

[Pseudemys Nelsoni]

hallo karmi,

die shellapi wollte ich eigentlich weglassen (hoffe du hast den code nicht extra geschrieben), sonst danke auf jeden fall :thumb:

Nur wie gesagt wollte ich die unit weglassen....ich dachte wie gesagt das FindFirstFile irgendwie auch unterverzeichnisse mit einbeziehen kann...aber scheint wohl nicht so.... gibt es denn sonst eine funktion um unterordner eines ordners in eine list zu bekommen oder so?
Ich möchte nämlich in einem verzeichnis(+ unterverzeichnisse) alle dateien anzeigen die die endung *.txt haben

[Luckie]

das geht mit FindeFirstFile genauso, wie mit FindFirst aus der Code-Lib. Und das umzuschreiben sollte kein Problem sein. FindFirst, FindNext durch FindFirstFile und FindnextFile ersetzen, Parameter anpassen und die eben den Rückgabewert der API-Funktionen auswerten.

Ich habe es mal schnell umgeschrieben:

Delphi-Quellcode:

procedure FindAllFiles(var FileList: TStrings; RootFolder: string; Mask: string =
  '*.*'; Recurse: Boolean = True);
var
  wfd: TWin32FindData;
  hFile: THandle;
begin
  if AnsiLastChar(RootFolder)^ <> '\' then
    RootFolder := RootFolder + '\';
  if Recurse then
  begin
    hFile := FindFirstFile(PChar(RootFolder + '*.*'), wfd);
    if hFile <> INVALID_HANDLE_VALUE then
    try
      repeat
        if wfd.dwFileAttributes and FILE_ATTRIBUTE_DIRECTORY = FILE_ATTRIBUTE_DIRECTORY then
          if (String(wfd.cFileName) <> '.') and (String(wfd.cFileName) <> '..') then
            FindAllFiles(FileList, RootFolder + wfd.cFileName, Mask, Recurse);
      until FindNextFile(hFile, wfd) = False;
    finally
      windows.FindClose(hFile);
    end;
  end;
  hFile := FindFirstFile(PChar(RootFolder + '*.*'), wfd);
  if hFile <> INVALID_HANDLE_VALUE then
  try
    repeat
      if wfd.dwFileAttributes and FILE_ATTRIBUTE_DIRECTORY <> FILE_ATTRIBUTE_DIRECTORY then
      begin
        FileList.Add(RootFolder + wfd.cFileName);
      end;
    until FindNextFile(hFile, wfd) = False;
  finally
    Windows.FindClose(hFile);
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  sl: TStrings;
begin
  sl := TStringList.Create;
  try
    FindAllFiles(sl, 'd:\', '*.*', True);
    ListBox1.Items := sl;
  finally
    sl.Free;
  end;
end;

Die TStrings wirst du mit einem dynamischen String Array los, aber das solltest du selber hinbekommen.

[MathiasSimmack]

Zitat:

Zitat von Pseudemys Nelsoni

die shellapi wollte ich eigentlich weglassen

Warum eigentlich? Die ShellAPI vergrößert dein Programm nicht bzw. unwesentlich. :)

[Muetze1]

Moin!

Zitat:

Zitat von Pseudemys Nelsoni

ich dachte wie gesagt das FindFirstFile irgendwie auch unterverzeichnisse mit einbeziehen kann...aber scheint wohl nicht so....

Einfach in dem Unterverzeichnis erneut suchen mit FindFirstFile() - es wurde doch nun schon mehrfach drauf hingewiesen das du es selber rekursiv machen musst. Vor allem: Warum sollte Windows eine solche Funktion anbieten?

MfG
Muetze1

[Luckie]

Und jetzt das ganze noch ohne TStrings und somit ohne die Unit Classes.pas:

Delphi-Quellcode:

type
  TStringDynArray = array of string;

var
  FileCount: Cardinal = 0;
  Files   : TStringDynArray = nil;

function FindAllFiles(RootFolder: string; Mask: string = '*.*'; Recurse: Boolean
  = True): TStringDynArray;
var
  wfd          : TWin32FindData;
  hFile        : THandle;
begin
  if AnsiLastChar(RootFolder)^ <> '\' then
    RootFolder := RootFolder + '\';
  if Recurse then
  begin
    hFile := FindFirstFile(PChar(RootFolder + '*.*'), wfd);
    if hFile <> INVALID_HANDLE_VALUE then
    try
      repeat
        if wfd.dwFileAttributes and FILE_ATTRIBUTE_DIRECTORY =
          FILE_ATTRIBUTE_DIRECTORY then
          if (string(wfd.cFileName) <> '.') and (string(wfd.cFileName) <> '..')
            then
            FindAllFiles(RootFolder + wfd.cFileName, Mask, Recurse);
      until FindNextFile(hFile, wfd) = False;
    finally
      windows.FindClose(hFile);
    end;
  end;
  hFile := FindFirstFile(PChar(RootFolder + '*.*'), wfd);
  if hFile <> INVALID_HANDLE_VALUE then
  try
    repeat
      if wfd.dwFileAttributes and FILE_ATTRIBUTE_DIRECTORY <>
        FILE_ATTRIBUTE_DIRECTORY then
      begin
        FileCount := length(Files)+1;
        Setlength(Files, FileCount);
        Files[FileCount - 1] := RootFolder + String(wfd.cFileName);
      end;
    until FindNextFile(hFile, wfd) = False;
  finally
    Windows.FindClose(hFile);
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  i            : Integer;
begin
  Files := nil;
  FindAllFiles('d:\Dokumente', '*.*', True);
  for i := 0 to length(Files) - 1 do
  begin
    Listbox1.Items.Add(Files[i]);
  end;
end;

[Kernel32.DLL]

Die Prozedur kommt ja wie gerufen...

[Pseudemys Nelsoni]

perfekt luckie, danke :???:

[EWeiss]

Zitat:

Zitat von Luckie

Und jetzt das ganze noch ohne TStrings und somit ohne die Unit Classes.pas:

Delphi-Quellcode:

type
  TStringDynArray = array of string;

var
  FileCount: Cardinal = 0;
  Files   : TStringDynArray = nil;

function FindAllFiles(RootFolder: string; Mask: string = '*.*'; Recurse: Boolean
  = True): TStringDynArray;
var
  wfd          : TWin32FindData;
  hFile        : THandle;
begin
  if AnsiLastChar(RootFolder)^ <> '\' then
    RootFolder := RootFolder + '\';
  if Recurse then
  begin
    hFile := FindFirstFile(PChar(RootFolder + '*.*'), wfd);
    if hFile <> INVALID_HANDLE_VALUE then
    try
      repeat
        if wfd.dwFileAttributes and FILE_ATTRIBUTE_DIRECTORY =
          FILE_ATTRIBUTE_DIRECTORY then
          if (string(wfd.cFileName) <> '.') and (string(wfd.cFileName) <> '..')
            then
            FindAllFiles(RootFolder + wfd.cFileName, Mask, Recurse);
      until FindNextFile(hFile, wfd) = False;
    finally
      windows.FindClose(hFile);
    end;
  end;
  hFile := FindFirstFile(PChar(RootFolder + '*.*'), wfd);
  if hFile <> INVALID_HANDLE_VALUE then
  try
    repeat
      if wfd.dwFileAttributes and FILE_ATTRIBUTE_DIRECTORY <>
        FILE_ATTRIBUTE_DIRECTORY then
      begin
        FileCount := length(Files)+1;
        Setlength(Files, FileCount);
        Files[FileCount - 1] := RootFolder + String(wfd.cFileName);
      end;
    until FindNextFile(hFile, wfd) = False;
  finally
    Windows.FindClose(hFile);
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  i            : Integer;
begin
  Files := nil;
  FindAllFiles('d:\Dokumente', '*.*', True);
  for i := 0 to length(Files) - 1 do
  begin
    Listbox1.Items.Add(Files[i]);
  end;
end;

Kann es sein das hier was fehlt ?
Oder welchen sinn macht es das Extension (Mask) zu übergeben ?
Ich will schon alle Dateien addieren aber nur die welche dem Extension entsprechen..

Denke dann wäre es so richtig Oder ?

Delphi-Quellcode:

  hFile := FindFirstFile(PChar(RootFolder + '*.*'), wfd); 
  if hFile <> INVALID_HANDLE_VALUE then
  try 
    repeat 
      if wfd.dwFileAttributes and FILE_ATTRIBUTE_DIRECTORY <> 
        FILE_ATTRIBUTE_DIRECTORY then 
      begin 
        if ExtractFileExt(String(wfd.cFileName)) = Mask then
        begin
          FileCount := length(Files)+1;
          Setlength(Files, FileCount);
          Files[FileCount - 1] := RootFolder + String(wfd.cFileName);
        end;
      end;
    until FindNextFile(hFile, wfd) = False;
  finally 
    Windows.FindClose(hFile); 
  end;

gruss Emil

[SirThornberry]

Das ist so damit der Fragesteller auch noch etwas machen muss und nicht einfach nur copy & paste machen kann :)

[EWeiss]

Zitat:

Zitat von SirThornberry

Das ist so damit der Fragesteller auch noch etwas machen muss und nicht einfach nur copy & paste machen kann :)

Hab nix copie & Paste
Siehe Berichtigung meinerseits.

Denke auch wenn man schon code bereitstellt dann sollte er auch funktionieren ;)
kann es sein das einige Leute hier immer unfreundlicher werden ?

gruss Emil

[Luckie]

Mein Code funktioniert immer - nur eben manchmal nicht so, wie er soll. :mrgreen:

[EWeiss]

Zitat:

Zitat von Luckie

Mein Code funktioniert immer - nur eben manchmal nicht so, wie er soll. :mrgreen:

Nö ;)
Was macht es für einen sinn ein Extension innerhalb der Funktion zu übergeben wenn es nicht ausgewertet wird.
Ansonsten ja er funktioniert. :)

War auch nicht bös von mir gemeint .. hab mich halt nur gewundert.

gruss Emil