strftime für Delphi ?

[myicq]

Hallo alle schlaue,

gibt es irgendwo eine strftime() Library für Delphi ?

Also, eine Funktion ähnlich in php, wo ich gleiches Formattierungsbild eingeben kann, ergebniss String.

Code:

 mystring := strftime('Heute ist %Y %m %d');

habe soweit nichts gefunden

[Schokohase]

System.SysUtils.FormatDateTime

Delphi-Quellcode:

str := System.SysUtils.FormatDateTime('"Heute ist "yyyy mm dd',System.SysUtils.Now());

[myicq]

Danke für das Antwort. Klar kenne ich die Formatcodes von Delphi.

In dieser Fall brauche ich aber die formatcodes von strftime() zu behandeln.

Ich kann das wenn notwendig selbst umsetzen. Aber hätte jemand das schon gemacht..

[myicq]

Ich habe beim neusuche herausgefunden das es strftime() gibt in MSVCRT.DLL. Das würde mir reichen.

Aber : ich mache irgendwas falsch ?

Gefunden habe ich das hier: http://rvelthuis.de/downloads.html

Mein Code + Unit im Anhang. Ich bekomme kein Fehler beim call an _strftime(), aber auch kein ergebniss.

Was mache ich falsch ?

[Luckie]

Zitat:

Zitat von myicq (Beitrag 1423134)

In dieser Fall brauche ich aber die formatcodes von strftime() zu behandeln.

Wie meinen?

[scrat1979]

Zitat:

Zitat von myicq (Beitrag 1423134)

Danke für das Antwort. Klar kenne ich die Formatcodes von Delphi.

In dieser Fall brauche ich aber die formatcodes von strftime() zu behandeln.

Ich kann das wenn notwendig selbst umsetzen. Aber hätte jemand das schon gemacht..

Wie wäre es denn, vor dem FormatDateTime durch StringReplace die Formatcodes umzuwandeln? So viele sind es ja nicht...

[freimatz]

Zitat:

Zitat von myicq (Beitrag 1423157)

Mein Code + Unit im Anhang. Ich bekomme kein Fehler beim call an _strftime(), aber auch kein ergebniss.
Was mache ich falsch ?

Allzuviel Ahnung habe ich da nicht davon, aber weil sonst keiner darauf geantwortet hat nur ein Verdacht: kann es sein, dass Du AnsiString statt String verwenden musst?

[Schokohase]

Zitat:

Zitat von scrat1979 (Beitrag 1423164)

Wie wäre es denn, vor dem FormatDateTime durch StringReplace die Formatcodes umzuwandeln? So viele sind es ja nicht...

Nicht so gut, wenn du dir diesen gültigen format-String anschaust

Code:

Aus %%Y wird %Y

rauskommen müsste durch

Delphi-Quellcode:

strftime

Code:

Aus %Y wird 2019

Der passende Format-String für Delphi wäre

Code:

"Aus %Y wird "yyyy

Meine Einschätzung: Es ist einfacher den Formatstring so wie er ist zu parsen und direkt die Werte zu ersetzen als diesen erst umzuformen (da muss man auch parsen) und dann durch

Delphi-Quellcode:

FormatDateTime

zu jagen.

[scrat1979]

Zitat:

Zitat von Schokohase (Beitrag 1423166)

Zitat:

Zitat von scrat1979 (Beitrag 1423164)

Wie wäre es denn, vor dem FormatDateTime durch StringReplace die Formatcodes umzuwandeln? So viele sind es ja nicht...

Nicht so gut, wenn du dir diesen gültigen format-String anschaust

Code:

Aus %%Y wird %Y

rauskommen müsste durch

Delphi-Quellcode:

strftime

Code:

Aus %Y wird 2019

Der passende Format-String für Delphi wäre

Code:

"Aus %Y wird "yyyy

Meine Einschätzung: Es ist einfacher den Formatstring so wie er ist zu parsen und direkt die Werte zu ersetzen als diesen erst umzuformen (da muss man auch parsen) und dann durch

Delphi-Quellcode:

FormatDateTime

zu jagen.

Vielleicht verstehen ich das ganze auch gerade falsch. Aber wenn ich beispielsweise %Y mit StringReplace in YYYY umwandle dann kommt doch bei FormatDateTime 2019 als Beispiel raus.

EDIT: Klar, direkt parsen ist natürlich besser :)

[Schokohase]

Wenn du bei

Code:

Aus %%Y wird %Y

alle

Delphi-Quellcode:

%Y

durch

Delphi-Quellcode:

YYYY

ersetzt, dann erhälst du

Code:

Aus %YYYY wird YYYY

Du brauchst aber für die korrekte Formatierung

Code:

"Aus %Y wird "YYYY

[scrat1979]

Zitat:

Zitat von Schokohase (Beitrag 1423171)

Wenn du bei

Code:

Aus %%Y wird %Y

alle

Delphi-Quellcode:

%Y

durch

Delphi-Quellcode:

YYYY

ersetzt, dann erhälst du

Code:

Aus %YYYY wird YYYY

Du brauchst aber für die korrekte Formatierung

Code:

"Aus %Y wird "YYYY

Ah, alles klar. Klingt irgendwie logisch :)

[Schokohase]

Es ist auch relativ simpel so einen Parser zu basteln.

Hier ein Anfang

Delphi-Quellcode:

function strftime(const Format: string; Value: TDateTime; const FormatSettings: TFormatSettings): string; overload;
var
  controlChar: Boolean;
  current: Char;
begin
  Result := string.Empty;
  controlChar := false;
  for current in Format do
  begin
    if controlChar then
    begin
      case current of
        // ---
        // Tag
        // ---
        'd':
          // Tag des Monats als zweistellige Zahl (ggf. mit vorangestellten Nullen)
          // 01 bis 31
          Result := Result + FormatDateTime('dd', Value, FormatSettings);
        // -----
        // Monat
        // -----
        'm':
          // Zweistellige numerische Darstellung des Monats
          // 01 (für Januar) bis 12 (für Dezember)
          Result := Result + FormatDateTime('mm', Value, FormatSettings);
        // ----
        // Jahr
        // ----
        'Y':
          // Vierstellige numerische Darstellung des Jahres
          // Beispiel: 2038
          Result := Result + FormatDateTime('yyyy', Value, FormatSettings);
        // -------------
        // Verschiedenes
        // -------------
        'n':
          // Ein Zeilenvorschubzeichen ("\n")
          Result := Result + sLineBreak;
        't':
          // Ein Tabulatorzeichen ("\t")
          Result := Result + #9;
        '%':
          // Ein Tabulatorzeichen ("\t")
          Result := Result + '%';
      else
        Result := Result + '%' + current;
      end;
      controlChar := False;
    end
    else
    begin
      if current <> '%' then
      begin
        Result := Result + current;
      end
      else
        controlChar := true;
    end;
  end;
  if controlChar then
    Result := Result + '%';
end;

function strftime(const Format: string; Value: TDateTime): string; overload;
begin
  Result := strftime(Format, Value, System.SysUtils.FormatSettings);
end;

function strftime(const Format: string): string; overload;
begin
  Result := strftime(Format, System.SysUtils.Now());
end;

Man braucht jetzt nur nach den Case-Teil um die anderen Zeichen ergänzen und fertig ist es.