eine Möglichkeit aus einem TMemoryStream herauszufinden welcher Dateityp?

[dstein]

Moin,
Gibt es eine Möglichkeit aus einem TMemoryStream herauszufinden welcher Dateityp enthalten ist.
ShortStory: ich benutze von Gaussi(Danke dafür) seine Mp3FileUtils. Ich lese damit ua. das hinterlegte Picture ein.
Doch kann mittlerweile nicht nur JPG sondern auch PNG hinterlegt werden.
Also muß ich bevor (Part2 Picture anzeigen) herausfinden ob ein JPG oder PNG hinterlegt ist.
Bei dem nachfolgendem Beispiel wird nur JPG akzeptiert bei PNG erfolgt klarerweise eine "ExceptionMessage="JPEG-Fehler #53".
Hat jemand einen Tipp wie ich hier weiterkomme?

Delphi-Quellcode:

type
 ImageMP3: TImage;

var
  PictureData: TStream;
  jp: TJPEGImage;
begin

  PictureData := TMemoryStream.Create;
  Id3v2Tag.GetPicture(PictureData, '*');

 // Part2 Picture anzeigen
  try
    PictureData.Seek(0, soFromBeginning);
    jp := TJPEGImage.Create;
    try
      try
        jp.LoadFromStream(PictureData);
        jp.DIBNeeded;
        ImageMP3.Picture.Bitmap.Assign(jp);
      except
        ImageMP3.Picture.Assign(NIL);
      end;
    finally
      jp.Free;
    end;
  finally
    PictureData.Free;
  end;
end;

Ergänzung bei einem File ermittle ich den Filetyp so (Beispiel):

Delphi-Quellcode:

function TForm1.GetGraphTyp(const AFileName: String): String;
var
  FileHandle: Integer;
  Buffer: Word;
begin
  { Buffer:
    GIF = 18759
    PNG = 20617
    JPG = 55551
    BMP = 19778
    ICO = 0 }

  FileHandle := FileOpen(AFileName, fmOpenRead);
  FileSeek(FileHandle, 0, 0);
  FileRead(FileHandle, Buffer, 2);
  FileClose(FileHandle);
  CodeSite.Send(' Buffer: ', Buffer);
  case Buffer of
    18759:
      Result := 'GIF';
    20617:
      Result := 'PNG';
    55551:
      Result := 'JPG';
    19778:
      Result := 'BMP';
    0:
      Result := 'Unbekannt';

  end;

  CodeSite.Send(' Result: ', Result);
end;

[Uwe Raabe]

Solange das Format über

Delphi-Quellcode:

TPicture.RegisterFileFormat

registriert ist, sollte

Delphi-Quellcode:

TPicture.LoadFromStream

das erkennen können.

[Delphi.Narium]

Lies einfach die ersten paar Byte des Streams aus.

JPeg: Byte 6 bis 9 = JFIF
PNG: Byte 1 bis 3 = PNG

Zählung beginnt bei 0.

[dstein]

Zitat:

Zitat von Delphi.Narium (Beitrag 1532024)

Lies einfach die ersten paar Byte des Streams aus.

JPeg: Byte 6 bis 9 = JFIF
PNG: Byte 1 bis 3 = PNG

Zählung beginnt bei 0.

Danke.
bei Files weiß ich wie es geht:
FileHandle := FileOpen(AFileName, fmOpenRead);
FileSeek(FileHandle, 0, 0);
FileRead(FileHandle, Buffer, 2);

Aber wie lese ich die ersten Byte bei einem Stream aus, denn ein "FileHandle" gibt es dort nicht?

[Dalai]

@Delphi.Narium:
Das ist nicht zuverlässig. JPGs mit EXIF-Daten haben möglicherweise keinen "JFIF"-Marker sondern stattdessen "Exif", und es gibt sogar JPGs, in denen weder Exif noch JFIF vorkommt. Der relevante Marker scheint FF D8 in den ersten beiden Bytes zu sein, siehe auch https://de.wikipedia.org/wiki/JPEG_F...rchange_Format (Magic Number).

[EDIT]
Beispiel eines solchen Bilds, das weder Exif noch JFIF enthält: https://i.imgur.com/KdP8C9R.jpg
[/EDIT]

Grüße
Dalai

[himitsu]

Zitat:

Zitat von dstein (Beitrag 1532025)

bei Files weiß ich wie es geht:

Ist beim Stream nicht anders.

Stream.Position := 0;
und Stream.Read bzw. Stream.BlockRead

Wobei man beim TMemoryStream oder TBytesStream auch direkt auf den internen Speicher zufreifen kann.

Delphi-Quellcode:

if (MemoryStream.Size >= 2) and (PWord(MemoryStream.Memory)^ = 123465) then

if (BytesStream.Size >= 2) and (BytesStream.Bytes[0] = 123) and (BytesStream.Bytes[1] = 456) then

Wie Uwe bereits anmerkte, können neuere Delphis das Image-Format selbst checken.

"Alte" Delphis konnten das bei LoadFromStream noch nicht, da dort nur im LoadFormFile über die Dateiendung registrierter TGrafic-Typen gesucht wurde.

Und lleider kann man den Scheißdreck nicht selbst benutzen, da der Mist wieder mal nur in der Implementation versteckt ist.
siehe

Delphi-Quellcode:

procedure TPicture.LoadFromStream(Stream: TStream);
...
    GraphicClass := FileFormats.FindFormat(Stream);

[add] Bei den TGraphic-Nachfahren kann man zumindestens einzeln CanLoadFromStream abfragen.
Zuminstenst für TJPEGImage, TPngImage, TGIFImage, TBitmap, TIcon und TMetafile wurde es implementiert.
Es wäre natürlich auch viel zu einfach, wenn man einfach nur die FileFormats-Liste fragen könnte, ob und was es bezüglich des Streams kennt.

[Delphi.Narium]

Zitat:

Zitat von Dalai (Beitrag 1532027)

@Delphi.Narium:
Das ist nicht zuverlässig. JPGs mit EXIF-Daten haben möglicherweise keinen "JFIF"-Marker sondern stattdessen "Exif", und es gibt sogar JPGs, in denen weder Exif noch JFIF vorkommt. Der relevante Marker scheint FF D8 in den ersten beiden Bytes zu sein, siehe auch https://de.wikipedia.org/wiki/JPEG_F...rchange_Format (Magic Number).

[EDIT]
Beispiel eines solchen Bilds, das weder Exif noch JFIF enthält: https://i.imgur.com/KdP8C9R.jpg
[/EDIT]

Grüße
Dalai

Ist die Erkennung für PNG denn zuverlässig?

Wenn ja, dann wird halt auf PNG geprüft. Da es nur PNG und JPeg zu geben scheint, ist alles, was nicht PNG ist automatisch Jpeg.

Ansonsten ergänzen wir die JPegprüfung um:

JPeg: Byte 0 bis 2 = $FF$D8$FF oder Byte 6 bis 9 = JFIF ($4A$46$49$46)

[Gausi]

Quick&Dirty kann man natürlich nach dem try-except-Teil mit TJpegImage das gleiche nochmal mit TPNGImage probieren. So mache ich das (noch) in meinem Player. Der Code stammt halt aus der Zeit, als TPicture das noch nicht konnte. :stupid:

Muss ich mal umschreiben zu TPicture.LoadFromStream. Das sollte auch etwas schneller gehen.

Zur Zuverlässigkeit: das kannste bei ID3Tags sowieso knicken. Was ich da schon alles für Mist drin gefunden habe ... inklusive der Textkodierung "UTF-32, mit BOM, Zeichenweise." Oder evtl. wars auch zeichenweise nullterminiert UTF-16 mit bom. Auf jeden Fall 6 Byte pro Zeichen. :pale:

[mytbo]

Zitat:

Zitat von dstein (Beitrag 1532020)

Gibt es eine Möglichkeit aus einem TMemoryStream herauszufinden welcher Dateityp enthalten ist.

Mit mORMot so:

Delphi-Quellcode:

uses
  mormot.core.buffers;

var stream: TMemoryStream := TMemoryStream.Create;
try
  stream.LoadFromFile('test.png');
  if GetMimeContentTypeFromMemory(stream.Memory, stream.Size) = mtPng then
    ShowMessage('PNG Datei');
finally
  stream.Free;
end;

Bis bald...
Thomas

[himitsu]

In Linux gibt es die Anwendung "file", bzw. das Projekt "filelib", wo ich vor Ewigkeiten auch irgendwo mal eine Übersetzung für Windows gesehen hatte.
Falls jemand die filelib für Windows findet, dann wäre es bestimmt witzig, das hierfür einzusetzen.
Gut, für die 5 Image-Typen vielleich ein winziges Bissl übertrieben.

Hier in der DP sollte sich auch irgendwo eine Funktion verstecken, welche die MagicBytes für die bekanntesten Imageformate prüft. (so weit ich mich erinnern können glaube)

Vielleicht war auch was in den Jedis versteckt.

[shebang]

Zitat:

Zitat von himitsu (Beitrag 1532034)

Hier in der DP sollte sich auch irgendwo eine Funktion verstecken, welche die MagicBytes für die bekanntesten Imageformate prüft. (so weit ich mich erinnern können glaube).

An der hast du sogar selbt mitgebastelt. ;-)

https://www.delphipraxis.net/213636-...-erkennen.html

[TurboMagic]

Zitat:

Zitat von himitsu (Beitrag 1532028)

Und leider kann man den Scheißdreck nicht selbst benutzen, da der Mist wieder mal nur in der Implementation versteckt ist.

DU weisst ja, was du tun solltest, sobald QP wieder verfügbar ist ;-)

[himitsu]

Hab ich schonmal mehrmals versucht ... da wird sich extrem kräftig gegen gewehrt.
Also jetzt noch nicht explizit hierfür, aber andere Dinge, welche sich ständig immer nur in der Implementation verstecken.

OK, bei Einem soll es ja nun endlich geklappt haben ... muß nur noch irgendwann mal nachsehn was und wie die es gelöst haben. (denn im Ticket wird ja nicht geantwortet, wo man das nun finden kann, wenn das Ticket geschlossen wurde)

[TurboMagic]

Naja, manchmal wird dagegen gewehrt und manchmal wird's eingesehen.
Geht halt immer um den Detailfall und wenn man ein gutes Beispiel liefern
kann wozu's gut ist, steigen die Chancen es zu bekommen doch erheblich!

[dstein]

Zitat:

Zitat von himitsu (Beitrag 1532028)

Ist beim Stream nicht anders.

Stream.Position := 0;
und Stream.Read bzw. Stream.BlockRead

Danke für den Tipp, funktioniert:

function TForm1.GetStreamGraphTyp(PictureData: TMemoryStream): String;
var
Buffer: Word;
begin
{ Buffer:
GIF = 18759
PNG = 20617
JPG = 55551
BMP = 19778
ICO = 0 }

PictureData.Position := 0;
PictureData.Read(Buffer, 2);

CodeSite.Send(' Buffer: ', Buffer);
case Buffer of
18759:
Result := 'GIF';
20617:
Result := 'PNG';
55551:
Result := 'JPG';
19778:
Result := 'BMP';
0:
Result := 'Unbekannt';
end;
CodeSite.Send(' Result: ', Result);
end;

[himitsu]

[DELPHI] ... [/DELPHI] um deine Codes ... PS: das ist der Knopf mit dem Delphi-Helm :zwinker:

Nicht

Delphi-Quellcode:

0:

, sondern

Delphi-Quellcode:

else

.
Bei einer XML oder INI steht Result sonst auf einem Zufallswert. (ja, es ist "zufall", dass Result hier so aussieht, als sei mit '' initialisiert, was aber nicht immer so sein muß)

Ist der Stream nur 0 oder 1 Byte groß, dann stehen Zufallswerte in der Buffer-Variable.
Entweder diese Variable vorher mit einem festen Wert initialisieren (z.B. 0 oder $FFFF)
oder die Rückgabe des Read auswerten, also z.B.

Delphi-Quellcode:

if PictureData.Read(Buffer, 2) <> 2 then Fehler;

oder die selbstprüfende Funktion

Delphi-Quellcode:

PictureData.ReadBuffer(Buffer, 2);

nutzen (wirft eine Exception, wenn nicht vollständig gelesen werden konnte)

[TurboMagic]

Ich stelle mir auch immer noch die Frage, warum er das nicht die TGraphics Klasse von Delphi selber ermitteln
lässt, die das ja heutzutage beherrscht...

Die könnte dann auch automatisch alle sonst noch in seinem Delphi registrierten Formate...

Grüße
TurboMagic

[himitsu]

https://www.delphipraxis.net/1532028-post6.html