Tagesanzahl Februar eines Jahres

[Kratos]

Hallo Leute,

ich hab jetzt sehr lange herumgesucht und auch einige Foreneinträge gefunden, die mich etwas weitergebracht haben.
Jedoch führte keines meiner Experimente zu dem Ergebnis, welches ich im Sinn hatte.
Dabei sieht die Problemstellung für mich doch recht banal aus...

Ich möchte eine Altersberechnung durchführen. Dazu benutze ich 3 Comboboxen.

cbbDay
cbbMonth
cbbYear

Die eigentliche Altersberechnung führe ich hiermit durch: https://www.delphipraxis.net/146593-...errechnen.html

Ich möchte mit einbauen, dass je nachdem welcher Monat in cbbMonth ausgewählt wird, die monatsspezifische Anzahl an Tagen in cbbDay geladen wird.
Das klappt auch für alle Monate. Bloß nicht für den Februar.

Mein Versuch:

Delphi-Quellcode:

var
   days: Cardinal;

begin
...
   days := DaysInMonth(StrToDate(cbbYear.Text + '.02'));
...
end;

Vorausgesetzt ich wähle 2020 in cbbYear, bringt er mir den Fehler

Code:

2020.02 ist kein gültiges Datum

Das seh ich auch ein.
Aber ich weiß einfach nicht wie ich das nun lösen soll.

Kompletter Code der Prozedur:

Delphi-Quellcode:

procedure TForm1.cbbMonthClick(Sender: TObject);
var
  i: Integer;
  days: Cardinal;
begin
  if cbbMonth.ItemIndex >= 0 then
  begin
    cbbDay.Enabled := True;
    if cbbMonth.ItemIndex in [0, 2, 4, 6, 7, 9, 11] then    // Monate mit 31 Tagen
    begin
      for i := 1 to 31 do                                   // Füge 31 Items(Tage) der cbbDay hinzu
      begin
        cbbDay.Items.Add(IntToStr(i));
      end;
    end
    else
    begin                                                   // alle anderen Monate
      if cbbMonth.ItemIndex = 1 then                        // Für Monat Februar
      begin
        days := DaysInMonth(StrToDate(cbbYear.Text + '.02'));
        for i := 1 to days do                  // Füge die jahrespezifische Tagesanzahl für Februar hinzu
        begin
          cbbDay.Items.Add(IntToStr(i));
        end
      end
      else
      begin
        for i := 1 to 30 do                                 // Monate mit 30 Tagen
        begin
          cbbDay.Items.Add(IntToStr(i));
        end;
      end;
    end;
  end
  else
  begin
    cbbDay.Enabled := False;
  end;
end;

Wie gesagt, ich denke die Lösung ist einfach, da mir auch die OH sagt, dass ich doch nur den Monat in TDateTime eingeben soll. :|
Ich weiß aber nicht, wie das aussehen soll.
Ich hoffe ihr könnt mir weiterhelfen.

VG Kratos

[Klaus01]

.. versuche mal

Delphi-Quellcode:

DaysInAMonth(year, month);

Grüße
Klaus

[haentschman]

Versuch es mal damit:

Delphi-Quellcode:

days := DaysInAMonth(StrToInt(cbbYear.Text, 2));

http://docwiki.embarcadero.com/Libra...s.DaysInAMonth

Zitat:

function DaysInAMonth(const AYear, AMonth: Word): Word;

[Uwe Raabe]

Wenn schon

Delphi-Quellcode:

DaysInMonth

verwenden, dann doch einfach in allen Fällen:

Delphi-Quellcode:

var
  i: Integer;
  days: Cardinal;
  month: Integer;
  year: Integer;
begin
  cbbDay.Enabled := False;
  if cbbMonth.ItemIndex >= 0 then
  begin
    month := cbbMonth.ItemIndex + 1;
    if TryStrToInt(cbbYear.Text, year) then
    begin  
      days := DaysInMonth(EncodeDate(year, month, 1));
      for i := 1 to days do // Füge die jahrespezifische Tagesanzahl für den Monat hinzu
      begin
        cbbDay.Items.Add(IntToStr(i));
      end;
      cbbDay.Enabled := True;
    end
    else 
    begin
      ShowMessage('ungültiges Datum!');
    end;
  end;
end;

[haentschman]

Ist das fehlende begin ein Kopierschutz? :stupid::zwinker:

...ändern ist gemein.:zwinker:

[Uwe Raabe]

Zitat:

Zitat von haentschman (Beitrag 1478870)

Ist das fehlende begin ein Kopierschutz?

Nein, eine Folge der fehlenden Visualisierungs-Tools des Forum-Editors. Ich habe so meine Probleme mit Web-Editoren. Der Cursor ist nie da wo man ihn vermutet und dann löscht man eine Zeile ohne es zu bemerken...

Normalerweise schreibe ich sowas in der Delphi-IDE, aber das setzt in der Regel ein compilierbares Projekt oder zumindest compilierbaren Code voraus.

[DeddyH]

Oder wenn man bei der ursprünglichen Lösung bleiben möchte:

Delphi-Quellcode:

if IsLeapYear(Year) then
  Days := 29
else
  Days := 28;

[Kratos]

Guten Morgen,

vielen Dank für die vielen Antworten!
Ich hab mich schlussendlich für die Lösung von DeddyH entschieden.
Es funktioniert. :)

VG
Kratos

[Delphi.Narium]

Geht aber kürzer ;-)

Delphi-Quellcode:

Days := IfThen(IsLeapYear(Year),29,28);

[taveuni]

Zitat:

Zitat von Delphi.Narium (Beitrag 1478939)

Geht aber kürzer ;-)

Delphi-Quellcode:

Days := IfThen(IsLeapYear(Year),29,28);

Wow!

[Andreas13]

Zitat:

Zitat von taveuni (Beitrag 1478965)

Zitat:

Zitat von Delphi.Narium (Beitrag 1478939)

Geht aber kürzer ;-)

Delphi-Quellcode:

Days := IfThen(IsLeapYear(Year),29,28);

Wow!

Diese neuere Kurzform

Delphi-Quellcode:

IfThen

trägt nicht unbedingt zur Übersichtlichkeit bei. Es ist eher fehleranfällig als gut, daher würde ich es persönlich nicht benutzen. Intern sind die beiden Befehle sicherlich identisch.
Andreas

[DeddyH]

Zitat:

Zitat von Andreas13 (Beitrag 1478968)

Intern sind die beiden Befehle sicherlich identisch.

Sind sie :wink:

[Delphi.Narium]

Zitat:

Zitat von Andreas13 (Beitrag 1478968)

Zitat:

Zitat von taveuni (Beitrag 1478965)

Zitat:

Zitat von Delphi.Narium (Beitrag 1478939)

Geht aber kürzer ;-)

Delphi-Quellcode:

Days := IfThen(IsLeapYear(Year),29,28);

Wow!

Diese neuere Kurzform

Delphi-Quellcode:

IfThen

trägt nicht unbedingt zur Übersichtlichkeit bei. Es ist eher fehleranfällig als gut, daher würde ich es persönlich nicht benutzen. Intern sind die beiden Befehle sicherlich identisch.
Andreas

Was ist daran fehleranfällig?

Wenn ich beim Programmieren nicht aufpasse, mache ich Fehler.

Beim Aufruf einer derartigen Funktion mit 'nem Rückgabewert ist (zumindest bei mir) die Fehlerhäufigkeit nicht höher, als bei beliebigen anderen Funktionen mit mehreren Parametern und 'nem Rückgabewert.

Und das IfThen 'ne neuere Kurzform ist, halt' ich für 'n Gerücht. Mein olles Delphi 7 aus dem Jahr 2002 enthält diese Funktionen in den Units Math und StrUtils. Die neuere Kurzform ist also erst / mindestens 18 Jahre alt und damit volljährig und darf wählen sowie gewählt werden. Ich wähle sie ;-)

Und wenn sich wer an dem If Then stört:

Delphi-Quellcode:

case IsLeapYear(Year) of
  true  : Days := 29;
  false : Days := 28;
end;

Oder ginge es auch so?

Delphi-Quellcode:

Days := 28 + Ord(IsLeapYear(Year));

[Andreas13]

Nichts für ungut: Bekanntlich darf jeder nach seiner Fasson glücklich werden. Ich habe lediglich meinen Standpunkt dargelegt. Wenn

Delphi-Quellcode:

 IfThen

schon "volljährig" ist, dann benutze ich es seit 18 Jahre bewußt nicht :wink:. Da ich 1985 mit Tubo Pacal 3 angefangen habe, können 18 Jahre "alte" Funktionen für mich durchaus als "neuere" gelten…:wink:

Die meisten Delphianer haben sich für Pascal entschieden, u. a. weil es eine disziplinierte Programmiersprache ist und unser Code dadurch leichter zu verstehen und warten ist. Allzu trickreiche Programmierung und Sprach-Akrobatik rächt sich meistens erst später bei der Pflege und Erweiterung der Programme.

Der Vorschlag von Detlef unter #7 in der ausführlichen Schreibweise ist selbsterklärend und "idiotensicher", während man bei

Delphi-Quellcode:

IfThen

die Reihenfolge der Parameter leicht vertauschen kann, ohne den Fehler zu merken.

Mein Motto ist daher, daß Übersichtlichkeit & Zuverlässigkeit vor Kürze gehen. Schreibfaulheit in der Kodierung ist eher ein Merkmal vieler C++-Programmierer. Wer möchte schon z. B. solche kryptischen Zeilen (= kurze, kompakte Befehle) nach Jahren weiterpflegen:

Code:

const Doub *xa = &xx[jl], *ya = &yy[jl]; 
... 
j = (Int)(pp % nhash); 
... 
Int k = ng ? garbg[--ng] : nn++ ; 
... 
for (;;) { 
for (i=1;i<=n;i++) x[i]=xold[i]+alam*p[i]; 
*f=(*func)(x); 
if (alam < alamin) 
for (i=1;i<=n;i++) x[i]=xold[i]; 
*check=1; 
return; 
} else if (*f <= fold+ALF*alam*slope) return; 
... 
k = ng ? garbg[--ng] : nn++ ; 
k != -1; k = next[k]) 
... 
y=ya[ns--]; 
... 
y += (dy=(2*(ns+1) < (mm-m) ? c[ns+1] : d[ns--])); 
...

Gruß, Andreas

[haentschman]

Moin...8-)

...man sollte aber auch dazu sagen, daß das dieses IfThen aus der Unit Math kommt. IfThen gibt es auch in SysUtils...die macht aber was ganz anderes. :zwinker:

http://docwiki.embarcadero.com/Libra...trUtils.IfThen
http://docwiki.embarcadero.com/Libra...em.Math.IfThen

[Uwe Raabe]

Bei

Delphi-Quellcode:

IfThen

gilt auch zu beachten, dass es sich hier um einen Funktionsaufruf handelt, bei dem immer alle Parameter ausgewertet werden.

Delphi-Quellcode:

var
  cmp: TComponent;
  cmpName: string;
begin
  cmp := FindComponent('Edit1');

  { hier kann ein Zugriffsfehler auftreten }
  cmpName := IfThen(cmp <> nil, cmp.Name, '');

  { kann hier nicht passieren }
  if cmp <> nil then
    cmpName := cmp.Name
  else
    cmpName := '';

[Delphi.Narium]

Zitat:

Zitat von Uwe Raabe (Beitrag 1478992)

Bei

Delphi-Quellcode:

IfThen

gilt auch zu beachten, dass es sich hier um einen Funktionsaufruf handelt, bei dem immer alle Parameter ausgewertet werden.

Delphi-Quellcode:

var
  cmp: TComponent;
  cmpName: string;
begin
  cmp := FindComponent('Edit1');

  { hier kann ein Zugriffsfehler auftreten }
  cmpName := IfThen(cmp <> nil, cmp.Name, '');

  { kann hier nicht passieren }
  if cmp <> nil then
    cmpName := cmp.Name
  else
    cmpName := '';

Stimmt, aber in so 'ner Situation käme ich nie und nimmer auf die Idee IfThen zu nutzen. Bei Parametern für IfThen weiß ich immer vorher, dass ich das problemlos drauf zugreifen kann.

Delphi-Quellcode:

var
  cmp: TComponent;
  cmpName: string;
begin
  cmp := FindComponent('Edit1');
  if Assigned(cmp) then begin // ohne das, geht es bei mir nach 'nem FindComponent o. ä. garantiert nicht weiter.
    ...
  end else begin
    ...
  end;

[Rollo62]

Zitat:

Zitat von Uwe Raabe (Beitrag 1478992)

Bei

Delphi-Quellcode:

IfThen

gilt auch zu beachten, dass es sich hier um einen Funktionsaufruf handelt, bei dem immer alle Parameter ausgewertet werden.

Sehr guter Hinweis.
Gäbe es denn irgendeinen Trick um das zu Vermeiden, ich denke mal nicht, oder ?
Shortcuts gibt es nur bei Operatoren soweit mir bekannt.

[joachimd]

Zitat:

Zitat von Andreas13 (Beitrag 1478981)

Code:

const Doub *xa = &xx[jl], *ya = &yy[jl]; 
... 
j = (Int)(pp % nhash); 
... 
Int k = ng ? garbg[--ng] : nn++ ; 
... 
for (;;) { 
for (i=1;i<=n;i++) x[i]=xold[i]+alam*p[i]; 
*f=(*func)(x); 
if (alam < alamin) 
for (i=1;i<=n;i++) x[i]=xold[i]; 
*check=1; 
return; 
} else if (*f <= fold+ALF*alam*slope) return; 
... 
k = ng ? garbg[--ng] : nn++ ; 
k != -1; k = next[k]) 
... 
y=ya[ns--]; 
... 
y += (dy=(2*(ns+1) < (mm-m) ? c[ns+1] : d[ns--])); 
...

So etwas habe ich in meinen C++-Jahren geliebt. Ich musste mich bei der Rückkehr zu Pascal damals extrem umstellen ;)

[Amateurprofi]

Zitat:

Zitat von Delphi.Narium (Beitrag 1478939)

Geht aber kürzer ;-)

Delphi-Quellcode:

Days := IfThen(IsLeapYear(Year),29,28);

oder noch kürzer

Delphi-Quellcode:

Days:=28+Ord(IsLeapYear(Year));

[DasWolf]

Zitat:

Zitat von Andreas13 (Beitrag 1478981)

Der Vorschlag von Detlef unter #7 in der ausführlichen Schreibweise ist selbsterklärend und "idiotensicher", während man bei

Delphi-Quellcode:

IfThen

die Reihenfolge der Parameter leicht vertauschen kann, ohne den Fehler zu merken.

Zitat:

Zitat von DeddyH (Beitrag 1478887)

Oder wenn man bei der ursprünglichen Lösung bleiben möchte:

Delphi-Quellcode:

if IsLeapYear(Year) then
  Days := 29
else
  Days := 28;

Kann man auch so idiotensicher verhauen:

Delphi-Quellcode:

if IsLeapYear(Year) then
  Days := 28
else
  Days := 29;