Leerzeichen in einem String rauslöschen

[Tails]

Hi! Kleine Beginner Frage hier. :wiejetzt:

Gibt es eine Funktion mit der ich in einem String alle Leerzeichen rauslöschen kann?

Hier ein Beispiel:

String := '12 34 56'
soll zu
String := '123456'
werden

Ich weiß ich kann mit der Funktion "Trim" bzw "Trimleft" & "Trimright"
die Leerzeichen am Anfang und Ende des Strings wegnehmen, geht es aber auch mit Leerzeichen mittendrin?

[DeddyH]

Einfachste Möglichkeit:

Delphi-Quellcode:

DeinString := StringReplace(DeinString, ' ', '', [rfReplaceAll]);

P.S.: Willkommen in der DP :dp:

[Tails]

Zitat:

Zitat von DeddyH (Beitrag 1280516)

Einfachste Möglichkeit:

Delphi-Quellcode:

DeinString := StringReplace(DeinString, ' ', '', [rfReplaceAll]);

P.S.: Willkommen in der DP :dp:

Cool danke für die Hilfe :thumb:

[himitsu]

PS: Jemand ist mal auf die saublöde Idee gekommen und hat auch noch ein ReplaceStr und ReplaceText eingeführt, welche für "ersetzte alles" irgendwie netter sind.
(einen Default-Wert für die TReplaceFlags wäre aber bestimmt besser gewesen :wall:)

Und, seit XE3, natürlich noch TStringHelper.Replace. :stupid:

[DeddyH]

Zitat:

Zitat von himitsu (Beitrag 1280527)

..., welche für "ersetzte alles" irgendwie netter sind.

Hm... http://docwiki.embarcadero.com/Libra...ils.ReplaceStr

Zitat:

Anmerkung: Das rekursive Ersetzen von Teilstrings wird nicht unterstützt. Das bedeutet Folgendes: Wenn die Ersetzung von AToText eine neue Übereinstimmung für AFromText ergibt, wird diese Übereinstimmung nicht ersetzt.

[himitsu]

Zitat:

Delphi-Quellcode:

function ReplaceStr(const AText, AFromText, AToText: string): string;
begin
  Result := AnsiReplaceStr(AText, AFromText, AToText);
end;

function AnsiReplaceStr(const AText, AFromText, AToText: string): string;
begin
  Result := StringReplace(AText, AFromText, AToText, [rfReplaceAll]);
end;

Wem glaubt man da wohl mehr? :roll:

[DeddyH]

Soll man nun jede Funktion erst im Quelltext nachlesen? Dafür ist mir meine Zeit zu schade.

[Sherlock]

Zitat:

Zitat von DeddyH (Beitrag 1280546)

Soll man nun jede Funktion erst im Quelltext nachlesen? Dafür ist mir meine Zeit zu schade.

Dafür ein +1

Sherlock

[himitsu]

Ich hatte das in der OH damals garnicht nachgelesen. Sah die Funktion nur mal in irgendeinem Code und dachte erst "hääääää, wird das nicht andersrum geschrieben?" und dort wurde es halb für "ersetzte Alles" verwendet, also hatte ich mir das so gemerkt. :oops:


Jetzt muß man sich nur noch überlegen was man repariert
* die OH umschreiben, damit dort steht, was wirklich passiert
* oder die Funktion umschreiben, damit sie das macht, was die OH behauptet :stupid:

[Der schöne Günther]

Ich schaue mittlerweile leider auch oft in den Quelltext. Die Hilfe hat mich schon zu oft belogen. RAD at its best.

[p80286]

Könntet Ihr mich mal aufklären worum es geht? in den Beiträgen sehe ich kein anders herum und abgesehen von der "replace"-Inflation sehe ich da eigentlich kein Problem.

Was das "rekursive Ersetzen" angeht, vor ein par Jahren hab ich hier gelesen

Delphi-Quellcode:

while position(FromText,text)>0 do
  replace(Text,FromText,ToText)

(ersetze postion und replace durch die richtigen/benötigten Routinen)

daran halte ich mich und hab bisher keine Probleme damit gehabt.

Gruß
K-H

[himitsu]

Delphi-Quellcode:

while position(FromText,text)>0 do
  replace(Text,FromText,ToText)

Bei Sowas muß man aufpassen, wenn der Suchtext ganz oder Teilweise im Ersetzungstext mit drin ist. > endlosscheife oder unerwartete Ereigebnisse.

Code:

'________'
'__' -> '*_'

'*_*_*_*_' <- das mat StringReplace/ReplaceStr
'*******_' <- das macht deine Schleife

Soein Ersetzungscode kann halt voll nicht das machen, was er soll.
[DELPHI] macht aus meinem String

Delphi-Quellcode:

'        '

mit 8 Leerzeichen nur ein Leerzeichen, da es, abgesehn von Einrückungsleerzeichen, einfach so alles löscht/kürzt.
Und [CODE] macht aus den 8 Leerzeichen einfach so 7 (bzw aus den mit Zwei wird einer), weil es die Platzhalter falsch verteilt.
(drum hab ich jetzt noch schnell die Leerzeichen durch _ ersetzt. :wall:)

[p80286]

Zitat:

Zitat von himitsu (Beitrag 1280618)

Delphi-Quellcode:

while position(FromText,text)>0 do
  replace(Text,FromText,ToText)

Bei Sowas muß man aufpassen, wenn der Suchtext ganz oder Teilweise im Ersetzungstext mit drin ist. > endlosscheife oder unerwartete Ereigebnisse.

So ad hoc:
zum einen kann eine unvollständige Ersetzung durchaus gewollt sein, dann setzt man diese Schleife natürlich nicht ein, zum anderen sollte der Programmierer

Zitat:

Suchtext ganz oder Teilweise im Ersetzungstext

erkennen können und sich dann vorher ein paar Gedanken machen.

Aber vielleicht ganz gut, daß Du das nochmal ins Bewußtsein rückst.

Gruß
K-H

[Dejan Vu]

Falls es noch jemanden interessiert: Ich mach das in einer Schleife (bzw. würde es bei langen Strings so machen):

Delphi-Quellcode:

Function ZapSpaces (Const s: String) : String;
Begin
  Result := '';
  for c in s do if c<>' ' then Result:=Result+c;
End;

Wegen FastMM4 als Speichermanager auch schnell genug. Meiner Meinung nach schneller als ReplaceString.

[Der schöne Günther]

Also das wäre mein Ansatz:

Delphi-Quellcode:

uses System.SysUtils, System.Character;

type
   IStringManipulator<T> = interface
   ['{F898C39A-F08E-452B-8948-343AC92C77A3}']
      function manipulate(const what: String): T;
   end;

   TSpaceZapper = class(TInterfacedObject, IStringManipulator<String>)
      protected var
         stringBuilder: TStringBuilder;
         characterPredicate: TPredicate<Char>;


      public
         constructor Create();
         destructor Destroy(); override;

         // IStringManipulator<String>
         function manipulate(const what: String): String;
    end;

constructor TSpaceZapper.Create();
begin
   inherited Create();
   stringBuilder := TStringBuilder.Create();

   characterPredicate :=
      function(item: Char): Boolean
      begin
         Result := not item.IsWhiteSpace();
      end;
end;

destructor TSpaceZapper.Destroy();
begin
   stringBuilder.Destroy();
   inherited;
end;

function TSpaceZapper.manipulate(const what: String): String;
var
   containedChar: Char;
begin
   stringBuilder.Clear();

   for containedChar in what do
      if characterPredicate(containedChar) then
         stringBuilder.Append(containedChar);

   Result := stringBuilder.ToString();
end;

Ich finde meinen Ansatz total toll, denn er ist total einfach zu benutzen:

Delphi-Quellcode:

var
   myElaborateStringManipulator: IStringManipulator<String>;
begin
   try
      myElaborateStringManipulator := TSpaceZapper.Create();
      WriteLn( myElaborateStringManipulator.manipulate('Hallo Welt ').QuotedString() );
   except
      on E: Exception do Writeln(E.ClassName, ': ', E.Message);
   end;
end.

Nein, ernsthaft. Ich wollte nur einwerfen dass ein Vergleich mit Anführungszeichen, Leertaste drücken, Anführungszeichen eine Menge anderer "Whitespaces" nicht erwischt.

[Dejan Vu]

Na dann haut man da ein "in [' ',#8,#13,#10]" rein. Im Titel steht übrigens Leerzeichen, was meiner bescheidenen Ansicht nach nicht mit weißer Leere übersetzt wird (oder weißen Welträumen) oder.. Und auch sonst taucht dieses Stichwort im Thread nur sehr spärlich auf. Um es mal übertrieben auszudrücken.