Array aus Labeln mit Events

[wovo]

Hallo!
Ich möchte ein Array aus Labeln zur Designzeit erzeugen.
Bisher habe ich dazu u.a.:

Code:

var
  Form1: TForm1;
  labs : array[1..4,1..12] of TLabel;

procedure TForm1.FormCreate(Sender: TObject);
var i,j : integer;
begin
 for i := 1 to 4 do
  for j := 1 to 12 do
  begin
   labs[i,j]         := TLabel.Create(Form1);
   labs[i,j].Parent  := Form1;
   labs[i,j].Left    := 144+(i-1)*48;
   labs[i,j].Top     := 160+(j-1)*48;
   labs[i,j].visible := true;
   labs[i,j].color   := clGray;
   labs[i,j].caption := '     ';
   labs[i,j].font.size := 15;
  end;

Das funktioniert.
Nun möchte ich(per for-Schleifen)jedem dieser Label zur Designzeit
einen Event zuordnen der Art
OnClick labs[i,j]Click ,
damit so etwas erzeugt wird wie z.B.

Code:

procedure TForm1.Labs[1,1]Click(Sender: TObject);
begin
 if click = 3 then labs[1,1.color := clRed;

Geht so etwas in Delphi?

Dank für Hilfe im voraus!
wovo

[Sir Rufo]

Willkommen in der DP.

Du sprichst hier aber von RunTime und nicht von DesignTime ;)

Das Array sollte ein Feld der Form sein.
Der Owner/Parent sollte nicht

Delphi-Quellcode:

Form1

sondern

Delphi-Quellcode:

Self

sein - das ist sicherer, falls du mal eine weitere Instanz dieser Form erzeugen möchtest.

Delphi-Quellcode:

type
  TForm1 = class( TForm )
    ...
  private
    FLabels : array[1..4,1..12] of TLabel;
  protected
    procedure LabelsClick( Sender : TObject );
  public
    ...
  end;

var
  Form1: TForm1;

procedure TForm1.FormCreate(Sender: TObject);
var 
  i,j : integer;
  LLabel : TLabel;
begin
 for i := 1 to 4 do
   for j := 1 to 12 do
   begin
     LLabel        := TLabel.Create(Self);

     LLabel.Parent := Self;
     LLabel.Left   := 144+(i-1)*48;
     LLabel.Top    := 160+(j-1)*48;
     LLabel.visible := true;
     LLabel.color  := clGray;
     LLabel.caption := '    '; 
     LLabel.font.size := 15;
     
     LLabel.OnClick := LabelsClick; // <- Event zuweisen

     FLabels[i,j] := LLabel;
  end; 
end;

procedure TForm1.LabelsClick( Sender : TObject );
var
  LLabel : TLabel;
begin
  // In Sender ist die Referenz zum Label enthalten, also brauchen wir nur casten
  LLabel := Sender as TLabel;
  LLabel.Font := clRed;
end;

Nur die Herkunft deiner Variablen

Delphi-Quellcode:

click

bei

Delphi-Quellcode:

if click = 3 then

ist mir schleierhaft ...

[himitsu]

Du weißt aber wozu der Sender-Parameter da ist?

[edit]
Zu langsam, aber die DP hat mir eh nicht gesagt, daß es schon eine Antwort gibt.

Und bezüglich des Form1 ... du solltest diese globale Variable besser ignorieren und niemals verwenden, vorallem nicht aus der Instanz raus, welche "vermutlich" darin gespeichert wurde.

[wovo]

Dank für die schnellen Antworten!

Da ich nicht sehr firm bin in Delphi (man merkt es),
habe ich mich bestimmt unklar ausgedrückt :-(

Die Lables in dem Array sollen in der Tat zur Laufzeit erzeugt werden.
Die Frage nach click ist verständlich. Ursprungscode war:

Code:

procedure TForm1.Label10Click(Sender: TObject);
begin
 if click = 3 then label10.color := clRed;
 {bei weiteren Clicks wird zyklisch eine andere Farbe angezeigt}

Bzgl. LLabel.OnClick := LabelsClick; // <- Event zuweisen
muss ich noch an der Umsetzung in mein Programm arbeiten.
Die Anweisung

Code:

 protected
    procedure LabelsClick( Sender : TObject );

erzeugt bei mir die Fehlermeldung

Code:

[Error] Unit1.pas(33): Unsatisfied forward or external declaration: 'TForm1.LabelsClick'

Aber ich arbeite weiter daran.
Gruß wovo

[Sir Rufo]

Kleiner Fehler in meinem Source :)

Habe ich gerade behoben, dann sollte auch der Fehler nicht mehr kommen

[Sir Rufo]

Das mit dieser zyklischen Farbzuweisung:

Ist der Zyklus für alle Labels oder pro Label?

Hier mal ein Beispiel für alle Labels

Delphi-Quellcode:

type
  TForm1 = class( TForm )
    ...
  private
    FLabelClickCount : Integer;
    FLabels : array[1..4,1..12] of TLabel;
  protected
    procedure LabelsClick( Sender : TObject );
  public
    ...
  end;

var
  Form1: TForm1;

procedure TForm1.FormCreate(Sender: TObject);
var 
  i,j : integer;
  LLabel : TLabel;
begin
 for i := 1 to 4 do
   for j := 1 to 12 do
   begin
     LLabel := TLabel.Create(Self);

     LLabel.Parent := Self;
     LLabel.Left := 144+(i-1)*48;
     LLabel.Top := 160+(j-1)*48;
     LLabel.visible := true;
     LLabel.color := clGray;
     LLabel.caption := ' '; 
     LLabel.font.size := 15;
     
     LLabel.OnClick := LabelsClick; // <- Event zuweisen

     FLabels[i,j] := LLabel;
  end; 
end;

procedure TForm1.LabelsClick( Sender : TObject );
const
  CLabelColors : array[0..3] of TColor = (clBlack, clBlue, clGreen, clRed);
var
  LLabel : TLabel;
begin
  // In Sender ist die Referenz zum Label enthalten, also brauchen wir nur casten
  LLabel := Sender as TLabel;

  // Jeden Klick mitzählen
  Inc( FlabelClickCount ); 

  // Abhängig von der Anzahl der Klicks eine Farbe aus dem Zyklus zuweisen
  LLabel.Font := CLabelColors[FLabelClickCount mod 4];
end;

[wovo]

Dank für die schnelle Hilfe!

Der Zyclus soll für jedes Label einzeln gelten, wenn es angelickt wird.
Jedes Label soll also durch einmaliges oder mehrmaliges Klicken eine bestimmte eigene Farbe bekommen.

Die von mir angegebene Fehlermeldung kommt leider immer noch.
Ich arbeite mit Delphi4 . Brauche ich evtl. eine neure Version?

Gruß wovo

[Sir Rufo]

Stell doch mal den gesamten Quelltext der form hier rein, dann kann man da auch etwas sehen

[sx2008]

Zitat:

Zitat von wovo (Beitrag 1234330)

Ich möchte ein Array aus Labeln zur Designzeit erzeugen.

Wozu brauchst du das?
Ich wette mit dir dass es einfachere und bessere Lösungen gibt an die du bisher nur nicht gedacht hast.

[wovo]

Hallo!
@Sir Rufo : Es sollen 48 einzele Label erzeugt werden mit 48 einzelnen Events. Später kommen noch mal 48 weitere ähnliche Label hinzu.
Das kann ich natürlich im Design einzeln erstellen. Funktioniert auch wie gewüscht. Ist nur nicht nur mühsam sondern auch recht unelegant.

Code:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  ExtCtrls, StdCtrls, Buttons;

type
  TForm1 = class(TForm)
    Label10: TLabel;
    Label1: TLabel;
    Label2: TLabel;
    Label3: TLabel;
    Label4: TLabel;
    Label5: TLabel;
    Label6: TLabel;
    Label7: TLabel;
    Label8: TLabel;
    Label11: TLabel;
    Label12: TLabel;
    Label13: TLabel;

    procedure FormCreate(Sender: TObject);
    procedure Label10Click(Sender: TObject);
    procedure Label11Click(Sender: TObject);
    procedure Label12Click(Sender: TObject);
    procedure Label13Click(Sender: TObject);

  private
    { Private declarations }
{  protected
    procedure LabelsClick( Sender : TObject );} <== Hier kommt die
                                                    Fehlermeldung
  public
    { Public declarations }
    click : integer
  end;

type
  ptyp = record
          pcol : integer;
          ppos : integer;
         end;
  atyp = record
          apos : integer;
          alab : TLabel
         end;
var
  Form1: TForm1;

  ziel  : array[1..4]  of ptyp;
  probe : array[1..12] of ptyp;
  col   : array[1..6]  of integer;

  plab   : array[1..4,1..12] of atyp;
  labs : array[1..4,1..12] of TLabel;

implementation

{$R *.DFM}

procedure TForm1.FormCreate(Sender: TObject);
var i,j : integer;
begin
 for i := 1 to 4 do
  for j := 1 to 12 do
  begin
   labs[i,j]         := TLabel.Create(Form1);
   labs[i,j].Parent  := self;
   labs[i,j].Left    := 144+(i-1)*48;
   labs[i,j].Top     := 160+(j-1)*48;
   labs[i,j].visible := true;
   labs[i,j].color   := clGray;
   labs[i,j].caption := '     ';
   labs[i,j].font.size := 15;

{   labs[i,j].OnClick := labels.click;}
  end;

 label1.color := clBlack;
 label2.color := clWhite;
 label3.color := clRed;
 label4.color := clYellow;
 label5.color := clLime;
 label6.color := clAqua;
 label7.color := clBlue;
 label8.color := clFuchsia;


 click     := 3;
end;

procedure TForm1.Label10Click(Sender: TObject);
begin
 if click = 3 then label10.color := clRed;
 if click = 4 then label10.color := clYellow;
 if click = 5 then label10.color := clLime;
 if click = 6 then label10.color := clAqua;
 if click = 7 then label10.color := clBlue;
 if click = 8 then label10.color := clFuchsia;
 inc(click);
 If click > 8 then click := 3
end;
procedure TForm1.Label11Click(Sender: TObject);
begin
 if click = 3 then label11.color := clRed;
 if click = 4 then label11.color := clYellow;
 if click = 5 then label11.color := clLime;
 if click = 6 then label11.color := clAqua;
 if click = 7 then label11.color := clBlue;
 if click = 8 then label11.color := clFuchsia;
 inc(click);
 If click > 8 then click := 3
end;
procedure TForm1.Label12Click(Sender: TObject);
begin
 if click = 3 then label12.color := clRed;
 if click = 4 then label12.color := clYellow;
 if click = 5 then label12.color := clLime;
 if click = 6 then label12.color := clAqua;
 if click = 7 then label12.color := clBlue;
 if click = 8 then label12.color := clFuchsia;
 inc(click);
 If click > 8 then click := 3
end;
procedure TForm1.Label13Click(Sender: TObject);
begin
 if click = 3 then label13.color := clRed;
 if click = 4 then label13.color := clYellow;
 if click = 5 then label13.color := clLime;
 if click = 6 then label13.color := clAqua;
 if click = 7 then label13.color := clBlue;
 if click = 8 then label13.color := clFuchsia;
 inc(click);
 If click > 8 then click := 3
end;

procedure init;
var z,p,c : integer;
 begin
  randomize;
  for z := 1 to 4 do
   begin
    c := random(5)+1;
    p := random(3)+1;
    ziel[z].pcol := c;
    ziel[z].ppos := p;
   end;

 end;

begin
 init;
end.

Ich danke für eure Mühe!
Gruß wovo

[sx2008]

Zitat:

Zitat von wovo (Beitrag 1234361)

Es sollen 48 einzele Label erzeugt werden mit 48 einzelnen Events. Später kommen noch mal 48 weitere ähnliche Label hinzu.

Warum redest du keinen Klartext?
Brauchst du das für ein Spiel oder soll es eine Art Kreuzverteiler werden?
Ist das Layout immer rechtwinklig mit 4 * 12 Zellen?

[Sir Rufo]

@wovo

Warum hast du denn nicht auch die Methode

Delphi-Quellcode:

LabelsClick

aus meinem Quelltext übernommen?

Wenn du die im Interface deklarierst, dann muss du die auch implementieren

[wovo]

Hallo!
Bzgl. Klartext : Ja, es geht um ein Spiel (Mastermind).
Und das Layout ist immer rechtwinklig mit 4x12 Zeilen.

@Sir Rufo : Ich hatte schon versucht, die besagte Methode zu implementieren (Im Quelltext steht sie, als Kommentar wegen Fehlermeldung).
Einer meiner Fehler war sicher, deinen Vorschlag nicht direkt übernommen zu haben. Es war der Versuch, von meinem Quellcode auszugehen.
Man sieht, ich verstehe die Zusammenhänge (noch) nicht.

Ich werde weiter basteln.
Aber vielen Dank für die Unterstützung.

Nebenbei: Primitiv programmiert - also statt for-Schleifen alles einzeln formuliert - klappt es inzwischen prima. Nur eben nicht so elegant bzw. professionell :-(

Gruß wovo

[Blup]

Zitat:

@Sir Rufo : Ich hatte schon versucht, die besagte Methode zu implementieren (Im Quelltext steht sie, als Kommentar wegen Fehlermeldung).

Der auskommentierte Quelltext ist eine Deklaration. Was fehlt ist die Implementation, das bemängelt auch der Compiler.
Bitte informiere dich über die Bedeutung dieser Schlüsselwörter, diese gehören zu den Grundlagen für das Verständnis von Programmiersprachen.

Zitat:

Der Zyklus soll für jedes Label einzeln gelten, wenn es angelickt wird.

Wenn jedes Label einen eigenen unabhängigen Zyklus hat, braucht jedes Label doch auch seinen eigenen Zähler.
Da es eine feste Reihenfolge der Farben gibt und die Farben darin eindeutig sind, kann man aber beim Click von der aktuellen Farbe auf die nächste schliessen.

Delphi-Quellcode:

implementation
{hier drunter steht, was die Methoden tun sollen}

procedure TForm1.LabelClick(Sender: TObject);
const
  CLabelColors : array[0..5] of TColor = (clRed, clYellow, clLime, clAqua, clBlue, clFuchsia);
var
  i, n: Integer;
begin
  {Index der aktuellen Farbe des Labels bestimmen}
  n := -1;
  for i := 0 to High(CLabelColors) do
  begin
    if TLabel(Sender).Color = CLabelColors[i] then
    begin
      n := i;
      Break;
    end;
  end;
  {Index der nächsten Farbe die das Label bekommt}
  n := (n + 1) mod Count(CLabelColors);
  TLabel(Sender).Color := CLabelColors[n];
end;

Dem Event-Property der einzelnen Labels musst du natürlich "LabelClick" zuweisen, nicht "labels.Click".

[sx2008]

Zitat:

Zitat von wovo (Beitrag 1234389)

Bzgl. Klartext : Ja, es geht um ein Spiel (Mastermind).
Und das Layout ist immer rechtwinklig mit 4x12 Zeilen.

Das hättest du gleich sagen sollen.
Vergiss die ganzen Labels; wirf sie einfach in die Tonne.
Stattdessen nimmst du ein Drawgrid mit 5 * 12 Zellen.
Vier Zellen dienen zur Anzeige der farbigen Pins und in der 5. Zelle wird das Ergebnis des Rateversuchs mit 4 kleinen weissen oder schwarzen Kreisen angezeigt.

In einem Drawgrid kann man Text, geometrische Formen aber auch Bitmaps anzeigen.
Durch Verwendung von Bitmaps bekommt das Spielbrett eine viel hübschere Optik.
Für den Anfang reicht es wenn du nur farbige Kreise zeichnest.

Ein Demo zum Drawgrid kannst du hier anschauen.
Download Sourcecode (im Unterverzeichnis "Schachbrett"): http://github.com/sx2008/Delphi-Test...ive/master.zip

Hier ist noch ein tolles Tutorial für ein Memory Spiel.
Dort kannst du auch den Sourcecode runterladen. :thumb:
"Memory" ist eine optimale Vorbereitung für Mastermind.

[wovo]

Dank für die Antworten!

@Blup : Ich bin eben noch Anfänger, weshalb ich noch viel zu Lernen habe,
und weshalb ich noch Fehler mache :-(
Bitte um Entschuldigung.

@sx2008 : Ich habe das Ziel am Anfang nicht genannt, weil ich lediglich
eine grundlegende, allgemeine Frage stellen wollte.
Den Ansatz mit dem DrawGrid werde ich verfolgen.
Dank für den Hinweis.

Aber eure Hilfestellungen zu den Labels, die zur Laufzeit incl. Events erstellt werden sollen, haben mir weitergeholfen.
Danke.
Ich bin von Haus aus eher Algorithmiker und nicht GUI-Programmierer.

Gruß wovo

[Sir Rufo]

Warum hast du denn nicht erst den Algorithmus und dann die GUI gebaut? ;)

Zunächst würde ich eine Klasse erstellen, die das gesamte Handling der Daten für MasterMind abtütet.
Erst dann baue ich die GUI und lese die Informationen für die Darstellung aus dieser Klasse.

[Blup]

@wovo
Fehler sind hier die Regel, deshalb braucht man sich nicht zu entschuldigen.
Wir weisen auf die Fehler oder Schwächen der Programme hin, damit eine bessere Lösung gefunden und daraus gelernt werden kann.

[wovo]

Nochmals Dank für die Hilfestellungen.

Da ich mich mit Objektorientierter Programmierung fast nicht auskenne,
ist deren Einsatz für mich das Hauptproblem.
(Ich komme aus einer Zeit, in der Algol60 innovativ war :-D )
Deshalb habe ich diesmal auch nicht als erstes den eigentlichen Algorithmus entwickelt und (vor)programmiert (im Kopf existiert der schon).

Bei jedem kleinen Progrämmchen, das ich - wie hier - so nebenbei zum Spaß entwickle, lerne ich ein wenig dazu.
Dank eurer Hilfe z.B., wie man (für euch Banales) Objekte zur Laufzeit erzeugt.
Es freut mich zudem, dass ihr gnädig gegenüber den Fehlern seid.

Gruß wovo