Beim Click eines Buttons OnMouseDown ausführen

[GroZ]

Moin,

Ich möchte wie bei MS Paint eine Linie zeichnen. Sprich wenn ich den Button Clicke er eine Anweisung ausführt die im Event OnMouseDown steht. Wie geht das?

[TiGü]

Was hast du denn bisher an Quelltext?

[baumina]

Beim Paint wüsste ich keinen Button, der gleich eine Linie zeichnet, denn um eine Linie zu zeichnen wirst du sicherlich auf die Position des Mauszeigers verweisen, der sich bei einem Buttonklick höchstwahrscheinlich auf dem Button befindet. Deswegen befürchte ich dass da ein kleiner Denkfehler besteht.

[GroZ]

naja zu dem thema nix. Brauch ich dafür ne Schleife ?

Delphi-Quellcode:

if Button3Click do

oder gibs dafür ne andere Methode?

[GroZ]

Zitat:

Zitat von baumina (Beitrag 1314250)

Beim Paint wüsste ich keinen Button, der gleich eine Linie zeichnet, denn um eine Linie zu zeichnen wirst du sicherlich auf die Position des Mauszeigers verweisen, der sich bei einem Buttonklick höchstwahrscheinlich auf dem Button befindet. Deswegen befürchte ich dass da ein kleiner Denkfehler besteht.

Nein ich meine das wenn ich den Button clicke > und dann auf die Zeichenfläche gehe das er dann weiß dass er eine Linie zeichnen muss. Mir gehts nur darum das er weiß wenn ich den button drücke er dann nicht mehr frei hand zeichnet sondern eine linie
Hoffe es ist einigermaßen verständlich

[mkinzler]

Rufe die Methode doch dort auf

Delphi-Quellcode:

FormMouseDown( self, TMouseButton.mbLeft, [], Mouse.CursorPos.X, Mouse.CursorPos.Y);

[TiGü]

Zitat:

Zitat von GroZ (Beitrag 1314252)

Mir gehts nur darum das er weiß wenn ich den button drücke er dann nicht mehr frei hand zeichnet sondern eine linie

Wer ist denn "er"?
Versuche dir nicht nur vorzustellen was du möchtest, sondern auch das wie!

Nehme mal einen Stift in die Hand und ein Blatt Papier.
Woher weißt du jetzt, dass du eine Linie mit dem Stift auf dem Papier malen kannst?
Steht in deinen Gehirn jetzt irgendwo die Information "Habe Stift ausgewählt/in der Hand", ja oder nein?

[baumina]

Du kannst dafür statt einem normalen Button z.B. einen Speedbutton verwenden. Ein Speedbutton kann als gedrückt (down) oder nicht gedrückt dargestellt werden. In dem MouseDown kannst du dann auf SpeedButton.Down abfragen.

[GroZ]

Zitat:

Zitat von baumina (Beitrag 1314259)

Du kannst dafür statt einem normalen Button z.B. einen Speedbutton verwenden. Ein Speedbutton kann als gedrückt (down) oder nicht gedrückt dargestellt werden. In dem MouseDown kannst du dann auf SpeedButton.Down abfragen.

Sehr gut danke :)

[Jumpy]

Besser erscheint es mir aber zusätzlich dazu einen Speedbutton zu verwenden einfach sich zu merken welches Zeichenwerkzeug (Freihand,Linie,Ellipse,Auswahlrechteck,...) gerade aktiv ist. Sprich beim drücken des Buttons das Werkzeug festlegen. Nicht, dass du immer in einer Schleife alle Werkzeugbuttons durchgehst um zu sehen, welcher gerade "down" ist.

[Neutral General]

Das mit dem Speedbutton ist visuell keine schlechte Idee aber ich glaube dein Problem sind Variablen.
Beim Klick auf den Button musst du dir merken dass du ab jetzt im MouseDown Linien zeichnen willst.
Dafür kannst du dir z.B. im private Teil des Formulars eine Boolean Variable anlegen:

Delphi-Quellcode:

TForm1 = class(TForm)
  // Komponenten und so
private
  FLinieZeichnen: Boolean;
public

end;

procedure TForm1.ButtonLinieClick(Sender: TObject);
begin
  FLinieZeichnen := true;
end;

procedure TForm1.ButtonFreiHandClick(Sender: TObject);
begin
  FLinieZeichnen := false;
end;

procedure TForm1.FormMouseDown(...);
begin
  if (FLinieZeichnen) then
  begin
    // Linie
  end
  else
  begin
    // frei Hand
  end;
end;

Wenn noch mehr verschiedene Möglichkeiten dazukommen sollten, dann bietet sich ein Aufzählungstyp an:

Delphi-Quellcode:

type
  TPaintmode = (pmFreiHand, pmLinie, pmRechteck, pmKreis);

  TForm1 = class(TForm)
    // Komponenten und so
  private
    FModus: TPaintmode;
  public

  end;

procedure TForm1.ButtonLinieClick(Sender: TObject);
begin
  FModus:= pmLinie;
end;

procedure TForm1.ButtonFreiHandClick(Sender: TObject);
begin
  FModus := pmFreiHand;
end;

procedure TForm1.ButtonRechteckClick(Sender: TObject);
begin
  FModus := pmRechteck;
end;

procedure TForm1.FormMouseDown(...);
begin
  if (FModus = pmLinie) then // Eventuell ist ein case-of hier praktischer
  begin
    // Linie
  end
  else
  if (FModus = pmRechteck) then
  begin
    // Rechteck
  end
  else
  if (FModus = pmFreiHand) then
  begin
    // frei Hand
  end;
end;

Versuch das mal. Und die Sache mit der Button-Schleife bedeutet, dass du noch grundlegende Verständnisprobleme hast was das Programmieren angeht.
Das ist nicht böse gemeint - habe das gesagt, damit dir bewusst ist/wird dass du da noch (z.T.) falsch denkst und du vllt. schauen kannst dass du diese Denkweise möglichst schnell aus deinem Kopf kriegst ;)

[TiGü]

Zitat:

Zitat von Neutral General (Beitrag 1314268)

Versuch das mal. Und die Sache mit der Button-Schleife bedeutet, dass du noch grundlegende Verständnisprobleme hast was das Programmieren angeht.
Das ist nicht böse gemeint - habe das gesagt, damit dir bewusst ist/wird dass du da noch (z.T.) falsch denkst und du vllt. schauen kannst dass du diese Denkweise möglichst schnell aus deinem Kopf kriegst ;)

Nun zeige ihn doch auch gleich case-of, sonst haben wir in zwei Tagen eine Frage mit ewig langen if-then-else-Konstrukten. :shock:

[Neutral General]

Zitat:

Zitat von TiGü (Beitrag 1314273)

Zitat:

Zitat von Neutral General (Beitrag 1314268)

Versuch das mal. Und die Sache mit der Button-Schleife bedeutet, dass du noch grundlegende Verständnisprobleme hast was das Programmieren angeht.
Das ist nicht böse gemeint - habe das gesagt, damit dir bewusst ist/wird dass du da noch (z.T.) falsch denkst und du vllt. schauen kannst dass du diese Denkweise möglichst schnell aus deinem Kopf kriegst ;)

Nun zeige ihn doch auch gleich case-of, sonst haben wir in zwei Tagen eine Frage mit ewig langen if-then-else-Konstrukten. :shock:

Okay :mrgreen:

Die in diesem Fall übersichtlichere case-of Variante sähe so aus:

Delphi-Quellcode:

procedure TForm1.FormMouseDown(...);
begin
  case (FModus) of
    pmFreiHand: 
    begin
      // Frei Hand
    end;
   
    pmLinie:
    begin
      // Linie
    end;

    pmRechteck:
    begin
      // Rechteck
    end;

    else
    begin
      // Ungültiger Modus!
    end;
  end;
end;

PS: Ich konnte in all den Jahren keine Art finden ein case-of so einzurücken dass ich 100%ig damit zufrieden bin..

[Perlsau]

@Groz: Wenn du dir die existierenden Malprogramme, z.B. MsPaint, mal anschaust, dann hast du nach dem Starten einen Pfeil als Mauscursor, der anzeigt, daß derzeit keine Zeichenfunktion aktiv ist (Anmerkung: Bei MsPaint in Win7 ist immer eine Zeichenfunktion aktiviert). Dann gibt es diverse Buttons in der Toolbar, mit denen man eine Zeichenfunktion auswählen kann. Intern ist das so geregelt, daß irgend eine Variable den aktuellen Zustand vorhält, also z.B. Freihandzeichnen ist aktiv oder Linie ist aktiv oder Rechteck ist aktiv oder eben keine Funktion ist aktiv usw. Ich hab das mal vor langer Zeit so gemacht, daß keine Funktion den Wert 0 hat, Freihand den Wert 1, Linie 2, Rechteck 3 usw.

Wenn der Anwender nun mit der Maus in den Grafikbereich klickt, wird in OnMouseDown bzw. OnMouseUp der Klick ausgewertet. Dort wird dann erst einmal nachgeschaut, welche Grafikfunktion denn gerade aktiv ist, denn davon abhängig muß entsprechend auf den Klick reagiert werden. Für die veschiedenen Reaktionen schreibst du dir eine Klasse mit entsprechenden Methoden, die jeweils einen Canvas entgegennehmen, auf dem sie zeichnen.

Aber ich fürchte, das alles ist derzeit noch zu hoch für deinen Kenntnisstand ...

[Sir Rufo]

Hierfür wäre das Strategy-Pattern perfekt - Sinn und Zweck soll ja auch der Lerneffekt sein.

Damit man einen ungefähren Anhaltspunkt hat, wie man so etwas umsetzt, hier ein kleines Beispiel:

Die Form ist relativ übersichtlich:

Delphi-Quellcode:

unit Forms_MainForm;

interface

uses
  PaintStrategy,

  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.ExtCtrls, Vcl.StdCtrls;

type
  TForm1 = class( TForm )
    PaintBox1: TPaintBox;
    Button1: TButton;
    Button2: TButton;
    Button3: TButton;
    Button4: TButton;
    Panel1: TPanel;
    procedure PaintBox1MouseDown( Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer );
    procedure PaintBox1MouseMove( Sender: TObject; Shift: TShiftState; X, Y: Integer );
    procedure PaintBox1MouseUp( Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer );
    procedure PaintBox1Paint( Sender: TObject );
    procedure Button1Click( Sender: TObject );
    procedure Button2Click( Sender: TObject );
    procedure Button3Click( Sender: TObject );
    procedure Button4Click( Sender: TObject );
  private
    FNullPaintStrategy   : TPaintStrategy;
    FCurrentPaintStrategy: TPaintStrategy;
    procedure SetCurrentPaintStrategy( const Value: TPaintStrategy );
    function GetCurrentPaintStrategy: TPaintStrategy;
  protected
    property CurrentPaintStrategy: TPaintStrategy read GetCurrentPaintStrategy write SetCurrentPaintStrategy;
  public
    procedure AfterConstruction; override;
    procedure BeforeDestruction; override;

  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}
{ TForm1 }

procedure TForm1.AfterConstruction;
begin
  inherited;
  FNullPaintStrategy := TNullPaintStrategy.Create;
end;

procedure TForm1.BeforeDestruction;
begin
  FNullPaintStrategy.Free;
  CurrentPaintStrategy := nil;
  inherited;
end;

procedure TForm1.Button1Click( Sender: TObject );
begin
  CurrentPaintStrategy := nil;
end;

procedure TForm1.Button2Click( Sender: TObject );
begin
  CurrentPaintStrategy := TLinePaintStrategy.Create;
end;

procedure TForm1.Button3Click( Sender: TObject );
begin
  CurrentPaintStrategy := TRectanglePaintStrategy.Create;
end;

procedure TForm1.Button4Click( Sender: TObject );
begin
  CurrentPaintStrategy := TEllipsePaintStrategy.Create;
end;

function TForm1.GetCurrentPaintStrategy: TPaintStrategy;
begin
  if not Assigned( FCurrentPaintStrategy )
  then
    Result := FNullPaintStrategy
  else
    Result := FCurrentPaintStrategy;
end;

procedure TForm1.PaintBox1MouseDown( Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer );
begin
  CurrentPaintStrategy.MouseDown( Button, Shift, X, Y );
  PaintBox1.Invalidate;
end;

procedure TForm1.PaintBox1MouseMove( Sender: TObject; Shift: TShiftState; X, Y: Integer );
begin
  CurrentPaintStrategy.MouseMove( Shift, X, Y );
  PaintBox1.Invalidate;
end;

procedure TForm1.PaintBox1MouseUp( Sender: TObject; Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer );
begin
  CurrentPaintStrategy.MouseUp( Button, Shift, X, Y );
  PaintBox1.Invalidate;
end;

procedure TForm1.PaintBox1Paint( Sender: TObject );
begin
  CurrentPaintStrategy.PaintOn( TPaintBox( Sender ).Canvas );
end;

procedure TForm1.SetCurrentPaintStrategy( const Value: TPaintStrategy );
begin
  if Value <> FCurrentPaintStrategy
  then
    begin
      FreeAndNil( FCurrentPaintStrategy );
      FCurrentPaintStrategy := Value;
    end;
end;

end.

und hier das Strategy-Pattern:

Delphi-Quellcode:

unit PaintStrategy;

interface

uses
  System.Classes,
  System.UITypes,
  System.Types,
  Vcl.Graphics;

type
  TPaintStrategy = class abstract
  public
    procedure MouseDown(
      Button: TMouseButton;
      Shift : TShiftState;
      X, Y  : Integer ); virtual;
    procedure MouseMove(
      Shift: TShiftState;
      X, Y : Integer ); virtual;
    procedure MouseUp(
      Button: TMouseButton;
      Shift : TShiftState;
      X, Y  : Integer ); virtual;
    procedure PaintOn( const ACanvas: TCanvas ); virtual; abstract;
  end;

  TNullPaintStrategy = class( TPaintStrategy )
  public
    procedure PaintOn( const ACanvas: TCanvas ); override;
  end;

  TTwoPointPaintStratgy = class( TPaintStrategy )
  protected
    FIsActive: Boolean;
    FStart   : TPoint;
    FCurrent : TPoint;
  public
    procedure MouseDown(
      Button: TMouseButton;
      Shift : TShiftState;
      X     : Integer;
      Y     : Integer ); override;
    procedure MouseMove(
      Shift: TShiftState;
      X    : Integer;
      Y    : Integer ); override;
    procedure MouseUp(
      Button: TMouseButton;
      Shift : TShiftState;
      X     : Integer;
      Y     : Integer ); override;
  end;

  TLinePaintStrategy = class( TTwoPointPaintStratgy )
  public
    procedure PaintOn( const ACanvas: TCanvas ); override;
  end;

  TRectanglePaintStrategy = class( TTwoPointPaintStratgy )
  public
    procedure PaintOn( const ACanvas: TCanvas ); override;
  end;

  TEllipsePaintStrategy = class( TTwoPointPaintStratgy )
  public
    procedure PaintOn( const ACanvas: TCanvas ); override;
  end;

implementation

{ TPaintStrategy }

procedure TPaintStrategy.MouseDown( Button: TMouseButton; Shift: TShiftState; X, Y: Integer );
begin
end;

procedure TPaintStrategy.MouseMove( Shift: TShiftState; X, Y: Integer );
begin
end;

procedure TPaintStrategy.MouseUp( Button: TMouseButton; Shift: TShiftState; X, Y: Integer );
begin
end;

{ TTwoPointPaintStratgy }

procedure TTwoPointPaintStratgy.MouseDown(
  Button: TMouseButton;
  Shift : TShiftState;
  X, Y  : Integer );
begin
  inherited;
  FIsActive := True;
  FStart.X  := X;
  FStart.Y  := Y;
  FCurrent  := FStart;
end;

procedure TTwoPointPaintStratgy.MouseMove(
  Shift: TShiftState;
  X, Y : Integer );
begin
  inherited;
  if FIsActive
  then
    begin
      FCurrent.X := X;
      FCurrent.Y := Y;
    end;
end;

procedure TTwoPointPaintStratgy.MouseUp(
  Button: TMouseButton;
  Shift : TShiftState;
  X, Y  : Integer );
begin
  inherited;
  if FIsActive
  then
    begin
      FIsActive := False;
    end;
end;

{ TNullPaintStrategy }

procedure TNullPaintStrategy.PaintOn( const ACanvas: TCanvas );
begin
end;

{ TRectanglePaintStrategy }

procedure TRectanglePaintStrategy.PaintOn( const ACanvas: TCanvas );
begin
  inherited;
  if FIsActive
  then
    begin
      ACanvas.Rectangle( FStart.X, FStart.Y, FCurrent.X, FCurrent.Y );
    end;
end;

{ TEllipsePaintStrategy }

procedure TEllipsePaintStrategy.PaintOn( const ACanvas: TCanvas );
begin
  inherited;
  if FIsActive
  then
    begin
      ACanvas.Ellipse( FStart.X, FStart.Y, FCurrent.X, FCurrent.Y );
    end;
end;

{ TLinePaintStrategy }

procedure TLinePaintStrategy.PaintOn( const ACanvas: TCanvas );
begin
  inherited;
  if FIsActive
  then
    begin
      ACanvas.MoveTo( FStart.X, FStart.Y );
      ACanvas.LineTo( FCurrent.X, FCurrent.Y );
    end;
end;

end.

Die Strategien sind natürlich noch nicht komplett. Denn am Ende benötigt man eine Liste von Paint-Objekten, die man aber nun leicht von der jeweiligen Strategie erzeugen lassen kann.

Kompletter Source und EXE jetzt im Anhang

[Neutral General]

Zitat:

Zitat von Sir Rufo (Beitrag 1314294)

Hierfür wäre das Stretegy-Pattern perfekt - Sinn und Zweck soll ja auch der Lerneffekt sein.

Nichts gegen deinen Vorschlag oder Code, aber ich glaube GroZ mangelt es momentan noch sehr an den Grundlagen und daher glaube ich nicht dass er mit deinem Vorschlag/Code in naher Zukunft etwas sinnvolles anfangen kann :?

[Sir Rufo]

Zitat:

Zitat von Neutral General (Beitrag 1314312)

Zitat:

Zitat von Sir Rufo (Beitrag 1314294)

Hierfür wäre das Stretegy-Pattern perfekt - Sinn und Zweck soll ja auch der Lerneffekt sein.

Nichts gegen deinen Vorschlag oder Code, aber ich glaube GroZ mangelt es momentan noch sehr an den Grundlagen und daher glaube ich nicht dass er mit deinem Vorschlag/Code in naher Zukunft etwas sinnvolles anfangen kann :?

Wieso nicht? In einer anderen Frage hat er quasi etwas ähnliches auch schon gezeigt. Das hier ist einfach nur konsequent weitergedacht und simpelstes OOP.

Zudem hat er jetzt mehrere Lösungsansätze und kann sich einen aussuchen.

[GroZ]

Danke an alle ich werd mir das alles mal genauer anschauen

[nuclearping]

Zitat:

Zitat von Neutral General (Beitrag 1314279)

PS: Ich konnte in all den Jahren keine Art finden ein case-of so einzurücken dass ich 100%ig damit zufrieden bin..

Ich handhabe das so:

Delphi-Quellcode:

procedure TForm1.FormMouseDown(...);
begin
  case (FModus) of
    pmFreiHand: 
      begin
        // Frei Hand
      end;
   
    pmLinie:
      begin
        // Linie
      end;

    pmRechteck:
      begin
        // Rechteck
      end;

    else
      begin
        // Ungültiger Modus!
      end;
  end;
end;

... Sieht mir am meisten nach "Baum" aus.

[Neutral General]

Ich weiß nicht. Das eingerückte begin-end; sieht seltsam aus. Das sieht für mich genauso seltsam aus wie sowas:

Delphi-Quellcode:

procedure Test;
  begin
    
  end;

Aber direkt unter dem Wert (so wie bei mir) sieht das ganze so nach Klotz aus.