Delphi GetIt Package Manager Command Line

[PatrickB08]

Aktuell arbeite ich am Aufsetzen eines automatisierten Test Servers für unsere Delphi Programme. Um unsere Tools automatisiert zu testen verwenden wir Jenkins und virtuelle Maschinen als Jenkins Windows slaves. Auf diesen wird Delphi mit Hilfe
einer silent Installation installiert (da wir auf den slaves nichts manuell selber installieren, alles nur mit batch files). Einige unsererer Apps benötigen jedoch noch zusätzliche Packages, welche wir bisher über den GetIt Package manager installieren konnten (zum Beispiel: LockBox3).
Auf den Windows slaves jedoch soll dies auch mit Hilfe eines batch files komplett automatisert geschehen. Nun wollte ich fragen, ob dies denn möglich ist und wenn ja, wie (zum Beispiel: Nutzen des getitcommand tools, welches jedoch laut Foren nicht supportet wird?).

[himitsu]

https://www.delphipraxis.net/205253-...errschaft.html
Bin aber leider noch nicht viel weiter gekommen.


Du kannst das Gewünschte auf auf einem PC via GetIt runterladen/installieren
und dann die nötigen Komponenten/Verzeichnisse kopieren.
%USERPROFILE%\Documents\Embarcadero\Studio\21.0\Ca talogRepository (C:\Users\%USERNAME%\...)
Dort findest je Komponente ein Verzeichnis, da drin noch ein Unterverzeichnis und dort dann oftmals die BAT/CMD/EXE des jeweiligen Installers.


Ansonsten:
Ich glaub ich hatte in der OpenToolsAPI (OTA) ein paar Interfaces für GetIt gesehen.

[PatrickB08]

Leider gibt es bei der LockBox keinen installer im entsprechendem Verzeichnis ("C:\Users\%USERNAME%\Documents\Embarcadero\Studio \20.0\CatalogRepository\LockBox-3.7"). Es gibt nur eine GetItInstaller.dat datei?

Anhang 52991

[himitsu]

Zitat:

Zitat von PatrickB08 (Beitrag 1472744)

GetItInstaller.dat

Wozu diese nutzlose Datei sein soll, hab ich auch noch nicht verstanden.
Dachte anfangs da stünde drin was gemacht werden muß .... aber neeeeee

Was zu machen ist, das steht in HKEY_CURRENT_USER\SOFTWARE\Embarcadero\BDS\21.0\CatalogRepository\Elements



%USERPROFILE%\Documents\Embarcadero\Studio\21.0\CatalogRepository\LockBox-3.7-Sydney\packages\Sydney\Delphi\*.dpr oder *.dproj

Du kannst alle .DPR mit DCC32 kompilieren
oder mit MSBuild, bzw. über BDS.exe die .DPROJ

Delphi-Quellcode:

bds -np -b C:\...\xxx.dproj 
bds -np -p Delphi -b C:\...\xxx.dproj  // im RAD Studio nicht sinnlos das C++ mit laden

Bei MSBuild und BDS würde auch PreBuild- und AfterBuild-Script mit ausgeführt.

Anschließend mußt du aber noch die Packages im Delphi registrieren, da über BDS.exe nur COMPILE oder BUILD angestoßen werden kann, aber nicht INSTALL.



Via OpenToolsAPI könnte man Projekte laden und das Compilieren+Installieren starten.

[himitsu]

Ach ja, wir haben inzwischen alles auf Komponenten umgestellt, wo wir auch den Quellcode bekommen.
Im Notfall selbst auf neues Delphi umstellbar (wenn der Hersteller nicht hinterherkommt oder tot ist) und auch selbst Bugfixe/Anpassungen einbauen können.

Dieses liegt im Git (zwei Repos für externe Komponenten und für das eigene Zeugs)
und wird vorwiegend im FinalBuilder kompiliert. (die eigenen Projekte auch im Delphi)
Der FB registriert ebenfalls die Packages im Delphi
HKEY_CURRENT_USER\SOFTWARE\Embarcadero\BDS\21.0\Kn own Packages
deregistriert vorher gleichnamige Packages (z.B. von einer lokalen Installation oder einer anderen Version)
und räumt die beim Arbeiten/Compilieren/Debuggen im Delphi deaktivierten Packages auf
HKEY_CURRENT_USER\SOFTWARE\Embarcadero\BDS\21.0\Di sabled Packages

Vorteil ist auch, dass man abwechselnd mit unterschiedlichen Versionen der Komponenten arbeiten kann.
z.B. alte Version für rückwärtige Bugfixe, oder schon die neue Version, bevor sie im Master an alle Verteilt wurde.

Wenn jeder Entwickler mit einer eigenen/anderen Version (über das GetIt) unsere Projekte kompilieren würde, dann gäbe es auch ein perfektes Chaos und würde bestimmt oft knallen, wenn Interfaces geändert wurden.

Aber ja, wenn man im GetIt eigene Packet-Quellen angeben könnte und man darüber seine "eigenen" Komponenten verteilen würde, dann wäre das bestimmt eine witzige Idee hierfür GetIt zu verwenden
und die Komponenten über die IDE zu verteilen, anstatt über ein externes Programm.

[TurboMagic]

Du kannst die Idee ja gerne als QP feature request anbringen.

[himitsu]

Zitat:

GetItCmd.exe

Im 10.4 Update 1 gab es irgendwelche Verbesserungen.
Kannst ja mal ausprobieren, ob das dir jetzt hilft.

Zitat:

Zitat von TurboMagic (Beitrag 1472819)

Du kannst die Idee ja gerne als QP feature request anbringen.

Dafür müssen die erstmal hinbekommen, dass man mehrere Komponenten auswählen und zusammen installieren kann,
sonst klickt man sich dumm und dusslig, während man sich dazwischen immer wieder zu tode langweilt.

[PatrickB08]

Zitat:

Zitat von himitsu (Beitrag 1472827)

Zitat:

GetItCmd.exe

Im 10.4 Update 1 gab es irgendwelche Verbesserungen.
Kannst ja mal ausprobieren, ob das dir jetzt hilft.

Leider finde ich dazu keine Dokumentation und nach eigenen Tests stürtzt das Programm immer ab.
Ich habe aber mal für die Installation für die LockBox ein Batch Skript geschrieben (Vorlage: https://www.delphipraxis.net/198824-...ml#post1472843).
Leider bekomme ich nun immer die Fehlermeldung, dass die designide fehlt (beim kompilieren von LockBox3FMXDD.dproj und LockBox3VCLDD.dproj). Diese gibt es auch nicht im entsprechenden lib order unter win64 nur für win32. Sollte dies eh nicht nur für win32 eine Rolle spielen?

Das Batch Skript:

Code:

CALL "C:\Program Files (x86)\Embarcadero\Studio\20.0\bin\rsvars.bat"
ECHO %BDS%
ECHO %BDSCOMMONDIR%
SET BPLREG="HKEY_CURRENT_USER\Software\Embarcadero\BDS\20.0\Known Packages"
ECHO %BPLREG%
SET LIBREG="HKEY_CURRENT_USER\Software\Embarcadero\BDS\20.0\Library\Win64"
ECHO %LIBREG%
SET BPLPATH="%BDSCOMMONDIR%\Bpl"
ECHO %BPLPATH%
SET BDSCATALOGREPO=C:\Users\%USERNAME%\Documents\TMP\Delphi
ECHO ================================================================================

rem LockBox3
ECHO LockBox3
ECHO LockBox3DR

rem add search path for library
SET LIB_LOCKBOX=%BDSCATALOGREPO%\LockBox3\design\;%BDSCATALOGREPO%\LockBox3\run\ciphers\;%BDSCATALOGREPO%\LockBox3\run\cryptography\;%BDSCATALOGREPO%\LockBox3\run\hashes\;%BDSCATALOGREPO%\LockBox3\run\library surface\;%BDSCATALOGREPO%\LockBox3\run\RSA\;%BDSCATALOGREPO%\LockBox3\run\utilities
:: extract path from registry entry
FOR /F "tokens=3* skip=2" %%a in ('reg query %LIBREG% /v "Search Path"') do set  "DELPHI_LIB_SEARCH=%%b" 
ECHO New variable DELPHI_LIB_SEARCH = %DELPHI_LIB_SEARCH%
:: check if substring is already present in path -> if not: add it to path
echo %DELPHI_LIB_SEARCH%|find /i "%LIB_LOCKBOX%">nul  || set DELPHI_LIB_SEARCH=%DELPHI_LIB_SEARCH%;%LIB_LOCKBOX%
reg add %LIBREG% /v "Search Path" /t REG_SZ /d "%DELPHI_LIB_SEARCH%" /f

:: compile in order to get *.bpl
msbuild "%BDSCATALOGREPO%\LockBox3\packages\Rio\Delphi\LockBox3DR.dproj" /t:Build /p:Configuration=Release /p:platform=Win64
IF NOT %ERRORLEVEL%==0 GOTO ERROR
reg delete %BPLREG% /v "%BPLPATH%\LockBox3DR260.bpl" /f >NUL 2>&1
reg add   %BPLREG% /v "%BPLPATH%\LockBox3DR260.bpl" /t REG_SZ /d "Turbo LockBox3 Delphi package" >NUL

::ECHO LockBox3FMXDD
msbuild "%BDSCATALOGREPO%\LockBox3\packages\Rio\Delphi\LockBox3FMXDD.dproj" /t:Build /p:Configuration=Release /p:platform=Win64
IF NOT %ERRORLEVEL%==0 GOTO ERROR
reg delete %BPLREG% /v "%BPLPATH%\LockBox3FMXDD260.bpl" /f >NUL 2>&1
reg add   %BPLREG% /v "%BPLPATH%\LockBox3FMXDD260.bpl" /t REG_SZ /d "Turbo LockBox3 FMX designtime package" >NUL

ECHO LockBox3VCLDD
msbuild "%BDSCATALOGREPO%\LockBox3\packages\Rio\Delphi\LockBox3VCLDD.dproj" /t:Build /p:Configuration=Release /p:platform=Win64
IF NOT %ERRORLEVEL%==0 GOTO ERROR
reg delete %BPLREG% /v "%BPLPATH%\LockBox3VCLDD260.bpl" /f >NUL 2>&1
reg add   %BPLREG% /v "%BPLPATH%\LockBox3VCLDD260.bpl" /t REG_SZ /d "Turbo LockBox3 VCL designtime package" >NUL

GOTO DONE

:ERROR
ECHO ================================================================================
ECHO FEHLER aufgetreten! ERRORLEVEL = %ERRORLEVEL%
ECHO ================================================================================
GOTO END

:DONE
ECHO ================================================================================
ECHO Build erfolgreich!
ECHO ================================================================================
GOTO END

:END
SET BPLREG=
SET BPLPATH=
SET LIBREG=
SET BDSCatalogRepository=
SET LIB_PATH_LOCKBOX=
SET BDSCATALOGREPO=
SET LIB_LOCKBOX=
SET DELPHI_LIB_SEARCH=

[PatrickB08]

hat sich erledigt. Hatte die falsche platform fürs kompilieren -> einfach auf win32 und jetzt läufts.

[himitsu]

Jupp, die IDE gibt es nur als 32 Bit, also braucht man DesignTime-Packages ausschließlich als Win32 und deswegen gibt es diese gegeimen IDE-DCUs auch nur in Win32.

[himitsu]

Hat das inzwischen jemand zum Laufen gebracht?

Vor Aufruf der getitcmd.exe soll man einmal die rsvars.bat aufrufen, um die Umgebungsvariablen von der IDE zu setzen.
Auflisten der Packages funktioniert. (so halbwegs)
Nur das mit dem Installieren, also der Hauptfunktion, ... naja.

Code:

cd /d "C:\Program Files (x86)\Embarcadero\Studio\21.0\bin"
rsvars
getitcmd --list= --filter=installed
getitcmd --list= --filter=all
getitcmd --install=Navigator-1.6.1 --accepteulas --installdeferred --verb=minimal --donotsetenvfile

Nach

Delphi-Quellcode:

getitcmd --list= --filter=all

stürzt GetIt ab, nachdem es fertig ist.

Code:

...
Command finished with success!
Runtime error 217 at 00409825

Bei

Delphi-Quellcode:

getitcmd --install=Navigator-1.6.1 --accepteulas --installdeferred --verb=minimal --donotsetenvfile

heißt es

Code:

ERROR: Too many arguments.

[edit] OK, Installdeferred, darf nicht mit Anderem zusammen. [/edit]

Das sind übrigens auch so in etwa die Parameter, welche die GetIt-Dependencies in den Projektoptionen benutzen, was auch nicht benutzbar ist.

Code:

[Warning Warnung] Checking GetIt package dependencies
[MSBuild Fehler] Unerwarteter Fehler bei der GetItCmd-Aufgabe.
System.NullReferenceException: Der Objektverweis wurde nicht auf eine Objektinstanz festgelegt.
   bei Borland.Build.Tasks.Common.CommandLineTask.Execute()
   bei Borland.Build.Tasks.Shared.GetItCmd.Execute()
   bei Microsoft.Build.BuildEngine.TaskEngine.ExecuteInstantiatedTask(EngineProxy engineProxy, ItemBucket bucket, TaskExecutionMode howToExecuteTask, ITask task, Boolean& taskResult)

aus CodeGear.Common.Targets (wer zu den GetIt-Dependencies etwas sucht und dort findet, dass man BDSHost=true in die Umgebungsvariablen schreiben soll ... hier sieht man das Gegenstück dazu)

Code:

  <!-- Since there's an IDE limitation about handling more than one compilation,
  GetItCmd should be called only when compiling from command line -->
  <Target Name="_CheckGetItPackageDependencies" DependsOnTargets="_CheckBDSHostObject"
    Condition="('$(GetItPackages)'!='') And '$(BDSHost)'!='true'">
    <CallTarget Targets="_ExecGetItCmd"/>
  </Target>

  <Target Name="_ExecGetItCmd">
    <Warning Text="Checking GetIt package dependencies"/>
    <GetItCmd
        ProjectFileName="$(MSBuildProjectFullPath)"
        Accept_eulas="true"
        InstallPackages="$(GetItPackages)"
        DoNotSetEnvFile="true"
        Verbosity="Normal"
    />
  </Target>

Und bei

Delphi-Quellcode:

getitcmd --install=Navigator-1.6.1 --accepteulas

will GetIt erstmal alles/einiges deinstallieren. (da hab ich den UAC-Dialog abgebrochen, bevor was kaputt geht)
Als Erstes gleich mal die Delphi-IDE selbst. (scheint das zu sein, was man sich mühevoll über den GetItInstaller runtergeholt hatte)

Code:

Uninstalling: Uninstalling Library "Delphi Common Files Enterprise German"...

Anfangen wollte ich erstmal mit.
10.4Patch1-10
10.4Patch2de-10
10.4Patch3-10
ParnassusCoreEditor-1.6.1 ?
Navigator-1.6.1
Bookmarks-1.6.1
Icons8-1.0
(Komponenten für's Programm werden wohl nie über GetIt verwendet, so lange man dort keine eigenen/alternativen Paketquellen angeben kann und somit auf's Gutdünken Embas angewiesen ist, außerdem haben wir die Fremdkomponenten größtenteils als Quellcode in einem eigenen Git-Repository ... den Teil aber über eine eigene Paketquelle wäre schon interessant, anstatt es manuell im FinalBuilder zu machen)


Man findet ja nicht viel zum Thema, aber da hat/hatte man auch das selbe Problem, wo Packages deinstalliert werden.
https://qiita.com/ht_deko/items/2e7184431888c6c0612f

[Benmik]

Zitat:

Zitat von himitsu (Beitrag 1477131)

Code:

cd /d "C:\Program Files (x86)\Embarcadero\Studio\21.0\bin"
rsvars
getitcmd --list= --filter=installed
getitcmd --list= --filter=all
getitcmd --install=Bookmarks-1.6.2 --accepteulas --verb=minimal --donotsetenvfile

Funktioniert! Allerdings fehlt da vorher noch

Delphi-Quellcode:

getitcmd -c=useonline

, sonst kommt "RADSTUDIO.JSON metadata not found".

[BastiFantasti]

Ich bringe das Thema nach sehr langer Zeit mal wieder nach oben :-)

Gibt es eine Möglichkeit die Pakete darüber zu installieren ohne die absolute Version anzugeben?
Hintergrund ist, ich möchte auf meinem bestehenden System die Paketliste exportieren, dann Delphi updaten und die Packages wieder installieren.
Allerdings ändert sich natürlich auch die Paketversion mit neueren Delphiversionen...

Praktisch wäre, wenn man die Pakete wie mit pip installiren könnte und getit die jeweils aktuelle und zur Delphiversion passende auswählen würde.

z.b.

Code:

getitcmd --install=Bookmarks --accepteulas --verb=minimal --donotsetenvfile

anstatt

Code:

getitcmd --install=Bookmarks-1.6.2 --accepteulas --verb=minimal --donotsetenvfile

Viele Grüße
Bastian

[BastiFantasti]

hab es mal mit der "EdgeBrowserDemo" versucht

das scheint leider nicht zu klappen...

Code:

getitcmd --install=EdgeBrowserDemo

[Uwe Raabe]

Du könntest ja das AutoGetIt entsprechend anpassen :)

[himitsu]

Es heißt ja auch EdgeBrowserDemo-1.0 :wink:
(ich finde immernoch, dass die Versionsnummer im Namen der größte Schwachsinn ist, zumindest wenn nicht optional)

Code:

getitcmd --list=

getitcmd --filter=all --list=

getitcmd --filter=all --list=EdgeBrowserDemo

Sicherheitshalber vorm getitcmd noch die rsvars.bat ausführen (weiß nicht ob es noch nötig ist, aber mit lief es bisher immer am Besten)

Code:

cd /d "C:\Program Files (x86)\Embarcadero\Studio\22.0\bin"
rsvars.bat
getitcmd --install=...

CD: Bzw. ich gehe im Explorer in dieses Verzeichnis (ist inzwichem im AutoComplete drin), schreibe oben in die Adressleiste

Delphi-Quellcode:

cmd

+ [Enter] und dann nur noch das Nachfolgende

[BastiFantasti]

Zitat:

Zitat von Uwe Raabe (Beitrag 1519570)

Du könntest ja das AutoGetIt entsprechend anpassen :)

Das schaue ich mir mal an. Danke

[BastiFantasti]

[QUOTE=himitsu;1519577]Es heißt ja auch EdgeBrowserDemo-1.0 :wink:
(ich finde immernoch, dass die Versionsnummer im Namen der größte Schwachsinn ist, zumindest wenn nicht optional)

ja, das ist ja das doofe.
Ich will ja nicht die Version pinnen.
Ich will ja nur unter einer neuen Delphiversion die entsprechend aktuell verfügbare Version des gleichen Pakets installieren.

Das Ziel soll ja sein, eine neue Delphiversion so schmerzfrei wie möglich aufzusetzen. 8-)

[BastiFantasti]

Zitat:

Zitat von Uwe Raabe (Beitrag 1519570)

Du könntest ja das AutoGetIt entsprechend anpassen :)

Das Programm kann das sogar schon :thumb:
Habe gerade in den Quellen geschaut.

Einfach aus der exportierten Liste händisch die Versionsnummern entfernen und fertig.
Beim Import wird automatisch geprüft mit "StartsText"

[BastiFantasti]

Habe nun versucht, einen neue Delphiversion (11.3) mittels AutoGetIt um die benötigten Pakete zu erweitern.
Das Problem ist, dass es von vielen Paketen welche mit XXXcb und ohne - alson nur XXX gibt.

Das heißt hier muss eine manuelle Auswahl erfolgen, oder der Paketnamen den Abschließenden Bindestrich bis zur Versionsbezeichnung beinhalten.
Die Installation einiger Pakete hat er mit Fehler abgebrochen und andere erfolgreich installierten Pakete wurden als nicht installiert angezeigt...

Also so ganz automatisch funktioniert das bei mir leider noch nicht...

[himitsu]

Zitat:

Zitat von BastiFantasti (Beitrag 1519639)

und andere erfolgreich installierten Pakete wurden als nicht installiert angezeigt...

Doch, werden sie,

wenn du die Delphi-IDE als Admin startest. :freak:
(mit dem User, der für die Installation benutzt wurde)