String umdrehen

[JuiceRob]

Hi,
hab hier einen Auftrag für die Schule aber ich komm kein Stück weiter und bei Google find ich auch nichts.

Wir sollten erst ein Wort umdrehen d.h. aus "Hallo" wird "ollaH".
Mit ReverseString kein Problem.

Jetzt sollen wir aber in einem Satz die Wörter einzeln umdrehen d.h. aus "Hallo wie gehts" wird "ollaH eiw stheg".

Hab jetzt schon bei Google ne weile gesucht aber nichts gefunden was mich weiter bringt.

Ich benutz auch noch Delphi 2005, weil wir das auch in der Schule benutzen...

Schon mal Danke für die Hilfe.

[-187-]

Die ReverseString Funktion ist doch perfekt dafür. Du musst dir zusätzlich eine Schleife bauen die einen TempStr ließt (immer bis zum nächsten Leerzeichen) und diesen einzeln umwandelt.

Wo ist das Problem ?

[JuiceRob]

gibt keins mehr danke trotzdem =)

[-187-]

Hab nochmal ein kleines Bsp aus meinen Übungen ausgekramt. Geht aber mit Sicherheit noch sinnvoller :D

Delphi-Quellcode:

function StringReverse(S:String):String;
var
  i: Integer;
begin
  Result:='';
  for i:=Length(S) downto 1 do
  Begin
    Result:=Result+Copy(S,i,1);
  end;
end;

function SentenceReverse(S:String):String;
var
  i,Pos1: Integer;
  tmpStr: String;
begin
  Result:='';
  repeat
    Pos1:=Pos(' ',S);
    if Pos1>0 then
      tmpStr:=Copy(S,1,Pos1-1) else
      tmpStr:=S;
    tmpStr:=StringReverse(tmpStr);
    if not (tmpStr=StringReverse(S)) then
      Result:=Result+tmpStr+' ' else
      Result:=Result+tmpStr;
    S:=Copy(S,Pos1+1,Length(S));
  until
    Pos1=0;
end;

[rollstuhlfahrer]

kleine Verbesserung:

Delphi-Quellcode:

Result:=Result+Copy(S,i,1);

->

Delphi-Quellcode:

Result:=Result + S[i];

.

Bernhard

[Corpsman]

Hätte auch noch ne Variante :)

Delphi-Quellcode:

Function StringReverse(S: String): String;
Var
  i: Integer;
  c: Char;
Begin
  For i := 1 To length(s) Div 2 Do Begin
    c := s[i];
    s[i] := s[length(s) - i + 1];
    s[length(s) - i + 1] := c;
  End;
  result := s;
End;

[Aphton]

Mein Ketchup dazu:

Delphi-Quellcode:

function ReverseString(const S: String): String;
var
  i, Len: Integer;
begin
  Len := Length( S );
  SetLength( Result, Len );
  for i := 1 to Len do
    Result[i] := S[Len+1-i];
end;

function PosEx(const SubStr: String; Str: String; const From: Integer): Integer;
begin
  Str := Copy( Str, From, Length( Str ) - From + 1 );
  Result := Pos( SubStr, Str );
  if Result > 0 then
    inc( Result, From - 1 );
end;

function ReverseSentence(const S: String; const Separator: Char = ' '): String;
var
  i, Len,
  p: Integer;
  Word: String;
begin
  Result := S;
  Len := Length( S );
  i := 1;
  while i < Len do
  begin
    p := PosEx( Separator, S, i );
    if p = 0 then
      p := Len + 1 - i
    else
      p := p - i;
    Word := ReverseString( Copy( S, i, p ) );
    Move( Word[1], Result[i], p );
    inc( i, p + 1 );
  end;
end;

[himitsu]

@Aphton:
Bitte Anfänger nicht unbedingt gleich mit Move, MoveMemory und Co. behelligen.

Vorallem da dein Code ab Delphi 2009 nicht mehr funktioniert, weil wieder mal nicht beachtet wurde, daß sich Char/String verändern können.
PS: PosEx sollte TDE aber schon kennen.



Wenn es ein Text nur aus Wörtern und Leerzeichen ist, dann ginge auch noch

- TStringList mit Leerzeichen als Delimiter
- darüber den Text aufsplitten (geht auch mit Explode, wie z.B. eines aus unserer CodeLib)
- dann ist in jeder Zeile ein Wort, welches man umdrehen kann
und zum Schluß alles wieder zurück in einen String.

[p80286]

Zitat:

Zitat von Aphton (Beitrag 1084766)

Delphi-Quellcode:

function ReverseSentence(const S: String; const Seperator: Char = ' '): String;
var
  i, Len,
  p: Integer;
  Word: String;
begin

das "Word" halte ich für nicht so gelungen, da es auch den Typ Word gibt. In diesem Falle bevorzuge ich dann doch Denglisch weil es dann keine Probleme mit Doppeldeutigkeiten geben kann.

Gruß
K-H

[Aphton]

Zitat:

Zitat von p80286 (Beitrag 1084826)

Zitat:

Zitat von Aphton (Beitrag 1084766)

Delphi-Quellcode:

function ReverseSentence(const S: String; const Seperator: Char = ' '): String;
var
  i, Len,
  p: Integer;
  Word: String;
begin

das "Word" halte ich für nicht so gelungen, da es auch den Typ Word gibt(...)

Da bin ich anderer Meinung!

@Himitsu - ja, da hast du Recht! Das kann zu Problemen führen.
Was das "Move" angeht - ich finde, so dürfte das schneller sein?!

Edit: Das sollte separator heißen :oops:

[rollstuhlfahrer]

Zitat:

Zitat von Aphton (Beitrag 1084903)

@Himitsu - ja, da hast du Recht! Das kann zu Problemen führen.
Was das "Move" angeht - ich finde, so dürfte das schneller sein?!

Ab D2009 (mit Unicode) führt das zu Problemen. Man kann diese Version aber etwas abändern und dann wird sie in allen weiteren Delphi-Versionen funktionieren (auch mit UTF-32):

Delphi-Quellcode:

Move( Word[1], Result[i], p * SizeOf(Char));

.
Das SizeOf(Char) ist der Multiplikator. Vor D2009 ist der 1 (weil 1 Zeichen -> 1 Byte), danach ist der 2 (weil 1 Zeichen -> 2 Bytes oder so), auf jeden Fall ist der dann zu der Delphi-Version passend und es sollte nicht zu Problemen kommen.

Bernhard

[himitsu]

Allerdings muß man nicht immer alles extremst optimieren,
denn soo oft wird diese Funktion bestimmt nicht aufgerufen, als daß da 'ne Microsekunde wirklich auffällt ... in soeinem Fall lieber einfachen Code verwenden, da weniger fehleranfällig und übersichtlicher.

[-187-]

Tja grade wenn er eine Aufgabe für die Schule bearbeitet wird er glaube ich mit Move nicht glücklich werden :)

Das sind einfach keine Basics mehr...

[dor557]

Hier mal meinen Senf dazu... Habe das getestet. Ist sicherlich Fähig zu optimieren :)

Ich benutze immer eine Funktion die sich Explode nennt da ich viel mit arrays arbeite ;)

hier mal mein Code :

Delphi-Quellcode:

  TSTringdynarray = array of String;
var
  Form1: TForm1;
  WechselText : TStringDynArray;

function Explode(const Separator, S: string; Limit: Integer = 0): TStringDynArray;
var
  SepLen: Integer;
  F, P: PChar;
  ALen, Index: Integer;
begin
  SetLength(Result, 0);
  if (S = '') or (Limit < 0) then Exit;
  if Separator = '' then
  begin
    SetLength(Result, 1);
    Result[0] := S;
    Exit;
  end;
  SepLen := Length(Separator);
  ALen := Limit;
  SetLength(Result, ALen);

  Index := 0;
  P := PChar(S);
  while P^ <> #0 do
  begin
    F := P;
    P := AnsiStrPos(P, PChar(Separator));
    if (P = nil) or ((Limit > 0) and (Index = Limit - 1)) then P := StrEnd(F);
    if Index >= ALen then
    begin
      Inc(ALen, 5);
      SetLength(Result, ALen);
    end;
    SetString(Result[Index], F, P - F);
    Inc(Index);
    if P^ <> #0 then Inc(P, SepLen);
  end;
  if Index < ALen then SetLength(Result, Index);
end;

procedure TForm1.Button1Click(Sender: TObject);
var I : Integer;
begin
 Edit2.text := '';
  WechselText := Explode(' ',Edit1.text);
  for I := 0 to Length(WechselText) - 1 do
  begin
    WechselText[i] := ReverseString(Wechseltext[i]);
    Edit2.text := Wechseltext[i] + ' ' + Edit2.text;
  end;
end;

Hoffe das ich jetzt nicht deine Hausaufgaben gemacht habe :wink:

gruss Sascha

[roboter202]

Hallo,

umdrehen geht auch so

Delphi-Quellcode:

for i := 1 to length(input) do
  begin
  output := output + input[length(input)-(i-1)]
  end;

Warum immer so Kompliziert :?:

[Aphton]

Das ist sehr unperformant, denn du fügst einem String einen weiteren String hinzu, was zu einem stetigen Erweitern und somit Speicher neu allozieren führt, das ja bekannterweise langsam ist!

[roboter202]

Hallo,

Zitat:

Zitat von Aphton (Beitrag 1086295)

Das ist sehr unperformant, denn du fügst einem String einen weiteren String hinzu, was zu einem stetigen Erweitern und somit Speicher neu allozieren führt, das ja bekannterweise langsam ist!

Das mag sein allerdings würde es funktionieren und wenn man nicht gerade von einem string mit millionen von zeichen ausgeht würde es nicht merklich länger dauern :stupid:

[Aphton]

Klar, ich habe ja die Funktionalität gar nicht bezweifel ;)
Aber wissen sollte man das schon, deshalb habe ich es auch erwähnt.