Clientbereich eines eigenen Controls beschränken

[RSE]

Hallo,

ich entwickle ein eigenes von TCustomControl abgeleitetes Control. Dessen Clientbereich soll nicht den ganzen Bereich des Controls umfassen, sondern oben einen von Caption abhängigen Bereich ausklammern. Der Clientbereich verändert sich also (wegen Zeilenumbruch) abhängig vom Caption in der Höhe und in der Position (Top). Was ich bis jetzt herausgefunden habe: Lediglich ClientHeight und ClintWidth kann man schreiben. Diese Werte verändern allerdings auch direkt Width und Height (was ich natürlich nicht will). Wie man den Top-Wert des Clientbereichs ändern kann, habe ich noch nicht herausgefunden. Die Elemente im Clientbereich sollen relativ zur oberen linken Ecke des Clientbereichs gleich positioniert bleiben, wenn ich diesen verschiebe.

Wie ist das korrekte Vorgehen beim Anpassen des Clientbereichs bei der Eigenentwicklung eines Controls?

[uligerhardt]

Wenn ich dich recht verstehe, willst du AdjustClientRect überschreiben.

[RSE]

Zitat:

...die Eigenschaft ClientRect nicht mit dem Bereich identisch ist, in dem untergeordnete Objekte angezeigt werden können.

Ich dachte eigentlich, dass ich ClientRect selbst ändern müsste. Ich werde mal probieren, was AdjustClientRect bewirkt.

[RSE]

Nein, durch ein Überschreiben von AdjustclientRect verschieben sich die untergeordneten Elemente auch nicht von selbst. Ich drücke mich mal etwas bildlicher aus, vielleicht habe ich es ja immernoch nicht korrekt formulieren können, was ich will:

Meine Komponente heiße MyControl. "Innerhalb" MyControl gebe es eine MyCheckbox, so dass MyCheckbox.Parent = MyControl. Wenn ich nun MyCheckbox.Top := 0 setze, dann soll MyCheckbox nicht bei MyControl.Top gezeichnet werden, sondern bei MyControl.Top+CaptionHeight. Meine Interpretation: Der Clientbereich von MyControl muss um CaptionHeight nach unten verschoben und in der Höhe um CaptionHeight verringert werden. Jedesmal, wenn sich CaptionHeight ändert, möchte ich den Clientbereich von MyControl anpassen. Dadurch soll MyCheckbox automatisch immer direkt unter dem Anzeigebereich von MyControl.Caption positioniert werden. Ist das nicht genau das, was die ganzen Client-Eigenschaften aussagen?

[ChrisE]

Hallo,

versuche mal die GetClientRect-Methode von TControl zu überschreiben.

Greez, Chris

[RSE]

GetClientRect ist ja letztlich auch nur ein WinAPI-Aufruf. Irgendwie muss der Clientbereich schon im Windows ordentlich gesetzt werden.

Inzwischen bin ich so weit ein Panel zu benutzen. Dann wäre der Clientbereich eben der Bereich des Panels... aber dann muss ich ja auch alles erst umbiegen auf das Panel. Weniger Aufwand wird das bestimmt nicht, unschön wär es dazu, aber es ginge...

[ChrisE]

Nein,

GetClientRect ist eine protected-Methode von TControl die virtuell deklariert ist. Diese wird z.B. aufgerufen um die property ClientRect den Wert zu geben. Schau dir bitte die Sourcen von TControl etc. an. Dann wirast du es sehen.

Greez, Chris

[RSE]

Du hast Recht. Und in TWinControl wird das Ergebnis von TControl mit dem Ergebnis der WinAPI-Funktion GetClientRect überschrieben. Wenn ich das ändere, dann erhalte ich das gleiche eigenartige Ergebnis, wie wenn ich WMNCCalcSize überschreibe und entsprechend ändere: MyCheckbox wird weiterhin über die Caption gezeichnet, aber der Hintergrund wird außerhalb vom eingeschränkten ClientRect nicht mehr gezeichnet...

[RSE]

Korrektur meiner Aussage von eben:
Mein Test mit WMNCCalcSize verschiebt die MyCheckBox dorthin, wo ich sie haben will. Ich muss jetzt nur noch all das selbst zeichnen, was außerhalb des eingeschränkten Clientbereichs liegt.

Code:

procedure TMyControl.WMNCCalcSize(var Message: TWMNCCalcSize);
begin
  with Message.CalcSize_Params^ do
    Inc(rgrc[0].Top,FCaptionHeight);
  inherited;
end;

[ChrisE]

Hallo,

du könntest auch von TGraphicControl ableiten (wie z.B. TSpeedButton auch).

Greez, Chris

[Bummi]

vielleicht kannst Du aus diesem Versuch was basteln??

Delphi-Quellcode:

unit Unit5;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type
  TMyWrapper=Class(TWincontrol)

  End;
  TMyComponent=Class(TwinControl)
    private
    MyParent:TWinControl;
    FLabel:TLabel;
    Constructor Create(AOwner:TComponent);override;
    Destructor Destroy;override;
    function GetParent: TwinControl;
    procedure SetParent(const Value: TwinControl);
    function Getheight: Integer;
    function GetWidth: Integer;
    procedure SetHeight(const Value: Integer);
    procedure SetWidth(const Value: Integer);
    public
    published
    Property Parent:TwinControl Read GetParent Write SetParent;
    Property Width:Integer read GetWidth Write SetWidth;
    Property Height:Integer read Getheight Write SetHeight;
  End;

  TForm5 = class(TForm)
    Label1: TLabel;
    Button1: TButton;
    Panel1: TPanel;
    procedure Button1Click(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form5: TForm5;

implementation

{$R *.dfm}

{ TMyComponent }

constructor TMyComponent.Create(AOwner: TComponent);
begin
   inherited create(AOwner);
   MyParent:=TMyWrapper.Create(nil);
   FLabel:=TLabel.Create(nil);
   Flabel.parent := MyParent;
   Flabel.Align := alTop;
   Flabel.Caption :='Test';
   inherited Parent := MyParent;
   Align := alClient;
end;

destructor TMyComponent.Destroy;
begin
  Parent := nil;
  Flabel.Free;
  inherited;
end;

function TMyComponent.Getheight: Integer;
begin
    Result := MyParent.Height;
end;

function TMyComponent.GetParent: TwinControl;
begin
  Result := MyParent.Parent;
end;

function TMyComponent.GetWidth: Integer;
begin
    Result := MyParent.Width;
end;

procedure TMyComponent.SetHeight(const Value: Integer);
begin
       MyParent.Height:= value;
end;

procedure TMyComponent.SetParent(const Value: TwinControl);
begin
   MyParent.Parent := value;
end;

procedure TMyComponent.SetWidth(const Value: Integer);
begin
         MyParent.Width:= value;
end;

procedure TForm5.Button1Click(Sender: TObject);
var
  my:TMyComponent;
  b:TButton;
begin
  my:=TMyComponent.Create(Self);
  With my do
    begin
      parent := panel1;
      width := 100;
      Height := 100;
    end;
  b := TButton.Create(my);
  With b do
    begin
      top := 0;
      left := 0;
      Width := 100;
      Height := 20;
      Caption :='Test';
      parent := my;
    end;
end;

end.

[RSE]

Hm, mit Align zu arbeiten wäre eine einfachere Möglichkeit gewesen, aber jetzt bin ich fast am Ziel :-) Ich habe folgendes programmiert:

Delphi-Quellcode:

    ...
    procedure SetHTMLCaptionHeight(const AValue: Integer); // löst alles aus

    procedure WMNCCalcSize(var Message: TWMNCCalcSize); message WM_NCCALCSIZE;
    procedure WMNCPaint(var Message: TWMNCPaint); message WM_NCPAINT;
    property HTMLCaptionHeight: Integer read FHTMLCaptionHeight write SetHTMLCaptionHeight;
    ...

procedure TCustomChoiceGroup.SetHTMLCaptionHeight(const AValue: Integer);
begin
  if FHTMLCaptionHeight = AValue then
    Exit;
  FHTMLCaptionHeight := AValue;
  // hier Win über notwendiges Resize informieren... wie?
end;

procedure TCustomChoiceGroup.WMNCCalcSize(var Message: TWMNCCalcSize);
begin // das muss nach SetHTMLCaptionHeight aufgerufen werden
  with Message.CalcSize_Params^ do
    Inc(rgrc[0].Top,FHTMLCaptionHeight); // Einschränkung des ClientRect
  inherited;
end;

procedure TCustomChoiceGroup.WMNCPaint(var Message: TWMNCPaint);
var
  DC: HDC;
  c: TCanvas;
begin // TCustomChoiceGroup.Canvas ist nur für den Client-Bereich
  c := TCanvas.Create;
  try
    DC := GetWindowDC(Handle);
    try
      c.Handle := DC;
      c.Brush.Color := Color;
      c.FillRect(Rect(0,0,Width,FHTMLCaptionHeight));
      HTMLDraw(c,Rect(0,0,Width,FHTMLCaptionHeight),HTMLCaption,False);
    finally
      ReleaseDC(Handle, DC);
    end;
  finally
    c.free;
  end;
  Message.Result := 0;
end;

Mit InvalidateRect kann ich Neuzeichnen initiieren, aber was muss ich für eine Message verschicken, damit ich WM_NCCALCSIZE zurückbekomme? Die ganzen VCL-Lösungen beziehen sich offenbar auf die Client-Area.

Edit:
Da sich die restliche Frage mehr auf die WinAPI bezieht, werde ich den Rest mal im entsprechenden Forum zu Ende führen:
http://www.delphipraxis.net/152921-w...geaendert.html