TStringList freigeben?

[Mysterio08]

Hallo,

ich habe eine Funktion erstellt, bei der eine TStringList den Rückgabewert definiert. Auf der Suche danach, wie ich diese TStringList freigebe, habe ich in einem Buch gesehen, dass man das weglassen kann. Aber ist das auch wirklich guter Programmierstil?
Wenn nicht: Wie muss ich dann Result freigeben, damit nicht eine leere TStringList zurückgegeben wird?

mfg.

[Deep-Sea]

Wie jetzt? Ist der Rückgabeparameter vom Typ TStringList oder verwendest du eine TStringList nur intern um einen Rückgabewert (String?) zu erstellen?

Edit:
Mal ein paar Vorlagen für die verschiedenen Fälle.

Hier, wenn eine Stringliste gefüllt werden soll. TStrings anstatt TStringList zu nehmen ist hier wohl besser bzw. allgemeiner.
Man muss sich um die Erzeugung oder Freigabe innerhalb der Funktion nicht kümmern, dafür aber außerhalb.

Delphi-Quellcode:

procedure ABC(AList: TStrings);
begin
  // Tue etwas mit AList
end;

Wenn sie nur intern benötigt wird.

Delphi-Quellcode:

function ABC: String;
var
  LList: TStringList;
begin
  LList := TStringList.Create;
  try
    // Tue etwas mit LList
    Result := LList.Text; // Wenn gewünscht
  finally
    LList.Free;
  end;
end;

Wenn sie von der Funktion erstellt und als Rückgabewert benutzt wird.
Dies ist aber glaube ich nicht so gerne gesehen. Man muss sich nach dem Aufruf dieser Funktion nämlich um die Freigabe der Stringliste kümmern.

Delphi-Quellcode:

function ABC: TStringList;
begin
  Result := TStringList.Create;
  try
    // Tue etwas mit Result
  except
    Result.Free;
    raise;
  end;
end;

[Mysterio08]

Ich meine das Prinzip des dritten von dir geposteten Codes, Deep-Sea.
"Man muss sich nach dem Aufruf dieser Funktion nämlich um die Freigabe der Stringliste kümmern." Wie genau macht man das?
Und das raise? Das ruft doch eine Exception auf, oder?

[DeddyH]

Sehr richtig, Funktionen, die Objekte erzeugen und zurückgeben sind nicht sonderlich elegant (dazu gibt es auch einige Threads hier). IMO ist die erste Lösung (TStrings als Parameter) wann immer möglich vorzuziehen.

[edit] Eine Freigabe des Rückgabewertes könnte so aussehen:

Delphi-Quellcode:

var l: TStrings;
begin
  l := Funktion;
  try
    MachWasMitL;
  finally
    l.Free;
  end;
end;

[/edit]

[Mysterio08]

Zitat:

Zitat von DeddyH (Beitrag 1070013)

IMO ist die erste Lösung (TStrings als Parameter) wann immer möglich vorzuziehen.

[edit] Eine Freigabe des Rückgabewertes könnte so aussehen:

Delphi-Quellcode:

var l: TStrings;
begin
  l := Funktion;
  try
    MachWasMitL;
  finally
    l.Free;
  end;
end;

[/edit]

Das Interessante ist doch jetzt, was hinter "Funktion" steckt, oder nicht? Denn TStrings muss ja analog wie TStringList erstellt und auch wieder freigegeben werden.

[DeddyH]

"Funktion" wäre dann so etwas:

Delphi-Quellcode:

function funktion: TStrings;
begin
  Result := TStringlist.Create;
  try
    Result.Add('Eins');
    Result.Add('Zwei');
  except
    FreeAndNil(Result);
    raise;
  end;
end;

[Mysterio08]

Aber das funktioniert doch auch mit TStringList so. Oder welchen Vorteil hat TStrings?

[Deep-Sea]

Zitat:

Zitat von Mysterio08 (Beitrag 1070012)

"Man muss sich nach dem Aufruf dieser Funktion nämlich um die Freigabe der Stringliste kümmern." Wie genau macht man das?
Und das raise? Das ruft doch eine Exception auf, oder?

Wie das mit dem Freigeben geht, hat DeddyH ja gepostet. Es ist eig. der zweite von mir gepostete Code, jedoch anstatt eines "TStringList.Create" wird eben die entsprechende Funktion aufgerufen.
raise alleine löst keine Exception aus, sondern wirft innerhalb eines except-Blocks nur eine bereits aufgetretene Exception erneut aus. Ohne den try-except-Block können bei der 3. Variante Speicherlecks entstehen.

Zitat:

Zitat von Mysterio08 (Beitrag 1070018)

Aber das funktioniert doch auch mit TStringList so. Oder welchen Vorteil hat TStrings?

TStrings ist der abstrakte Vorgänger von TStringList und kann/sollte nicht erzeugt werden. Aber als Parametertyp ist es trotzdem praktisch, um andere Stringlisten als TStringList als Parameter zu erlauben.

[Tyrolean]

Zitat:

Zitat von Mysterio08 (Beitrag 1069998)

Hallo,

ich habe eine Funktion erstellt, bei der eine TStringList den Rückgabewert definiert. Auf der Suche danach, wie ich diese TStringList freigebe, habe ich in einem Buch gesehen, dass man das weglassen kann. Aber ist das auch wirklich guter Programmierstil?
Wenn nicht: Wie muss ich dann Result freigeben, damit nicht eine leere TStringList zurückgegeben wird?

mfg.

*Wie* man eine Stringlist freigibt ist klar. Stringlist.Free. die Frage ist eher wann

Delphi-Quellcode:

var
  sl : TStringlist;
begin
  sl := Callfunction;
  // mit sl viel oder wenig tun
  sl.Free;
end;

[Deep-Sea]

@Tyrolean:
Try-finally nicht vergessen :wink:

[Tyrolean]

Zitat:

Zitat von Deep-Sea (Beitrag 1070023)

@Tyrolean:
Try-finally nicht vergessen :wink:

eh klar :)

[Luckie]

also ich bin der Meinung, dass man Objekte auch da wieder freizugeben sollte, wo man sie erzeugt. Ansonsten wird es ziemlich unübersichtlich und man ist am Suchen, wo das erzeugte Objekt wieder freigegebene wird:

Delphi-Quellcode:

procedure FooBar(Strings: TStrings);
begin
  Strings.Add('jsbvjdasbjÄ');
  Strings.Add('iuerwtrei');
end;

Und der Aufruf:

Delphi-Quellcode:

var
  Strings: TStringList;
begin
  Strings := TStringList.Create;
  try
    Foobar(Strings);
    // Mach was mit Strings
  finally
    Strings.Free;
  end;

Damit ist auch der Aufrufer der Funktion für das Freigeben verantwortlich und man hat alles zusammen und man muss nicht wild umher scrollen, um den Ort zu finden, wo das Objekt wieder freigegeben wird.

[Mysterio08]

Generell weiß ich natürlich, wie man Objekte erstellt und wieder freigibt. Nur nicht, wenn der Rückgabewert ein Objekt, wie z.B. TStringList, ist.

Zitat:

Zitat von DeddyH (Beitrag 1070017)

Delphi-Quellcode:

function funktion: TStrings;
begin
  Result := TStringlist.Create;
  try
    Result.Add('Eins');
    Result.Add('Zwei');
  except
    FreeAndNil(Result);
    raise;
  end;
end;

Ich bin mal mit dem Compiler durchgesprungen: Der Except-Block wird nicht durchlaufen und somit das Objekt auch nicht freigegeben. Oder habe ich noch nicht richtig verstanden, was "raise" macht?

[DeddyH]

@Luckie: Hatten wir das nicht schon 2 mal gesagt? :gruebel:
@Mysterio: hast Du denn auch eine Exception provoziert?

[Mysterio08]

Zitat:

Zitat von DeddyH (Beitrag 1070030)

@Mysterio: hast Du denn auch eine Exception provoziert?

Nein, habe ich nicht. Das heißt dann aber auch: Wenn keine Exception (bewusst) ausgelöst wird, wird das Objekt nicht freigegeben! Irgendwie ein wenig "verkrampft" dieses Prinzip, wie es mir gerade erscheint...

[DeddyH]

Du willst das Objekt ja zurückgeben, daher darf es natürlich nicht innerhalb der Funktion freigegeben werden (wir machen das ja nur im Fehlerfall und geben über die Exception Rückmeldung, dass etwas schief gegangen ist). Und wie Du selbst bemerkst, ist diese Vorgehensweise daher alles andere als optimal.

[Deep-Sea]

Delphi-Quellcode:

function UnsichereMethode: TStringList;
begin
  Result := TStringlist.Create;
  Result.Add('Eins');
  raise Exception.Create('Ein Test.');
  Result.Add('Zwei');
end;

function SichereMethode: TStringList;
begin
  Result := TStringlist.Create;
  try
    Result.Add('Eins');
    raise Exception.Create('Ein Test.');
    Result.Add('Zwei');
  except
    Result.Free;
    raise;
  end;
end;

procedure TueEtwas;
var
  LList: TStringList;
begin
  LList := SichereMethode;
  try
    // Tue etwas mit LList
  finally
    LList.Free;
  end;
end;

Würdest du nun in TueEtwas anstatt SichereMethode die Funktion UnsichereMethode aufrufen, würde ein Speicherleck entstehen, da du das LList.Free in TueEtwas nie erreichst. Darum ist in SichereMethode der Try-except-Block, um im Fehlerfall die Liste freizugeben und somit ein Speicherleck zu verhindern.

[Luckie]

Zitat:

Zitat von DeddyH (Beitrag 1070030)

@Luckie: Hatten wir das nicht schon 2 mal gesagt? :gruebel:

Ja, hattet ihr. Aber ich hatte im Thread noch keinen schönen Beispielcode gesehen, deswegen noch mal von mir.

[DeddyH]

Zitat:

Zitat von Luckie (Beitrag 1070035)

Aber ich hatte im Thread noch keinen schönen Beispielcode gesehen, deswegen noch mal von mir.

Die möglichen Spielarten standen doch bereits in #2, aber egal.

[Christian Seehase]

Moin Mysterio,

Zitat:

Zitat von Mysterio08 (Beitrag 1070029)

Generell weiß ich natürlich, wie man Objekte erstellt und wieder freigibt. Nur nicht, wenn der Rückgabewert ein Objekt, wie z.B. TStringList, ist.

Genau deshalb sollte man es vermeiden ein Objekt als Rückgabewert einer Funktion zu verwenden.
Es wird zu unübersichtlich. Man kann sich dabei zu leicht Speicherlecks, oder Exceptions auf Grund an falscher Stelle freigegebener Objekte einhandeln.

Eine Ausnahme fällt mir dazu aber auch noch ein:
Wenn es sich um eine Methode einer Klasse handelt, die die zurückgegebenen Objekte selber verwaltet, z. B. TListView.
TListView verwaltet die Items selber, so dass TListItem als Rückgabewert von TListView.Items.Add kein Problem darstellt.

Zitat:

Zitat von Mysterio08 (Beitrag 1070029)

Zitat:

Zitat von DeddyH (Beitrag 1070017)

Delphi-Quellcode:

function funktion: TStrings;
begin
  Result := TStringlist.Create;
  try
    Result.Add('Eins');
    Result.Add('Zwei');
  except
    FreeAndNil(Result);
    raise;
  end;
end;

Oder habe ich noch nicht richtig verstanden, was "raise" macht?

Raise ruft die Exception auf Grund derer in den except-Zweig verzweigt wurde noch einmal auf.
Erst wird die Exception abgefangen (try/except), dann das Objekt freigegeben (FreeAndNil(Result)) und dann der Grund für den Fehler erneut angezeigt (raise).