Bildereffekt

[S2B]

Hi @all,
ich möchte ein Programm schreiben, das folgenden Effekt zu einem Bild hinzufügt (Bild im Anhang).

Zuerst möchte ich den Effekt nur anzeigen lassen und dann mit einem Speichern-Button in die Datei schreiben! Ich hab schon mitgekriegt, dass man das irgendwie mit DirectX machen kann, hab aber keinen Schimmer, wie ich das machen soll... :gruebel: Hab nämlich noch nichts mir DirectX gemacht!

Also, hoffe ihr könnt mir helfen!

[Phantom1]

Sieht nach einen einfachen Blureffekt aus. Ich habe dafür schon vor einiger Zeit mal eine Procedure geschrieben (geschwindigkeitsoptimiert), du kannst sie ja mal probieren:

Delphi-Quellcode:

procedure BmpGBlur(Bmp: TBitmap; radius: Single);
Type
  TRGB      = Packed Record b, g, r: Byte End;
  TRGBs     = Packed Record b, g, r: Single End;
  TRGBArray = Array[0..0] of TRGB;
Const
  ZeroTRGBs: TRGBs=(b:0; g:0; r:0);
Var
  MatrixRadius: Byte;
  Matrix : Array[-100..100] of Single;

  Procedure CalculateMatrix;
  Var x: Integer; Divisor: Single;
  Begin
    radius:=radius+1; // der mittel/nullpunkt muss mitgerechnet werden
    MatrixRadius:=Trunc(radius);
    If Frac(radius)=0 Then Dec(MatrixRadius);
    Divisor:=0;
    For x:=-MatrixRadius To MatrixRadius Do Begin
      Matrix[x]:=radius-abs(x);
      Divisor:=Divisor+Matrix[x];
    End;
    For x:=-MatrixRadius To MatrixRadius Do
      Matrix[x]:=Matrix[x]/Divisor;
  End;

Var
  BmpSL              : ^TRGBArray;
  BmpRGB             : ^TRGB;
  BmpCopy            : Array of Array of TRGBs;
  BmpCopyRGBs         : ^TRGBs;
  PixelRGBs          : TRGBs;
  BmpWidth, BmpHeight: Integer;
  x, y, mx           : Integer;
Begin
  Bmp.PixelFormat:=pf24bit;  
  If radius<=0 Then radius:=1 Else If radius>99 Then radius:=99; // radius bereich 0 < radius < 99
  CalculateMatrix;
  BmpWidth:=Bmp.Width;
  BmpHeight:=Bmp.Height;
  SetLength(BmpCopy,BmpHeight,BmpWidth);
  // Alle Bildpunkte ins BmpCopy-Array schreiben und gleichzeitig HORIZONTAL blurren
  For y:=0 To Pred(BmpHeight) Do Begin
    BmpSL:=Bmp.Scanline[y];
    BmpCopyRGBs:=@BmpCopy[y,0];
    For x:=0 to Pred(BmpWidth) Do Begin
      BmpCopyRGBs^:=ZeroTRGBs;
      For mx:=-MatrixRadius To MatrixRadius Do Begin
        If x+mx<=0 Then
          BmpRGB:=@BmpSL^[0]              // erster Pixel
        Else If x+mx>=BmpWidth Then
          BmpRGB:=@BmpSL^[Pred(BmpWidth)] // letzter Pixel
        Else
          BmpRGB:=@BmpSL^[x+mx];
        BmpCopyRGBs^.b:=BmpCopyRGBs^.b+BmpRGB^.b*Matrix[mx];
        BmpCopyRGBs^.g:=BmpCopyRGBs^.g+BmpRGB^.g*Matrix[mx];
        BmpCopyRGBs^.r:=BmpCopyRGBs^.r+BmpRGB^.r*Matrix[mx];
      End;
      Inc(BmpCopyRGBs);
    End;
  End;
  // Alle Bildpunkte zurück ins Bmp-Bitmap schreiben und gleichzeitig VERTIKAL blurren
  For y:=0 To Pred(BmpHeight) Do Begin
    BmpRGB:=Bmp.ScanLine[y];
    For x:=0 to Pred(BmpWidth) Do Begin
      PixelRGBs:=ZeroTRGBs;
      For mx:=-MatrixRadius To MatrixRadius Do Begin
        If y+mx<=0 Then
          BmpCopyRGBs:=@BmpCopy[0,x]                // erster Pixel
        Else If y+mx>=BmpHeight Then
          BmpCopyRGBs:=@BmpCopy[Pred(BmpHeight),x]  // letzter Pixel
        Else
          BmpCopyRGBs:=@BmpCopy[y+mx,x];
        PixelRGBs.b:=PixelRGBs.b+BmpCopyRGBs^.b*Matrix[mx];
        PixelRGBs.g:=PixelRGBs.g+BmpCopyRGBs^.g*Matrix[mx];
        PixelRGBs.r:=PixelRGBs.r+BmpCopyRGBs^.r*Matrix[mx];
      End;
      BmpRGB^.b:=Round(PixelRGBs.b);
      BmpRGB^.g:=Round(PixelRGBs.g);
      BmpRGB^.r:=Round(PixelRGBs.r);
      Inc(BmpRGB);
    End;
  End;
End;

Wenn du ein normales Image benutzt müsste es so gehen: BmpGBlur(Image1.Picture.Bitmap, 1.0);
Mit radius ist übrigens der Pixelradius gemeint, je größer der ist um so mehr wird geblurrt. Normal ist so 0.5 bis 5.0

[S2B]

Cool! Es geht! Danke! Jetzt hab ich nur noch 1 Problem:
Ich wollte noch den Rand des Bildes so in die Form übergehen lassen!

[Gandalfus]

also Alphablending?

[S2B]

Könnte man so sagen...
Edit: Meintest du mit dem Kommentar etwa sowas?

[S2B]

Hätte da einer eine Idee, wie man den Code nur am Rand und so abgestuft verwenden könnte?

[S2B]

Hat denn keiner eine Idee, wie man das umsetzen könnte?

[shmia]

Zitat:

Zitat von S2B

Hätte da einer eine Idee, wie man den Code nur am Rand und so abgestuft verwenden könnte?

Ist doch nicht so schwer: :shock:
1.) Auf das Bild einen weissen Rahmen zeichnen; dabei werden einige Pixel des Bildes am Rand
mit Weiß überschrieben.
2.) Bild unscharf machen (Blur-Effekt)

[Sebastian Nintemann]

Hallo S2B, wie meinst du denn

Zitat:

nur am Rand und so abgestuft verwenden

?

Falls du so einen Effekt meinst wie auf deinem geposteten Bild, also dass von der Hintergrundfarbe am Rand so in das Bild geblendet wird, dann versuch doch folgendes:
Du vergrößerst dein Bild zu jeder Seite um eine bestimmte Anzahl von Pixeln, und füllst diesen Rand mit der Hintergrundfarbe. Danach wendest du die Prozedur von Phantom1 auf das Bitmap an. So sollte es einen weichen Übergang von der Hintergrundfarbe auf das eigentliche Bild geben (welches dann ja auch weichgezeichnet ist).

Viele Grüße, Sebastian

[S2B]

Wie kann man den Rahmen zeichnen? Ich hab nämlich keinen Schimmer! :oops:

[S2B]

Also, ich hab das jetzt rausgefunden, wie man einen Rahmen zeichnet! Jetzt muss ich den nur noch transparent machen! Mein Code:

Delphi-Quellcode:

  Canvas:=Image1.Canvas.Create;
  Canvas.Pen.Color := clWhite;
  Canvas.Pen.Width:=20;
  Canvas.Brush.Style := bsClear;
  Canvas.Rectangle(0,0,Image1.Width,Image1.Height);

Wie kann ich jetzt das Canvas so transparent machen, dass es innen weniger transparent ist als außen? (so muss ich das doch machen, oder?)

[S2B]

Sorry, dass ich jetzt zum 3. Mal am Stück hier Poste, aber ich habs jetzt fast geschafft! Ich müsste nur noch wissen, wie man ein Image vergrößern kann!
Hoffe, mir kann einer Helfen, dieses letzte Problem noch zu beseitigen!

[fkerber]

Hi!

Da war doch was mit StretchDraw glaube ich.
Verrätst du uns auch deine komplette Lösung?


Ciao fkerber

[S2B]

Vielen Dank für die schnelle Antwort! Jetzt geht endlich alles! :thuimb:
Ich stelle das fertige Programm wahrscheinlich heute oder morgen mit Source in den OpenSource-Bereich!

Edit: Das mit der Transparenz hat sich ganz erledigt, weil das der Blur-Effekt schon miterledigt! :mrgreen:

[dizzy]

@S2B: (mini-OT) Ich würde dir grundsätzlich raten, die Graphics32-Library zu benutzen ( www.g32.org ). Die dort enthaltene Klasse TBitmap32 ist sehr schnell, und gerade was das Vergößern/Verkleinern angeht, ist man damit gut beraten. Das Stadard-VCL-Bitmap kennt nämlich keine Interpolation -> Bild wird bei Größenänderung pixelig. TBitmap32 bietet gleich (ich glaube) 5 verschiedene Interpolationsmethoden an, die das verhindern.

[S2B]

Ich wollte das Bild nicht direkt vergrößern, sondern nur pro Seite 10 Pixel Rand lassen, auf den dann das Canvas gezeichnet wird! Trotzdem danke für den Tip!

[Sebastian Nintemann]

Hallo S2B,
ich habe mal das gemacht was ich im meinem letzten Beitrag meinte:

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var
  bmp,bmpblur: TBitmap;
begin
  bmp := TBitmap.Create;
  bmpblur := TBitmap.Create;
  try
    bmp.LoadFromFile('C:\test.BMP');
    bmpblur.Width := bmp.Width + 10;  //5 Pixel Rand auf jeder Seite
    bmpblur.Height := bmp.Height + 10;
    bmpblur.Canvas.Brush.Color := Form1.Color;
    bmpblur.Canvas.FillRect(rect(0,0,bmpblur.Width,bmpblur.Height)); //Hintergrund des neuen Bildes mit Hintergrundfarbe füllen
    bmpblur.Canvas.Draw(5,5,bmp); //Altes bitmap in die Mitte des neuen setzen
    BmpGBlur(bmpblur,5);  //Effekt 
    Canvas.Draw(10,15,bmp);
    Canvas.Draw(bmp.Width+15,10,bmpBlur); //beide nebeneinander zeichnen um den Vergleich zu sehen
  finally
    FreeAndNil(bmpblur);
    FreeAndNil(bmp);
  end;
end;

Die Prozedur BmpGBlur muss natürlich irgendwo implementiert sein.

In der Anlage ein Screenshot des Ergebnisses. Sieht doch fast so aus wie das Bild das du gepostet hast.

Viele Grüße, Sebastian


//EDIT VERDAMMT jetzt bist du schon fertig bevor ich gepostet hab :evil: :wink:

[fkerber]

Hi!

:thuimb:
Das Ergebnis kann sich sehen lassen.


Ciao fkerber

[S2B]

Sorry, hab doch noch ne Frage: Wie kann man ein Bild im TImage an allen Seiten um 10 Pixel vergrößern, sodass ein weißer Rand entsteht? Das ist mir noch nicht ganz klar!

Edit: Hat sich erledigt!
Der Link bringt euch zum "Programm-Beitrag" in OpenSource!