Eintrag in TStringList wird gelöscht wenn value auf '' gesetzt wird

[softtouch]

Delphi 12.2

Ich habe eine Test Stringliste, mit folgenden Einträgen:

Delphi-Quellcode:

sl.addpair('Line1','value1');
sl.addpair('Line2','value2');
sl.addpair('Line3','value3');

zeigt mir:
Line1=value1
Line2=value2
Line3=value3

Wenn ich nun einen Wert auf '' setzte:

Delphi-Quellcode:

sl.valuefromindex[1]:='';

bleiben nur noch:
Line1=value1
Line3=value3

und nicht wie erwartet:
Line1=value1
Line2=
Line3=value3

Das ist mir neu. Wie kann ich denn einen Wert löschen ohne das der Eintrag gelöscht wird?
ich kann die Liste ja auch mit leeren Werten füllen:

Delphi-Quellcode:

sl.addpair('Line1','value1');
sl.addpair('Line2','');
sl.addpair('Line3','value3');

zeigt mir:
Line1=value1
Line2=
Line3=value3

[itsChris]

Moin, hier der Code, der bei

Delphi-Quellcode:

sl.valuefromindex[1]

aufgerufen wird und deinen Eintrag unerwartet löscht:

Delphi-Quellcode:

procedure TStrings.SetValueFromIndex(Index: Integer; const Value: string);
begin
  if Value <> '' then
  begin
    if Index < 0 then Index := Add('');
    Put(Index, Names[Index] + NameValueSeparator + Value);
  end
  else
    if Index >= 0 then Delete(Index);
end;

Wenn du auf ein Element zugreifen willst, dann kannst du einfach

Delphi-Quellcode:

sl[1] := ''

schreiben.

[himitsu]

Ja, leider werden leere Items immer gelöscht.

Du könntest ein Leerzeichen zuweisen, anstatt eines Leerstrings,
und beim Lesen halt mit Trim.

Oder, entsprechend dem PUT, die ganze Zeile zuweisen, anstatt nur den Value.

Zitat:

Delphi-Quellcode:

procedure TStrings.SetValue(const Name, Value: string);
var
  I: Integer;
begin
  I := IndexOfName(Name);
  if Value <> '' then
  begin
    if I < 0 then I := Add('');
    Put(I, Name + NameValueSeparator + Value);
  end else
  begin
    if I >= 0 then Delete(I);
  end;
end;

procedure TStrings.SetValueFromIndex(Index: Integer; const Value: string);
begin
  if Value <> '' then
  begin
    if Index < 0 then Index := Add('');
    Put(Index, Names[Index] + NameValueSeparator + Value);
  end
  else
    if Index >= 0 then Delete(Index);
end;

[itsChris]

SetValue wird aber nicht bei

Delphi-Quellcode:

sl[1] := ''

aufgerufen (Jedenfalls in Delphi 11 nicht).

[jaenicke]

Das hört sich so an, als sei z.B. ein TDictionary hier geeigneter.

[Uwe Raabe]

Zitat:

Zitat von itsChris (Beitrag 1541877)

SetValue wird aber nicht bei

Delphi-Quellcode:

sl[1] := ''

aufgerufen (Jedenfalls in Delphi 11 nicht).

In dem Fall würde ja auch nicht nur der Value geleert, sondern das gesamte Name/Value-Pair durch einen Leerstring ersetzt.

[itsChris]

Zitat:

Zitat von Uwe Raabe (Beitrag 1541882)

Zitat:

Zitat von itsChris (Beitrag 1541877)

SetValue wird aber nicht bei

Delphi-Quellcode:

sl[1] := ''

aufgerufen (Jedenfalls in Delphi 11 nicht).

In dem Fall würde ja auch nicht nur der Value geleert, sondern das gesamte Name/Value-Pair durch einen Leerstring ersetzt.

Stimmt...hab mal wieder nicht richtig gelesen. Die Zuordnung mit dem Namen hab ich übersehen :oops:.

[haentschman]

Wie wäre es denn mit TDictionary<string, string>?
https://docwiki.embarcadero.com/Libr...ns.TDictionary

[himitsu]

Da Values[name] beim Auslesen von nichtexistierenden Namen einen Leerstring zurück gibt, ist es immer Programm auch egal, ob es gelöscht wird, oder nicht.

Außer wenn es z.B. in einer Datei gespeichert werden soll und es dort für "Andere" vorhanden bleiben muß.

[softtouch]

Da die Namen in der Liste erhalten bleiben müssen, unabhängig ob Value einen Wert hat oder nicht, habe ich es einfach so gelöst:

Delphi-Quellcode:

s:=<originaler wert> oder leer

sl[i]:=sl.names[i]+'='+s;

[himitsu]

Wenn es den Eintrag gibt, dann ist es so OK.

Statt '=' kannst/solltest du aber SL.NameValueSeparator nutzen,
falls es mal was Anderes ist.




Ich würde mal einen FeatureRequest zu erstellen, damit man das Löschen in der Liste deaktivieren kann, oder es ein eine Art

Delphi-Quellcode:

SL.ValuesNotDeleteIfEmpty[name] :=

gibt.

Außerdem wollte ich eh mal einen 20 Jahre alten Bug beheben lassen.
Dieses blöde ValueFromIndex wurde ja nur erfunden, weil man ursprünglich (bis Delphi 7 oder so) die Default-Property und Array-Property nicht überladen konnte,
aber seit 15-20 Jahren geht es ja nun direkt

Delphi-Quellcode:

property Values[const Name: string]: string read GetValue write SetValue;
property Values[Index: Integer]: string read GetValueFromIndex write SetValueFromIndex;  // das hier neu

property ValueFromIndex[Index: Integer]: string read GetValueFromIndex write SetValueFromIndex;  // anstatt ähhhhhhhh, zusätzlich zu dem