Noten als enum auslegen

[EWeiss]

Ich erstelle ein Enum um die Noten zu transponieren.

Delphi-Quellcode:

 TTranspose = (C = 1, C# = 2, D = 3, D# = 4, E = 5, F = 6, F# = 7, G = 8, G# = 9, A = 10, A# = 11, B = 12);

Jetzt meldet der Compiler C wäre redifiniert.
Wie wäre es richtig?

Ich brauche die Bezeichnungen als String im Enum.
Oder kann man dies später zu einem Array assigned?

gruss

[Neutral General]

Du kannst "#" nicht in Bezeichnern verwenden.

[EWeiss]

Zitat:

Zitat von Neutral General (Beitrag 1399402)

Du kannst "#" nicht in Bezeichnern verwenden.

Ja das habe ich mir gedacht deshalb der Fehler.
Nur wie könnte man es anders besser machen?

Ich brauche die Halbtöne.

gruss

[Zacherl]

Naja, einfach anders benennen halt :-D

Delphi-Quellcode:

C_HALF/C_MAJOR

oder so.

[EWeiss]

Zitat:

Zitat von Zacherl (Beitrag 1399406)

Naja, einfach anders benennen halt :-D

Delphi-Quellcode:

C_HALF/C_MAJOR

oder so.

Delphi-Quellcode:

function TransposeChord(sChord: string; Pitch: Integer): string;
var
  sResult: string;
  sTranspose: Array[1..12] of TTranspose;
  K, MaxK, Found: Integer;
begin

  sResult := sChord;
  MaxK := High(sTranspose);

  for K := 1 to MaxK do
  begin
    if sTranspose[K] = sChord then
    begin
      Found := (K + Pitch) mod MaxK;
      if Found < 1 then
        inc(Found, MaxK);

      sResult := sTranspose[Found];
      break;
    end;
    Result := sResult;
  end;
end;

Nun einfach?
Umbenennen ist nicht möglich wie gesagt ich brauche den String 'C#'

gruss

[JasonDX]

Eine separate Methode zum Konvertieren zwischen Enum und String wäre dann sinnvoll.

[EWeiss]

Zitat:

Zitat von JasonDX (Beitrag 1399409)

Eine separate Methode zum Konvertieren zwischen Enum und String wäre dann sinnvoll.

Dann mache ich es so..

Delphi-Quellcode:

const
cTranspose : Array[TTranspose ] of String = ('C, 'C#, 'D, 'D#');

und benenne das enum um.
Danke.

gruss

[EWeiss]

Sorry bin wieder blöd heute.

Delphi-Quellcode:

type  
  TTranspose = (C, C_, D, D_, E, F, F_, G, G_, A, A_, B);

const
  cTranspose : Array[TTranspose] of String = ('C', 'C#', 'D', 'D#', 'E', 'F', 'F#',
    'G', 'G#', 'A', 'A#', 'B');

Delphi-Quellcode:

function TransposeChord(sChord: string; Pitch: Integer): string;
var
  sResult: string;
  sTranspose: Array[0..11] of TTranspose; // scheint ein Problem mit dieser Definition zu sein. aber brauche ein Array wenn auch vielleicht nicht dieses
  K, MaxK, Found: Integer;
begin

  sResult := sChord;
  MaxK := High(sTranspose);

  for K := 0 to MaxK do
  begin
    if cTranspose[sTranspose[K]] = sChord then
    begin
      Found := (K + Pitch) mod MaxK;
      if Found < 1 then
        inc(Found, MaxK);

      sResult := cTranspose[sTranspose[Found]];
      break;
    end;
    Result := sResult;
  end;
end;

kann mir bitte jemand auf die Sprünge helfen ?

gruss

[himitsu]

# gibt es so ähnlich auch als andere Unicodezeichen ... wenn dieses andere Zeichen vom Compiler als "gültiges" alphanumerisches Zeichen anerkannt ist, dann könnte man auch das nehmen.
Aber ohne Codevervollständigung oder Copy&Paste sind solche Namen dann schwer zu schreiben, so als würdest du ohne IME versuchen chinesische Typenbezeichner zu verwenden.

[EWeiss]

Zitat:

Zitat von himitsu (Beitrag 1399415)

# gibt es so ähnlich auch als andere Unicodezeichen ... wenn dieses andere Zeichen vom Compiler als "gültiges" alphanumerisches Zeichen anerkannt ist, dann könnte man auch das nehmen.
Aber ohne Codevervollständigung oder Copy&Paste sind solche Namen dann schwer zu schreiben, so als würdest du ohne IME versuchen chinesische Typenbezeichner zu verwenden.

Bekomme hier außerhalb des gültigen Bereich.

Delphi-Quellcode:

if cTranspose[sTranspose[K]] = sChord then

Ich erzeuge hier 12 x mal TTranspose

Delphi-Quellcode:

sTranspose: Array[0..11] of TTranspose;

Obwohl ich nur den Wert innerhalb eines einmalig erstellen TTranspose benötige.
Das scheint mein Fehler zu sein. (Array ist eigentlich überflüssig) Hmmm...
Aber ohne kann ich K nicht auswerten.

Heute ist ein schlechter Tag.. Hehehehehehe

EDIT:
Ok hat sich erledigt.

Delphi-Quellcode:

function TransposeChord(sChord: string; Pitch: Integer): string;
var
  sResult: string;
  K, MaxK, Found: Integer;
begin

  sResult := sChord;
  MaxK := 12;

  for K := 0 to (MaxK - 1) do
  begin
    if cTranspose[TTranspose(K)] = sChord then
    begin
      Found := (K + Pitch) mod MaxK;
      if Found < 1 then
        inc(Found, MaxK);

      sResult := cTranspose[TTranspose(Found)];
      break;
    end;
    Result := sResult;
  end;
end;

gruss

[Luckie]

Nimm doch "Cis" usw. Allerdings müsstest du dann beim "H" (dt.) aufpassen.

C_Major (C-Dur) wäre übrigens falsch. Es geht um einzelne Noten, nicht um Akkorde.

[EWeiss]

Zitat:

Zitat von Luckie (Beitrag 1399419)

Nimm doch "Cis" usw. Allerdings müsstest du dann beim "H" (dt.) aufpassen.

C_Major (C-Dur) wäre übrigens falsch. Es geht um einzelne Noten, nicht um Akkorde.

Ja könnte man machen aber ich denke so ist es auch verständlich.

Delphi-Quellcode:

TTranspose = (C, C_, D, D_, E, F, F_, G, G_, A, A_, B);

Bin ja noch am Anfang.

gruss

[Delphi.Narium]

Delphi-Quellcode:

TTranspose = (C, Cis, D, Dis, E, F, Fis, G, Gis, A, Ais, B);

ist auch für 'nen Musiker ohne Programmierkenntnisse verständlich. Der _ macht keinerlei Aussage darüber, was gemeint sein könnte. Um es zu verstehen, muss man bereits wissen, was gemeint ist. Bei der von Luckie vorgeschlagenen alternativen Nutzung der regulären Tonbezeichnungen, ist das nicht erforderlich.

[EWeiss]

Zitat:

Zitat von Delphi.Narium (Beitrag 1399421)

Delphi-Quellcode:

TTranspose = (C, Cis, D, Dis, E, F, Fis, G, Gis, A, Ais, B);

ist auch für 'nen Musiker ohne Programmierkenntnisse verständlich. Der _ macht keinerlei Aussage darüber, was gemeint sein könnte. Um es zu verstehen, muss man bereits wissen, was gemeint ist. Bei der von Luckie vorgeschlagenen alternativen Nutzung der regulären Tonbezeichnungen, ist das nicht erforderlich.

Für mich bedeutet der unterstrich die hälfte eines Notenwertes.
Wer das als Musiker nicht erkennt dem kann nicht geholfen werden.

Und ja ich spiele selbst seit 50 Jahren.
Blockflöte, Mundharmonika, Gitarre, E-Gitarre, Klavier, Akkordeon, jegliche andere Art von Tasten Instrumenten. usw..

Zumal die richtige Notation erst im String ersichtlich ist. (Also was der User sieht.)
Den Anwender interessiert es nicht wie ich dafür die Deklarationen im Code ausgelegt habe.

gruss

[Delphi.Narium]

Was die Vielfalt der Instrumente angeht, kann ich nicht mithalten, in Bezug auf Dauer aber schon, man wird halt alt ;-)

Delphi-Quellcode:

TTranspose = (C, H, B, A, A_, G, G_, F, E, E_, D, D_);

Delphi-Quellcode:

TTranspose = (C, D_, D, E_, E, F, G_, G, A_, A, B_, B);

Auch hier ist der _ ein halber Notenschritt. Welche Hälfte ergibt sich aber nur aus dem Zusammenhang.

Mir persönlich ist es halt lieber, wenn ich bei sowas direkt im Quelltext lesen kann, was gemeint ist und dabei Bezeichnungen genutzt werden, die auch außerhalb des Quelltextes gebräuchlich sind. Ist halt Geschmacksache.

So gefällt es mir eben besser, als mit Unterstrichen:

Delphi-Quellcode:

TTranspose = (C, H, B, A, As, G, Ges, F, E, Es, D, Des);

Delphi-Quellcode:

TTranspose = (C, Des, D, Es, E, F, Ges, G, As, A, B, H);

[Luckie]

Zitat:

Zitat von EWeiss (Beitrag 1399423)

Für mich bedeutet der unterstrich die hälfte eines Notenwertes.
Wer das als Musiker nicht erkennt dem kann nicht geholfen werden.

Also mir als Musiker erschließt es sich nicht. Aber da es ja sowieso nur eine interne Darstellung ist, spielt es für den Anwender keine Rolle.

[EWeiss]

Zitat:

Welche Hälfte ergibt sich aber nur aus dem Zusammenhang.

Nun für Gitarre gibt es da eine ganz einfache Lösung.

Eine Alte Dame Geht Honig Essen!
Zumindest hast du jetzt schon mal die Noten der einzelnen Gitarren Seiten.

Bei dem anderen ist halt Auslegungssache wie gesagt der User(Anwender sieht es nicht)

gruss

[Amateurprofi]

Zitat:

Zitat von EWeiss (Beitrag 1399416)

Zitat:

Zitat von himitsu (Beitrag 1399415)

# gibt es so ähnlich auch als andere Unicodezeichen ... wenn dieses andere Zeichen vom Compiler als "gültiges" alphanumerisches Zeichen anerkannt ist, dann könnte man auch das nehmen.
Aber ohne Codevervollständigung oder Copy&Paste sind solche Namen dann schwer zu schreiben, so als würdest du ohne IME versuchen chinesische Typenbezeichner zu verwenden.

Bekomme hier außerhalb des gültigen Bereich.

Delphi-Quellcode:

if cTranspose[sTranspose[K]] = sChord then

Ich erzeuge hier 12 x mal TTranspose

Delphi-Quellcode:

sTranspose: Array[0..11] of TTranspose;

Obwohl ich nur den Wert innerhalb eines einmalig erstellen TTranspose benötige.
Das scheint mein Fehler zu sein. (Array ist eigentlich überflüssig) Hmmm...
Aber ohne kann ich K nicht auswerten.

Heute ist ein schlechter Tag.. Hehehehehehe

EDIT:
Ok hat sich erledigt.

Delphi-Quellcode:

function TransposeChord(sChord: string; Pitch: Integer): string;
var
  sResult: string;
  K, MaxK, Found: Integer;
begin

  sResult := sChord;
  MaxK := 12;

  for K := 0 to (MaxK - 1) do
  begin
    if cTranspose[TTranspose(K)] = sChord then
    begin
      Found := (K + Pitch) mod MaxK;
      if Found < 1 then
        inc(Found, MaxK);

      sResult := cTranspose[TTranspose(Found)];
      break;
    end;
    Result := sResult;
  end;
end;

gruss

Mir scheint deine Funktion enthält Fehler.
1)

Delphi-Quellcode:

if Found < 1 then

sollte wohl besser

Delphi-Quellcode:

if Found < 0 then

heißen.
Andernfalls würde z.B. TransposeChord('C',0') in einem Fehler resultieren.
Warum?!
K wäre = 0, Found wäre zunächst = 0 und würde um 12 auf 12 erhöht und wäre dann außerhalb des gültigen Bereiches von TTranspose.
2)
Das

Delphi-Quellcode:

Result := sResult;

gehört 2 Zeilen tiefer (hinter die for-Schleife.

Und warum so kompliziert?

Delphi-Quellcode:

FUNCTION xTransposeChord(sChord:String; Pitch:Integer):String;
const ChordText='C C#D D#E F F#G G#A A#B';
var I:Integer;
begin
   I:=Pos(sChord,ChordText);
   if I=0 then Exit(sChord);
   I:=(I div 2 + Pitch mod 12 + 12) mod 12;
   Result:=cTranspose[TTranspose(I)];
end;

[EWeiss]

Zitat:

Mir scheint deine Funktion enthält Fehler.

Nein das scheint nicht nur so das ist es .. Danke für die Info.

Mein Array ging vorher von 1..XX aber nach der Änderung des Enums habe ich das nicht mehr korrigiert.

Danke..

Bei dem Anderen Vorschlag möchte ich gerne bei meiner Lösung bleiben da ich weis was ich hier geschrieben habe.
Bei deiner Lösung auch wenn sie richtig sein mag muss ich erst wieder raten.
Und ist von der Berechnung her zu kompliziert und unübersichtlich.

Viele Wege führen zum Ziel.

Zitat:

Das Result := sResult; gehört 2 Zeilen tiefer (hinter die for-Schleife.

Na ja eine Zeile tiefer.

Wird aber in jedem fall aufgerufen auch wenn ich es so belassen würde. ;)
Der Wert wird also in jedem fall richtig übergeben.

gruss

[Amateurprofi]

Zitat:

Zitat von EWeiss (Beitrag 1399441)

Zitat:

Mir scheint deine Funktion enthält Fehler.

Nein das scheint nicht nur so das ist es .. Danke für die Info.

Mein Array ging vorher von 1..XX aber nach der Änderung des Enums habe ich das nicht mehr korrigiert.

Danke..

Bei dem Anderen Vorschlag möchte ich gerne bei meiner Lösung bleiben da ich weis was ich hier geschrieben habe.
Bei deiner Lösung auch wenn sie richtig sein mag muss ich erst wieder raten.
Und ist von der Berechnung her zu kompliziert und unübersichtlich.

Viele Wege führen zum Ziel.

Zitat:

Das Result := sResult; gehört 2 Zeilen tiefer (hinter die for-Schleife.

Na ja eine Zeile tiefer.

Wird aber in jedem fall aufgerufen auch wenn ich es so belassen würde. ;)
Der Wert wird also in jedem fall richtig übergeben.

gruss

Zitat:

Wird aber in jedem fall aufgerufen auch wenn ich es so belassen würde. ;)
Der Wert wird also in jedem fall richtig übergeben.

Nein, das ist nicht so.
Es wird fast immer der falsche Wert übergeben und nur in Ausnahmefällen der richtige.

Wenn sChord = "C" ist, wird überhaupt nichts in Result gestellt.
Wenn sChord <> "C" ist, wird nur dann der korrekte Wert in Result gestellt, wenn Pitch = 0 oder 12 oder ein Vielfaches von 12 ist.

Damit man das innerhalb dieses Beitrags nachvollziehen kann, habe ich die fragliche Funktion hier rein gestellt.

Delphi-Quellcode:

function TransposeChord(sChord: string; Pitch: Integer): string;
var
   sResult: string;
   K, MaxK, Found: Integer;
begin
   sResult := sChord;
   MaxK := 12;
   for K := 0 to (MaxK - 1) do
   begin
     if cTranspose[TTranspose(K)] = sChord then
     begin
       Found := (K + Pitch) mod MaxK;
       if Found < 1 then
         inc(Found, MaxK);
       sResult := cTranspose[TTranspose(Found)];
       break;
     end;
     Result := sResult;
   end;
end;

Fall 1: sChord = "C"
Beim ersten Durchlauf der For-Schleife ist cTranspose[TTranspose(K)] = sChord
also wird auf Basis Pitch der neue Wert in sResult (nicht in Result) gestellt und die For-Schleife mittels Break verlassen.
Die Zeile Result := sResult wird nicht ausgeführt.

Fall 2: sChord <> "C"
Beim ersten Durchlauf der For-Schleife ist cTranspose[TTranspose(K)] <> sChord.
Also wird das am Ende der For-Schleife stehende Result := sResult ausgeführt, wobei sResult=sChord ist.
Das wird solange wiederholt, wie cTranspose[TTranspose(K)] <> sChord ist.
Wenn dann das richtige K gefunden ist, wird (wie im Fall 1) auf Basis von Pitch der neue Wert berechnet und in sResult (nicht in Result) gestellt und die For-Schleife mittels Break verlassen.
Die Zeile Result := sResult wird nicht ausgeführt.
In Result steht also der in sChord an die Funktion übergebene Wert und der ist nur dann richtig, wenn Pitch = 0 oder 12 oder ein Vielfaches von 12 ist.

Zitat:

Das Result := sResult; gehört 2 Zeilen tiefer (hinter die for-Schleife.

Zitat:

Na ja eine Zeile tiefer.

Eine Zeile tiefer steht ein "end;", und unter die Zeile mit dem "end;" soll es gebracht werden, also 1 + 1 = 2 Zeilen tiefer.

Zitat:

Viele Wege führen zum Ziel.

Ja, wenn man denn einen der vielen richtigen Wege geht.

[EWeiss]

Zitat:

Ja, wenn man denn einen der vielen richtigen Wege geht.

Seltsam nur das bei mir die richtigen Ergebnisse ausgegeben werden.

Siehe shot

oben A ,B genau das was erwartet wird.

Delphi-Quellcode:

for k = 0 to xx do
begin

end
Result := bla; // und hier das result. dort wird ausgewertet wenn die schleife beendet wird auf welchen weg auch immer.

Keine Ahnung was du willst?

Zitat:

Die Zeile Result := sResult wird nicht ausgeführt.

Wird immer ausgeführt.

Zitat:

Eine Zeile tiefer steht ein "end;", und unter die Zeile mit dem "end;" soll es gebracht werden, also 1 + 1 = 2 Zeilen tiefer.

Keine Ahnung was du da rechnest oder meinst zu sehen.
Wie ich schon sagte 1 zeile tiefer.

Delphi-Quellcode:

function TransposeChord(sChord: string; Pitch: Integer): string;
var
  sResult: string;
  K, MaxK, Found: Integer;
begin

  sResult := sChord;
  MaxK := 12;

  for K := 0 to (MaxK - 1) do
  begin
    if cTranspose[TTranspose(K)] = sChord then
    begin
      Found := (K + Pitch) mod MaxK;
      if Found < 0 then
        inc(Found, MaxK);

      sResult := cTranspose[TTranspose(Found)];
      break;
    end;
  end;
  Result := sResult;
end;

EIne Zeile tiefer vergleiche es!
Vorher stand es über den End nun drunter.

gruss

[KodeZwerg]

ot
Hör auf so viele geniale Bilder zu Zaigen, da werd ich blass vor Neid! (soll ein Kompliment sein)
/ot

[Amateurprofi]

Zitat:

Zitat von EWeiss (Beitrag 1399448)

Zitat:

Ja, wenn man denn einen der vielen richtigen Wege geht.

Seltsam nur das bei mir die richtigen Ergebnisse ausgegeben werden.

Siehe shot

oben A ,B genau das was erwartet wird.

Delphi-Quellcode:

for k = 0 to xx do
begin

end
Result := bla; // und hier das result. dort wird ausgewertet wenn die schleife beendet wird auf welchen weg auch immer.

Keine Ahnung was du willst?

Zitat:

Die Zeile Result := sResult wird nicht ausgeführt.

Wird immer ausgeführt.

Zitat:

Eine Zeile tiefer steht ein "end;", und unter die Zeile mit dem "end;" soll es gebracht werden, also 1 + 1 = 2 Zeilen tiefer.

Keine Ahnung was du da rechnest oder meinst zu sehen.
Wie ich schon sagte 1 zeile tiefer.

Delphi-Quellcode:

function TransposeChord(sChord: string; Pitch: Integer): string;
var
  sResult: string;
  K, MaxK, Found: Integer;
begin

  sResult := sChord;
  MaxK := 12;

  for K := 0 to (MaxK - 1) do
  begin
    if cTranspose[TTranspose(K)] = sChord then
    begin
      Found := (K + Pitch) mod MaxK;
      if Found < 0 then
        inc(Found, MaxK);

      sResult := cTranspose[TTranspose(Found)];
      break;
    end;
  end;
  Result := sResult;
end;

EIne Zeile tiefer vergleiche es!
Vorher stand es über den End nun drunter.

gruss

Ich hatte mich auf die Funktion in deinem Beitrag #10 bezogen.
In der stand das

Delphi-Quellcode:

Result:=sResult;

innerhalb der For-Schleife, wurde also nicht ausgeführt, wenn die For-Schleife mit Break verlassen wird.
Ich hatte dann u.A. vorgeschlagen das

Delphi-Quellcode:

Result:=sResult;

2 Zeilen nach unten, also hinter die For-Schleife zu verschieben.
Zu diesem Vorschlag hattest du in #19 gesagt

Zitat:

Na ja eine Zeile tiefer.

Wird aber in jedem fall aufgerufen auch wenn ich es so belassen würde.
er Wert wird also in jedem fall richtig übergeben.

Und hierzu hatte ich angemerkt, dass das nicht richtig ist.

Hierzu sagst du

Zitat:

Seltsam nur das bei mir die richtigen Ergebnisse ausgegeben werden.

Siehe shot

oben A ,B genau das was erwartet wird.

Welcher "Shot" ?
Und ja klar bringt die von dir jetzt gezeigte Funktion richtige Ergebnisse, denn sie enthält ja auch die von mir vorgeschlagenen Korrekturen, insbesondere die, das

Delphi-Quellcode:

Result:=sResult;

hinter die For-Schleife zu verschieben.
Mein Einwand bezog sich aber auf deinen Kommentar, dass auch dann wenn man das

Delphi-Quellcode:

Result:=sResult;

so belässt (also innerhalb der For-Schleife), die richtigen Werte übergeben werden.

[EWeiss]

Zitat:

Mein Einwand bezog sich aber auf deinen Kommentar, dass auch dann wenn man das Result:=sResult; so belässt (also innerhalb der For-Schleife), die richtigen Werte übergeben werden.

Nein wenn ich es da belassen hätte wären die werte falsch. Korrekt.

Na ok dann habe ich dich falsch verstanden. Entschuldige bitte.
Danke! ;)

Zitat:

Welcher "Shot" ?

Habe ihn wieder gelöscht.

gruss

[himitsu]

Delphi-Quellcode:

c_, c, c¯, c⌂, cʭ, c败

Ob auch sowas als Bezeichner erlaubt ist, hab ich jetzt nicht getestet.
[edit] Die ersten 4 sind erlaubt, seit 2009. :stupid:
♬ ♮ ♫ ♯ ♮
https://unicode.org/charts/PDF/U1D100.pdf
https://de.wikipedia.org/wiki/Unicod...schriftzeichen

[EWeiss]

Zitat:

Zitat von himitsu (Beitrag 1399499)

Delphi-Quellcode:

c_, c, c¯, c⌂, cʭ, c败

Ob auch sowas als Bezeichner erlaubt ist, hab ich jetzt nicht getestet.
[edit] Die ersten 4 sind erlaubt. :stupid:
♬ ♮ ♫ ♯ ♮
https://unicode.org/charts/PDF/U1D100.pdf
https://de.wikipedia.org/wiki/Unicod...schriftzeichen

Was es nicht alles gibt :)

gruss

[Neutral General]

Zitat:

Zitat von himitsu (Beitrag 1399499)

Delphi-Quellcode:

c_, c, c¯, c⌂, cʭ, c败

Ob auch sowas als Bezeichner erlaubt ist, hab ich jetzt nicht getestet.
[edit] Die ersten 4 sind erlaubt, seit 2009. :stupid:
♬ ♮ ♫ ♯ ♮
https://unicode.org/charts/PDF/U1D100.pdf
https://de.wikipedia.org/wiki/Unicod...schriftzeichen

Ich hab irgendwie Probleme die einzubinden.
Weder direkt per Copy&Paste noch Caption := #$1D120; funktioniert.
Ich bekomme da nur Kästchen. Hab auch ein paar gängige Schriftarten ausprobiert :|

[Daniel]

Das hat mit den Noten jetzt aber weniger zutun.

[himitsu]

Ja, nicht alle Zeichen sind überall (gut) sichtbar.
Bei ♬ ♮ ♫ ♯ ♮ sehe ich im XE den Letzten auch nur als Kästchen, weil es in der Schrift dieses Zeichen nicht gibt und keine Umleitung zu einer anderen Schrift für dieses Zeichen registriert wurde.
Und dazu kommt dann noch, dass bei der gleichbreiten rechteckigen kleinen Schrift im Editor vieles nicht erkennbar ist.

Aber grundsätzlich ging es ja nur darum "Noten" als Bezeichner zu verwenden, was prinzipiell geht.

Bezeichner unterliegen einer gewissen Syntax (vor dem Unicode-Compiler war sie noch recht simpel, aber inzwischen ist wesentlich mehr erlaubt)

Als RegEx

Delphi-Quellcode:

^[A-Za-z_][A-Za-z_0-9]*$

für Delphi 7
und für ab D2009

Delphi-Quellcode:

^([[:alnum:]]|_)([[:alnum:]]|_)*$

.

Delphi-Quellcode:

Aus SysUtils des XE, aber groß wird sich daran nicht viel gändert haben.

function IsValidIdent(const Ident: string; AllowDots: Boolean): Boolean;
{$IFNDEF UNICODE}
const
  Alpha = ['A'..'Z', 'a'..'z', '_'];
  AlphaNumeric = Alpha + ['0'..'9'];
  AlphaNumericDot = AlphaNumeric + ['.'];
var
  I: Integer;
begin
  Result := False;
  if (Length(Ident) = 0) or not (Ident[1] in Alpha) then Exit;
  if AllowDots then
    for I := 2 to Length(Ident) do
      begin
        if not (Ident[I] in AlphaNumericDot) then Exit
      end
  else
    for I := 2 to Length(Ident) do if not (Ident[I] in AlphaNumeric) then Exit;
  Result := True;
end;
{$ELSE UNICODE}
  function Alpha(C: Char): Boolean; inline; 
  begin
    Result := TCharacter.IsLetter(C) or (C = '_');
  end;

  function AlphaNumeric(C: Char): Boolean; inline;
  begin
    Result := TCharacter.IsLetterOrDigit(C) or (C = '_');
  end;

  function AlphaNumericDot(C: Char): Boolean; inline;
  begin
    Result := TCharacter.IsLetterOrDigit(C) or (C = '_') or (C = '.');
  end;

var
  I: Integer;
begin
  Result := False;
  if (Length(Ident) = 0) or not Alpha(Ident[1]) then
    Exit;
  if AllowDots then
    for I := 2 to Length(Ident) do
      begin
        if not AlphaNumericDot(Ident[I]) then
          Exit
      end
  else
    for I := 2 to Length(Ident) do
      if not AlphaNumeric(Ident[I]) then
        Exit;
  Result := True;
end;
{$ENDIF UNICODE}