Rekursive Dateisuche lässt Unterverzeichnisse aus

[Ykcim]

Hallo Zusammen,

mit diesem Code, den ich übernommen, nachvollzogen und angepasst habe, möchte ich alle Dateien, in denen ein Teilstring ("4711") vorkommt, in einem StringGrid mit dem jeweiligen Pfad ausgeben. Dabei sollen alle Unterverzeichnisse mit überprüft und die Dateien und Pfade ebenfalls ausgegeben werden.

Delphi-Quellcode:

function FileSearches(const PathName, FileName : string; const InDir : boolean): TRows; // InDir gibt an ob Unterverzeichnisse mit durchsucht werden sollen
var   Rec : TSearchRec;
      Path : string;
begin
   setlength(Result,2,0);
   Path := IncludeTrailingBackslash(PathName);
   if FindFirst(Path + '*'+FileName+'*', faAnyFile and not faDirectory, Rec) = 0 then
      try
         repeat
            SetLength(Result,2,Length(Result[0])+1);
            Result[0,Length(Result[0])-1]:=Path;
            Result[1,Length(Result[0])-1]:=Rec.Name;
         until FindNext(Rec) <> 0;
      finally
         FindClose(Rec);
      end;
   If not InDir then Exit;
   if FindFirst(Path + '*.*', faDirectory, Rec) = 0 then
      try
         repeat
            if (Rec.Attr in [faDirectory]) and (Rec.Name<>'.') and (Rec.Name<>'..') then //An dieser Stelle werden die Bedingungen nicht erfüllt, obwohl Unterverzeichnisse und weitere Treffer vorhanden sind
            FileSearches(Path + Rec.Name, FileName, True);
         until FindNext(Rec) <> 0;
      finally
         FindClose(Rec);
      end;
end;

Ich habe verschiedene Möglichkeiten versucht, aber es wird immer nur im Hauptverzeichnis gesucht und nicht in darin enthaltenen Unterverzeichnissen. Kann mir jemand weiterhelfen?

Vielen Dank
Patrick

[DeddyH]

Zitat:

Delphi-Quellcode:

if (Rec.Attr in [faDirectory])

Müsste das nicht so lauten?

Delphi-Quellcode:

if (Rec.Attr and faDirectory = faDirectory)

[Sir Rufo]

Zitat:

Zitat von DeddyH (Beitrag 1278064)

Zitat:

Delphi-Quellcode:

if (Rec.Attr in [faDirectory])

Müsste das nicht so lauten?

Delphi-Quellcode:

if (Rec.Attr and faDirectory = faDirectory)

oder einfach andersherum

Delphi-Quellcode:

if ( faDirectory in Rec.Attr )

sollte auch gehen :)

Was sagt die Doku zu TSearchRec? Nö, geht doch nicht, ist nämlich kein Set ... sondern nur ein Integer

[DeddyH]

Japp, nur so wie ursprünglich klappt es eben nicht, wenn das Verzeichnis noch weitere Attribute hat.

[Der schöne Günther]

Warum so kompliziert?

Delphi-Quellcode:

uses System.IOUtils;

procedure listFiles();
const
   searchPattern: String = '*4711*';
var
   fileName: String;
begin
   for fileName in TDirectory.GetFiles('x:\', searchPattern, TSearchOption.soAllDirectories) do
      WriteLn(fileName);
end;

[Sir Rufo]

Zitat:

Zitat von Der schöne Günther (Beitrag 1278068)

Warum so kompliziert?

Delphi-Quellcode:

procedure listFiles();
const
   searchPattern: String = '*4711*';
var
   fileName: String;
begin
   for fileName in TDirectory.GetFiles('x:\', searchPattern, TSearchOption.soAllDirectories) do
      WriteLn(fileName);
end;

Weil das ja jeder einfach so machen könnte ;)

[Ykcim]

Hallo,

erst mal vielen Dank für die schnellen Antworten!!!

Delphi-Quellcode:

if (Rec.Attr and faDirectory = faDirectory)

Ich habe es ausprobiert, aber leider kein Erfolg.
faDirector=16
Rec.Attr=48 Ich weiß beide Werte leider nicht zu interpretieren.

Delphi-Quellcode:

if ( faDirectory in Rec.Attr )

hier kommt die Fehlermeldung

Delphi-Quellcode:

E2015 Operator ist auf diesen Operandentyp nicht anwendbar

Gruß Patrick

[DeddyH]

Würde aber passen.

Code:

00110000 //Rec.Attr
00010000 //faDirectory
========
00010000 //faDirectory

[Sir Rufo]

Das Problem sind die fehlenden Klammern ;)

[Ykcim]

@Sir Rufo
Jepp, die Fehlermeldung ist weg, aber ich das Ergebnis ist das gleiche - es wird nur die Datei in dem Hauptverzeichnis angezeigt...

Ich weiß nicht ob es wichtig ist, aber der Pfad sieht so aus:
\\172.30.44.120\Zeichnungen\
Und dann gibt es halt Unterverzeichnisse
\\172.30.44.120\Zeichnungen\A\
\\172.30.44.120\Zeichnungen\Neu\

Ich versuche gerade den Gedanken vom schönen Günter umzusetzen...

Vielen Dank
Patrick

[Sir Rufo]

Ähm meine Aussage bezog sich auf den Code-Schnipsel von DeddyH. Meinen Code-Schnipsel habe ich in meinem Beitrag schon für ungültig erklärt.

Zitat:

Zitat von Sir Rufo (Beitrag 1278065)

Zitat:

Zitat von DeddyH (Beitrag 1278064)

Zitat:

Delphi-Quellcode:

if (Rec.Attr in [faDirectory])

Müsste das nicht so lauten?

Delphi-Quellcode:

if (Rec.Attr and faDirectory = faDirectory)

oder einfach andersherum

Delphi-Quellcode:

if ( faDirectory in Rec.Attr )

sollte auch gehen :)

Was sagt die Doku zu TSearchRec? Nö, geht doch nicht, ist nämlich kein Set ... sondern nur ein Integer

So sollte es funktionieren

Delphi-Quellcode:

if ( ( Rec.Attr and faDirectory ) = faDirectory)

[DeddyH]

Was sollen zusätzliche Klammern denn bewirken (außer, dass der Programmierer es evtl. etwas besser versteht)?

[Perlsau]

Bei mir funktioniert dieser Code schon seit vielen Jahren in zahlreichen Anwendungen absolut zuverlässig:

Delphi-Quellcode:

procedure GetFilesInDirectory(ADirectory: string; AMask: String; AList, DatList, GrossList: TStrings; ARekursiv: Boolean);
var
  SR    : TSearchRec;
  Datum : TDateTime;

begin
   ADirectory := BackShlashAmEnde(ADirectory);

   if (SysUtils.FindFirst(ADirectory + AMask,faAnyFile and not faDirectory,SR) = 0) then
   begin
      repeat
          if (SR.Name<>'.') AND (SR.Name<>'..') AND (SR.Attr<>faDirectory) then
          begin
             AList.Add(ADirectory+SR.Name);
             Datum := FileDateToDateTime(Sr.Time);
             DatList.Add(DateToStr(Datum));
             GrossList.Add(IntToStr(Sr.size));
          end;
      until SysUtils.FindNext(SR)<>0;
      SysUtils.FindClose(SR);
   end;

   if ARekursiv then
      if (SysUtils.FindFirst(ADirectory+'*.*',faDirectory,SR)=0) then
      begin
         repeat
             if (SR.Name<>'.') AND (SR.Name<>'..') then
                GetFilesInDirectory(ADirectory+SR.Name,AMask,AList,DatList,GrossList,True);
         until FindNext(SR)<>0;
         SysUtils.FindClose(SR);
      end;
end;

In ADirectory wird das zu durchsuchende Verzeichnis angegeben.
AMask enthält die Suchmaske.
AList liefert die Dateiliste zurück.
DatList liefert die zugehörigen Datei-Datumwerte zurück.
GrossList liefert die zugehörigen Datei-Größen zurück.
ARekursiv gibt an, ob Unterverzeichnisse durchsucht werden sollen.

[DeddyH]

Kann ich mir nicht vorstellen, denn

Zitat:

Delphi-Quellcode:

SR.Attr<>faDirectory

ist definitiv falsch. faDirectory muss ja nicht als einziges Attribut gesetzt sein, es können ja noch weitere vorhanden sein (Archiv, komprimiert, versteckt, etc.)

[Dalai]

Ist schon jemandem aufgefallen, dass

Delphi-Quellcode:

FileSearches

eine

Delphi-Quellcode:

function

mit dem Rückgabetyp

Delphi-Quellcode:

TRows

ist, dessen Ergebnis für die Unterverzeichnisse weder zugewiesen noch ausgewertet wird? Das dürfte das Problem erklären. Oder verstehe ich die Rekursion falsch?

MfG Dalai

[DeddyH]

Nö, aber ich dachte, dass er mittels Debugger die gekennzeichnete Zeile als fehlerhaft ausgemacht hat. Das hat mit dem Funktionsergebnis erstmal nichts zu tun, obwohl das natürlich auch vom Compiler bemängelt werden sollte.

[Ykcim]

Hallo Zusammen,

vielen Dank für die zahlreiche Unterstützung!!!

So klappt es jetzt:

Delphi-Quellcode:

function listFiles(Pfad, FileName: string): TRows;
var   I: integer;
begin
   filename:='*'+fileName+'*';
   setlength(Result,1,0);
    for fileName in TDirectory.GetFiles(Pfad, FileName, TSearchOption.soAllDirectories) do begin
      SetLength(Result,2,Length(Result[0])+1);
      Result[0,Length(Result[0])-1]:=FileName;
   end;
end;

Ich hätte erwähnen sollen, dass TRows ein Array of Array of string ist.

@Sir Rufo
Ich hatte die eckigen Klammern vergessen, wodurch die Fehlermeldung ausgelöst wurde.

Vielen Dank nochmal
Patrick

[himitsu]

Zitat:

Zitat von Sir Rufo (Beitrag 1278072)

Das Problem sind die fehlenden Klammern ;)

Bei was?

Wenn hier

Delphi-Quellcode:

if (Rec.Attr and faDirectory = faDirectory)

:
AND wir immer vor = aufgelöst, also passt es.

Da aber alle Dateiattribute nur aus einem Bit bestehen, kann man das noch kürzen

Delphi-Quellcode:

if (Rec.Attr and faDirectory <> 0)

Das mit dem IN klappt nicht, da Attr ein Integer und kein Set ist, außerdem sind die fa-Konstanten Bit-Masken und keine Indize.
(gut, man könnte den Integer in ein

Delphi-Quellcode:

set of 0..31

, aber dann ist noch das Problem mit den Konstanten, also wenn dann lieber direkt in ein TAttributeSet casten und als Property in TSearchRec rein)

[DeddyH]

Zitat:

Zitat von himitsu (Beitrag 1278084)

Wenn hier

Delphi-Quellcode:

if (Rec.Attr and faDirectory = faDirectory)

:
AND wir immer vor = aufgelöst, also passt es.

Muss ja so sein, denn dies

Delphi-Quellcode:

if (Rec.Attr and (faDirectory = faDirectory))

wird gar nicht kompiliert, dazu müsste man schon explizit Rec.Attr nach Boolean casten, dann ist man aber auch selbst Schuld, wenn es nicht stimmt.

Zitat:

Zitat von himitsu (Beitrag 1278084)

Da aber alle Dateiattribute nur aus einem Bit bestehen, kann man das noch kürzen

Delphi-Quellcode:

if (Rec.Attr and faDirectory <> 0)

Kann man, hat aber keinen Mehrwert. Wozu soll man sich Gedanken machen (oder nachsehen), ob wirklich alle Attribute 2er-Potenzen sind? Da bleib ich lieber bei der gezeigten Schreibweise, das passt immer, selbst wenn irgendwann mal ein mehrbittiges Attribut hinzukommen sollte.

[Sir Rufo]

@himitsu

Ja, Ja ... :)

@DeddyH

Der Code von Perusau funktioniert, denn der Such-Filter steht auf

Delphi-Quellcode:

faAnyFile and not faDirectory

.
Allerdings könnte das hier

Delphi-Quellcode:

if (SR.Name<>'.') AND (SR.Name<>'..') AND (SR.Attr<>faDirectory) then

direkt wieder raus, der dürfte nie anschlagen ;)

[Der schöne Günther]

Zitat:

Zitat von Ykcim (Beitrag 1278083)

So klappt es jetzt:

Pascal-Leute sind ja immer wahre Performance-Freaks, deshalb noch ein paar Hinweise:

• Die Variable "i" wird nicht verwendet
• Der Parameter "Pfad" wird nicht geändert und kann mit "const" markiert werden
• Das ständige SetLength sorgt nicht nur dafür dass das Array ständig im Speicher kopiert und hin und her wandert, sondern ist auch total unverständlich zu lesen. Speicher dir doch einmal das was GetFiles(..) zurückgibt in einem StringArray und stecke das dann anschließend in dein Result.

Ich habe SetLength(..) noch nie mit zwei Parametern gesehen. Ich habe auch, glaube ich, noch nie mehrdimensionale Arrays benutzt. Deshalb kann es auch sein, dass ich die Intention dahinter nicht verstehe.



PS: So würde ich es schreiben

Delphi-Quellcode:

uses
  System.SysUtils,
  System.IOUtils,
  System.Types;

type TRows = array of array of string;

function listFiles(
   const Pfad: String;
   FileName: string
): TRows;
var
   fileNames:       TStringDynArray;
   fileNameIndex:   Integer;
begin
   filename := '*' + fileName + '*';
   fileNames := TDirectory.GetFiles(Pfad, FileName, TSearchOption.soAllDirectories);

   SetLength(Result, 2);
   SetLength( Result[0], Length(fileNames) );
   SetLength( Result[1], Length(fileNames) );

   for fileNameIndex := Low(fileNames) to High(fileNames) do
      Result[0, fileNameIndex] := fileNames[fileNameIndex];
end;

[DeddyH]

@Sir Rufo: ich hab mich nur an Threads wie diesen hier erinnert, deshalb traue ich dem Attributfilter nicht so recht über den Weg.

[Dejan Vu]

Zitat:

Zitat von Der schöne Günther (Beitrag 1278093)

..Das ständige SetLength sorgt nicht nur dafür dass das Array ständig im Speicher kopiert und hin und her wandert...

Nee. Mach dir keinen Kopp, das ist hochoptimiert. Aber der Rest ist 100% richtig ergo: Weg. Nur eine Performancebremse ist das nicht mehr, dank FastMem.