Bei Sortierung Komma zeichen ignorieren

[DelphiDustin]

Hi ich bin ziemlich neu bei Delphi und habe die Aufgabe bekommen Zahlen zu sortieren diese soll der Anwender mit einem Komma getrennt in ein edit feld schreiben z.B 5, 32, 2, 86 und später in einer Listbox ausgegeben werden. Wie bekomme ich es hin dass das Programm die einzelnen Zahlen erkennt und die Kommas so zu sagen ignoriert?

[mkinzler]

Nur indem man seine eigene Sortierungsfunktion (bzw. Comparer) verwendet. Was soll den sortiert werden? (StringListe?)

[Der schöne Günther]

Kannst du vielleicht einmal darlegen was du schon hast? Bekommst du es hin eine einzelne Zahl in einem Edit-Feld überhaupt zu erkennen? Also z.B. zwei Edit-Felder, in beide muss eine Zahl eingetragen werden und dein Programm sagt welche Zahl größer ist? Bekommst du das hin? Hast du überhaupt Erfahrung in Software-Entwicklung oder fängst du bei absolut Null an?

[Schokohase]

Da du die Delphi-Version nicht angegeben hast, gehe ich mal von der neuesten (Rio 10.3.2) aus.

Delphi-Quellcode:

uses
  System.SysUtils,
  System.Generics.Collections;

procedure TForm1.SortButtonClick(Sender: TObject);
var
  input: string;
  splitted: TArray<string>;
  strItem: string;
  numbers: TArray<Integer>;
  numItem: Integer;
begin
  // Auslesen aus dem Edit
  input := InputEdit.Text;
  // Trennen am Komma
  splitted := input.Split([',']);
  // Umwandeln in (Ganz-)Zahlen
  numbers := [];
  for strItem in splitted do
  begin
    numbers := numbers + [Integer.Parse(strItem)];
  end;
  // Sortieren
  TArray.Sort<Integer>(numbers);
  // Ausgabe
  SortedNumberListBox.Items.BeginUpdate();
  try
    SortedNumberListBox.Items.Clear();
    for numItem in numbers do
      SortedNumberListBox.Items.Add(numItem.ToString());
  finally
    SortedNumberListBox.Items.EndUpdate();
  end;
end;

[DelphiDustin]

@Der schöne Günther "Bekommst du es hin eine einzelne Zahl in einem Edit-Feld überhaupt zu erkennen?" Nein das bekomme ich nicht hin. "Also z.B. zwei Edit-Felder, in beide muss eine Zahl eingetragen werden und dein Programm sagt welche Zahl größer ist?" Das würde ich vlt hinbekommen aber es soll hat nur in einem edit feld stehen."Hast du überhaupt Erfahrung in Software-Entwicklung oder fängst du bei absolut Null an? " Ich kenne mich mit Visual Basic ganz ok aus und arbeite erst seit gestern mit Delphi also kenne ich da wirklich nur absolute Grundlagen.

[Klaus01]

..sollte es nicht auch so funktionieren:

Delphi-Quellcode:

sl := TStringList.create;
sl.delimiter := ',';
sl.delimtedText := edit1.Text;
sl.sorted := true;

ungetestet

Grüße
Klaus

[Der schöne Günther]

Zitat:

Zitat von DelphiDustin (Beitrag 1445488)

Das würde ich vlt hinbekommen aber es soll hat nur in einem edit feld stehen.

Wäre doch trotzdem schon einmal besser als nichts, oder? Weil da hättest du dich zwangsläufig schon einmal damit befassen müssen wie man den Inhalt des Edit-Felds (String) in eine Zahl umwandelt. Also das was dir der nette Schokohase schon fertig in seinem Quelltext-Schnippsel zeigt ;-)

[Luckie]

Ich würde die Kommata mit dem folgendem Leerzeichen durch einen Zeilenumnruch #13#10 ersetzen, das Ergebnis in eine Stringlist packen und diese mit Bubblesort numerisch sortieren.

[Uwe Raabe]

Mit einem halbwegs aktuellen Delphi kann man auch recht einfach Zahlen in einer Stringlist sortieren:

Delphi-Quellcode:

uses
  System.SysUtils,
  System.Classes;

function NumberCompareStrings(List: TStringList; Index1, Index2: Integer): Integer;
begin
  Result := string.Compare(List[Index1], List[Index2], [coDigitAsNumbers]);
end;

procedure Main;
var
  lst: TStringList;
  I: Integer;
begin
  lst := TStringList.Create;
  try
    lst.CommaText := '5, 32, 2, 86';
    lst.CustomSort(NumberCompareStrings);
    Writeln(lst.CommaText); // => 2,5,32,86
  finally
    lst.Free;
  end;
end;

[Luckie]

Er nun wieder. :mrgreen:

Aber wie und wo bekommt deine Sortierfunktion die Parameter übergeben?

[Schokohase]

Zitat:

Zitat von Luckie (Beitrag 1445549)

Er nun wieder. :mrgreen:

Aber wie und wo bekommt deine Sortierfunktion die Parameter übergeben?

Das verrät dir ein Blick in die Dokumetation
System.Classes.TStringList.CustomSort und das bringt einen dann zu
System.Classes.TStringListSortCompare

[mkinzler]

Zitat:

Aber wie und wo bekommt deine Sortierfunktion die Parameter übergeben?

Ist ja eigentlich eine Vergleichsfunktion, welche von der Listkomponentenklasse während des Sortiervorganges mehrfach ( beim Vergleich 2er Elemente der Liste) aufgerufen wird.

[Luckie]

Danke. Aber beide deiner Links werden bei mir nicht gefunden: 404.

[haentschman]

Tipp mal TStringList.CustomSort in die Delphi Referenz ein...8-)

[Luckie]

Habe ich dann auch gemacht.

[Schokohase]

Zitat:

Zitat von Luckie (Beitrag 1445553)

Danke. Aber beide deiner Links werden bei mir nicht gefunden: 404.

Links korrigiert

[DelphiDustin]

Hallo Ich bins nochmal,

also ich habe es jetzt hinbekommen dass 4 Zahlen aus einem edit feld in einer listbox angegeben werden aber ich hab den soritierungs fehler das immer nur nach der ersten zahl sortiert wird heißt

24
5
67
9
z.B es soll aber natürlich

5
9
24
67

dort stehen hat jemand eine gute methode für mich das leicht zu lösen?

[Uwe Raabe]

Dann zeig doch erst mal wie du das bisher machst.

[Luckie]

In wie vielen Themen diskutieren wir jetzt das selbe Problem? :roll:

Hier geht's weiter: https://www.delphipraxis.net/201930-...ml#post1445694

Geschlossen.

[DP-Maintenance]

Dieses Thema wurde am "11. Sep 2019, 12:20 Uhr" von "Luckie" aus dem Forum "Neuen Beitrag zur Code-Library hinzufügen" in das Forum "Object-Pascal / Delphi-Language" verschoben.