ClientDataset: Wie Record verschieben oder Position tauschen

[Harry Stahl]

Ich verwende ein ClientDataset mit einem TDataSource ohne spezifische Datenbank dahinter (fülle das ClientDataset mit Daten aus einer StringList).

Ich zeige die Daten mit einen DBGrid an. In der grundsätzlich nicht sortierten Ansicht (es existiert keine Index) würde ich gerne

* einen ausgwählten Datensatz eine Position nach oben oder nach unten verschieben.
* einen ausgewählten Datensatz an eine andere Postion verschieben, z.B. von Zeile 100 zu Zeile 2.

Ich habe keine vorgegebenen Funktionen dafür im ClientDataset gefunden. Oder habe ich etwas übersehen?

[jaenicke]

Der Austausch ist über den ActiveBuffer kein Problem. Du holst dir den Inhalt zum Kopieren entweder über ActiveBuffer oder mit GetCurrentRecord, dann setzt du den Zielcursor und schreibst den Inhalt in den ActiveBuffer.
Leider ist ActiveBuffer jetzt ein NativeInt obwohl es ein Pointer ist, d.h. du musst casten:
http://qc.embarcadero.com/wc/qcmain.aspx?d=115916

// EDIT:
Ich würde allerdings eher eine TFDMemTable benutzen. Die ist schneller als ein TClientDataSet. Übrigens gab es in den Beispielen zu Delphi mal ein Text-DataSet, bis XE6 war das dabei:

Zitat:

C:\Users\Public\Documents\Embarcadero\Studio\14.0\ Samples\Object Pascal\Database\TextData

Da kannst du direkt mit den Daten hinter dem Dataset arbeiten.

[Harry Stahl]

Also gibt es keine fertigen Funktionen.

So wie Du es beschreibst würde ich aber nur den anderen Datensatz mit dem aktuellen überschreiben, oder?

Müsste also den ActiveBuffer speichern, einen neuen Datensatz an der gewünschten Stelle einfügen, den mit dem Inhalt des zuvor gespeicherten ActiveBuffer überschreiben und dann zurück zu dem alten Datensatz, den wieder zum aktiven Datensatz machen und löschen?

Wie füge ich dann den alten Inhalt des ActiveBuffer in den aktuellen Inhalt des ActiveBuffers ein?

[Uwe Raabe]

Eine direkte Methode zum verschieben von Records gibt es nicht. Es bleibt also nur das Lesen und Schriben der einzelnen Felder des jeweiligen Datensatzes. Für solche Zwecke habe ich mir mal zwei Hilfsroutinen geschrieben, mit denen man den aktuellen Datensatz einfach sichern und wieder zurückschreiben kann.

Delphi-Quellcode:

type
  TRecordStore = TDictionary<string, Variant>;

  TDataSetHelper = class helper for TDataSet
  public
    procedure LoadRecord(Source: TRecordStore); 
    procedure StoreRecord(Target: TRecordStore); 
  end;

procedure TDataSetHelper.LoadRecord(Source: TRecordStore);
{ Überträgt die Daten aus dem RecordStore in den aktuellen Datensatz }
var
  fld: TField;
  fldName: string;
begin
  for fldName in Source.Keys do begin
    fld := FindField(fldName);
    if (fld <> nil) and not fld.ReadOnly then begin
      fld.Value := Source[fldName];
    end;
  end;
end;

procedure TDataSetHelper.StoreRecord(Target: TRecordStore);
{ Überträgt den aktuellen Datensatz in den RecordStore }
var
  fld: TField;
begin
  Target.Clear;
  for fld in Fields do begin
    Target.AddOrSetValue(fld.FieldName, fld.Value);
  end;
end;

Für deinen Fall könnte man das etwa so verwenden:

Delphi-Quellcode:

var
  sto: TDictionary<string, Variant>;
  sto2: TDictionary<string, Variant>;
begin
  sto := TRecordStore.Create;
  try
    sto2 := TRecordStore.Create;
    try
      ClientDataSet1.First;
      ClientDataSet1.StoreRecord(sto);
      ClientDataSet1.Last;
      ClientDataSet1.StoreRecord(sto2);
      ClientDataSet1.Edit;
      ClientDataSet1.LoadRecord(sto);
      ClientDataSet1.Post;
      ClientDataSet1.First;
      ClientDataSet1.Edit;
      ClientDataSet1.LoadRecord(sto2);
      ClientDataSet1.Post;
    finally
      sto2.Free;
    end;
  finally
    sto.Free;
  end;

[jaenicke]

Zitat:

Zitat von Uwe Raabe (Beitrag 1337550)

Eine direkte Methode zum verschieben von Records gibt es nicht. Es bleibt also nur das Lesen und Schriben der einzelnen Felder des jeweiligen Datensatzes.

Mit dem Record Buffer funktioniert es doch ohne die Felder alle extra auszulesen. Bei Blobfeldern oder ähnlichem sieht es anders aus, aber einfache Datentypen funktionieren so eigentlich problemlos und in einem Rutsch.

Zitat:

Zitat von Harry Stahl (Beitrag 1337548)

Wie füge ich dann den alten Inhalt des ActiveBuffer in den aktuellen Inhalt des ActiveBuffers ein?

Einfach an die Adresse des Pointers ActiveBuffer kopieren. Der Datensatz muss natürlich schon da sein.

[Uwe Raabe]

Zitat:

Zitat von jaenicke (Beitrag 1337551)

Mit dem Record Buffer funktioniert es doch ohne die Felder alle extra auszulesen. Bei Blobfeldern oder ähnlichem sieht es anders aus, aber einfache Datentypen funktionieren so eigentlich problemlos und in einem Rutsch.

Klar! Das war auch einfach nur als Alternative gedacht. Funktioniert nämlich auch, wenn die Record-Struktur der Zieltabelle anders ist (z.B. Felder dazu kommen oder wegfallen), die Feldnamen aber gleich bleiben. Nebenbei werden auch noch Read-Only Felder berücksichtigt (z.B. AutoInc-Felder). Im Original gibt es auch noch jeweils eine overloaded-Version, bei der man eine Feldnamen-Liste mitgeben kann, wenn man mal nur Teile des Records braucht.

[Harry Stahl]

@Uwe: Danke für die Antwort und den zur Verfügung gestellten Source-Code.

Habe mir in der Zwischenzeit eine eigene Lösung gestrickt. Wäre die nach Deiner Auffassung auch akzeptabel, oder wäre es aus einem bestimmten Grund eher zu empfehlen, auf Deine Lösung umzuschwenken?

Hier mein Ansatz (verschiebt den aktuellen Datensatz auf die Postion ToNr):

Delphi-Quellcode:

procedure MoveCurrentToRecordNo(ToNr: Integer; Dataset:TClientdataset);
var
  aField : Variant;
  OldRecNo, i: Integer;
begin
  if ToNr <= 0 then exit;
  if ToNr > DataSet.RecordCount then exit;

  // Create a variant Array
  aField := VarArrayCreate([0,DataSet.Fieldcount-1],VarVariant);

  // read the current values into the array
  for i := 0 to (DataSet.Fieldcount-1) do begin
    aField[i] := DataSet.fields[i].Value ;
  end;

  OldRecNo := Dataset.RecNo;

  if (ToNr > OldRecNo) and (ToNr < DataSet.RecordCount) then begin
    Dataset.RecNo := ToNr+1;
  end else begin
    Dataset.RecNo := ToNr;
  end;

  if ToNr = Dataset.RecordCount then Dataset.Append else Dataset.Insert;

  // Put array values into new the record
  for i := 0 to (DataSet.Fieldcount-1) do begin
    DataSet.fields[i].Value := aField[i] ;
  end;

  if ToNr < OldRecNo then begin
    Dataset.RecNo := OldRecNo+1;
  end else begin
    Dataset.RecNo := OldRecNo;
  end;

  Dataset.Delete;
  Dataset.MergeChangeLog;
  Dataset.RecNo := ToNr;
end;

[Harry Stahl]

Zitat:

Zitat von jaenicke (Beitrag 1337551)

Einfach an die Adresse des Pointers ActiveBuffer kopieren. Der Datensatz muss natürlich schon da sein.

Da hat sich mein posting gerade überschnitten. Ok, dann könnte man meinen Ansatz noch etwas vereinfachen.

[Jumpy]

Nur aus Neugier, warum würde man sowas machen? Kann man nicht einfach den Datensätzen eine Positions-ID oder so geben und diese ggf. tauschen? Oder hab ich falsch verstanden, worum es geht (die Anzeige)?

[himitsu]

Sicherheitshalber sollte man vielleicht noch groß erwähnen, dass man es so nicht machen sollte (mit Edit+Post), wenn das DataSet an einer Database hängt.
Dann würde man ja nicht nur lokal, sondern auch DB-seitig die beiden Datensätze umschreiben, durch den POST. (außer man aktiviert vorher die CachedUpdates und vergisst nicht das Rollback)
Macht sonst viel Freude, wenn da böse Trigger dran hängen und vorallem wenn man Unique-Constraints antrifft.

Ach ja, für Blobs sollten Instanz-Zeiger von TData-Nachfahren im Buffer stehen ... würde Denken, dass das Bufferkopieren auch die Blolbzeiger umkopiert.
(hoffentlich gibt TDataSet nicht die TData-Instanzen frei, deren Pointer überschrieben werden, aber so schlau ist Emba bestimmt nicht, das so einzubauen)

[p80286]

Zitat:

Zitat von Jumpy (Beitrag 1337782)

Nur aus Neugier, warum würde man sowas machen? Kann man nicht einfach den Datensätzen eine Positions-ID oder so geben und diese ggf. tauschen? Oder hab ich falsch verstanden, worum es geht (die Anzeige)?

Nun ich denke daß Harry, da er eine "einfache" Lösung bevorzugt, im Dataset herumfummelt, damit die Anzeige seinen Ansprüchen genügt. Das widerspricht zwar jeder Trennung von Daten und Anzeige aber dieser Lösungsweg ist für Datensensitive Komponenten wohl der offensichtliche.

Gruß
K-H

[himitsu]

Die Grids von Embarcadero sind Schrott (vorallem VCL) und können so einfache Dinge nicht, wie z.B. das Sortieren und Filtern ... da muß man das dann im DataSet machen (besser aber schon im Query, bevor es im DataSet landet).

[p80286]

Zitat:

Zitat von himitsu (Beitrag 1337791)

Die Grids von Embarcadero sind Schrott (vorallem VCL) und können so einfache Dinge nicht, wie z.B. das Sortieren und Filtern ... da muß man das dann im DataSet machen (besser aber schon im Query, bevor es im DataSet landet).

Würde die Anzeige in einem "normalen" Grid gemacht, und würden die Daten von der Query zum Grid mit z.B. einer Liste transportiert, dann könnte man diese Liste unterwegs so durch die Mühle drehen, daß man seine eigenen Daten nicht mehr wiedererkennt, wenn man will.

Zitat:

besser aber schon im Query

Auf jeden Fall der richtige Ort um die Daten so aufzubereiten (sortieren), wie man sie gerne von der DB bekäme. Denn für das Verarbeiten größerer Datenmengen sind DB#s im allgemeinen prädestiniert.

Gruß
K-H

[TRomano]

Himitsu hat schon Recht mit den Emba-Grids.
Die DB-Admins sehen es nicht gerne, wenn bei jedem Klick auf ein Header des DBGrid eine neue Query (mit neuer Sortierung) vom Server abgerufen wird. Das gibt Traffic ...
Dann lieber die Abfrage in einem ClientDataSet mit verschiedenen Indexen definieren und dieses dann nach jedem Header-Click mit dem entsprechenden Index "sortieren". Sollte dann alles lokal ablaufen.

[Harry Stahl]

Zitat:

Zitat von p80286 (Beitrag 1337789)

Zitat:

Zitat von Jumpy (Beitrag 1337782)

Nur aus Neugier, warum würde man sowas machen? Kann man nicht einfach den Datensätzen eine Positions-ID oder so geben und diese ggf. tauschen? Oder hab ich falsch verstanden, worum es geht (die Anzeige)?

Nun ich denke daß Harry, da er eine "einfache" Lösung bevorzugt, im Dataset herumfummelt, damit die Anzeige seinen Ansprüchen genügt. Das widerspricht zwar jeder Trennung von Daten und Anzeige aber dieser Lösungsweg ist für Datensensitive Komponenten wohl der offensichtliche.

Gruß
K-H

Wäre natürlich auch eine Möglichkeit, einen quasi User-sortierbaren Index hinzuzufügen. Diesen Index müsste ich aber auch speichern. Müsste also das Format der "Datenbank" (=einfache StringList, mit Feldtrennzeichen getrennt) ändern. Das wollte ich aber nicht aus Gründen der Rückwärtskompatibilität. Klar, könnte jetzt noch verschiedene Verrenkungen machen, um das alte Dateiformat bei der nächsten Installation des Programms durch das neue Datenformat der Datei zu ersetzten.

Aber warum sollte ich das machen, wenn es auch so geht.

Ich hatte hier in gewisser Hinsicht den Ansatz einer nicht sortierten Stringlist im Kopf, wo man ja auch per .exchange oder .move die einzelnen Zeilen / Datensätze an andere Positionen verschieben kann.

Ein Problem bezüglich Trennung von Daten und Anzeige sehe ich bei meinem Ansatz übrigens nicht. Denn es werden ja keine Daten im Grid gespeichert, ich ändere nur die unter dem Grid liegende Datenschicht, die Anzeige im Grid passt sich automatisch an.

Da es im vorliegenden Fall auch nur um eine lokale Verwaltung eines kleinen Datenbestandes geht, keine echte Datenbank dahinter liegt (benutze nur ClientDataset und Datasource) und somit auch keine Client-Server Abfragen oder ähnliches erforderlich sind, sehe ich hier kein Problem.

Lasse mich aber gerne eines Besseren belehren.

[Uwe Raabe]

Zitat:

Zitat von Harry Stahl (Beitrag 1337833)

Diesen Index müsste ich aber auch speichern. Müsste also das Format der "Datenbank" (=einfache StringList, mit Feldtrennzeichen getrennt) ändern. Das wollte ich aber nicht aus Gründen der Rückwärtskompatibilität. Klar, könnte jetzt noch verschiedene Verrenkungen machen, um das alte Dateiformat bei der nächsten Installation des Programms durch das neue Datenformat der Datei zu ersetzten.

Den Index musst du gar nicht speichern. Beim Laden der Datenbank aus der Datei wird das Indexfeld einfach hochgezählt und beim Speichern gibt die Reihenfolge des Index ja die Reihenfolge der Datensätze vor.

[Harry Stahl]

OK, ich müsste aber manuell den Index-Filter verwalten, wenn ich z.B. per Drag & Drop eine Zeile an eine andere Position verschiebe, z.B. von 100 auf 4. Oder? Das wäre wieder zusätzlich Aufwand. Würde ich ja machen, wenn ich einen zusätzlichen Nutzen bei dieser Lösung erkennen würde.

Das Speichern vom ClientDataset in die Stringlist mache übrigens wie nachfolgend. Habe ich hier evtl. typische Anfängerfehler drin, bzw. geht es einfacher?

Z.B. würde mich interessieren, muss ich immer erst den Filter ausschalten, um wieder die volle Anzahl der Records zu bekommen oder gibt es eine andere Variante, um durch den ganzen Datenbestand zu iterieren?

Delphi-Quellcode:

procedure TF_ConvertList.SaveClientDataSetToStringList;
var
  L, x, c, current: Integer; s: string;
  Filterstatus: Boolean;
begin
  current := cds1.RecNo;
  cds1.DisableControls;

  FilterStatus := cds1.Filtered;
  cds1.Filtered := false;

  try
    cds1.MergeChangeLog;

    c := cds1.FieldCount;
    slProp.Clear;

    cds1.First;

    for L := 0 to cds1.RecordCount-1 do begin
      S := '';
      for x := 0 to c-1 do begin
        if x = c-1 then begin
          S := S + cds1.Fields[x].Text;
        end else begin
          S := S + cds1.Fields[x].Text + #1;
        end;
      end;
      slProp.Add(S);
      cds1.Next;
    end;

    slProp.SaveToFile(CurrentFileName);

  finally
    cds1.EnableControls;
  end;

  cds1.Filtered := FilterStatus;
  if Current <> -1 then cds1.RecNo := Current;
end;

[Uwe Raabe]

So ist es meiner Meinung nach etwas einfacher.

Delphi-Quellcode:

var
  current: Integer;
  Filterstatus: Boolean;
  fld: TField;
  linelist: TStringList;
  datalist: TStringList;
begin
  current := cds1.RecNo;

  FilterStatus := cds1.Filtered;
  cds1.DisableControls;
  try
    cds1.Filtered := false;
    cds1.MergeChangeLog;
    datalist := TStringList.Create;
    try
      linelist := TStringList.Create;
      try
        linelist.Delimiter := #1;
        linelist.StrictDelimiter := true;
        cds1.First;
        while not cds1.Eof do begin
          linelist.Clear;
          for fld in cds1.Fields do begin
            linelist.Add(fld.Text);
          end;
          datalist.Add(linelist.DelimitedText);
          cds1.Next;
        end;
      finally
        linelist.Free;
      end;

      datalist.SaveToFile(CurrentFileName);
    finally
      datalist.Free;
    end;

  finally
    cds1.Filtered := FilterStatus;
    cds1.EnableControls;
  end;

  if Current <> -1 then cds1.RecNo := Current;
end;

[Harry Stahl]

@Uwe: Danke für die Optimierungshinweise.

Mit anderen Worten, es gibt keine einfachere Variante, um auf die Datensätze innerhalb des Clientdataset zuzugreifen. Ist jetzt kein Drama, aber wenn es eine Möglichkeit gegeben hätte, wäre es gut, das zu wissen.

[jaenicke]

Noch einfacher wäre es nur, wenn das Dateiformat nicht vorgegeben wäre. Wir benutzen einfach die integrierte Methode zum Speichern und Laden von XML Dateien. Das hat den angenehmen Nebeneffekt, dass auch die Feldinformationen schon automatisch dabei sind usw. und es ist eben nur die eine Zeile Quelltext jeweils.