In Klasse auf Funktion zugreifen oder auf Property?

[norwegen60]

Hallo zusammen,

gibt es Argumente die für oder gegen einer dieser beiden Methoden sprechen? Außer der dass die zweite Lösung mehr Zeilen Code sind.

Delphi-Quellcode:

  TTest = class 
  private
  public
    function CountIrgendwas:Integer
  end;

implementation

function TTest:CountIrgendwas:Integer;
begin
  Result := (Zähl irgend was);
end;

oder

Delphi-Quellcode:

  TTest = class
  private
    FCountIrgendwas : Integer;
    function GetCountIrgendwas:Integer;
  public
    property CountIrgendwas:Integer read GetCountIrgendwas; 
  end;

implementation

function TTest:GetCountIrgendwas:Integer;
begin
  Result := (Zähl irgend was);
end;

Danke
Gerd

[günni0]

Ich mache es immer wie in deinem ersten Beispiel. Zusätzlich noch mit class und static/inline deklarationen.

Delphi-Quellcode:

 TTest = class 
  private
  public
   class function CountIrgendwas: Integer; static;
  end;

class function TTest.CountIrgendwas: Integer;
begin
 Result := (Zähl irgend was);
end;

[norwegen60]

Und was bewirkt das zusätzliche class und static?

[Sequitar]

Zitat:

Zitat von norwegen60 (Beitrag 1397629)

Und was bewirkt das zusätzliche class und static?

Klassenmethoden sind solche die auf der klasse, nicht auf deren objekte angewandt werden.
Du brauchst also zum aufruf keine instanz der klasse zu erzeugen:

Delphi-Quellcode:

Type
  TAsimpleclass = Class
  Private
    Procedure Dosomething;
  End;

  Tclasswithclassmethod = Class
  Private
    Class Procedure Dosomething;
  End;

  // Implementation normaler aufruf

Procedure TAsimpleclass.Dosomething;
  Begin
    Writeln('Helloworld');
  End;
{ Beispiel klassenmethode: }

Class Procedure Tclasswithclassmethod.Dosomething;
  Begin
    Writeln('Helloworld');
  End;

Procedure Main_simple;
  Var
    Asimpleobject: TASimpleclass;
  Begin
    Asimpleobject := TASimpleclass.Create;
    // object instance der klasse TASimpleclass
    Asimpleobject.Dosomething;
    Asimpleobject.Free;
  End;

Procedure Main_classmember;
  // var Asimpleobject:TASimpleclass; //wird nicht mehr benötigt, da wir auf der Klasse operieren
  Begin
    // Asimpleobject:=TASimpleclass.create; //object instance der klasse TASimpleclass
    Tclasswithclassmethod.Dosomething;
    // direkter aufruf über den Klassennamen und die class procedure
    // Asimpleobject.free;
  End;

Begin
  Main_simple;
  Main_classmember;

End.

Erläuterung für static members:
https://ibeblog.com/2010/08/18/delphi-static-members/

[Sequitar]

Zur allgemeinen Frage:
Properties eignen sich zum kontrollierten Zugriff auf die Daten deiner objekte. Sie können lesend, schreibend oder beides sein. Demnach kannst du bestimmen wie auf deine Daten zugegriffen werden darf, anstatt jeden Nutzer direkt mit deinen Variablen in Kontakt treten zu lassen, was mglw. ungewollte Folgen haben kann.
Ausserdem kannst du relativ einfach bei vererbten klassen die zugriffs- und sichtbarkeitsrechte ändern.

Delphi-Quellcode:

Type
  TX = Class
  Private
    Fvalue: Integer;            // feld zum speichern der daten
    Function Getvalue: Integer; // zugriffsfunktion
  Protected                     // nur für Erben sichtbar
    Property Avalue: Integer Read Getvalue;
    // Zugriffsbeschränkung auf nur lesend
  Public
    Constructor Create;
  End;

 TX2 = Class(TX)
  Private
    Procedure Setvalue(Value: Integer);
  Public
    Property Avalue Write Setvalue;
    // Sichtbarkeit geändert, jetzt 'überall' sichtbar; ausserdem darf der wert geändert werden
  End;

Damit ist jetzt nur noch Folgendes möglich:

Delphi-Quellcode:

 { TX }

Constructor TX.Create;
  Begin
    Fvalue := 42;
  End;

Function TX.Getvalue: Integer;
  Begin
    Result := Fvalue;
  End;
{ TX2 }

Procedure TX2.Setvalue(Value: Integer);
  Begin
    Fvalue := Value;
  End;

Procedure Main;
  Var
    X: Tx;
    Y: Tx2;
  Begin
    X := Tx.Create;
    // X.Avalue := 42;  //Cannot assign to a read only propery
    Writeln(X.Avalue); // writes 42
    X.Free;
    Y := Tx2.Create;
    Y.Avalue := 55;
    Writeln(Y.Avalue); // writes 55
    Y.Free;
  End;

[norwegen60]

Mir ist der Sinn von Properties schon klar. Die Frage ist:
Wenn eine Funktion z.B. die Verknüpfung mehrere Properties darstellt, und damit der Wert immer nur lesend sein kann, ob es dann einen Unterschied macht ob ich direkt auf den Getter indem ich dem schon den Variablenname gebe und so direkt auf den Getter zugreife oder über den Umweg eines zusätzlichen Werts (FCountIrgendWas)

[Der schöne Günther]

Nein, technisch ist das kein Unterschied, der Compiler macht das Gleiche draus.

Der Sinn von Properties in Delphi erschließt sich mir bis heute nicht. Sie können nichts was man mit den Gettern und Settern (die man sowieso schreiben muss) nicht auch kann. Man kann sie nicht als

Delphi-Quellcode:

var

oder

Delphi-Quellcode:

out

-Parameter übergeben (z.B.

Delphi-Quellcode:

Inc(someValue)

). In der Code-Completion ist noch nicht einmal sichtbar ob ich eine Property überhaupt beschreiben darf, wenn eine Methode getXX oder setXX heißt sehe ich das sofort.


Properties sind nur noch mehr Schreibarbeit. Gewonnen hat man dadurch nichts.

[norwegen60]

Hallo Günther,

Zitat:

Zitat von Der schöne Günther (Beitrag 1397637)

Properties sind nur noch mehr Schreibarbeit. Gewonnen hat man dadurch nichts.

danke für die klare Antwort. Auch wenn du mir etwas voreingenommen scheinst ;-). Bei Variablen die Getter und Setter haben finde ich es ganz OK wobei ich die Set/Get nur verwende wenn ich noch was zusätzliche machen will. z.B. so:

Delphi-Quellcode:

TTest = class
  private
    FChanged: Boolean;
    FNormal : String;
    FTuWas : String;

    procedure SetTuWas(Value:String);
  public
    property Normal: String read FNormal write FNormal;
    property TuWas: String read FTuWas write SetTuWas;
  end;

procedure TTest.SetTuWas(Value:String);
begin
  if FTuWas <> Value then
  begin
    FTuWas := Value;
    FChanged := true;
  end;
end;

[KodeZwerg]

Ich schließe mich dem schönen Günther an wobei ich solche Klassen meist nur verwende um Original-Units zu kürzen.
Da wird dann aus "Uses SysUtils" zum Beispiel ein "SysUtils = Class". So bleibt der Aufruf im Code meist gleich.

[freimatz]

Zitat:

Zitat von Der schöne Günther (Beitrag 1397637)

Der Sinn von Properties in Delphi erschließt sich mir bis heute nicht. ...
Properties sind nur noch mehr Schreibarbeit. Gewonnen hat man dadurch nichts.

Der Sinn ist dass man eine Eigenschaft hat. Das was sich hinter Getter und Setter verbirgt gehört zusammen. Das gehört zum Thema Clean Code.
Durch die Verwendung von Eigenschaften habe ich weniger Schreibarbeit und zwar weil ich MMX verwende. Der fasst die Eigenschaft, die Getter und Setter und auch noch das Feld sofern vorhanden zusammen. Da kann ich dann:
- Getter, Setter und Feld in der Baumansicht ausblenden, es wird dadurch übersichtlicher.
- Die ganze Eigenschaft mit den Dingern auschneiden, kopieren und/oder woanders einfügen

[himitsu]

Ich halte es eher mehr nach Nice-Code.
Wenn diese "Funktion" logisch zu einer Reihe anderer Property gehört, dann mach ich das als ReadOnly-Property, damit es sich in der Klassendeklaration ansehnlicher einfügt.
Im Programmablauf ist es egal, da der Compiler das Property durch die Funktion ersetzt hat.

UND bei Custom-Klassen mach ich es eben so, denn Property kann man später in der Sichtbarkeit einfach verschieben.

Zitat:

Zusätzlich noch mit class und static/inline deklarationen.

Das Zusätzlich war falsch und kann hier auch falsch sein,
wenn auf Daten der Objektinstanz zugegriffen werden soll.

class function = Methode an der Klasse (nur globale Funktion ohne Bindung an eine Instanz)
function = Methode am Objekt, inkl. Zugriff auf Felder/Methoden dieser Instanz

static = statische Funktion > ohne SELF-Variable
Hier hat man nichtmal mehr Zugriff auf den aktuellen Klassentyp, bei abgeleiteten Klassen.
> der implizite SELF-Parameter wird nicht übergeben, was den Funktionsaufruf kleiner macht
> Letztendlich ist der Aufruf genau so, wie bei einer "normalen" Funktion, welche nicht in einer Klassendefinition steckt (zuzüglich Zugriff auf z.B. Class-Vars)

[günni0]

Zitat:

> Letztendlich ist der Aufruf genau so, wie bei einer "normalen" Funktion, welche nicht in einer Klassendefinition steckt (zuzüglich Zugriff auf z.B. Class-Vars)

Richtig. Ist auch immer mein Ziel. Das mit Class usw. hat den Vorteil, dass man die Unit umbenennen kann, ohne an zig-Stellen was abändern zu müssen.
Ich persönlich benenne Units oft um. Weniger oft jedoch record- und class-Namen.

Record benutze ich, um den ganzen Clutter der Codecompletion drum herum wegzubekommen.

[Delphi.Narium]

Zitat:

Zitat von Der schöne Günther (Beitrag 1397637)

Der Sinn von Properties in Delphi erschließt sich mir bis heute nicht. ...
Properties sind nur noch mehr Schreibarbeit. Gewonnen hat man dadurch nichts.

Also sowas finde ich mit Properties viel schöner als ohne:

Delphi-Quellcode:

Label.Caption := Label.Caption + '*';

// statt
var
  s : String;
begin
  s := Label.GetCaption;
  s := s + '*';
  Label.SetCaption(s);
end;

// ok, das ginge wohl auch:
Label.SetCaption(Label.GetCaption + '*');

Mir gefällt die erste Variante am Besten, da sie im Quelltext am leichtesten zu lesen ist.

Und beim Programmieren interessiert es mich nicht, ob es einen Setter und einen Getter gibt. Mir reicht es, wenn ich eine Eigenschaft einfach per Zuweisung mit 'nem Wert versehen kann, ob das intern über 'nen Getter und 'nen Setter (oder jeweils nur einen davon) abläuft, interessiert mich nicht.

Baut jemand eine Klasse, bei der es für eine Eigenschaft weder Setter noch Getter gibt, so kann ich da einen Wert zuweisen.
Baut jetzt jemand später Getter und Setter ein und ich kann nur diese nutzen, so fällt eine Änderung des Quelltextes an.

Bei der Nutzung von Eigenschaften ist das für den Programmierer transparent. Die Sichtbarkeit läßt sich bei der Vererbung leicht verändern, aber über weitere interne Änderungen muss ich mir da keinen Kopp machen. Das ist innerhalb der Klasse und sollte nach außen keine Änderungen am Quelltext erforderlich machen.

[Der schöne Günther]

Bei einer Methode mit get oder set im Namen sehe ich ob es ums Lesen oder Schreiben geht. Bei einer Property weiß ich erst dass Schreiben nicht geht wenn ich F9 gedrückt, ein paar Sekunden Däumchen gedreht habe und dann unten in der Textbox eine Fehlermeldung erscheint.

Über die Jahre gerechnet habe ich damit bestimmt schon mehrere Tage Arbeitszeit gespart 8-)

[himitsu]

Zitat:

Zitat von Der schöne Günther (Beitrag 1398050)

Bei einer Property weiß ich erst dass Schreiben nicht geht wenn ich F9 gedrückt,

CodeInsight, HelpInsight, eventuell die Dokumentation (DocuInsight) und sogar die CodeCompletation hätten dir das auch sofort verraten.

[Der schöne Günther]

Ist Code Insight nicht die Code Completion?

Wie auch immer, ich bin zu dumm zu sehen wo man sich das herleiten könnte.

[MichaelT]

Für eine Property wird/wurde RTTI generiert (Hinweis auf published). Das ist mal der pragmatische Grund warum Properties sehr bliebt waren/sind neben den hier angeführten Gründen. Das hat dazu geführt, dass das Konzept ein wenig überstrapaziert wurde.

Properties sind uralt und waren tatsächlich gedacht für Datenvalidierung im Falle von Verbundstrukturen. Das Konzept der Property ist so alt, da gab es grad mal Klassen in Smalltalk in den Papers.

Du kannst die interne Repräsentation eleganter von der Außenwelt verstecken. Du weist String zu und speicherst intern bspw. eine exaktere Struktur.

Wenn du nur lesend zugreifst mache einfach eine Funktion.

[MichaelT]

Gar nicht :-D. Allein kannst du nicht verhindern, dass die Left Side angeboten werden muss. Woher sollte die IDE wissen, dass du hernach eine Zuweisung schreibst.

Delphi und das durchsuchen der generelleren Klassen :-D. Warum kommt mir die Büchse der Pandorra in den Sinn.

Der MMX zeigt es an, aber ansonsten ... mhhh.

Verwende Property nicht als Teil des Klassennames wenn du CNPack nimmst.

Zitat:

Zitat von Der schöne Günther (Beitrag 1398055)

Ist Code Insight nicht die Code Completion?

Wie auch immer, ich bin zu dumm zu sehen wo man sich das herleiten könnte.

[himitsu]

Zitat:

Zitat von MichaelT (Beitrag 1398126)

Das ist mal der pragmatische Grund warum Properties sehr bliebt waren/sind neben den hier angeführten Gründen.

Und man sieht es im Objektinspector.

Das kann auch für ReadOnly-Property gut sein. z.B. um dort einen internen Komponenten-Status oder die Verison anzuzeigen.


Und selbst Write-Only-Property gibt es, die manchmal ganz nett sind.

[MichaelT]

Die Properties sind ursprünglich zumeist Ganzzahlwerte oder Zeichenketten in Datenbanken (Systeminformation) in geschützten Speicherbereichen und vorzüglich Konfigurationsparameter. Weswegen die Entsprechung mit published im Kontext der IDE an sich stimmig ist.

Wenn du wirklich ein Framework dicht machen willst und gegen insbesondere unbewusste missbräuchliche Verwendung durch andere Team Mitglieder schon während der Entwicklung willst schützen musst du am Ende auf C/C++ zurückgreifen. Das ist zumeist ein Overkill. Für die gebräuchliche Verwendung ist im Delphi genug da.

Die meisten Sachen grad im Zusammenhang mit Vererbung und Delphi bspw. sind in der Praxis nicht relevant, da eine Klassenbibliothek nicht viel mehr als 4 (bis max 7 im Ausnahmefall) Vererbungstiefe sollte aufweisen. Respektive war als Delphi das Licht der Welt erblickte diese Forderung eher eine technische Notwendigkeit, aber nicht nur. die Forderung hat aber auch mit Übersichtlichkeit zu tun. Damit relativiert sich viel. Die Verantwortlichkeit ist eben sauberer abgebildet.

Jetzt werden gleich die ersten schreiben. 'Aber es darf nur einen Ort gehen an dem etwas im Programm passiert'. Das stimmt zwar, kommt aber ursprünglich aus dem systemischen Zugang zu modularen Systemen. In der echten 'OO' ist der eine Platz einfach im Kontext einer Klasse oder einem Objekt definiert welches zuständig ist. Die Hybridsprachen müssen das alles eher in der Vererbungshierarchie abbilden. Die sind ewig auf der Suche nach dem zuständigen Typen und fragen nicht einfach ein Objekt von dem sie glauben oder wissen.

So irr wie das ganze heute betrieben wird in der Objektorientierung hat auch nie jemand verlangt.

Die Java Leute haben mit den Design Patterns im Java Framework angefangen und MS hat das ganze zur Perversion getrieben. HIT ist der Standardimplementierungsmehtode, fast alles ist abgesichert bis zum Abwinken und von IDE der unterstützt. Sowie da.

Es geht heut keiner mehr her und sagt, 'Jetzt haben wir einen netten Code geschrieben und freuen uns, dass dieser sogar funktioniert'.

Die IT war schon mal gemütlicher und damals hat man sich mehr Gedanken drüber gemacht wie man sich Arbeit erspart. Diese Denke war/ist im Delphi Umfeld sehr verbreitet.

Im Ferrari einen Marathon zu fahren ist auch nicht sportlicher als gleich einen 100m Sprint laufen.

Zitat:

Zitat von himitsu (Beitrag 1398130)

Zitat:

Zitat von MichaelT (Beitrag 1398126)

Das ist mal der pragmatische Grund warum Properties sehr bliebt waren/sind neben den hier angeführten Gründen.

Und man sieht es im Objektinspector.

Das kann auch für ReadOnly-Property gut sein. z.B. um dort einen internen Komponenten-Status oder die Verison anzuzeigen.


Und selbst Write-Only-Property gibt es, die manchmal ganz nett sind.