Komma automatisch setzen bei Geldbetrag im Edit

[ickehausen]

Hallo,

ich möchte gerne in ein Edit-Feld einen Geldbetrag eingeben. Das Komma als Trennung zwischen Euro und Cent soll automatisch erscheinen. Ich gebe also z. B. folgendes ein und im Edit soll dann folgendes stehen:

bei

1 ---> 1
12 ---> 12
123 ---> 1,23
1234 ---> 12,34
usw.

Wenn ich es über das Change-Ereignis versuche, erhalte ich nur Mist, da durch das Ändern des Edit.Text in der Ereignisroutine das Change-Ereignis scheinbar wieder aufgerufen wird.

Delphi-Quellcode:

procedure TForm2.Edit1Change(Sender: TObject);
var s1,s2,s3:String;
    l:Integer;
begin
  l := length(Edit1.Text);
  if l > 3 then
  begin
    s1 := copy(Edit1.Text,1,l-4);
    s2 := copy(Edit1.Text,l-3,1);
    s3 := copy(Edit1.Text,l-2,2);
    Edit1.Text:= s1 + s2 + ',' + s3;
    Edit1.SelStart := l;
  end;
  if l = 3 then
  begin
      s1 := copy(Edit1.Text,1,l-2);
      s2 := copy(Edit1.Text,l-1,2);
      Edit1.Text:= s1 + ',' + s2;
      Edit1.SelStart := l;
  end;
end;

[DeddyH]

Würde es im OnExit-Event nicht genügen? Das ist dann nicht so umständlich. Allerdings muss man dann bei der Eingabe daran denken, dass da ggf. noch durch 100 geteilt wird.

[Uwe Raabe]

Wenn du das Edit1.Tag nicht schon für was anderes brauchst (sonst halt eine extra Variable deklarieren):

Delphi-Quellcode:

var
  s1, s2, s3: string;
  l: Integer;
  S: string;
begin
  if Edit1.Tag > 0 then Exit;
  Edit1.Tag := Edit1.Tag + 1;
  try
    S := Edit1.Text;
    l := Pos(',', S);
    if l > 0 then
      Delete(S, l, 1);
    l := length(S);
    if l > 2 then
      Insert(',', S, l - 1)
    else
      Exit;
    Edit1.Text := S;
    Edit1.SelStart := length(S);
  finally
    Edit1.Tag := Edit1.Tag - 1;
  end;
end;

[himitsu]

Wie gesagt ... OnExit.

Woher will man bei einer 1 im Edit wissen, ob daraus nicht mal eine 12 wird?

[Klaus01]

.. würde sich da nicht maskedEdit anbieten?

Grüße
Klaus

[Uwe Raabe]

Zitat:

Zitat von himitsu (Beitrag 1119322)

Wie gesagt ... OnExit.

Woher will man bei einer 1 im Edit wissen, ob daraus nicht mal eine 12 wird?

Ich kenne diese Art der Eingabe. Das habe ich früher an meinen alten Tischrechnern auch so gemacht. Man gibt immer die Cent-Beträge ein und der Rechner formatiert das automatisch auf Euro (OK, damals noch Pfennig und Mark).

[Neutral General]

Hallo,

So funktioniert es:

Delphi-Quellcode:

procedure TForm1.Edit1Change(Sender: TObject);
var Text: String;
    Sel: Integer;
begin
  Sel := Edit1.SelStart;
  Text := StringReplace(Edit1.Text,',','',[rfReplaceAll]);

  if Length(Text) > 2 then
  begin
    Insert(',',Text,Length(Text)-1);
    if Sel > Length(Text)-2 then
      inc(Sel);
  end;

  Edit1.Text := Text;
  Edit1.SelStart := Sel;
end;

[DeddyH]

Wenn immer Cent-Beträge eingegeben und als Euro-Beträge ausgegeben werden sollen, dann könnte man das doch auch im OnKeyPress regeln: eine interne Integer-Variable, die bei Eingabe zwischen '0' und '9' mit 10 multipliziert wird und dann die umgewandelte Eingabe dazuaddiert. Das Ganze dann nur noch formatiert ausgeben und gut. Bei Backspace wird dann eben wieder durch 10 dividiert.

[edit] Das setzt allerdings voraus, dass die Eingabe mittels Tastatur geschieht und nicht z.B. über die Zwischenablage. [/edit]

[Uwe Raabe]

Zitat:

Zitat von Neutral General (Beitrag 1119328)

So funktioniert es:

Das Event wird so aber ab einer Textlänge von drei bei jedem Tastendruck zweimal aufgerufen.

[Neutral General]

Zitat:

Zitat von Uwe Raabe (Beitrag 1119339)

Zitat:

Zitat von Neutral General (Beitrag 1119328)

So funktioniert es:

Das Event wird so aber ab einer Textlänge von drei bei jedem Tastendruck zweimal aufgerufen.

Jo.. Im Zweifelsfall umgibt man die Zuweisung mit

Delphi-Quellcode:

Edit1.OnChange := nil;
  ..
Edit1.OnChange := Edit1Change;

Ist zwar jetzt nicht so schön aber naja. Ansonsten wirds halt eben 2x aufgerufen. Negative Auswirkungen hat das ja keine (bis auf ein bisschen CPU-Zeit)

[bernerbaer]

Aua, das tut mir weh! Komma ist nicht Komma! Warum wird hier nirgends auf die Problematik mit dem Dezimalseperator hingewiesen?

Auf meinen Rechnern Deutsch-CH,EN-USA oder RU gäbs da gewaltige Probleme mit dem fest kodierten ","
dezimalseperator!

[DeddyH]

Mit Format() würde das aber immer passen :D

[bernerbaer]

Zitat:

Zitat von DeddyH (Beitrag 1119356)

Mit Format() würde das aber immer passen :D

Du überforderst mich :stupid:, ich sehe den Zusammenhang mit Format() und den vorgeschlagenen Funktionen nicht.
Mit Format gestalte ich ja nur die Ausgabe (hier) einer Zahl, es wird aber mit StringReplace gearbeitet. warum nicht einfach "," mit decimalseperator ersetzen?

[DeddyH]

Ich war jetzt wieder bei meinem anderen Ansatz, ganz weg von Strings. Aber da muss man dann auch nicht mehr auf den Dezimalseparator achten.

Delphi-Quellcode:

type
  TFormTest = class(TForm)
    Edit1: TEdit;
    procedure Edit1KeyPress(Sender: TObject; var Key: Char);
  private
    { Private-Deklarationen }
    FCentbetrag: integer;

...

procedure TFormTest.Edit1KeyPress(Sender: TObject; var Key: Char);
begin
  case Key of
    '0' .. '9':
      FCentbetrag := FCentbetrag * 10 + StrToInt(Key);
    #8:
      FCentbetrag := FCentbetrag div 10;
    '-':
      FCentbetrag := -FCentbetrag;
  end;
  Key := #0;
  Edit1.Text := Format('%.2f', [FCentbetrag / 100]);
  Edit1.SelStart := MaxInt;
end;

[Frickler]

Bei Tests mittels OnChange immer mit "if Edit1.Modified ..." klammern. Soft wird das öfter aufgerufen, als einem lieb ist....

[ickehausen]

Wollte nur mal kurz Danke an alle sagen. Ich habe die Lösung von Uwe implementiert, dass scheint mir die sauberste Lösung zu sein.
@bernerbaer:
Mit dem Dezimaltrenner ist es vollkommen egal, da ich nur kleine Progrämmchen für den internen Bereich bastle. Dadurch auch immer wieder Fragen, über die echte Programmierer wahrscheinlich nur den Kopf schütteln.

Gruß
Frank:-D

[himitsu]

Dennoch kann man sowas einbauen, dazumal es nichtmal schwer umzusetzen ist.

Einfach immer nur statt

Delphi-Quellcode:

','

ein

Delphi-Quellcode:

DecimalSeparator

hinzuschreiben ist ja keine schwere Sache.

[DeddyH]

Was passiert eigentlich, wenn man mal versehentlich einen Buchstaben eingibt?

[mkinzler]

Dann wird man mit einer schönen Exception belohnt :stupid:

[DeddyH]

Danke für die Bestätigung, ich dachte schon, ich hätte etwas überlesen :)