Kreuzworträtsel

[Noobmaster]

Hallo Leute,

mein Kreuzwortprogramm macht nicht das, was es tun soll.
Ein Screenshot befindet sich im Anhang zum besseren Verständnis.

Die obere Listbox enthält alle horizontalen, die untere alle vertikalen Fragen.
Wählt man einen Eintrag aus, so springt das rote Quadrat auf dem Stringgrid in fast allen Fällen in die richtige Zelle des Stringgrids:

Delphi-Quellcode:

//
//TForm1.GeheZuFrage: Markiert das erste Feld der gesuchten Frage (markiert in Listbox)
//
procedure TForm1.GeheZuMarkierterFrage(var pListBox: TListBox);
var
   i,j: Integer;
   FrageNr: String;
   Vertikal: Integer;
   Horizontal: Integer;
begin
   //Vertikal oder Horizontal?
   Horizontal := 0;
   Vertikal := 0;
   if pListBox = ListBoxHorizontal then Horizontal := 1 else Vertikal := 1;

   //Anfangskaestchen finden

   //zunächst die Nr der Frage bestimmen
   FrageNr := '';
   i := 1;
   while pListbox.Items[pListbox.ItemIndex][i] in ['0'..'9'] do
   begin
      FrageNr := FrageNr + pListbox.Items[pListbox.ItemIndex][i];
      Inc(i);
   end;

   //Vorangestellte 0 eliminieren
   FrageNr := IntToStr(StrToInt(FrageNr));

   //Alle Kästchen nach der Nummer durchsuchen
   for i := 0 to SGridKreuzwort.ColCount - 1 do
      for j := 0 to SGridKreuzwort.RowCount - 1 do
         if SGridKreuzwort.Cells[i,j] = FrageNr then
         begin
            SGridKreuzwort.Col := (i + Horizontal);
            SGridKreuzwort.Row := (j + Vertikal);
         end;
end;

Das Problem taucht auf, wenn Frage vier markiert ist.
Diese ist als einzige in beiden Listboxes enthalten.
Hier springt das rote Kästchen gar nicht, ich weiß aber absolut nicht warum.

Zur Zusatzinfo die wichtigsten Ereignisse:

Delphi-Quellcode:

//
//TForm1.ListBoxHorizontalClick: Sucht eine ausgewählte horizontale Frage
//
procedure TForm1.ListBoxHorizontalClick(Sender: TObject);
begin
   ListBoxHorizontal.Update;
   ListBoxHorizontal.Repaint;
   GeheZuMarkierterFrage(ListBoxHorizontal);
   GeheZuMarkierterFrage(ListBoxHorizontal); //bei einmaligen Aufruf springt das Kästchen manchmal falsch
   Richtung := RHorizontal;
   SGridKreuzwort.SetFocus();
end;

//
//TForm1.ListBoxVertikalClick: Sucht eine ausgewählte vertikale Frage
//
procedure TForm1.ListBoxVertikalClick(Sender: TObject);
begin
   ListBoxVertikal.Update;
   ListBoxVertikal.Repaint;
   GeheZuMarkierterFrage(ListBoxVertikal);
   GeheZuMarkierterFrage(ListBoxVertikal);
   Richtung := RVertikal;
   SGridKreuzwort.SetFocus();
end;

Das rote Kästchen wird in der Prozedur OnDrawCell des Stringgrids gezeichnet:

Delphi-Quellcode:

      //Markierte Zelle einfärben
      if SGridKreuzwort.IsCellSelected[aCol,aRow] then
      begin
         //Zelleninhalt mit Hintergrundfarbe löschen/einfärben
         SGridKreuzwort.Canvas.Brush.Color := clRed;
         SGridKreuzwort.Canvas.Fillrect(aRect);
         //Mit kleinerem Kästchen in Originalfarbe übermalen -> Rahmen entsteht
         SGridKreuzwort.Canvas.Brush.Color := clWhite; //Standardfarbe
         outRect.Left   := aRect.Left+2;
         outRect.Top    := aRect.Top+2;
         outRect.Right  := aRect.Right-2;
         outRect.Bottom := aRect.Bottom-2;
         SGridKreuzwort.Canvas.Fillrect(outRect);
      end;

[omata]

Zitat:

Zitat von Noobmaster (Beitrag 1168600)

mein Kreuzwortprogramm macht nicht das, was es tun soll.

Antwort: Benutze den Debugger, um herauszufinden an welcher Stelle dein Algorithmus und deine Gedankenwelt voneinander abweichen.

[Noobmaster]

Genau das habe ich ja getan. Aber obwohl ich das Programm schrittweise ablaufen lasse, finde ich nicht die Fehlerstelle.
Und wie gesagt, der Fehler tritt nur auf, wenn man eine Frage auswählt, die in beiden Listboxen vorkommt. Das einzige, was ich zusätzlich weiß ist, dass er in diesem Fall zwar das richtige Kästchen findet und auswählt (Stringgrid.Row := richtig, Stringgrid.Col := richtig), im OnDrawEreignis aber plötzlich falsche Werte stehen.

[Noobmaster]

Der Code

Delphi-Quellcode:

//
//TForm1.GeheZuFrage: Markiert das erste Feld der gesuchten Frage (markiert in Listbox)
//
procedure TForm1.GeheZuMarkierterFrage(var pListBox: TListBox);
var
   i,j: Integer;
   FrageNr: String;
   Vertikal: Integer;
   Horizontal: Integer;
begin
   //Vertikal oder Horizontal?
   Horizontal := 0;
   Vertikal := 0;
   if pListBox = ListBoxHorizontal then Horizontal := 1 else Vertikal := 1;

   //Anfangskaestchen finden

   //zunächst die Nr der Frage bestimmen
   FrageNr := '';
   i := 1;
   while pListbox.Items[pListbox.ItemIndex][i] in ['0'..'9'] do
   begin
      FrageNr := FrageNr + pListbox.Items[pListbox.ItemIndex][i];
      Inc(i);
   end;

   //Vorangestellte 0 eliminieren
   FrageNr := IntToStr(StrToInt(FrageNr));

   //Alle Kästchen nach der Nummer durchsuchen
   for i := 0 to SGridKreuzwort.ColCount - 1 do
      for j := 0 to SGridKreuzwort.RowCount - 1 do
         if SGridKreuzwort.Cells[i,j] = FrageNr then
         begin
            SGridKreuzwort.Col := (i + Horizontal);
            SGridKreuzwort.Row := (j + Vertikal);
         end;
end;

markiert das richtige Kästchen.

Aber in dem OnDrawCell-Ereignis des Stringgrids ist eine andere Zelle markiert, was mir trotz schrittweisen Durchlaufen des Programms mit dem Debugger rätselhaft bleibt, da es ja in allen anderen Fällen funktioniert.

Delphi-Quellcode:

      //Markierte Zelle einfärben
      if SGridKreuzwort.IsCellSelected[aCol,aRow] then
      begin
         //Zelleninhalt mit Hintergrundfarbe löschen/einfärben
         SGridKreuzwort.Canvas.Brush.Color := clRed;
         SGridKreuzwort.Canvas.Fillrect(aRect);
         //Mit kleinerem Kästchen in Originalfarbe übermalen -> Rahmen entsteht
         SGridKreuzwort.Canvas.Brush.Color := clWhite; //Standardfarbe
         outRect.Left := aRect.Left+2;
         outRect.Top := aRect.Top+2;
         outRect.Right := aRect.Right-2;
         outRect.Bottom := aRect.Bottom-2;
         SGridKreuzwort.Canvas.Fillrect(outRect);
      end;

[DeddyH]

Könnte die Bedingung

Zitat:

Delphi-Quellcode:

if SGridKreuzwort.Cells[i,j] = FrageNr then

evtl. mehrfach zutreffen? Suchst Du in dem Fall nur nach dem ersten Treffer? Das könnte zumindest ein Anhaltspunkt sein, da Deine For-Schleifen ja trotzdem weiter abgearbeitet werden.

[Noobmaster]

Delphi-Quellcode:

   for i := 0 to SGridKreuzwort.ColCount - 1 do
      for j := 0 to SGridKreuzwort.RowCount - 1 do
         if SGridKreuzwort.Cells[i,j] = FrageNr then
         begin
            SGridKreuzwort.Col := (i + Horizontal);
            SGridKreuzwort.Row := (j + Vertikal);
            {SGridKreuzwort.Update;
            SGridKreuzwort.Repaint;}
            break; //Schleife abbrechen, da Kästchen gefunden
         end;

Auch mit "break;" tritt der Fehler immer noch auf. Ich habe jetzt mal im OnDrawCell-Ereignis

Delphi-Quellcode:

if SGridKreuzwort.IsSelected[aCol,aRow]

ersetzt mit

Delphi-Quellcode:

if (ACol = SGridKreuzwort.Col) and (aRow = SGridKreuzwort.Row)

Scheint zu funktionieren.

Was mich allerdings stutzig macht, ist die Tatsache dass ich in den OnClick-Ereignissen der beiden Listboxen die Prozedure GeheZuMarkierterFrage() 2x aufrufen muss...

[Blup]

Zitat:

Zitat von Noobmaster (Beitrag 1168600)

Delphi-Quellcode:

procedure TForm1.GeheZuMarkierterFrage(var pListBox: TListBox);
{...}

Objektvariablen sind bereits Zeiger auf das Objekt, eine Übergabe als Varparameter ist überflüssig:

Delphi-Quellcode:

procedure TForm1.GeheZuMarkierterFrage(AListBox: TListBox);
{...}

Hier solltest du unbedingt nach der Ursache forschen und diese abstellen:

Zitat:

Zitat von Noobmaster (Beitrag 1168600)

Delphi-Quellcode:

   GeheZuMarkierterFrage(ListBoxHorizontal);
   GeheZuMarkierterFrage(ListBoxHorizontal); //bei einmaligen Aufruf springt das Kästchen manchmal falsch

Ohne den kompletten Quelltext kann ich nur vermuten, du reagierst auch im SGridKreuzwort auf das Auswählen einer Zelle und beeinflusst dort den Index in den Listboxen. Das sollte aber beim Debuggen auffallen.

Im OnDrawEreignis bekommst du übrigends den Status der zu zeichnenden Zelle in "State" mitgeliefert.

Delphi-Quellcode:

  if gdSelected in State then
{...}

Break bricht nur die innere Schleife ab.

[Noobmaster]

Zitat:

Zitat von Blup (Beitrag 1168720)

Hier solltest du unbedingt nach der Ursache forschen und diese abstellen:

Delphi-Quellcode:

   GeheZuMarkierterFrage(ListBoxHorizontal);
   GeheZuMarkierterFrage(ListBoxHorizontal); //bei einmaligen Aufruf springt das Kästchen manchmal falsch

Ohne den kompletten Quelltext kann ich nur vermuten, du reagierst auch im SGridKreuzwort auf das Auswählen einer Zelle und beeinflusst dort den Index in den Listboxen. Das sollte aber beim Debuggen auffallen.

Delphi-Quellcode:

//
//TForm1.SGridKreuzwortSelectCell: wird beim Auswählen einer Zelle aufgerufen
//
procedure TForm1.SGridKreuzwortSelectCell(Sender: TObject; aCol, aRow: Integer;
   var CanSelect: Boolean);
var
   FrageExistiert: Boolean;
begin
   //Verhindern, dass Kästchen mit Zahlen oder geschwärzte Kästchen ausgewählt werden
   if DasKreuzWortgitter.Breite > 0 then
   begin
      CanSelect := (DasKreuzwortgitter.GibFeld(aRow,aCol).Farbe  = clWhite) and
                   not (DasKreuzwortgitter.GibFeld(aRow,aCol).Inhalt[1] in ['1'..'9']);  
   end;
end;

Mehr passiert hier nicht. Der Index einer Listbox wird nicht verändert.

Zitat:

Zitat von Blup (Beitrag 1168720)

Im OnDrawEreignis bekommst du übrigends den Status der zu zeichnenden Zelle in "State" mitgeliefert.

Delphi-Quellcode:

  if gdSelected in State then
{...}

Cool, danke.

Zitat:

Zitat von Blup (Beitrag 1168720)

Break bricht nur die innere Schleife ab.

Da wie im Screenshot zu sehen keine Zahl doppelt vorkommt, ist das nicht allzu tragisch.

Danke nochmal für die Antworten.

[Jumpy]

Hallo,

ich kann dir jetzt nicht bei deinem Problem helfen, da ich auch nicht sehe, was da schief läuft, aber wäre es nicht einfacher für beide Listbox_onClicks, das selbe Event zu verwenden? Der ausgewählte String in der Listbox enthält doch die Info vertikal/horizontal und die Fragenummer.
Das könnte man dann als Info an eine MarkiereZelle-Prozedur übergeben und das war's.

Auf dem Screenshot sieht es ja so aus, das auf vertikal 4 geklickt wurde, warum ist dann aber auch noch horizontal Frage 7 markiert? Es wäre vllt. übersichtlicher, in der jeweils anderen Listbox die Selektion aufzuheben.

Cool wäre natürlich auch, nicht nur die erste Zelle der Antwort zu markieren, sondern gleich alle betroffenden Zellen, z.B. blass-rot einzufärben.

Nur so als Anregung,
Jumpy

[Noobmaster]

Danke für die Anregungen :-). Ich hab die EinProzeduren-Lösung schon eingebaut. Das mit dem blassroten Einfärben hab ich eh noch vor, aber erst muss der Rest mal laufen :-D.

Ich glaube, ich habe das Problem nach vielen vielen Debuggerschritten nun lokalisiert:

Delphi-Quellcode:

            SGridKreuzwort.Col := (i + Horizontal);
            SGridKreuzwort.Row := (j + Vertikal);

Beim Setzen von SGridKreuzwort.Col wird bereits das OnSelection-Ereignis des Stringgrids und das OnDraw-Ereignis aufgerufen. Da ich aber manche Zellen gesperrt habe, kann es sein, dass das Programm dabei auf eine gesperrte Zelle trifft und beide Werte intern wieder ändert.
Wie kann ich Col und Row verändern (die Zelle mit diesen Koordinaten selektieren), sodass erst nach der Änderung beider Werte die Stringgrid-Ereignisse aufgerufen werden?

[Helmi]

Zitat:

Zitat von Noobmaster (Beitrag 1168761)

Wie kann ich Col und Row verändern (die Zelle mit diesen Koordinaten selektieren), sodass erst nach der Änderung beider Werte die Stringgrid-Ereignisse aufgerufen werden?

Hallo,

zwei Ideen:
- entweder sich eine bool´sche Variable setzen und im ersten Aufruf im OnDraw-Event gleich mit exit die Procedure beenden
- das OnDraw-Event auf nil setzen und erst nach dem setzen von Col und vor dem Setzen von Row wieder definieren

[Blup]

Zumindest in Delphi ist diese Variante denkbar:

Delphi-Quellcode:

type
  TMyGridHelper = class helper for TCustomGrid
    procedure Select(ACol, ARow: Longint);
  end;

  procedure TMyGridHelper.Select(ACol, ARow: Longint);
  begin
    FocusCell(ACol, ARow, True);
  end;

{...}
SGridKreuzwort.Select(i + Horizontal, j + Vertikal);

Alternativ könnte man auch eine Klasse von TStringGrid ableiten und diese Methode implementieren.

[Noobmaster]

Delphi-Quellcode:

   //Alle Kästchen nach der Nummer durchsuchen
   for i := 0 to SGridKreuzwort.ColCount - 1 do
      for j := 0 to SGridKreuzwort.RowCount - 1 do
         if SGridKreuzwort.Cells[i,j] = FrageNr then
         begin
            SGridKreuzwort.OnSelectCell := nil; //Verhindern, dass OnSelectCell sofort ausgeführt wird
            SGridKreuzwort.Col := (i + Horizontal);
            SGridKreuzwort.OnSelectCell := @SGridKreuzwortSelectCell; //darf wieder ausgeführt werden
            SGridKreuzwort.Row := (j + Vertikal);
         end;

Nach ein paar Tests scheint diese Methode zu funktionieren.

Vielen vielen Dank für die vielen, schnellen und hilfreichen Antworten!

[Helmi]

du solltest aber trotzdem noch beide Schleifen beenden, wenn die FrageNr gefunden wurde

[DeddyH]

Das habe ich ja gestern auch schon angedeutet, wenn auch etwas durch die Blume :zwinker:

[Noobmaster]

Die innere Schleife kann ich ja mit "break" beenden. Aber wie beende ich die äußere Schleife auch noch in der if-Bedingung? Muss ich dann zweimal "break" setzen?

[Helmi]

Zitat:

Zitat von Noobmaster (Beitrag 1168942)

Die innere Schleife kann ich ja mit "break" beenden. Aber wie beende ich die äußere Schleife auch noch in der if-Bedingung? Muss ich dann zweimal "break" setzen?

pro Schleife ist ein break notwendig!

Beispiel:

Delphi-Quellcode:

var
  bfound: Boolean;

{...}

   bfound := false;

   //Alle Kästchen nach der Nummer durchsuchen
    for i := 0 to SGridKreuzwort.ColCount - 1 do
      begin
        for j := 0 to SGridKreuzwort.RowCount - 1 do
          if SGridKreuzwort.Cells[i,j] = FrageNr then
            begin
              SGridKreuzwort.OnSelectCell := nil; //Verhindern, dass OnSelectCell sofort ausgeführt wird
              SGridKreuzwort.Col := (i + Horizontal);
              SGridKreuzwort.OnSelectCell := @SGridKreuzwortSelectCell; //darf wieder ausgeführt werden
              SGridKreuzwort.Row := (j + Vertikal);

              bfound := true;
              break;
            end; 
        If bfound then
          break;
      end;

[Noobmaster]

Alles klar, danke :-)

[Helmi]

Wenn die Schleifen am Ende einer Procedure stehen, dann könnte man auch ein exit in der zweiten Schleife benutzen, dann wird sofort die Procedure beendet!
ja - ich bin mir bewusst dass ich für diese Aussage Schläge bekommen könnte!

[DeddyH]

Oder ganz ohne break oder exit:

Delphi-Quellcode:

found := false;
i := 0;
while (i < SGridKreuzwort.ColCount) and not found do
  begin
    j := 0;
    while (j < SGridKreuzwort.RowCount) and not found do
      begin
        if ... then
          begin
            found := true;
            (* weiterer Code *)
          end;
        inc(j);
      end;
    inc(i);
  end;

[Helmi]

Zitat:

Zitat von DeddyH (Beitrag 1168948)

Oder ganz ohne break oder exit:

ich liebe break, continue und exit

[DeddyH]

Ich will das ja auch nicht verteufeln, sondern nur eine Alternative zeigen.