TStringGrid -[goRowSelect] wird nicht visualisiert

[hoika]

Hallo,

folgender Code schaltet goRowSelect ein oder aus (per CheckBox).
Problem:
wird RowSelect eingeschaltet, wird brav die ganze Zeile markiert,
wird es ausgeschaltet, bliebt die Zeile markiert, bis man in eine Zelle klickt.
Danach ist nur diese eine Zelle markiert, wie erwartet.
BeginUpdate/EndUpdate, Refresh, Repaint, nichts hilft.

Das sollte für das TMS-TAdvStringGrid sein, aber auch das normale TStringGrid reagiert so.

Hat jemand eine Lösung?

Danke

Delphi-Quellcode:

  if CheckBox1.Checked then
  begin
    AdvStringGrid1.Options := AdvStringGrid1.Options-[goRowSelect];
    StringGrid1.Options := StringGrid1.Options-[goRowSelect];
  end
  else
  begin
    AdvStringGrid1.Options := AdvStringGrid1.Options+[goRowSelect];
    StringGrid1.Options := StringGrid1.Options+[goRowSelect];
  end;

[Harry Stahl]

Ergänze nach dem Click einfach wie folgt:

Delphi-Quellcode:

 for L := AdvStringGrid1.ColCount-1 downto AdvStringGrid1.FixedCols
      do AdvStringGrid1.Col := L;

Das funktioniert sowohl mit dem StringGrid als auch mit dem TMS-AdvStringGrid

[Volker Z.]

Hallo,

geht das in Deine Richtung?

Delphi-Quellcode:

procedure TForm1.SetRowSelect (const Value : Boolean; const Grid : TDrawGrid);
var
  l, t : Integer;
begin
  l := Grid.Col;
  t := Grid.Row;

  Grid.Selection := TGridRect (Rect (l, t, l, t));
  if Value then
    Grid.Options := Grid.Options + [goRowSelect]
  else
    Grid.Options := Grid.Options - [goRowSelect]
end;

procedure TForm1.CheckBox1Click(Sender: TObject);
begin
  SetRowSelect (CheckBox1.Checked, StringGrid1);
  SetRowSelect (CheckBox1.Checked, AdvStringGrid1);
end;

Gruß

[EDIT]Kein roter Kasten[/EDIT]

[Captnemo]

Zitat:

Zitat von Harry Stahl (Beitrag 1306788)

Ergänze nach dem Click einfach wie folgt:

Delphi-Quellcode:

 for L := AdvStringGrid1.ColCount-1 downto AdvStringGrid1.FixedCols
      do AdvStringGrid1.Col := L;

Das funktioniert sowohl mit dem StringGrid als auch mit dem TMS-AdvStringGrid

Würde da nicht einfach nur

Delphi-Quellcode:

AdvStringGrid1.Col := AdvStringGrid1.FixedCols

reichen?
Da FixedCols ja die Anzahl der fixierten Spalten ist, würde diese Zahl als Index verwendet immer die erste Zelle innerhalb der Zeile selektieren. Warum erst von größten Spalte runterzählen?

[idefix2]

Weil col eine Property ist, bei deren Zuweisung noch andere Dinge passieren (z.B. eben markieren/Markierung löschen, wie hier gefragt - falls die Lösung so funktioniert :) )

[Captnemo]

Zitat:

Zitat von idefix2 (Beitrag 1306891)

Weil col eine Property ist, bei deren Zuweisung noch andere Dinge passieren (z.B. eben markieren/Markierung löschen, wie hier gefragt - falls die Lösung so funktioniert :) )

Soll das eine Erklärung sein, warum man nacheinander von der größten col her selektieren soll?

[hoika]

Hallo,

der Code von Harry klappt, danke!

Das hier klappt nicht, warum auch immer.
AdvStringGrid1.Col := AdvStringGrid1.FixedCols


Heiko

[idefix2]

Zitat:

Zitat von Captnemo (Beitrag 1306952)

Soll das eine Erklärung sein, warum man nacheinander von der größten col her selektieren soll?

In der anderen Richtung, von links nach rechts, würde es genauso funktionieren. Aber dann wäre eben am Ende die Zelle in der äussersten rechten Spalte selektiert und nicht die erste. Allem Anschein nach wird erst beim Selektieren einer Zelle die Zelle, die vorher selektiert war, deselektiert.

[Captnemo]

Okay, das so nicht ganz korrekt.
col:= selectiert die Column wohl nur, wenn diese nicht bereits selectiert ist (was aber bei der Option goRowSelect bereit der fall ist). Darum funktioniert das auch nicht, wenn man goRowSelect wieder auf False setzt, weil sich die Selection dabei nicht verändert, also alle Zellen der Row noch selektiert bleiben. Ist aber vorher nur eine Zelle selektiert, selektiert col:= diese sofort.

Richtig (oder richtiger) wäre dann aber

Delphi-Quellcode:

strngrd1.Selection:=TGridRect(Rect(strngrd1.FixedCols,strngrd1.Row,strngrd1.FixedCols,strngrd1.Row));

womit eben die erste Zelle der aktuellen Zeile selektiert wäre.
Kommt zwar am Ende das gleich bei raus, aber man muss nicht jeder Zelle der Zeile rückwärts selektieren.

[idefix2]

Zitat:

Zitat von Captnemo (Beitrag 1307035)

Okay, das so nicht ganz korrekt.
col:= selectiert die Column wohl nur, wenn diese nicht bereits selectiert ist (was aber bei der Option goRowSelect bereit der fall ist).

Das Problem ist ja nicht das Selektieren einer Zelle, das funktioniert, sondern, dass die bisher selektierten Zellen nicht automatisch deselektiert werden (bzw. dieses Deselektieren in der Bildschirmdarstellung nicht erkennbar ist), wenn goRowSelect ausgeschaltet wird.

Zitat:

Zitat von Captnemo (Beitrag 1307035)

Kommt zwar am Ende das gleich bei raus, aber man muss nicht jeder Zelle der Zeile rückwärts selektieren.

Ich gehe davon aus, dass du das nicht ausprobiert hast, sonst hättest du gesehen, dass das nicht der Fall ist (vermute ich einmal, ausprobiert habe ich es auch nicht). Das "rückwärts selektieren" macht man ja nicht, damit die Zellen der Reihe nach selektiert werden, sondern damit sie der Reihe nach ERKENNBAR deselektiert werden, wenn die nächste Zelle (links davon) selektiert wird.

Möglicherweise würde auch ein grid.invalidate helfen, mit dem Neuzeichnen nach Veränderungen ist das Stringgrid generell recht zurückhaltend.

[Captnemo]

Zitat:

Zitat von idefix2 (Beitrag 1307053)

Zitat:

Zitat von Captnemo (Beitrag 1307035)

Okay, das so nicht ganz korrekt.
col:= selectiert die Column wohl nur, wenn diese nicht bereits selectiert ist (was aber bei der Option goRowSelect bereit der fall ist).

Das Problem ist ja nicht das Selektieren einer Zelle, das funktioniert, sondern, dass die bisher selektierten Zellen nicht automatisch deselektiert werden (bzw. dieses Deselektieren in der Bildschirmdarstellung nicht erkennbar ist), wenn goRowSelect ausgeschaltet wird.

Dann probier das doch mal aus.
Denn

Delphi-Quellcode:

  strngrd1.Options:=strngrd1.Options-[goRowSelect];
  strngrd1.Col:=1;

führt dazu, das nach wie vor alle Zellen der Zeile selektiert sind. Lediglich die Darstellung verändert sich ein wenig. Während bei einem goRowSelect alle Zellen mit 1 gemeinsamen Rahmen versehen sind, nach diesen beiden Zeilen alle Zellen mit einem eigenen Rahmen versehen. Sind aber noch alle markiert.

Zitat:

Zitat von idefix2 (Beitrag 1307053)

Zitat:

Zitat von Captnemo (Beitrag 1307035)

Kommt zwar am Ende das gleich bei raus, aber man muss nicht jeder Zelle der Zeile rückwärts selektieren.

Ich gehe davon aus, dass du das nicht ausprobiert hast, sonst hättest du gesehen, dass das nicht der Fall ist. Das "rückwärts selektieren" macht man ja nicht, damit die Zellen der Reihe nach selektiert werden, sondern damit sie der Reihe nach ERKENNBAR deselektiert werden, wenn die nächste Zelle (links davon) selektiert wird.

Ich habe das sehr wohl ausprobiert. Aber von einem "ERKENNBAREM" delektieren ist im Ausgangspost vom TE nicht die Rede. Ihm ging es darum, dass wenn man im Code goRowSelect wieder aus den Optionen entfernt, nicht automatisch nur noch eine Zelle markiert ist, auch nicht, wenn man der Eigenschaft Col eine neuen Wert zuweist.

Hier, mach dir mal ne Form mit einen StringGrid und 4 Buttons und probier das mal aus.

Delphi-Quellcode:

unit Unit1;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, Vcl.Grids;

type
  TForm1 = class(TForm)
    strngrd1: TStringGrid;
    btn1: TButton;
    btn2: TButton;
    btn3: TButton;
    btn4: TButton;
    procedure btn4Click(Sender: TObject);
    procedure btn1Click(Sender: TObject);
    procedure btn2Click(Sender: TObject);
    procedure btn3Click(Sender: TObject);
    procedure FormShow(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.btn1Click(Sender: TObject);
begin
  strngrd1.Options:=strngrd1.Options-[goRowSelect];
  strngrd1.Col:=1;
end;

procedure TForm1.btn2Click(Sender: TObject);
begin
  strngrd1.Options:=strngrd1.Options-[goRowSelect];
  strngrd1.Col:=2;
end;

procedure TForm1.btn3Click(Sender: TObject);
begin
  strngrd1.Options:=strngrd1.Options-[goRowSelect];
  strngrd1.Col:=3;
  strngrd1.Selection:=TGridRect(Rect(strngrd1.FixedCols,strngrd1.Row,strngrd1.FixedCols,strngrd1.Row));

end;

procedure TForm1.btn4Click(Sender: TObject);
begin
  strngrd1.Options:=strngrd1.Options+[goRowSelect];
end;

procedure TForm1.FormShow(Sender: TObject);
begin
  btn4Click(self);
end;

end.

Du wirst feststellen, dass beim Klick auf btn1 außer der visuellen Veränderung, wie ich oben geschrieben habe, nicht viel passiert. Auch nicht, wenn man noch mal drauf klickt. Erst wenn man danach mal auf btn2 klickt, wird tatsächlich die 2 Zelle auch selektiert.
Wohingegen ein klick auf btn3 immer funktioniert.
btn4 selektiert dann wieder die ganze Zeile.

PS: Die visuelle Veränderung, die ich oben erwähne, kann aber bei einer anderen OS- oder Delphiversion möglichweise sich anders darstellen.