exe in die exe integrieren

[Meflin]

Hi,
ich müsste eine exe in meine anwendung einbinden, sodass ich zur laufzeit darauf zugreifen kann. dazu wären mir als möglichkeit zum einen resourcen bekannt. mein rs-compiler geht aber wegen xp net so toll (der is ja konsole). dann kenn ich noch die möglichkeit aus der delphi source library. die fällt auch weg, da ich mein programm komprimiere und somit die dateigröße nicht angeben kann! jetzt such ich dringend irgend ne möglichkeit, eine exe in mein programm zu integrieren! Gibts da vielleicht irgend ne kompo?

*MFG*

[The-X]

Hi,
Du kannst dir ne Kopie einer vorhandenen .res datei machen und diese mit dem Resource-Hacker bearbeiten d.h. alle anderen Resourcen löschen und deine Exe hinzufügen

so hab ich das jedenfalls das erste mal gemacht

ansonsten versuch es doch mal mit cmd/bat dateien
meist funktioniert das nicht weil das Anfangsverzeichnis nicht richtig ist

[ustra]

Hi,

ich habe auch das Problem so ähnlich gehabt. Ich wollte eine exe ins Programm einbinden und bei Bedarf extrahieren. Dazu suche hier mal nach Putbintores. Das extrahiert dir eine exe aus einer exe wieder raus. Vielleicht Dir das weiter.

Beste Grüße
Ulrich

[Meflin]

das einzige was ich da finde ist ein verfahren, die anwendung zu kopieren. bei mir handelt es sich aber um zwei verschiedene anwendungen!
@the-x: das problem ist, dass sich der compiler schliesst, bevor ich irgendwas machen kann!

[The-X]

Code:

@echo off
cdd D:\bla
rem alternativ D: und danach cd \bla
brcc32 bla.rc
Pause

Dann siehst auch was da steht und erst nach einem tastendruck wird das Fenster geschlossen

[Meflin]

wie muss denn die resourceart der exe im rs file heissen?

[Jens Schumann]

Hallo,
im Download ist ein Beispiel, wie man aus einer EXE eine EXE startet.
Also aus einer Resource heraus.

[ustra]

Hi,

ich habe mich vertan. Die Funktion heißt PutBinResto.

Das hilft Dir auf jedenfall weiter: Seite

Ulrich

[Meflin]

ok thx ich denke das sollte reichen! eine komfortablere möglichkeit wie die mit dem ressourcencompiler gibts eigentlich nicht?

[Luckie]

@Jens Schumann: Du startest aber nicht aus der Ressource raus, sondern von der Platte. Du schreibst die Ressource ja erst auf die Platte bevor du sie startest. Wenn du sehen willst, wie man eine Exe "aus" der Ressource ausführt, also ohne sie auf der Platte zu speichern, dann kuck dir mal hier: http://www.luckie-online.de/files/exports/inmemexe.zip von Nico an.

Zitat:

mein rs-compiler geht aber wegen xp net so toll (der is ja konsole).

Start -> Ausführen -> cmd -> Return. Dan gib mal in der Konsole brcc32 /? ein. :roll:

[NicoDE]

Zitat:

Zitat von Meflin

die fällt auch weg, da ich mein programm komprimiere und somit die dateigröße nicht angeben kann!

Musst Du doch gar nicht. Folgende Funktion ermittelt, wie groß die Exe vor dem Anhängen der Daten war (zur Laufzeit).

Delphi-Quellcode:

function DetectPE32Overlay(out Offset, Size: DWORD): Boolean;
type
  PImageSectionHeaders = ^TImageSectionHeaders;
  TImageSectionHeaders = array [Word] of TImageSectionHeader;
var
  Hand: THandle;
  Read: DWORD;
  DosHdr: TImageDosHeader;
  NtHdrs: TImageNtHeaders;
  SecHdr: PImageSectionHeaders;
  SecIdx: Word;
begin
  Result := False;
  // Datei zum Lesen oeffnen...
  Hand := CreateFile(PChar(ParamStr(0)), GENERIC_READ, FILE_SHARE_READ,
    nil, OPEN_EXISTING, 0, 0);
  if (Hand <> INVALID_HANDLE_VALUE) then
  try
    // MS-DOS Datei-Header einlesen um den Offset des PE32-Headers zu erhalten
    // (unter einigen OS nicht zwingend; aber in fast allen Faellen vorhanden)
    if not ReadFile(Hand, DosHdr, SizeOf(TImageDosHeader), Read, nil) or
      (Read <> SizeOf(TImageDosHeader)) or
      (DosHdr.e_magic <> IMAGE_DOS_SIGNATURE) then
      DosHdr._lfanew := 0;
    // PE32-Header einlesen (inklusive 'optionalem' Header)
    if (SetFilePointer(Hand, DosHdr._lfanew, nil, FILE_BEGIN) <> DWORD(-1)) and
      (ReadFile(Hand, NtHdrs, SizeOf(TImageNtHeaders), Read, nil) and
      (Read = SizeOf(TImageNtHeaders))) and
      (NtHdrs.Signature = IMAGE_NT_SIGNATURE) then
      // 'Optionalen' Header pruefen
      with NtHdrs, FileHeader, OptionalHeader do
        if (SizeOfOptionalHeader >= IMAGE_SIZEOF_NT_OPTIONAL_HEADER) and
          (OptionalHeader.Magic = IMAGE_NT_OPTIONAL_HDR_MAGIC) then
        begin
          // Sektionen durchlaufen und letzte merken
          SecHdr := GetMemory(NumberOfSections * SizeOf(TImageSectionHeader));
          if (SecHdr <> nil) then
          try
            if (SetFilePointer(Hand,
              SizeOfOptionalHeader - IMAGE_SIZEOF_NT_OPTIONAL_HEADER,
              nil, FILE_CURRENT) <> DWORD(-1)) and
              ReadFile(Hand, SecHdr^,
              NumberOfSections * SizeOf(TImageSectionHeader),
              Read, nil) and
              (Read = NumberOfSections * SizeOf(TImageSectionHeader)) then
            begin
              Offset := 0;
              for SecIdx := 0 to NumberOfSections - 1 do
                with SecHdr[SecIdx] do
                  if ((PointerToRawData + SizeOfRawData) > Offset) then
                    Offset := (PointerToRawData + SizeOfRawData);
              Size := GetFileSize(Hand, nil) - Offset;
              Result := True;
            end;
          finally
            FreeMemory(SecHdr);
          end;
        end;
  finally
    CloseHandle(Hand);
  end;
end;

Beispiel:

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var
  Offset: DWORD;
  Size: DWORD;
begin
  if DetectPE32Overlay(Offset, Size) then
    ShowMessage('Offset'#9': 0x' + IntToHex(Offset, 8) + #13#10 +
      'Size'#9': 0x' + IntToHex(Size, 8));
end;

Nach dem Kopilieren zeigt es an:

Code:

Offset: 0x00068400
Size  : 0x00000000

Nach "COPY /B Project1.exe + /B Projekt1.dpr Foo.exe" zeigt Foo.exe an:

Code:

Offset: 0x00068400
Size  : 0x00000107

Nach "upx.exe --best Foo.exe" zeigt Foo.exe an:

Code:

Offset: 0x00029E00
Size  : 0x00000107

(letzteres weil UPX die angehängten Daten erkennt und nach dem Komprimieren wieder hinten anhängt)


Gruss Nico

[edit] Typo im Kommentar - sind bestimmt noch mehr :) [/edit]

[Meflin]

ok leute thx, ich habs schon zum laufen gebracht!