AlwaysOnTop mit mehreren Formularen

[Dalai]

Ein freundliches Hallo an die Experten :). [Ggf. passt das Thema auch zu GUI-Design.]

Bislang setze ich Formulare OnTop mit der folgenden Funktion:

Delphi-Quellcode:

procedure AlwaysOnTop(AOnTop: Boolean; const AFormHandle: THandle);
begin
  if AOnTop then
      SetWindowPos(AFormHandle, HWND_TOPMOST, 0, 0, 0, 0, SWP_NOACTIVATE or SWP_NOMOVE or SWP_NOSIZE)
  else
      SetWindowPos(AFormHandle, HWND_NOTOPMOST, 0, 0, 0, 0, SWP_NOACTIVATE or SWP_NOMOVE or SWP_NOSIZE);
end;

Das funzt auch wunderbar - jedenfalls in allen Anwendungen, die nur ein Formular haben bzw. bei denen nur eines OnTop sein soll.

Gestern fügte ich einem Projekt ein weiteres Formular hinzu, das wie das erste Formular OnTop sein soll. Jeden, der nun anmerkt, dass nicht beide OnTop sein können, kann ich beruhigen, denn die Formulare sind explizit nicht übereinander sondern immer nebeneinander auf dem Bildschirm. Es geht nur darum, dass beide Formulare über den Fenstern anderer Anwendungen liegen sollen.

Nachfolgend ein simples Testprojekt, das das Verhalten ebenfalls zeigt. Form1 wird automatisch erzeugt, Form2 nicht.

Unit1 mit Form1:

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  uGUIHelper, Unit2;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure FormActivate(Sender: TObject);
  private
    Fform2: TForm2;
  public
  end;

const
  bShowForm2: Boolean = True;

var
  Form1: TForm1;

implementation

{$R *.DFM}

procedure TForm1.FormCreate(Sender: TObject);
begin
    if bShowForm2 then begin
        Fform2:= TForm2.Create(nil);
        Fform2.Show;
    end;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
    Fform2.Free;
end;

procedure TForm1.FormActivate(Sender: TObject);
begin
    uGUIHelper.AlwaysOnTop(True, Self.Handle);
end;

end.

Unit2 mit Form2:

Delphi-Quellcode:

unit Unit2;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs;

type
  TForm2 = class(TForm)
    procedure FormActivate(Sender: TObject);
  private
  public
  end;

implementation

uses uGUIHelper;

{$R *.DFM}

procedure TForm2.FormActivate(Sender: TObject);
begin
    uGUIHelper.AlwaysOnTop(True, Self.Handle);
end;

end.

Problemstellung: Beim mehrfachen Umschalten zwischen Form2 und anderen Anwendungen passiert es in aller Regel beim zweiten Umschaltvorgang, dass mindestens Form2, manchmal auch beide Formulare das OnTop-Attribut verlieren. Schaltet man zwischen Form1 und anderen Anwendungen um, passiert dies nicht.

Kann mir jemand erklären, warum das passiert? Ich schätze mal, die VCL macht da mehr, als ich in diesem Fall gebrauchen kann. Gibt es eine Möglichkeit, zu verhindern, dass die Formulare das Flag HWND_TOPMOST verlieren?

Grüße
Dalai

[Uwe Raabe]

Das Property

Delphi-Quellcode:

FormStyle = fsStayOnTop

macht eigentlich genau das und erhält diesen Status auch über ein Recreate des Handles hinaus aufrecht. Es sollte also ausreichen, im Objektinspektor bei beiden Forms das FormStyle-Property entsprechend zu setzen.

[Dalai]

Über FormStyle hatte ich auch schon nachgedacht, aber ich meine mich zu erinnern, dass es damit irgendeinen Ärger gab. Dennoch habe ich es gerade im Testprojekt ausprobiert und stelle fest, dass das ähnlich unzuverlässig funktioniert, egal ob das Property per Code oder Objektinspektor gesetzt wird. Manchmal bleiben beide Forms OnTop, manchmal gar keine, manchmal nur die zweite. Offenbar hängt das auch von der Windows-Version ab.

Im Application.OnDeactivate die Funktion AlwaysOnTop für beide Formulare zu rufen funktioniert etwas besser, aber auch das ist noch weit von verlässlich entfernt...

Da bin ich ja fast geneigt, den Inhalt der zweiten Form in ein eigenes simples Programm auszulagern. Andererseits bin ich der Meinung, dass das zum Funktionieren zu bringen sein muss.

Grüße
Dalai

[Dalai]

Vielleicht ist auch noch wichtig, wie das Umschalten zwischen Programmen erfolgt. Getestet hab ich per Maus und Alt+Tab. Letzteres funktioniert etwas besser, aber die eigentliche Anwendung wird eher per Maus benutzt werden, und beim Umschalten damit bleiben die Fenster fast nie im Vordergrund.

Grüße
Dalai

[himitsu]

Zitat:

Zitat von Uwe Raabe (Beitrag 1464073)

Das Property

Delphi-Quellcode:

FormStyle = fsStayOnTop

macht eigentlich genau das

"genau" ist trifft es nicht so ganz genau.

Beim Ändern wird die innere Form komplett neu generiert, anstatt nur die eine Option zu ändern.


In Windows 10, da ist und bleibt zwar bei beiden Forms die Option aktiv (siehe Caption), aber nur der Erste, welcher diese Option setzt, ist wirklich ganz oben.

Unabhängig vom ExStyle, gibt es ja auch nur eine Liste mit den Z-Positionen und da kann nur einer ganz oben sein,
aber vielleicht wurde das früher im Windows mal anders behandelt.

Eventuell gibt es auch noch einen Unterschied bei MultiMonitor-Systemen, wenn man jemanden glauben mag, falls man z.B. nach multiple HWND_TOPMOST sucht.
Hab hier jetzt nur einen Monitor aktiv (bzw. ist gespiegelt), aber könnte es nächste Woche mal ausprobieren.

Delphi-Quellcode:

uses Unit2;

implementation

procedure TForm1.Button1Click(Sender: TObject);
begin
  TForm2.Create(Self).Show;
end;

procedure TForm1.FormActivate(Sender: TObject);
begin
  //SetWindowLong(Handle, GWL_EXSTYLE, GetWindowLong(Handle, GWL_EXSTYLE) or WS_EX_TOPMOST);
  // theoretisch, aber ändern via SetWindowLong, siehe https://docs.microsoft.com/de-de/windows/win32/winmsg/extended-window-styles
  SetWindowPos(Handle, HWND_TOPMOST, 0, 0, 0, 0, SWP_NOACTIVATE or SWP_NOMOVE or SWP_NOSIZE);
end;

procedure TForm1.Timer1Timer(Sender: TObject);
begin
  Caption := BoolToStr(GetWindowLong(Handle, GWL_EXSTYLE) and WS_EX_TOPMOST <> 0, True);
end;

Delphi-Quellcode:

implementation

uses Unit1;

procedure TForm2.FormActivate(Sender: TObject);
begin
  SetWindowPos(Handle, {Form1.Handle}HWND_TOPMOST, 0, 0, 0, 0, SWP_NOACTIVATE or SWP_NOMOVE or SWP_NOSIZE);
end;

procedure TForm2.Timer1Timer(Sender: TObject);
begin
  Caption := BoolToStr(GetWindowLong(Handle, GWL_EXSTYLE) and WS_EX_TOPMOST <> 0, True);
end;

[Uwe Raabe]

Zitat:

Zitat von himitsu (Beitrag 1464078)

Beim Ändern wird die innere Form komplett neu generiert, anstatt nur die eine Option zu ändern.

Wo siehst du das denn?

Delphi-Quellcode:

  
  if FFormStyle <> Value then
  begin
    if ((Value = fsNormal) and (FFormStyle = fsStayOnTop)) or
       ((Value = fsStayOnTop) and (FFormStyle = fsNormal)) then
    begin
      FFormStyle := Value;
      if not (csDesigning in ComponentState) and HandleAllocated then
        SetWindowPos(Handle, HWND_STYLE[FFormStyle = fsStayOnTop], 0, 0, 0, 0,
          SWP_NOMOVE or SWP_NOSIZE or SWP_NOACTIVATE or SWP_NOOWNERZORDER);
    end
    else
      ...
    end;
  end;

[Uwe Raabe]

Wenn du sagst, die Fenster verlieren ihre TOPMOST Eigenschaft, wie äußert sich das? Sind plötzlich andere Forms deiner eigenen Anwendung über diesen (eigentlich TOPMOST) Forms oder sind nur Fenster einer anderen Anwendung darüber?

[himitsu]

Windows 10 und Delphi 10.3, gestern ausprobiert: Nur das erste TopMost-Fesnter ist immer oben,
aber in den Fenstereigenschaften steht es dennoch bei Beiden drin. (Dachte vielleicht Windows schaltet es beim anderen Fenster ab, bzw. ignoriert das Setzen im Zweiten)

Mir war so, als wenn da das Fenster immer so richtig schön kurz wegblinkte. Vielleicht wurde es ja inzwischen geändert.
Aber ich geb mit Stolz zu, dass ich seit vielen Jahren mich erfolgreich von TopMost verabschiedet hab, da es mehr Arbeit machte, als Freude zu bereiten.

[Uwe Raabe]

Grundsätzlich kann ja auch nur ein Fenster oben sein. TOPMOST heißt ja auch nur: das Fenster ist über den Fenstern, die nicht TOPMOST sind. Innerhalb von TOPMOST und NON-TOPMOST gibt es natürlich jeweils eine Reihenfolge.

Zitat:

Zitat von Dalai (Beitrag 1464072)

Es geht nur darum, dass beide Formulare über den Fenstern anderer Anwendungen liegen sollen.

Das wird nur gehen, wenn die anderen Anwendungen nicht dasselbe vorhaben und ihre eigenen Fenster auch als TOPMOST deklarieren.

[himitsu]

Es kommt drauf an, wie man es sieht/auslegt

TopMost = über ALLEM (da ginge nur Einer, so ala Highlander)
TopMost = über allem, was nicht TopMost ist

In einem Programm/Thread bekomm ich jetzt auch nur 1 Fenster, was immer oben bleibt,

aber starte ich das Programm doppelt (pro Programm/Thread nur ein Fenster), dann geht es auch mehrfach.
> das was den Fokus hat, jeweils ganz oben, aber alle immer über den normalen Fenstern

[Dalai]

Zitat:

Zitat von Uwe Raabe (Beitrag 1464128)

Das wird nur gehen, wenn die anderen Anwendungen nicht dasselbe vorhaben und ihre eigenen Fenster auch als TOPMOST deklarieren.

Wie ich bereits schrieb, ist mir das "Highlander-Prinzip" in diesem Fall bekannt. Ist das Problem denn mit meinem Testprogramm nachvollziehbar, wenn die beiden Formulare nebeneinander positioniert sind? Denn wie gesagt interessiert mich nicht, ob Formular 2 der Anwendung über Formular 1 derselben Anwendung liegt, denn das passiert nicht und das teste ich auch nicht. Wichtig für mich ist ausschließlich, dass beide Formulare meiner Anwendung (die immer nebeneinander liegen) über den Fenstern anderer Anwendungen (ohne TOPMOST) liegen. Es geht da auch um nichts Großes, das eine Formular ist 65x31 Pixel, das andere ~170x20 Pixel.

Zwischenzeitlich hab ich das zweite Form in eine eigene Anwendung überführt (weil ich für ein anderes Projekt fix eine Lösung brauchte), aber ich bin dennoch an einer Lösung innerhalb einer Anwendung interessiert.

Grüße
Dalai

[himitsu]

siehe #5 ?

[edit]
Hab's aber grad nochmal probiert ... ich glaub Delphi bzw. die VCL ist Schuld.

Vorhin falsch geguckt, denn so ist es aktuell in Windows 10 + Delphi 10.3:
* das zweite Fenster ist immer über dem Ersten
* wären Beide gleich (StayOnTop oder nicht), müsste jeweils das Aktive oben sein
* vermutlich irgendwas in Richtung PopupMode, aber das steht (standardmäßig) eigentlich auf pmNone :grueble:

[edit2]

Delphi-Quellcode:

procedure TCustomForm.CreateParams(var Params: TCreateParams);
...
        case LPopupMode of
          pmNone:
            begin
              if Application.MainFormOnTaskBar then
              begin
                // FCreatingMainForm is True when the MainForm is
                // being created, Self = Application.MainForm during CM_RECREATEWND.
                if FCreatingMainForm or (Self = Application.MainForm) then
                  WndParent := 0
                else
                  if Assigned(Application.MainForm) and Application.MainForm.HandleAllocated then
                  begin
                    WndParent := Application.MainFormHandle;
                    if WndParent = Application.MainForm.Handle then
                    begin
                      if Application.MainForm.PopupChildren.IndexOf(Self) < 0 then
                        Application.MainForm.PopupChildren.Add(Self); <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
                      FreeNotification(Application.MainForm);
                    end;
                  end
                  else
                    WndParent := Application.Handle;
              end
              else
              begin
                WndParent := Application.Handle;
                SetWindowLong(WndParent, GWL_EXSTYLE, GetWindowLong(WndParent, GWL_EXSTYLE) and not WS_EX_TOOLWINDOW);
              end;
            end;
          pmAuto:
            begin
              if FCreatingMainForm then
                WndParent := 0 // A main form can't be parented to another form
              else

Keine Ahnung wer auf diese bescheuerte Idee gekommen ist auch bei NONE etwas zu machen.

Lösung:
Und statt OnActivate, ist sowieso CreateWnd besser. (auch wenn Beides geht)

Delphi-Quellcode:

type
  TForm3 = class(TForm)
    procedure FormCreate(Sender: TObject);
  protected
    procedure CreateWnd; override;
  end;

var
  Form3: TForm3;

implementation

{$R *.dfm}

procedure TForm3.CreateWnd;
begin
  inherited;
  SetWindowPos(Handle, HWND_TOPMOST, 0, 0, 0, 0, SWP_NOACTIVATE or SWP_NOMOVE or SWP_NOSIZE);
end;

procedure TForm3.FormCreate(Sender: TObject);
begin
  PopupMode := TPopupMode(9);
end;

[Edit3]
Oder Application.OnGetMainFormHandle benutzen und dort

Delphi-Quellcode:

HWND(-1)

zurückgeben.

[Uwe Raabe]

Zitat:

Zitat von himitsu (Beitrag 1464144)

Es kommt drauf an, wie man es sieht/auslegt

TopMost = über ALLEM (da ginge nur Einer, so ala Highlander)
TopMost = über allem, was nicht TopMost ist

Wohl eher nicht wie man das sieht/auslegt, sondern wie MS das implementiert hat.

Zitat:

HWND_TOPMOST: Places the window above all non-topmost windows. The window maintains its topmost position even when it is deactivated.

Um ein TOPMOST Fenster über alle anderen (auch TOPMOST) zu legen, kann man ein SetWindowPos mit HWND_TOP senden. Das platziert ein Fenster so weit vorn wie möglich - bei einem TOPMOST Fenster halt ganz nach vorn. Das hält aber auch nur solange bis ein anderes TOPMOST Fenster (z.B. einer anderen Anwendung) sich davor legt.

Man kann auch noch mit PopupParent experimentieren. Ist das nicht gesetzt, wird implizit das MainForm verwendet. Das hat aber nur Auswirkungen auf die eigenen Anwendung.

[himitsu]

Ja, "normal" war es so, dass bei mehreren TopMost beide vor allen anderen Nicht-TopMost blieb
und bei mehreren TopMost dort jeweils das ganz obe, was man zuletzt angeklickt/fokusiert hat.

Wenn man den "neuen" Mist im TCustomForm.CreateParams "repariert", dann ist es auch wieder so.
Wenn die Entwickler das Verhalten ändern wollen, dann dürfen sie gern pmAuto als Default festlegen, aber niemals pmNone kaputt machen.

[Dalai]

OK, nachdem ich wieder etwas Luft habe, hab mir das jetzt im Detail angeschaut. Leider musste ich an mehreren Stellen drehen, um einige Nebeneffekte zu unterbinden.

Zitat:

Zitat von himitsu (Beitrag 1464149)

Lösung:
Und statt OnActivate, ist sowieso CreateWnd besser. (auch wenn Beides geht)

Wenn man die Fenster immer OnTop setzen will, dann mag das besser sein. Wenn man dem Nutzer die Wahl lassen will, ist das ungeeignet, denn CreateWnd wird vor dem FormCreate gefeuert, so dass man gar keine Möglichtkeit hat, etwas zu setzen. CreateWnd wird zwar offenbar vor dem OnShow nochmals gerufen, aber ich mag Eindeutigkeit (und werde daher beim OnActivate bleiben).

Zitat:

Delphi-Quellcode:

procedure TForm3.FormCreate(Sender: TObject);
begin
  PopupMode := TPopupMode(9);
end;

Wenn ich das richtig verstehe, zwingt das die Routine im TCustomForm.CreateParams dazu, keinen speziellen Code zur Bearbeitung des Window Parent auszuführen. Was bedeutet das genau?

Dummerweise hat das zur Folge, dass die Form2 im Beispiel einen eigenen Button in der Taskleiste bekommt. Das kann ich gar nicht brauchen.

Nach einigen Versuchen hab ich eine Lösung gefunden, aber ich frag lieber nach, ob das eine saubere Variante ist.

Unit1:

Delphi-Quellcode:

procedure TForm1.FormCreate(Sender: TObject);
begin
    if bShowForm2 then begin
        Fform2:= TForm2.Create(nil);
        Fform2.BorderStyle:= bsNone;
        Fform2.PopupParent:= Self;
    end;
end;

Restliche Funktionen der Unit wie gehabt.

Unit2:

Delphi-Quellcode:

procedure TForm2.FormCreate(Sender: TObject);
begin
    Self.PopupMode:= TPopupMode(99);
end;

---

Eine andere Variante kam mir gerade aufgrund eines anderen Projektes in den Sinn.
Unit1: wie im OP.
[EDIT]Der Aufruf von TForm2.Create muss natürlich etwas anders aussehen, aber der Rest bleibt gleich.

Delphi-Quellcode:

procedure TForm1.FormCreate(Sender: TObject);
begin
    if bShowForm2 then begin
        Fform2:= TForm2.Create(nil, Self.Handle);
        Fform2.BorderStyle:= bsNone;
    end;
end;

[/EDIT]

Unit2:

Delphi-Quellcode:

type
  TForm2 = class(TForm)
    procedure FormActivate(Sender: TObject);
  private
    FWndParent: HWND;
  protected
    procedure CreateParams(var Params: TCreateParams); override;
  public
    constructor Create(AOwner: TComponent; AWndParent: HWND); reintroduce; overload;
  end;
  
implementation
  
constructor TForm2.Create(AOwner: TComponent; AWndParent: HWND);
begin
    Self.FWndParent:= AWndParent;
    inherited Create(AOwner);
end;

procedure TForm2.CreateParams(var Params: TCreateParams);
begin
    inherited;
    Params.WndParent:= Self.FWndParent;
end;

procedure TForm2.FormActivate(Sender: TObject);
begin
    uGUIHelper.AlwaysOnTop(True, Self.Handle);
end;

Vorteil: Kein Button erscheint für Form2 in der Taskleiste und ein Setzen des PopupMode entfällt, was den Nebeneffekt hat, dass es sogar im Delphi 5 funktioniert ;).

Meinungen zu den beiden Lösungsvarianten? Ist eine besser geeignet als die andere? Und wenn ja, warum?

Grüße
Dalai