SelectDirectory

[Walter Landwehr]

Hallo, gibt es etwas wie SelectDirectory das auch die verbundenen Laufwerke mit anzeigt.

[mkinzler]

SelectDirectory() sollte das beim Setzen der Option sdShowShares können.

[KodeZwerg]

Vielleicht magst Du ja eine Zwei-In-Einem Variante, für WindowsXP dein SelectDirectory und ab Vista das neue Fenster.
Ist Hauptsächlich nur die Optik.

Delphi-Quellcode:

function SelDir ( StartPath : String; var SelectedDir : String ) : Boolean;
begin
  Result := False;
  if Win32MajorVersion >= 6 then
  with TFileOpenDialog.Create(nil) do
    try
      Title := 'Select Directory';
      Options := [fdoPickFolders, fdoPathMustExist, fdoForceFileSystem];
      OkButtonLabel := 'Select';
      DefaultFolder := StartPath;
      FileName := StartPath;
      if Execute then
      begin
        SelectedDir := FileName;
        Result := True;
      end;
    finally
      Free;
    end
    else
    if SelectDirectory('Select Directory', ExtractFileDrive(StartPath), StartPath,
                       [sdNewUI, sdNewFolder, sdShowShares]) then
     begin
       SelectedDir := StartPath;
       Result := True;
     end;
end;


// Beispiel Aufruf:
procedure TForm2.Button1Click(Sender: TObject);
var
  s : String;
begin
 if SelDir('',S) then ShowMessage(s);
end;

Unterschiede zwischen Vista und XP Dialog wäre falls Du so

Delphi-Quellcode:

SelDir('C:\XYZ\',S)

den Aufruf machst, unter Vista wäre der User beim Aufruf bereits in "C:\XYZ\" drinnen bei XP hingegen hätte der Dialog "C:\XYZ\" ausgewählt.

[Walter Landwehr]

Hallo Markus, hat ich auch gedacht, funktioniert aber nicht.

Hier mein Code:

Delphi-Quellcode:

procedure TOptionenFrm.dedtSicherungspfadPropertiesButtonClick(Sender: TObject;
  AButtonIndex: Integer);
Var Dir : string;
begin
  if (dmMain.ibqryOptionen.State <> dsEdit) then
      dmMain.ibqryOptionen.Edit;

  SelectDirectory('Einen Ordner zum Speichern wählen.', '', Dir, [sdShowEdit, sdNewFolder, sdShowShares, sdNewUI]);

  dmMain.ibqryOptionen.FieldByName('SICHERUNGSPFAD').AsString := Dir;
end;

Hallo CodeZwerg,

werde ich morgen mal probieren, berichte dann.

[KodeZwerg]

Hallo, ich habe noch mal ein wenig rumprobiert und etwas festgestellt:
Wenn ich SelectDirectory() aufrufe mit einem Start-Verzeichniss als Parameter, dann werden merkwürdigerweise alle Laufwerke ausgeblendet, auch lokale, es wird nur das Laufwerk eingeblendet was im Start-Parameter übergeben wurde.
Könnte es daran liegen das es bei Dir nicht fruchtet?

[himitsu]

Lasst doch bitte das uralte SelectDirectory links liegen und verwendet TFileOpenDialog mit fdoPickFolders. (bzw. siehe Kapselungen ala dem SelDir von da oben)
Den der alte Dialog ist absolut nicht benutzerfreundlich und dazu auch noch hässlich.

Einzig und allein das SelectDirectory mit dem Directories:TArray<string> wäre brauchbar, denn das nutzt oben genannten Dialog.

Zitat:

Wenn ich SelectDirectory() aufrufe mit einem Start-Verzeichniss als Parameter

Ich seh alles.

[KodeZwerg]

Ja ich hatte auch probiert die andere SelectDirectory() Methode zu verwenden aber bin nicht dahintergekommen wie ich den korrekt Aufrufe, könntest Du so lieb sein ein Beispiel dafür geben?

[himitsu]

Ich nutze ein eigenes TFileOpenDialog mit fdoPickFolders, quasi in einer etwas aufgemotzteren Version dieses SelDir.

Aber ein Blick in das Code Insight oder in die OH und schon kommt sowas bei raus, als Minimalbeispiel.

Delphi-Quellcode:

var
  A: TArray<string>;
begin
  //if SelectDirectory('', A) then
  //if SelectDirectory('D:\', A) then
  if SelectDirectory('D:\', A, [sdAllowMultiselect], 'Der Titel', 'Ein Label', 'Der Button') then
    ShowMessage(string.Join(sLineBreak, A));  // bei nur einem reicht A[0]

  if FileOpenDialog1.Execute then  // mit fdoPickFolders und sdAllowMultiselect
    ShowMessage(FileOpenDialog1.Files.Text);  // FileOpenDialog1.FileName

[KodeZwerg]

Vielen Dank, teste ich gleich mal aus und "upgrade" den OldSchool Dialog.
Ps: Ich vermute ein "TArray<string>;" weil damit auch Multiple-Sachen selektiert werden können.

edit
Nun weiß ich warum mein voriger Versuch immer fehlschlug, da gibt es ja ein anderes Option-Set :wall:

[himitsu]

War'n kleiner Copy&Paste-Error drin.

PS: Bei den neuen Open-/SaveDialogs kann man eine GUID angeben, damit speichert Windows das zuletzt ausgewählte Verzeichnis.
Wird wieder ein Dialog mit dieser GUID aufgerufen, dann wird InitialDir ignoriert und das letzte Verzeichnis geladen.

[KodeZwerg]

SelDir() Update

Delphi-Quellcode:

function SelDir ( StartPath : String; var SelectedDir : String ) : Boolean;
var
 tmp : TArray<string>;
begin
  Result := False;
  if Win32MajorVersion >= 6 then
  with TFileOpenDialog.Create(nil) do
    try
      Title := 'Select Directory';
      Options := [fdoPickFolders, fdoPathMustExist, fdoForceFileSystem];
      OkButtonLabel := 'Select';
      DefaultFolder := StartPath;
      FileName := StartPath;
      if Execute then
      begin
        SelectedDir := FileName;
        Result := True;
      end;
    finally
      Free;
    end
    else
//  Mögliche Options: sdHidePinnedPlaces, sdNoDereferenceLinks, sdForceShowHidden, sdAllowMultiselect
     if SelectDirectory(StartPath, tmp, [sdForceShowHidden], 'Select Directory', 'Foldername:', 'Select')
// BACKUP - hier noch der Aufruf für den kleinen Dialog
//  Mögliche Options: sdNewFolder, sdShowEdit, sdShowShares, sdNewUI, sdShowFiles, sdValidateDir
//  mit Option sdShowFiles wird aus dem auch ein Datei-Selektor
//    if SelectDirectory('Select Directory', ExtractFileDrive(StartPath), StartPath,
//                       [sdNewFolder, sdShowEdit, sdShowShares, sdNewUI, sdValidateDir])
     then begin
       SelectedDir := tmp[0]; // Achtung, hier wird nur der erste Eintrag genommen! Also so nicht "sdAllowMultiselect" fähig
//       SelectedDir := StartPath; //  BACKUP - für den alten Dialog
       Result := True;
     end;
end;


// Beispiel Aufruf:
procedure TForm2.Button1Click(Sender: TObject);
var
  s : String;
begin
 if SelDir('C:\Tools\',S) then ShowMessage(s);
end;

Dank gilt himitsu für's Zeit nehmen und Erklären und das bei mir endlich der Groschen gefallen ist warum ich's Anfang nicht hinbekam, es gibt zwei Unterschiedliche Option-Sets, muss man auch erstmal draufkommen :)

Nun sehen Dialoge unter XP und Vista sogut wie gleich aus, beide Verhalten sich relativ identisch.

[Walter Landwehr]

Das sieht zwar sehr schön aus, aber mir fehlen immer noch die verbundenen Laufwerke. (siehe Anhang) Für den Anwender ist es einfacher, wenn diese sichtbar sind, als über das Netzwerk diese zu suchen was die meisten nicht mal verstehen.
Gibt's da noch einen Trick?

Ansonsten wirklich super, vielen Dank schon mal.

[KodeZwerg]

Zitat:

Zitat von Walter Landwehr (Beitrag 1399213)

mir fehlen immer noch die verbundenen Laufwerke

Das verstehe ich gerade nicht, im Bild sind doch Netzlaufwerke abgebildet?

[Walter Landwehr]

Sorry das Bild kommt von dem Windows Explorer. Hier das Bild von TFileOpenDialog.

[Walter Landwehr]

Es geht wenn man mit net use die Laufwerke zuweist.

[KodeZwerg]

Delphi-Quellcode:

function SelDir ( StartPath : String; var SelectedDir : String ) : Boolean;
begin
  Result := False;
  with TFileOpenDialog.Create(nil) do
    try
      Title := 'Select Directory';
      Options := [fdoPickFolders, fdoPathMustExist, fdoAllNonStorageItems, fdoShareAware, fdoForceShowHidden, fdoDefaultNoMiniMode];
      OkButtonLabel := 'Select';
      DefaultFolder := StartPath;
      FileName := StartPath;
      if Execute then
      begin
        SelectedDir := FileName;
        Result := True;
      end;
    finally
      Free;
    end
end;

Nur ein Versuch, hier habe ich andere Optionen gewählt die Eigentlich auch Netzlaufwerke Anzeigen sollte.
Bitte einmal Testen, Danke.
Ps: Hier ist der XP Dialog komplett weg.

Nachteil: Es werden dummerweise auch Archive angezeigt :(

edit
hab diese Überbleibsel entfernt

Code:

var tmp : TArray<string>;

[Walter Landwehr]

Ja das funktioniert auch. Danke für Deine Hilfe.

[KodeZwerg]

Das freut mich wenn alles nun klappt!
Da leider auch, zumindest bei mir, auch Archive angezeigt werden wäre da eventuell noch ein "ExtractFilePath()" sinnvoll.
Nicht das Dein Programm Versucht eine Datei als Ordner zu benutzen.

[KodeZwerg]

Delphi-Quellcode:

function SelDir ( StartPath : String; var SelectedDir : String ) : Boolean;
begin
  Result := False;
  with TFileOpenDialog.Create(nil) do
    try
      Title := 'Select Directory';
      Options := [fdoPickFolders, fdoPathMustExist, fdoAllNonStorageItems, fdoShareAware, fdoForceShowHidden, fdoDefaultNoMiniMode];
      OkButtonLabel := 'Select';
      DefaultFolder := StartPath;
      FileName := StartPath;
      if Execute then
      begin
        if FileExists(FileName) then SelectedDir := ExtractFilePath(FileName) else SelectedDir := FileName;
        Result := True;
      end;
    finally
      Free;
    end
end;

So wärst Du auf der sicheren Seite, falls User eine .CAB Datei wählt, wird dessen Verzeichniss genommen anstelle des Archivnamens.

[Walter Landwehr]

Danke habe ich umgesetzt.

[KodeZwerg]

Gern geschehen und weiterhin Viel Erfolg!