Wie anmelden an entfernten Webservice per Headerinfo?

[TiGü]

Hallo Gemeinde,

ich stehe gerade wie der Ochs vorm Berg und hoffe auf hilfreiche Inspirationen euerseits.

Gegeben ist der Versuch der Kommunikation mit einem Webservice.
Dieser Webservice gibt es zum einen als lokale Variante als Windows-Dienst.
Zu diesem Webservice gibt es auch eine WSDL-Datei, die importiert ein Interface anbietet plus die typische Factory-Funktion:

Delphi-Quellcode:

  IPOS = interface(IInvokable)
  ['{E2FA8424-460E-C4F7-2508-000E745AD493}']
    function  Sign(const data: ReceiptRequest2): ReceiptResponse2; stdcall;
    function  Journal(const ftJournalType: Int64; const from: Int64; const to_: Int64): StreamBody; stdcall;
    function  Echo(const message_: string): string; stdcall;
  end;

function GetIPOS(UseWSDL: Boolean=System.False; Addr: string=''; HTTPRIO: THTTPRIO = nil): IPOS;

Für die lokale Variante muss man eine HTTP-Adresse angeben die sich aus der IP-Adresse und Port sowie einer spezifischen GUID zusammensetzt.
Die GUID wird in der Konfiguration des Dienstes übergeben.
Ein typischer Aufruf würde so aussehen:

Delphi-Quellcode:

var
  FiskalTrust: IPOS;
  address: string; 
begin
  address := 'http://localhost:1200/d89e2e41-55ae-40f5-97b9-7a8743411b50';
  FiskalTrust := GetIPOS(false, address);

if FiskalTrust.Echo('Hello') <> 'Hello' then
  raise EProgrammerNotFound.Create('Is nich!');

Soweit ist das für mich auch kein Problem.
Alles geht soweit, ich kann die drei Methoden des Interfaces aufrufen und erhalte Antworten.


Nun ist es so, dass es diesen Webservice auch als eine Art Cloud-Dienst gibt.
Man steuert also keinen im lokalen Netzwerk liegenden Dienst an, sondern geht ins böse Internet.
Zusätzlich muss man sich dabei laut Dokumentation mithilfe einer GUID und AccessToken (irgendwas-BASE64 kodiertes) anmelden.
Mein Problem ist jetzt...wie kriege ich das per GetIPOS-Funktion hin??
Die Dokumentation sagt darüber sowas wie:

Zitat:

Der Url für die Signaturecloud ist
https://signaturcloud-sandbox.fiskaltrust.at/ für die Sandbox
https://signaturcloud.fiskaltrust.at/ für das Echtsystem

Der Server reagiert nicht auf Ping. Um ihn anzusprechen müssen das Accesstoken und die CashboxID im Header der Anfrage mitgesendet werden. Als Methode POST, nicht GET.

Gültige AccessToken und die CashboxID in Form einer GUID liegen mir vor.

Dann gibt es noch den Verweis auf ein C#-Beispiel, wo aber - ich sag mal - low level REST-Anfragen per SOAP/JSON/XML getätigt werden und nicht die importierte WSDL-Datei oder das passende NuGet-Package genommen wird:
https://github.com/fiskaltrust/inter...EST/Program.cs

Daraus als Beispiel die Methode echoJSON:

Code:

 static void echoJson(string url, Guid cashboxid = default(Guid), string accesstoken = null)
        {

            var webreq = (HttpWebRequest)HttpWebRequest.Create(url + "/json/echo");
            webreq.Method = "POST";
            webreq.ContentType = "application/json;charset=utf-8";

            webreq.Headers.Add("cashboxid", cashboxid.ToString());
            webreq.Headers.Add("accesstoken", accesstoken);

            byte[] reqecho = Encoding.UTF8.GetBytes(JsonConvert.SerializeObject("Hello World"));
            webreq.ContentLength = reqecho.Length;
            using (var reqStream = webreq.GetRequestStream())
            {
                reqStream.Write(reqecho, 0, reqecho.Length);
            }

            var webresp = (HttpWebResponse)webreq.GetResponse();
            if (webresp.StatusCode == HttpStatusCode.OK)
            {
                using (var respReader = new System.IO.StreamReader(webresp.GetResponseStream(), Encoding.UTF8))
                {
                    var json = respReader.ReadToEnd();
                    var respecho = JsonConvert.DeserializeObject<string>(json);
                    Console.WriteLine("{0:G} Echo {1}", DateTime.Now, respecho);
                }
            }
            else
            {
                Console.WriteLine("{0:G} {1} {2}", DateTime.Now, webresp.StatusCode, webresp.StatusDescription);
            }
        }

FRAGE:Wie kann ich jetzt mithilfe meiner GetIPOS-Funktion per Angabe der Header-Parameter von CashboxID und AccessToken mit dem Cloud-Webservice kommunizieren?

Ich sehe, dass man als dritten Parameter selber eine Instanz von THTTPRIO reinreichen kann.
Wo und wie kann ich eine Instanz davon manipulieren, dass es die Header-Parameter übernimmt.
Ich sehe den Wald vor lauter Bäumen nicht.

[mjustin]

Dazu habe ich dieses gefunden:

Die Methode HTTPRIOHTTPWebNode1BeforePost kann verwendet werden, um dem HTTP Request einen oder mehrere Header hinzuzufügen.

In diesem Fall sind das - nach dem JavaScript Beispielcode:

Code:

webreq.Headers.Add("cashboxid", cashboxid.ToString());
webreq.Headers.Add("accesstoken", accesstoken);

Beispielcode:

Delphi-Quellcode:

procedure TMyForm.HTTPRIOHTTPWebNode1BeforePost(
 const HTTPReqResp: THTTPReqResp; Data: Pointer);
begin
  HttpAddRequestHeaders(Data, PChar('...'), Length('...'), HTTP_ADDREQ_FLAG_ADD);
  HttpAddRequestHeaders(Data, PChar('...'), Length('...'), HTTP_ADDREQ_FLAG_ADD);
end;

https://stackoverflow.com/questions/...in-http-header

[TiGü]

Delphi-Quellcode:

type
  THelper = class
  public
    procedure BeforePost(const HTTPReqResp: THTTPReqResp; Data: Pointer);
  end;

procedure THelper.BeforePost(const HTTPReqResp: THTTPReqResp; Data: Pointer);
var
  accesstoken: string;
  cashbox: string;
begin
  cashbox := '31ada64f-bafd-492e-ac92-867f82bb2e59';
  accesstoken := 'BJLC+VckWl36AhGwvH3sOC6bQcowHjWq7vx3wsDy42nnLcyB49vrgkxkeMvqodNtvtwaJ51HUaBs7eiX7PUyiOg=';

  HttpAddRequestHeaders(Data, PChar(cashbox), Length(cashbox), HTTP_ADDREQ_FLAG_ADD);
  HttpAddRequestHeaders(Data, PChar(accesstoken), Length(accesstoken), HTTP_ADDREQ_FLAG_ADD);
end;

procedure Main;
var
  baseaddress: string;
  address: string;
  FiskalTrust: IPOS;
  Call, Echo: string;
  Rio: THTTPRIO;
  helper: THelper;
begin
  helper := THelper.Create;
  // baseaddress := 'https://signaturecloud.fiskaltrust.at';
  baseaddress := 'https://signaturcloud-sandbox.fiskaltrust.at';

  address := baseaddress;

  Rio := THTTPRIO.Create(nil);
  Rio.HTTPWebNode.OnBeforePost := helper.BeforePost;

  FiskalTrust := GetIPOS(false, address, Rio);
  Call := 'Hello';
  Echo := FiskalTrust.Echo(Call);
  if Echo <> Call then
    raise EProgrammerNotFound.Create('Is nich!');

  Writeln(Echo + sLineBreak);
end;

Hm, also mein OnBeforePost wird zwar aufgerufen, aber weiter komme ich nicht.
Der Aufruf der Echo-Methode schlägt fehl und ich erhalte eine 404-Fehler.

Zitat:

Project BlaBlupp.exe raised exception class ESOAPHTTPException with message 'Not Found (404) - 'https://signaturcloud-sandbox.fiskaltrust.at''.

Ich werde wohl nochmal mit den Anbieter in Kontakt treten.
Nicht das ich ständig den Fehler bei mir suche und am Ende ist die Endstelle offline.

[jaenicke]

Zitat:

Zitat von TiGü (Beitrag 1360489)

// baseaddress := 'https://signaturecloud.fiskaltrust.at';
baseaddress := 'https://signaturcloud-sandbox.fiskaltrust.at';

Fehlt da vielleicht schlicht ein e? Mal mit mal ohne e?

Zitat:

signatur< >cloud-sandbox

Ich würde meinen das sollte so sein:

Zitat:

https://signaturecloud-sandbox.fiskaltrust.at

[TiGü]

:shock::shock::shock:
Wenn es wirklich daran liegen sollte!!!:wall::spin::roteyes:

Ich werde gleich morgen früh testen! Danke für den Hinweis.

[jus]

Hallo TiGü,

mein Wissen zu Fiskaltrust ist nicht mehr auf den aktuellsten Stand, obwohl dies bei uns in der Firma bald wieder ansteht(spätestens am 1.April :stupid:). Seit letzten Frühjahr hat sich vermutlich einiges geändert. Damals gab es zwar eine Möglichkeit, und vermutlich jetzt immer noch, dass man statt den Weg übers Interface auch direkt über das Json-Format diesen Dienst anzusprechen kann. Ich hatte mal die Kommunikation mit Hilfe von diesem Forum in Beitrag " Kommunikation mit Windows WCF Dienst" gelöst. :wink:

Anbei das Ergebnis meiner Versuche von damals:

Delphi-Quellcode:

procedure TForm1.Button3Click(Sender: TObject);
var
  HTTP: TIdHTTP;
  RequestBody: TStream;
  ResponseBody: string;
  s: String;
begin
  HTTP := TIdHTTP.Create;
  try
    try
      s := '{"ftCashBoxID":"fiskaltrust-TEST","cbTerminalID":"1","cbReceiptReference":"9c856fa6-5e3c-4e2c-b275-82cf35363fdf","cbReceiptMoment":"\/Date(1452442695134+0100)\/",';
      s := s+'"cbChargeItems":[';
      s := s+'{"Quantity":1.0,"Description":"Artikel1","Amount":4.8,"VATRate":20.0,"ftChargeItemCase":4707387510509010944,"ftChargeItemCaseData":"","AccountNumber":"","CostCenter":"","ProductGroup":"","ProductNumber":"1","ProductBarcode":"","Unit":""},';
      s := s+'{"Quantity":1.0,"Description":"Artikel 2","Amount":3.6,"VATRate":20.0,"ftChargeItemCase":4707387510509010944,"ftChargeItemCaseData":"","AccountNumber":"","CostCenter":"","ProductGroup":"","ProductNumber":"2","ProductBarcode":"","Unit":""}],';
      s := s+'"cbPayItems": [{"Quantity":1.0,"Description":"Bar","Amount":8.4,"ftPayItemCase":4707387510509010944,"ftPayItemCaseData":"","AccountNumber":"","CostCenter":"","MoneyGroup":"","MoneyNumber":""}], "ftReceiptCase":4707387510509010944}';
      //s:=utf8encode(s);
      Memo1.Lines.Add(s);
      RequestBody := TStringStream.Create(s);
      try
        HTTP.Request.Accept := 'application/json';
        HTTP.Request.ContentType := 'application/json';
        HTTP.Request.ContentEncoding:= 'utf-8';

        ResponseBody := HTTP.Post('http://localhost:1201/fiskaltrust/POS/json/sign', RequestBody);

        Memo1.Lines.Add(ResponseBody);
        Memo1.Lines.Add(HTTP.ResponseText);
      finally
        RequestBody.Free;
      end;
    except
      on E: EIdHTTPProtocolException do
      begin
        Memo1.Lines.Add(E.Message);
        Memo1.Lines.Add(E.ErrorMessage);
      end;
      on E: Exception do
      begin
        Memo1.Lines.Add(E.Message);
      end;
    end;
  finally
    HTTP.Free;
  end;
end;

Ich vermute aber stark, dass sich die Json Schnittstelle geändert hat und du den obigen Code anpassen mußt. Mit der alten Version von Fiskaltrust war der obige Code lauffähig. Eigentlich habe ich mir das Json-Format von Excel-Beispiel abgeschaut. Damals war aber noch keine Rede von AccessToken und Cloud. Haben die dir ein PDF mit "Delphi Fiskaltrust Einbindung per WSDL Importer" mitgeschickt?

Gib bitte bescheid, falls du da was neues rausfindest, da es mich auch interessiert. :-D

Lg,
jus

[mjustin]

Zitat:

Zitat von TiGü (Beitrag 1360489)

Delphi-Quellcode:

var
  accesstoken: string;
  cashbox: string;
begin
  cashbox := '31ada64f-bafd-492e-ac92-867f82bb2e59';
  accesstoken := 'BJLC+VckWl36AhGwvH3sOC6bQcowHjWq7vx3wsDy42nnLcyB49vrgkxkeMvqodNtvtwaJ51HUaBs7eiX7PUyiOg=';

  HttpAddRequestHeaders(Data, PChar(cashbox), Length(cashbox), HTTP_ADDREQ_FLAG_ADD);
  HttpAddRequestHeaders(Data, PChar(accesstoken), Length(accesstoken), HTTP_ADDREQ_FLAG_ADD);
end;

Hm, also mein OnBeforePost wird zwar aufgerufen, aber weiter komme ich nicht.

Die Header haben die Form 'key: value', wie auch im verlinkten Beispiel zu sehen ist. Hier im Delphi Code fehlt der key (und der Doppelpunkt), der Server wird daher nicht den erwarteten Header im Request finden.

[mjustin]

Zitat:

Zitat von jaenicke (Beitrag 1360496)

Ich würde meinen das sollte so sein:

Zitat:

https://signaturecloud-sandbox.fiskaltrust.at

Im DNS ist dieser Server nicht eingetragen, der Server signaturcloud-sandbox.fiskaltrust.at dagegen schon.

[jaenicke]

Mit dem e im Domainnamen und den korrekten Headern mit Name und Doppelpunkt als Trennzeichen klappt es auch. Das haben wir heute Vormittag getestet, hab grad gesehen, dass er noch gar nichts dazu geschrieben hat. :)

[TiGü]

Zitat:

Zitat von mjustin (Beitrag 1360541)

Zitat:

Zitat von TiGü (Beitrag 1360489)

Delphi-Quellcode:

var
  accesstoken: string;
  cashbox: string;
begin
  cashbox := '31ada64f-bafd-492e-ac92-867f82bb2e59';
  accesstoken := 'BJLC+VckWl36AhGwvH3sOC6bQcowHjWq7vx3wsDy42nnLcyB49vrgkxkeMvqodNtvtwaJ51HUaBs7eiX7PUyiOg=';

  HttpAddRequestHeaders(Data, PChar(cashbox), Length(cashbox), HTTP_ADDREQ_FLAG_ADD);
  HttpAddRequestHeaders(Data, PChar(accesstoken), Length(accesstoken), HTTP_ADDREQ_FLAG_ADD);
end;

Hm, also mein OnBeforePost wird zwar aufgerufen, aber weiter komme ich nicht.

Die Header haben die Form 'key: value', wie auch im verlinkten Beispiel zu sehen ist. Hier im Delphi Code fehlt der key (und der Doppelpunkt), der Server wird daher nicht den erwarteten Header im Request finden.

Dank den Hinweis von Sebastian kommt kein 404-Fehler mehr.
Es hat wirklich das E gefehlt.

Auch vielen Dank an den Hinweis mit key: value.

Leider Gottes ist der Response-Stream leer, woraus ein XML geformt werden soll.
Kein Plan ob es an mir liegt oder an der Gegenseite.

Code:

First chance exception at $7433A832. Exception class EDOMParseError with message
'Ein XML-Dokument muss ein Element der obersten Ebene enthalten.

Line: 0
'.
Process FiskalTrustJournal.exe (7844)

Code:

:7433a832 KERNELBASE.RaiseException + 0x62
Xml.XMLDoc.TXMLDocument.LoadData
Xml.XMLDoc.TXMLDocument.SetActive(???)
Xml.XMLDoc.TXMLDocument.LoadFromStream(???,???)
Soap.OPToSOAPDomConv.TOPToSoapDomConvert.ProcessResponse($4F259C,$2917248,$19FE48,$2985770,$2960E40)
Soap.Rio.TRIO.DoDispatch($2985770,???,$19FE48)
Soap.Rio.TRIO.Generic($29855E8,((($5850C4, TValueDataImpl($2953394) as IValueData, 0, 0, 0, nil, nil, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, (nil, nil), nil)), (($4012CC, TValueDataImpl($2953354) as IValueData, 0, 0, 0, nil, nil, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, (nil, nil), nil))),$19FEE0)
Soap.Rio.TRIO.QueryInterface$15$ActRec.$0$Body(???,???,$19FEE0)
System.Rtti.TVirtualInterface.RawCallback($2959F28,((($5850C4, TValueDataImpl($2953394) as IValueData, 0, 0, 0, nil, nil, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, (nil, nil), nil)), (($4012CC, TValueDataImpl($2953354) as IValueData, 0, 0, 0, nil, nil, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, (nil, nil), nil))),$19FEE0)
System.Rtti.TVirtualInterface.Create$547$ActRec.$0$Body(???,???,$19FEE0)
System.Rtti.TMethodImplementation.Intercept($19FF08)

Im Eventhandler THTTPRIO.OnBeforePost greife ich den SOAPRequest: TStream ab und lade ihn in einen Stringstream und lasse ihn mir ausgeben.

Das schicke ich also zum Dienst hin:

Code:

<?xml version="1.0"?>
<SOAP-ENV:Envelope xmlns:SOAP-ENV="http://schemas.xmlsoap.org/soap/envelope/" xmlns:xsd="http://www.w3.org/2001/XMLSchema" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"><SOAP-ENV:Body><Echo xmlns="http://tempuri.org/"><message>Hello</message></Echo></SOAP-ENV:Body></SOAP-ENV:Envelope>

Es muss doch möglich sein mithilfe des importieren IPOS-Interfaces auf den externen Webservice zuzugreifen, ich will auf keinen Fall anfangen die JSON- oder XML-Request "per Hand" zu knüppeln.

[TiGü]

Zitat:

Zitat von jus (Beitrag 1360503)

Hallo TiGü,

mein Wissen zu Fiskaltrust ist nicht mehr auf den aktuellsten Stand, obwohl dies bei uns in der Firma bald wieder ansteht(spätestens am 1.April :stupid:).

Hallo jus,

habt ihr denn keine österreichischen Bestandskunden?
Bis zum April muss das ja schon alles stehen und fertig sein!!! :roteyes:

Zitat:

Zitat von jus (Beitrag 1360503)

Seit letzten Frühjahr hat sich vermutlich einiges geändert.

Ich hab irgendwann letztes Jahr im Spätsommer/Herbst angefangen und seitdem hat sich einiges geändert.

Zitat:

Zitat von jus (Beitrag 1360503)

Damals gab es zwar eine Möglichkeit, und vermutlich jetzt immer noch, dass man statt den Weg übers Interface auch direkt über das Json-Format diesen Dienst anzusprechen kann.

Das würde ich gerne vermeiden, weil im lokalen Netzwerk ich ja keine Probleme habe.
Nur das anbinden an die Cloud (für Kunden die sich keine Hardware hinstellen wollen), funktioniert nicht so wie gewünscht.

Zitat:

Zitat von jus (Beitrag 1360503)

Haben die dir ein PDF mit "Delphi Fiskaltrust Einbindung per WSDL Importer" mitgeschickt?

Die aktuelle WSDL liegt im fiskaltrust-Portal, ich kann sie auch gerne auf Wunsch hier mit anhängen.
Außerdem findest du dort eine PDF mit der Schnittstellenbeschreibung.

[mjustin]

Auf Github liegt ein .Net Projekt unter https://github.com/fiskaltrust/interface, könnte man dieses nicht in Visual Studio zu Tests verwenden? Wenn man dann mit Fiddler2 die funktionierenden Requests aufzeichnet und mit denen aus Delphi kann man den Unterschied vermutlich schnell finden.

[TiGü]

Ich hab gerade die Bestätigung bekommen, dass es per IPOS-Interface aus der WSDL nicht funktioneren kann:

Zitat:

Nein. Unsere Cloud spricht nur REST, die WSDL erstellt ein SOAP Interface. Wobei sie sonst vom Aufbau ident sind, nur die Übertragungsart ist unterschiedlich.

Will mir zwar nicht einleuchten, weil man ja auch per XML statt JSON kommunizieren kann, aber soviel verstehe ich auch nicht von Webservices.

[kretabiker]

Hallo,

ich bin positiv überrascht, dass ich hier Themeneinträge zu fiskaltrust finde - die haben mir aktuell sehr geholfen!

Anmerkung dazu: Da ich auch gerade mit fiskaltrust zu tun habe - und zwar mit der reinen Cloud-Lösung "SignatureCloud + Sorglos" seien zwei Hinweise:

- Die Kommunikation mit der RestClient-Library von Delphi 10.1 Berlin Update 2 schlug fehl mit der Fehlermeldung "415: Wrong media type". Ich schätze mal, das liegt daran, dass die RestClient-Library als Format application/x-www-form-urlencoded überträgt, was der REST-Webservice von fiskaltrust nicht mag. Das habe ich aber erst rausgefunden, nachdem ich Fiddler installiert hatte.
- Der Request-Header muss erweitert werden um die beiden Einträge "cashboxid" und "accesstoken" - diese Names müssen klein geschrieben sein, und nicht wie in der fiskaltrust-Doku als CashBoxId bzw. AccessToken, sonst gibt es wieder ne Fehlermeldung. Bei Indys THTTP geht das mit

Delphi-Quellcode:

HTTP.Request.CustomHeaders.AddValue('cashboxid', 'xxxx');

bzw.

Delphi-Quellcode:

HTTP.Request.CustomHeaders.Values['cashboxid'] := 'xxxx';

Vielleicht ersparen diese Hinweise dem einen oder anderen längere Suchen.

Viele Grüße

[TiGü]

Ich bin dazu übergegangen, alles in eine DLL (gebaut mit Delphi Berlin Update 2) zu packen und nach draußen zur EXE hin mit COM-Interfaces zu arbeiten.
Intern wird dann anhand der übergebenen Parameter unterschieden, ob es zu einen lokalen Dienst geht und mit SOAP und dem Import der WSDL gearbeitet wird ODER ob ich per REST-Komponenten und JSON arbeite.

Was mich ewig aufgehalten hat, war das automatische kodieren der Parameter. Das habe ich auch nur per Fiddler raus gefunden.
Beim Anlegen der Header am REST-Request kann man aber sagen, das nicht kodiert werden soll.

Hier ein Quellcode-Schnipsel dazu:

Delphi-Quellcode:

procedure TCloudPOS.InitRestComponents;
var
  Param: TRESTRequestParameter;
begin
  FRESTClient := TRESTClient.Create(nil);
  FRESTClient.Accept := 'application/json, text/plain; q=0.9, text/html;q=0.8,';
  FRESTClient.AcceptCharset := 'UTF-8, *;q=0.8';
  FRESTClient.ContentType := 'application/json';
  FRESTClient.HandleRedirects := True;
  FRESTClient.SynchronizedEvents := False;

  FRESTRequest := TRESTRequest.Create(nil);
  FRESTRequest.Client := FRESTClient;
  FRESTRequest.Method := rmPOST;

  Param := FRESTRequest.Params.AddHeader('accesstoken', FAccessToken);
  Param.Options := Param.Options + [TRESTRequestParameterOption.poDoNotEncode]; // <--- das hier ist der Trick!
  Param := FRESTRequest.Params.AddHeader('cashboxid', FCashBoxId);
  Param.Options := Param.Options + [TRESTRequestParameterOption.poDoNotEncode]; // <--- das hier ist der Trick!

  FRESTResponse := TRESTResponse.Create(nil);
  FRESTRequest.Response := FRESTResponse;
end;

Und natürlich die Delphi-Implementierung des JSON-Serialisieres für leere Arrays, das war auch nochmal so ein Ding für 100 graue Haare mehr:
http://www.delphipraxis.net/191908-r...yn-arrays.html

[kretabiker]

Danke für dein Update zur RestClient-Lib. Werde ich nachzuvollziehen, aber da hätte ich mich totgesucht. Das Thema hat durchaus Potential für eine Menge neuer grauer Haare :-)

[yonojoy]

Hallo TiGü,

ich habe eben mit Entsetzen deinen Post gelesen, dass WSDL vom fiskaltrust-Server nicht unterstützt wird, sondern nur vom Local-Service :-(

Den von dir beschriebenen Weg halte ich in Anbetracht der Umstände für sehr sinnvoll:

Zitat:

Zitat von TiGü (Beitrag 1363588)

Ich bin dazu übergegangen, alles in eine DLL (gebaut mit Delphi Berlin Update 2) zu packen und nach draußen zur EXE hin mit COM-Interfaces zu arbeiten.
Intern wird dann anhand der übergebenen Parameter unterschieden, ob es zu einen lokalen Dienst geht und mit SOAP und dem Import der WSDL gearbeitet wird ODER ob ich per REST-Komponenten und JSON arbeite.

Gibt es eine Chance, dass du den Code für die DLL zur Verfügung stellen würdest? Gegen $$$, versteht sich...

[TiGü]

Zitat:

Zitat von yonojoy (Beitrag 1364107)

Gibt es eine Chance, dass du den Code für die DLL zur Verfügung stellen würdest? Gegen $$$, versteht sich...

Siehe persönliche Nachricht (Benachrichtigungsglocke oben).