Eigene Komponente mit OnClose-Event

[Jasocul]

Ich stehe gerade auf dem Schlauch oder habe ein Brett vor dem Kopf. ganz wie ihr wollt.
Ich habe eine Komponente programmiert, die jetzt ein OnCreate- und ein OnDestroy-Ereignis bekommen soll.

Die Komponente ist abgeleitet von TComponent.
Das OnCreate funktioniert inzwischen, nachdem ich den üblichen Standard-Source in die protected Methode Loaded eingebaut (AfterConstruction war zu früh) habe:

Delphi-Quellcode:

procedure TMyComp.Loaded;
begin
  inherited;

  if Assigned(FOnCreate) then
  begin
    FOnCreate(self);
  end;

Aber OnDestroy bereitet mir noch Probleme.
BeforeDestruction ist zu spät.
Mache ich es mit Message-Handling, ist die Applikation offensichtlich schon nicht mehr verfügbar. Zumindest habe ich keinen Zugriff mehr. Ein einfaches ShowMessage wird schon nicht mehr angezeigt, obwohl fehlerfrei durch den Source gelaufen wird (Debugger).

Google spuckt auch nichts Brauchbares aus (oder ich stelle die falsche Frage).

Weiß jemand, wie es richtig geht und kann mir das verraten?

[Jasocul]

Ich habe es jetzt erstmal im BeforeDestruction eingebaut.
Damit sollte die Komponente zumindest die zur Zeit geplanten Routinen im OnDestroy abarbeiten können. Anwender-Benachrichtigungen mit ShowMessage gehen so allerdings leider nicht.

[himitsu]

Bei einer Komponente ist BeforeDestruction das Früheste, was es gibt.
Ausnahme, wenn z.B. in der Form ein Code eingebaut wurde, welcher die Komponente rechtzeitig informiert. (leider gibt es kein TComponent.BeforeClose, zu dem TComponent.Loaded und TObject.BeforeDestruction)

Bei Forms gibt es noch OnCloseQuery und OnClose, aber das wird natürlich nicht aufgerufen, wenn im Programm Form.Free azfgerufen wird, sondern nur beim Form.Close.

[Jasocul]

Danke himitsu.
Dann bin ich also doch nicht zu blöd, etwas entsprechendes zu finden. :-D

[Sir Rufo]

Man kann durchaus in so einem

Delphi-Quellcode:

OnDestroy

Event mit ShowMessage arbeiten ... wenn man etwas beachtet:

Delphi-Quellcode:

procedure TFooForm.MyComponentDestroy( Sender: TObject );
begin
  if not csDestroying in Application.ComponentState then
    ShowMessage( 'Bin dann mal weg!' );
end;

[Jasocul]

Nette Idee, funktioniert aber nicht. Ich habe es vorsichtshalber auch nochmal getestet. ShowMessage wird auf keinen Fall ausgeführt. :wink:

Eigentlich ist das Verhalten auch korrekt. Wenn die Form zerstört wird, bekommen alle Komponenten, deren Owner die Form ist, die Nachricht, sich zu zerstören. Wenn eine Komponente jetzt im eigenen Destroy einen Event-Handler bekommt, kann es zu merkwürdigen Nebeneffekten kommen. Allein der Zugriff auf andere Komponenten, die auf der Form liegen, kann zu unkontrollierbaren Zugriffsverletzungen führen. Klar kann man die Erstellungsfolge beeinflussen, aber eine Komponente sollte schon richtig gekapselt sein.
Dieses Problem kann mich natürlich auch im BeforeDestruction treffen, aber es handelt sich um eine firmeninterne Komponente, die dann entsprechend dokumentiert ist.

Das, was die Komponente in dem Ereignis machen soll, funktioniert problemlos. Nur eine Rückmeldung an den Anwender müssen wir gegebenenfalls anders lösen. Normalerweise ist die Rückmeldung aber nicht erforderlich.

[himitsu]

Zitat:

kann es zu merkwürdigen Nebeneffekten kommen.

Darum muß der auch im BeforeDestruction aufgerufen werden, denn die Form sendet erst an alle Komponenten das BeforeDestruction und danach nacheinander Free/Destroy aufgerufen.

[Jasocul]

Das mache ich ja jetzt auch:

Delphi-Quellcode:

procedure TMyComp.BeforeDestruction;
begin
  if Assigned(FOnDestroy) then
  begin
    FOnDestroy(Self);
  end;

  inherited;
end;

In der Form sieht es dann so aus:

Delphi-Quellcode:

procedure TfrmMain.MyCompDestroy(Sender: TObject);
begin
  ShowMessage('Meine Komponente OnDestroy');
end;

Das ShowMessage wird zwar durchlaufen, aber nicht ausgeführt.
Wenn ich die Variante von Sir Rufo verwende, ist die Bedingung im If nicht erfüllt. Dementsprechend ist das Verhalten dann identisch, bis auf die zusätzliche Prüfung.

[Sir Rufo]

Also ich weiß nicht, was da nicht funtionieren sollte, denn das funktioniert hier einwandfrei:

Die Komponente

Delphi-Quellcode:

unit MyComponent;

interface

uses
  System.Classes;

type
  TMyComponent = class( TComponent )
  private
    FOnDestroy: TNotifyEvent;
  protected
    procedure NotifyOnDestroy;
  public
    procedure BeforeDestruction; override;
  published
    property OnDestroy: TNotifyEvent read FOnDestroy write FOnDestroy;
  end;

implementation

{ TMyComponent }

procedure TMyComponent.BeforeDestruction;
begin
  NotifyOnDestroy( );
  inherited;

end;

procedure TMyComponent.NotifyOnDestroy;
begin
  if Assigned( FOnDestroy ) then
    FOnDestroy( Self );
end;

end.

und die Form

Delphi-Quellcode:

unit Unit2;

interface

uses
  MyComponent,

  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type
  TForm2 = class( TForm )
    Button1: TButton;
    Button2: TButton;
    procedure FormCreate( Sender: TObject );
    procedure Button1Click( Sender: TObject );
    procedure Button2Click( Sender: TObject );
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
  private
    FMyComponent: TMyComponent;
    procedure CreateMyComponent;
    procedure MyComponentDestroy( Sender: TObject );
  public
    { Public-Deklarationen }
  end;

var
  Form2: TForm2;

implementation

{$R *.dfm}

procedure TForm2.Button1Click( Sender: TObject );
begin
  FreeAndNil( FMyComponent );
end;

procedure TForm2.Button2Click( Sender: TObject );
begin
  CreateMyComponent( );
end;

procedure TForm2.CreateMyComponent;
begin
  FreeAndNil( FMyComponent );
  FMyComponent := TMyComponent.Create( Self );
  FMyComponent.OnDestroy := MyComponentDestroy;
end;

procedure TForm2.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  Action := caFree;
end;

procedure TForm2.FormCreate( Sender: TObject );
begin
  CreateMyComponent( );
end;

procedure TForm2.MyComponentDestroy( Sender: TObject );
begin
  if not( csDestroying in Application.ComponentState ) then
    ShowMessage( 'Ich bin dann mal weg!' );
end;

end.

Solange die Anwendung selber nicht beendet wird, erscheint immer die Message.

[Jasocul]

Zitat:

Zitat von Sir Rufo (Beitrag 1303782)

Solange die Anwendung selber nicht beendet wird, erscheint immer die Message.

Ah, da ist unser Missverständnis. Ich erzeuge die Instanz nicht zur Laufzeit. Dementsprechend zerstöre ich diese auch nicht selbst.
Die MainForm der Anwendung wird geschlossen und somit auch die Anwendung. Das Handle der MainForm ist dann im Event schon nicht mehr verfügbar.
Was allerdings funktioniert ist folgendes:

Delphi-Quellcode:

MessageBox(Application.Handle, 'Komponente OnDestroy', 'TMyComp', 0);

Also ist nur das Handle der MainForm ungültig. Das Handle der Anwendung ist aber noch nutzbar.

[Sir Rufo]

Zitat:

Zitat von Jasocul (Beitrag 1303783)

Zitat:

Zitat von Sir Rufo (Beitrag 1303782)

Solange die Anwendung selber nicht beendet wird, erscheint immer die Message.

Ah, da ist unser Missverständnis. Ich erzeuge die Instanz nicht zur Laufzeit. Dementsprechend zerstöre ich diese auch nicht selbst.

Das ist doch völlig egal, wer wann was erzeugt und wann wer was freigibt.

Es gibt hier nur eine Regel, die man beachten muss

Delphi-Quellcode:

  if not( csDestroying in Application.ComponentState ) then
    ShowMessage( 'Ich bin dann mal weg!' );

oder auf deutsch:

Wenn die Anwendung selber den Status Zerstören hat, dann darf ich bestimmte Dinge nicht mehr machen (wie. z.B.

Delphi-Quellcode:

ShowMessage

aufrufen).

[himitsu]

ShowMessage wird hier wohl über CreateDialogIndirect erstellt und das reagiert auf Application.Terminated und schießt sich sofort wieder, da es so eine VCL-TForm ist.
(altes Delphi oder altes Windows)

[Jasocul]

@Sir Rufo, das ist mir schon klar. Ich bin halt davon ausgegangen, dass das BeforeDestruction ausgeführt, bevor irgendwas anderes tatsächlich zerstört wird. Dies ist aber offensichtlich eine falsche Annahme gewesen. Asche auf mein Haupt.
Als Nutzer einer Komponente würde es mich allerdings schon irritieren, dass ich erst prüfen muss, ob ich in der Anwendung überhaupt ein ShowMessage aufrufen darf, wenn das gewünschte Ereignis abgearbeitet wird.

@himitsu:
Es macht zumindest den Eindruck, dass es so abläuft.

[Mikkey]

Zitat:

Zitat von Jasocul (Beitrag 1303788)

Als Nutzer einer Komponente würde es mich allerdings schon irritieren, dass ich erst prüfen muss, ob ich in der Anwendung überhaupt ein ShowMessage aufrufen darf, wenn das gewünschte Ereignis abgearbeitet wird.

Musst Du ja nicht, Du schreibst ja selbst:

Zitat:

Zitat von Jasocul (Beitrag 1303788)

Mache ich es mit Message-Handling, ist die Applikation offensichtlich schon nicht mehr verfügbar. Zumindest habe ich keinen Zugriff mehr. Ein einfaches ShowMessage wird schon nicht mehr angezeigt, obwohl fehlerfrei durch den Source gelaufen wird

Wenn das Programm beendet wird, wird eine WM_QUIT-Nachricht losgelassen, die die Haupt-Nachrichtenschleife beendet. Danach ist halt kein normales Arbeiten mit Windows mehr möglich.

[Sir Rufo]

@Jasocul

Was glaubst du wohl, wieviele Nutzer von Kettensägen überrascht geschaut haben, als sie den Ast abgesägt haben auf dem sie selber gerade saßen?

Egal was man hat (Kettensäge, Komponente, ...): Man kann es richtig oder falsch verwenden.

Und das oben geschilderte Verhalten ist kein Alleinstellungsmerkmal der Kettensäge.

[Jasocul]

@Mikkey:
Ja, ich weiß das. Aber die Kollegen, die die Komponente nutzen, sehen ja nur, dass es ein Event gibt, das sie benutzen können. Was dahinter steckt, ist erstmal uninteressant. Wenn ich in so einem Event eine Nachricht ausgeben möchte, sollte das auch passieren.

@Sir Rufo:
Natürlich muss man aufpassen, dass das, was man benutzt, auch da ist. Aber bisher war es bei mir bisher nicht erforderlich, dass ich prüfen muss, ob die Anwendung noch "existiert", in der ich den Code ablaufen lasse.

[Sir Rufo]

Zitat:

Zitat von Jasocul (Beitrag 1303792)

@Sir Rufo:
Natürlich muss man aufpassen, dass das, was man benutzt, auch da ist. Aber bisher war es bei mir bisher nicht erforderlich, dass ich prüfen muss, ob die Anwendung noch "existiert", in der ich den Code ablaufen lasse.

Aber was hat das alles mit deiner Komponente zu tun? Rein gar nichts!

Deine Komponente stellt doch nur sicher, dass der Event zum angegeben Zeitpunkt aufgerufen wird - Punkt. Und das macht die doch auch. Was willst du also noch?

Im Übrigen habe ich festgestellt, dass auch der Befehl

Delphi-Quellcode:

ÜbernehmeDieWeltherrschaft();

nicht korrekt ausgeführt wird.

Es liegt nicht in der Verantwortlichkeit der Komponente, ob der Eventhandler-Code korrekt abgearbeitet wird, sondern ausschließlich darin, dass der Event aufgerufen wird, wie vereinbart.