Ärger mit Shellexecute

[Delbor]

Hi zusammen

In meinem OpenfileFrame möchte ich PDF-Dateien direkt in einem entsprechenden Programm öffnen, bearbeiten und wieder schliessen Zudem soll das fremde Programm auf einem Container als Parent platziert werden. Dazu verwende ich vorerstfolgendes Codeschnipsel, noch ohne die beabsichtigte Platzierung:

Delphi-Quellcode:

procedure TAlexOpenfileFrame.TVFilesExplorerMouseDown(Sender: TObject;
    Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
    var AnItem: TTreeNode; P: TPoint; LSelectItem, ext : String;
  begin
    AnItem := TVFilesExplorer.GetNodeAt(X, Y);
    if Button =(mbLeft) then
    begin
      LSelectItem := PNameRec(AnItem.Data)^.RealName;
      ext := ExtractFileExt(LSelectItem);
      if ext = '.pdf' then
      begin
        ShellExecute(handle, 'open', PChar('F:\Externer Programmordner\Ashampoo\Ashampoo PDF Free\Ashampoo PDF.exe', PChar(LSelectItem), nil, SW_SHOWNORMAL));

      end;
    end;
...
...

Sorgen macht mir die Zeile mit Shellexecute.Die Fehlermeldung :

Zitat:

[dcc32 Fehler] AlexOpenfileFrameUnit.pas(691): E2029 ')' erwartet, aber ',' gefunden

Dabei ist schon vorher die letzte Klammer rot markiert. Und was soll das mit dem Komma? Da ist weit und breit keines. Einzig LSelectItem könnte der Übeltäter sein - der enthält den kompletten Pfad. Aber auch das wird mW. so erwartet.

Gruss
Delbor

[DeddyH]

Zähl doch einfach mal die öffnenden und die schließenden Klammern, dann wirst Du merken, dass nach dem ersten Cast zu PChar die Klammer nicht geschlossen ist. Soviel Eigeninitiative könnte man aber IMO schon erwarten.

[edit] Ah, das hast Du scheinbar bereits gemacht und dann wohl einfach mal eine Klammer ganz ans Ende gesetzt. Kann man machen, aber das muss nicht funktionieren. [/edit]

[Delbor]

Hi DeddyH

Zitat:

Ah, das hast Du scheinbar bereits gemacht ...

Deine Antwort liess mich genauer hingucken - und da wurde auch die Sache mit dem Komma klar. Von wem stammt der Spruch:
"Wer Augen hat zu sehen...", oder ist der schon abgewandelt?
Vielen Dank und schönes restliches Wochenende!

Gruss
Delbor

[Delbor]

Hi zusammen

Nachdem ich nun die Klammer richtig gesetzt habe, lässt sich nun das fremde Programm starten. Nun will ich es noch auf ein Tabsheet einpassen Es soll da bis zur Beendigung des "Mutterprogramms" bleiben, so dass es jederzeit erneut zur Verfügung steht.
Das soll vorerst mal mit diesem Code geschehen:

Delphi-Quellcode:

procedure TAlexOpenfileFrame.TVFilesExplorerMouseDown(Sender: TObject;
    Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
    var AnItem: TTreeNode; P: TPoint; LSelectItem, ext : String;
  begin
    FCodeReportlist.Add('procedure TAlexOpenfileFrame.TVFilesExplorerMouseDown');
    FCodeReportlist.Add('--------------------------------------');
    AnItem := TVFilesExplorer.GetNodeAt(X, Y);
    if Button =(mbLeft) then
    begin
      LSelectItem := PNameRec(AnItem.Data)^.RealName;
      ext := ExtractFileExt(LSelectItem);
      if ext = '.pdf' then
      begin
        ShellExecute(handle, 'open', PChar('F:\Externer Programmordner\Ashampoo\Ashampoo PDF Free\Ashampoo PDF.exe'),
                                     PChar(LSelectItem), nil, SW_SHOWNORMAL);
        SetAppParent(Application.Name);
      end;
    end;
    if Button =(mbRight) then
    begin

und

Delphi-Quellcode:

procedure TAlexOpenfileFrame.SetAppParent(Application : String);
 var aWnd : Hwnd; WPM : TWindowPlacement; Rect : TRect;
begin
  aWnd:=Findwindow(PChar(Application),nil);
  if aWnd<>0 then
  begin
    Winapi.Windows.SetParent(awnd,OfficerAlexMain.tbsAppParent.Handle);

    WPM.Length:=SizeOf(WPM);
    GetWindowPlacement(awnd,@WPM);
    Rect.Top :=0;
    Rect.Left :=0;
    Rect.Right :=OfficerAlexMain.tbsAppParent.Width;
    Rect.Bottom:=OfficerAlexMain.tbsAppParent.Height;
    wpm.rcNormalPosition:=Rect;
    SetWindowPlacement(awnd,@WPM);
  end;

end;

Zur Zeit habe ich einen Breakpoint beim Aufruf 'SetAppParent'gesetzt, Delphi hält da an,und zur gleichen Zeit wird die App gestartet. Allerdings nicht auf dem Tabsheet, sondern Solo.

Der letzte Parameter von Shellexecute ist hier SW_SHOWNORMAL - der könnte wohl in SW_Hide geändert werden und erst bei/nach Rückkehr aus SetAppParent auf SW_SHOWNORMAL gesetzt werden - ob das allerdings so einfach ist, wie das in Pascal wohl wäre...
Hat jemand eine bessere Idee?

Gruss
Delbor

[himitsu]

Natürlich nicht.

Du setzt die Platzierung (Position/Placement) über die Position,
aber du setzt nicht den Parent, also die Form in dein Panel.

SetParent

[Delbor]

Hi zusammen

Im Moment ist vor allem das eine Handle nil(0):

Delphi-Quellcode:

        aWnd:=FindWindow(PChar('Ashampoo PDF'), nil);
          if aWnd<>0 then
          begin
            Winapi.Windows.SetParent(awnd,OfficerAlexMain.tbsAppParent.Handle);
          end;

Ich hab bisher noch weiter gesucht und mit verscchiedenen Codeversionne gearbeitet - wenn aWnd 0 ist, nützt das alles nichts.
Ich habe auch eine

Delphi-Quellcode:

procedure TOfficerAlexMain.FindPaint;
var aWnd : Hwnd;
    WPM : TWindowPlacement;
    Rect : TRect;
begin
  aWnd:=Findwindow('paint.net',nil);
  if aWnd<>0 then begin
    Winapi.Windows.SetParent(awnd,OfficerAlexMain.tbsAppParent.Handle);
    WPM.Length:=SizeOf(WPM);
    GetWindowPlacement(awnd,@WPM);
    Rect.Top :=0;
    Rect.Left :=0;
    Rect.Right :=Panel1.Width;
    Rect.Bottom:=Panel1.Height;
    wpm.rcNormalPosition:=Rect;
    SetWindowPlacement(awnd,@WPM);
    end;
end;

von zwei ähnlichen Prozeduren mal separat als Reaktion auf einen Button nachgebaut:

Delphi-Quellcode:

procedure TOfficerAlexMain.FindPaint;
var aWnd : Hwnd;
    WPM : TWindowPlacement;
    Rect : TRect;
begin
  aWnd:=Findwindow('paint.net',nil);
  if aWnd<>0 then begin
    Winapi.Windows.SetParent(awnd,OfficerAlexMain.tbsAppParent.Handle);
    WPM.Length:=SizeOf(WPM);
    GetWindowPlacement(awnd,@WPM);
    Rect.Top :=0;
    Rect.Left :=0;
    Rect.Right :=Panel1.Width;
    Rect.Bottom:=Panel1.Height;
    wpm.rcNormalPosition:=Rect;
    SetWindowPlacement(awnd,@WPM);
    end;
end;

Hier und in meinen bisherigen Umsetzungen ist die Variable aWnd immer 0, womit der darunter folgende Code nicht ausgeführt wird.

Wieso das?

Gruss
Delbor

[venice2]

Wenn es das Paint.net ist das ich meine ist es normal das du kein Handle (HWND) bekommst
denn dein Class Name stimmt nicht und dieser ändert sich mit jeden neuem Start der Anwendung.
Prüfe den Classnamen einfach mal mit einer Spy Anwendung.

Paint.net vers. 4.3.11

1 Start
WindowsForms10.Window.8.app.0.24cbd2a_r3_ad1
2 Start
WindowsForms10.Window.8.app.0.2428e43_r3_ad1

TIP:
Versuche es einfach mal mit dem Window Title.

[DeddyH]

Hast Du es mal mit WinSpy versucht? Damit bekommt man sehr schön heraus, wie man an das Fensterhandle kommt.

[KodeZwerg]

Vielleicht hilft dir mein code schnippsel weiter um ans ziel zu gelangen.

Delphi-Quellcode:

type
  TExec = packed record
    Filename     : string;
    PID          : DWORD;
    WindowHandle : HWND;
  end;

var
  Exec: TExec;

procedure ResetExec;
begin
  Exec.Filename      := '';
  Exec.PID           := 0;
  Exec.WindowHandle  := 0;
end;

function EnumWindowsProc(Wnd : HWND; ProcessID : Cardinal) : Boolean; stdcall;
var
  PID : Cardinal;
begin
  GetWindowThreadProcessId(Wnd, @PID);
  if ProcessID = PID then
    Exec.WindowHandle := Wnd;
  Result := True;
end;

function ExecFile(const AFilename: string): Boolean;
var
  Executable : string;
  Security   : TSecurityAttributes;
  ProcessInfo: TProcessInformation;
  StartupInfo: TStartupInfo;
  dummy      : HINST;
begin
  Result := False;
  ResetExec;

  if (not FileExists(AFilename)) then
    Exit;

  SetLength(Executable, MAX_PATH);
  dummy := FindExecutable(PChar(AFilename), nil, PChar(Executable));
  if dummy > 32 then
  begin
    SetLength(Executable, StrLen(PChar(Executable)));
    UniqueString(Executable);

    Security.nLength              := SizeOf(TSecurityAttributes);
    Security.lpSecurityDescriptor := nil;
    Security.bInheritHandle       := False;

    FillChar(StartupInfo, SizeOf(TStartupInfo), #0);
    StartupInfo.cb          := SizeOf(TStartupInfo);
    StartupInfo.dwFlags     := STARTF_USESHOWWINDOW or STARTF_FORCEONFEEDBACK;
    StartupInfo.wShowWindow := SW_SHOWNORMAL {SW_HIDE};

    Win32Check(CreateProcess(PChar(Executable), PChar(Format('%s %s', [Executable, AFilename])), @Security, @Security, False, CREATE_NEW_CONSOLE or NORMAL_PRIORITY_CLASS, nil, PChar(ExtractFilePath(Executable)), StartupInfo, ProcessInfo));
    try
      WaitForInputIdle(ProcessInfo.hProcess, INFINITE);
      Exec.Filename := Executable;
      Exec.PID := ProcessInfo.dwProcessId;
      EnumWindows(@EnumWindowsProc, LPARAM(Exec.PID));
    finally
      CloseHandle(ProcessInfo.hProcess);
      CloseHandle(ProcessInfo.hThread);
      Result := True;
    end;
  end;
end;

nach dem aufruf steht in globaler variable Exec.WindowHandle was du brauchst. Ist ein Versuch Wert.

[Delbor]

Hi zusammen

Ich hab mir gestern abend das von DeddyH vorgeschlagene Wynspy mal 'installiert', aber heute morgen nichts davon vorgefunden, ausser dass mir Windows unter 'Zuletzt neu hinzugefügt' Delphi Alexandria meldet. Das hab ich gestartet und hatte bislang den Eindruck eines gewöhnlichen Delphi-Starts, bin allerdings noch nicht alle Menuepunkte durchgegangen.
Den Code von CodeZwerg werd ich mir mal in eine Unit/Klasse packen.

Gruss
Delbor

[KodeZwerg]

Zitat:

Zitat von Delbor (Beitrag 1506601)

Den Code von CodeZwerg werd ich mir mal in eine Unit/Klasse packen.

Bin gespannt was dabei rauskommt, bei meiner Variante ist der ClassName völlig egal da ich über die erzeugte ProcessID das Fensterhandle versuche zu holen.
Diese Methodik funktioniert zu 100% immer zuverlässig solange das "ExecFile" kein "Wrapper" für andere Executables ist (Programm A lädt beim start Programm B oder Fenster wird in DLL erzeugt... etc) bzw solange die ProcessID ein Fenster besitzt.

Wenn Du noch Fragen dazu haben solltest, ich hoffe ich kann Dir weiterhelfen.

[Delphi.Narium]

Muss es unbedingt Ashampo zur Anzeige von PDF-Dateien sein?

Wenn nein: Bei mir ist seit 'ner Weile Sumatra im Einsatz. Klappt so gut, dass es mir nicht mher auffällt, dass ich da "was fremdes" in meine Programme einbette.

Zuerst wird geprüft, ob Sumatra vorhanden ist, wenn ja, wird es genutzt. Sollte es nicht gefunden werden, wird es mit dem AcrobatReader versucht. Den Teil kann man aber auch entfernen, wenn die Nutzung vom Acrobat ausgeschlossen werden soll.

Da ich nur Delphi 7 habe, wirst Du im folgenden Quelltext vermutlich einige Anpassungen vornehmen müssen.

Zuerst die DFM:

Delphi-Quellcode:

object fmPDFVorschau: TfmPDFVorschau
  Left = 476
  Top = 60
  Width = 249
  Height = 138
  Caption = 'PDF-Vorschau'
  Color = clBtnFace
  Font.Charset = DEFAULT_CHARSET
  Font.Color = clWindowText
  Font.Height = -11
  Font.Name = 'MS Sans Serif'
  Font.Style = []
  KeyPreview = True
  OldCreateOrder = False
  OnCreate = FormCreate
  OnKeyDown = FormKeyDown
  OnResize = FormResize
  OnShow = FormResize
  PixelsPerInch = 96
  TextHeight = 13
  object pnPDF: TPanel
    Left = 0
    Top = 0
    Width = 241
    Height = 111
    Align = alClient
    BevelOuter = bvNone
    TabOrder = 0
  end
end

und dann die dazugehörige Unit:

Delphi-Quellcode:

unit uPDFVorschau;

interface

uses
  AcroPDFLib_TLB, 
  Forms,
  Classes,
  Controls,
  ExtCtrls;

type
  TfmPDFVorschau = class(TForm)
    pnPDF: TPanel;
    procedure FormResize(Sender: TObject);
    procedure FormKeyDown(Sender: TObject; var Key: Word; Shift: TShiftState);
    procedure FormCreate(Sender: TObject);
  protected
    procedure CreateParams(var Params: TCreateParams) ; override;
  private
    { Private-Deklarationen }
    fAcroPDF       : TAcroPDF;
    fPDFFile       : String;
    fUseSumatraPDF : Boolean;
  public
    { Public-Deklarationen }
    procedure LoadPDF(APdfFile : String);
    procedure LoadArcoPDF;
    procedure LoadSumatraPdF;
    property  PDFFile : String read fPDFFile;
    property  UseSumatraPDF : Boolean read fUseSumatraPDF write fUseSumatraPDF default false;
  end;

var
  fmPDFVorschau: TfmPDFVorschau;

implementation

{$R *.dfm}

uses
  Windows,
  SysUtils,
  ShellAPI;

const
  csCaption = 'PDF-Vorschau - %s';

// Eigenen Button in die Taskbar machen, damit man per STRG+TAB zwischen den
// Fenstern wechseln kann. Der eingebettet Acrobat nimmt sich leider das Recht
// heraus alle Tastaturkürzel zu ignorieren, wenn sie vom Programm sind und
// sich selbst so in den Focus zu setzen, dass man nicht per Mausklick ...
// problemlos mit dem Programm arbeiten kann.
procedure TfmPDFVorschau.CreateParams(var Params: TCreateParams);
begin
  inherited;
  Params.ExStyle   := Params.ExStyle or WS_EX_APPWINDOW;
  Params.WndParent := 0;
end;

procedure TfmPDFVorschau.FormCreate(Sender: TObject);
begin
  // Das muss ggfls. angepasst werden.
  fUseSumatraPDF := FileExists('.\Lib\SumatraPDF.exe');
end;

procedure TfmPDFVorschau.FormResize(Sender: TObject);
begin
  if not fUseSumatraPDF then begin
    if Assigned(fAcroPDF) then begin
      if fAcroPDF.Visible then begin
        fAcroPDF.LoadFile(fPDFFile);
        fAcroPDF.Update;
      end;
    end;
  end else
  if Assigned(pnPDF) then begin
    pnPDF.Align := alTop;
    Application.ProcessMessages;
    pnPDF.Align := alClient;
  end;
end;

procedure TfmPDFVorschau.LoadPDF(APDFFile : String);
begin
  fPDFFile          := APDFFile;
  Caption           := Format(csCaption,[ChangeFileExt(ExtractFileName(fPDFFile),'')]);
  case fUseSumatraPDF of
    true  : LoadSumatraPDF;
    false : LoadArcoPDF;
  end;
end;

procedure TfmPDFVorschau.LoadArcoPDF;
begin
  Screen.Cursor := crHourGlass;
  if Assigned(pnPDF) then pnPDF.Visible := False;
  if not Assigned(fAcroPDF) then begin
    fAcroPDF                := TAcroPDF.Create(Self);
    fAcroPDF.Parent         := Self;
    fAcroPDF.Left           := 0;
    fAcroPDF.Top            := 0;
    fAcroPDF.Width          := Width;
    fAcroPDF.Height         := Height;
    fAcroPDF.TabStop        := False;
    fAcroPDF.Align          := alClient;
    fAcroPDF.ParentShowHint := False;
    fAcroPDF.ShowHint       := True;
    fAcroPDF.TabOrder       := 0;
    fAcroPDF.Visible        := True;
  end;
  fAcroPDF.src  := fPDFFile;
  fAcroPDF.LoadFile(fPDFFile);
  Screen.Cursor := crDefault;
  Show;
end;

procedure TfmPDFVorschau.LoadSumatraPDF;
var
  sParam : String;
begin
  Screen.Cursor := crHourGlass;
  if Assigned(fAcroPDF) then fAcroPDF.Visible := False;
  // Caption       := Format(csCaption,[fPDFFile]);
  // -reuse-instance funktioniert nur, wenn immer die gleiche Datei geladen wird,
  // andernfalls entsteht für jede PDF-Datei eine neue Instanz von SumatraPDF.
  // Die Instanzen von SumatraPDF werden beendet, wenn man das Programm beendet.
  // Bei diesem Vorgehen entsteht aber nur eine Instanz von SumatraPDF.
  pnPDF.Free;
  Sleep(1000); // Warten, bis sich SumatraPDF beendet hat.
  pnPDF            := TPanel.Create(Self);
  pnPDF.Parent     := Self;
  pnPDF.Left       := 0;
  pnPDF.Top        := 0;
  pnPDF.Width      := Width;
  pnPDF.Height     := Height;
  pnPDF.BevelOuter := bvNone;
  pnPDF.TabOrder   := 1;
  pnPDF.Align      := alClient;
  pnPDF.Visible    := True;
  sParam           := Format('-lang de -reuse-instance -plugin %d "%s"',[pnPDF.Handle,fPDFFile]);
  ShellExecute(Self.Handle,'open',PAnsiChar('SumatraPDF.exe'),PAnsiChar(sParam),'',sw_normal);
  Screen.Cursor    := crDefault;
  Show;
end;

procedure TfmPDFVorschau.FormKeyDown(Sender: TObject; var Key: Word; Shift: TShiftState);
begin
  case key of 27 : Close; end;
end;

end.

[TurboMagic]

Zitat:

Zitat von Delbor (Beitrag 1506601)

Hi zusammen

Ich hab mir gestern abend das von DeddyH vorgeschlagene Wynspy mal 'installiert', aber heute morgen nichts davon vorgefunden, ausser dass mir Windows unter 'Zuletzt neu hinzugefügt' Delphi Alexandria meldet. Das hab ich gestartet und hatte bislang den Eindruck eines gewöhnlichen Delphi-Starts, bin allerdings noch nicht alle Menuepunkte durchgegangen.
Den Code von CodeZwerg werd ich mir mal in eine Unit/Klasse packen.

Gruss
Delbor

Ich glaube nicht, das WinSpy was in der Delphi IDE ist.
Das ist denke ich ein separat aufrufbares Programm, welches einem alle handles usw. anzeigt.

[DeddyH]

Einfach auf den Link Klicken, dann sieht man, dass das ein Programm des DP-Mitglieds toms ist ;-)

[Delbor]

Hi zusammen

@ Delphi.Narium: Nebst einem kostenpflichtigen Programm, das ich mir schon vor Jahr(-zehnt)en zugelegt habe, habe ich mir noch Ashampo PDF Free zugelegt, womit ich PDFs ausfüllen und sie mit beliebigen, auch benutzerdefinierten Stempeln versehen kann - und die Internethilfe ist in normalem Deutsch ohne jegliches Fachchinesisch abgehalten (..). Das ist für mich der Hauptgrund, warum ich vorerst bei Ashompoo bleiben will.
Für mein Programm hingegen muss es völlig gleichgültig sein, mit welchen fremden Programmen es arbeitet.

@Turbomagic:

Zitat:

Ich glaube nicht, das WinSpy was in der Delphi IDE ist.

Ich dachte auch erst an ein eigenständiges Programm, hab dann aber nichts gefunden ausser eben Delphi Alexandria, das ganz zuoberst in der Startleiste als neu hinzugefügt aufgeführt war/ist. Wenn das die letzte vorgenommenen Installation gewesen wäre... War sie aber nicht: das war Winspy. Und davor mindestens CNPack und GEXPERTS.


Gruss
Delbor

[DeddyH]

Der Download ist ein Zip-Archiv, da wird nichts installiert. Du musst also den Ordner öffnen, in den Du entpackt hast und dort die WinSpy.exe starten.

[venice2]

Hier!

[Andreas13]

Hier ist eine deutlich jüngere Version von Winspy aus dem Jahr 2018: https://sourceforge.net/projects/winspyex/
VirusTotal https://www.virustotal.com meldet allerdings eine Handvoll von Trojanern... :cry:
Bestimmt nur ein Fehlalarm?
Gruß, Andreas

[Delbor]

Hi zusammen

Zitat:

Der Download ist ein Zip-Archiv, da wird nichts installiert. Du musst also den Ordner öffnen, in den Du entpackt hast und dort die WinSpy.exe starten.

Ein Ordner mit Reissverschluss?
Anhang 55129
Nach dem entpacken und "installieren":
Anhang 55130
und der Taskmanager
Anhang 55131

Wie ich den wieder anzeige, ist mir ein Rätsel. Auch das menü des Taskmanagers weiss es nicht:
Anhang 55132
Zumindest, wenn ich richtig gelesen habe.

Was mache ich falsch?

@Andreas13 Habe deinen Beitag eben jetzt gesehen. Danke! Allerdings von wegen Viruse - ich arbeite mit dem windowseigenen Defender.

Gruss
Delbor

[TiGü]

Nutze lieber den Window Detective, der kann noch ein bisschen mehr und kann wahlweise per Installer heruntergeladen werden:
https://windowdetective.sourceforge.io/

[KodeZwerg]

Zitat:

Zitat von Delbor (Beitrag 1506616)

@ Delphi.Narium: Nebst einem kostenpflichtigen Programm, das ich mir schon vor Jahr(-zehnt)en zugelegt habe, habe ich mir noch Ashampo PDF Free zugelegt, womit ich PDFs ausfüllen und sie mit beliebigen, auch benutzerdefinierten Stempeln versehen kann - und die Internethilfe ist in normalem Deutsch ohne jegliches Fachchinesisch abgehalten (..). Das ist für mich der Hauptgrund, warum ich vorerst bei Ashompoo bleiben will.

Der Unterschied ist, Delphi.Narium's varianten sind darauf ausgelegt eingebettet zu werden (sie haben anscheinend Child-Windows), dein Wunsch-Programm anscheinend nicht (bzw ich habs nicht zum testen, lese nicht dessen webseite etc....)

Idr. muss man per "AttachThreadInput()" die beiden seperaten prozesse vereinen, aber nichts desto trotz, generisch betrachtet ist es das schlimmste an was man überhaupt denken kann, da du keine Ahnung von den inneren Message-Ketten hast, die bei solch einem vorhaben schlichtweg zerschossen werden könnten.

[Delbor]

Hi zusammen

Zitat:

Zitat von KodeZwerg (Beitrag 1506635)

Der Unterschied ist, Delphi.Narium's varianten sind darauf ausgelegt eingebettet zu werden (sie haben anscheinend Child-Windows), dein Wunsch-Programm anscheinend nicht (bzw ich habs nicht zum testen, lese nicht dessen webseite etc....)

Idr. muss man per "AttachThreadInput()" die beiden seperaten prozesse vereinen, aber nichts desto trotz, generisch betrachtet ist es das schlimmste an was man überhaupt denken kann, da du keine Ahnung von den inneren Message-Ketten hast, die bei solch einem vorhaben schlichtweg zerschossen werden könnten.

Dein erster Abschnitt ist hochinteressant - Absicht ist oder wäre, ein bestimmtes PdF anzuzeigen und nach dessen Inhalt einen Datenbankeintrag zu generieren. Das funktioniert soweit, als dass ich Ashampoo und das PDF starten kann. Allerdings nicht als dem Tabsheet untergeaordnet, sondern solo über meinem Programm liegend. Positiv: die beiden Programme sind beide bearbeitbar. Negativ ist: Wenn ich Asampoo instinktiv über die rechte obere Ecke schliesse, friert mein Programm ein.
Ich werde noch einen Versuch mit Createprozess und warten auf das Ende probieren - aber ich fürchte, dass ich dann entweder das eine oder andere Programm bearbeiten kann, nicht jedoch beide.

Dein zweiter Abschnitt, und besonders dein letzter Satz, habensaber in sich!

Gruss
Delbor

[KodeZwerg]

Zitat:

Zitat von Delbor (Beitrag 1506643)

Wenn ich Asampoo instinktiv über die rechte obere Ecke schliesse, friert mein Programm ein.

Das könnte ich damit gemeint haben das Message-Ketten kaputt gehen. (abhilfe könnte schaffen indem du das "X" entfernst. ob das dann zielführend ist bezweifle ich da nun dein eigenes programm schon einen schaden genommen hat)

Zitat:

Zitat von Delbor (Beitrag 1506643)

Dein zweiter Abschnitt, und besonders dein letzter Satz, habensaber in sich!

Ich bin nur ehrlich.

Nebenbei, "CreateProcess()" nutze ich nur um sofort die 100% stimmende ProcessID zu erhalten um dann wiederum das WindowHandle zu ermitteln. (Windows arbeitet nun mal intern nur mit ProcessIDs und Handles)
Da ein Prozess mehrfach geladen werden kann sind andere Methoden zur Ermittlung eher... schwammig :-)

[himitsu]

Bei einem externen Programm mußt du das richtige Fenster finden und dort kannst du den Parant auf etwas in deinem Programm (Form/Panel/...) setzen.



Vom Acrobat-Reader gibt es noch eine ActiveX-Komponente, die man in sein Programm einbinden kann.

Aber offiziell wird sie nicht mehr für "fremde" Programme entwickelt, sondern nur für die Einfondung in die bekanntestens Browser. (sagt der Hersteller)
Und außerdem ändern die Arschlöcher andauern das Verhalten, was dann im eigenen Programm keinen Spaß macht und unsere Kunden nervt.

Daher nutzen wir aktuell die Komponente von DevExpress, um PDFs im Programm anzuzeigen. (die kann nicht alles und ist auch etwas langsamer, aber daran wird weiter gearbeitet)
Diese Komponente ist nun im Programm und bleibt somit immer gleich. Versuch mal einem Nutzer deines Programms zu erklären, dass es nicht deine Schuld ist, wenn es ein Update bei Acrobat gab und es in "deinem" Programm dann nicht mehr so geht, wie es soll.


Selbst Schuld, dass Acrobat nun immer mehr an Bedeutung verliert, dazumal inzwischen alle großen Browser selber was für PDF mitbringen.
Im Prinzip kann man somit nun auch im Delphi z.B. den TWebBrowser nutzen und darin dann die PDF anzeigen und sei es, indem man selbst eine Version von z.B. PDF.js mitbringt.

[Delbor]

Hi zusammen

Mein dringlichstes 'Problem', nämlich die Anzeige eines fremden Programmws in meinem, habe ich nun 'gelöst'. Bei MausDown in meinem TAlexOpenfileFrame:

Delphi-Quellcode:

    if Button =(mbLeft) then
    begin
      LSelectItem := PNameRec(AnItem.Data)^.RealName;
      ext := ExtractFileExt(LSelectItem);
      if ext = '.pdf' then
      begin
        ShellExecAndWait('F:\Externer Programmordner\Ashampoo\Ashampoo PDF Free\Ashampoo PDF.exe', LSelectItem, SW_Normal );

      end;
    end;

und

Delphi-Quellcode:

procedure TAlexOpenfileFrame.ShellExecAndWait(dateiname, Parameter: string; ShowHide: Integer);   // benötigt ShellAPI in Uses
var executeInfo: TShellExecuteInfo;
dw: DWORD;
begin
   FillChar(executeInfo, SizeOf(executeInfo), 0);
   with executeInfo do
      begin
         cbSize := SizeOf(executeInfo);
         fMask := SEE_MASK_NOCLOSEPROCESS or SEE_MASK_FLAG_DDEWAIT;
         Wnd := GetActiveWindow();
         executeInfo.lpVerb := 'open';
         executeInfo.lpParameters := PChar(Parameter);
         lpFile := PChar(dateiname);
         nShow := ShowHide;
      end;
      if ShellExecuteEx(@executeInfo) then dw := executeInfo.HProcess
         else
            begin
               ShowMessage('Fehler: ' + SysErrorMessage(GetLastError));
               exit;
            end;
      while WaitForSingleObject(executeInfo.hProcess, 50) <> WAIT_OBJECT_0 do
      Application.ProcessMessages;
      CloseHandle(dw);
end;

Der Code stammt bis auf meine Komponenten von hier, bzw hier.
Na ja, so ähnlich zumindest. Ich bin so frei und erspare mir den Versuch des Abgleichs mit all den in diesem Forum gefundenen wohl mehreren dutzend Codeschnipsel.
Das vorerst wichtigste: Ich kann abwechselnd mit beiden Programmen arbeiten.


Gruss
Delbor