TTimer als Var im Constructor eines TForms übergeben

[razer91]

Hallo Leute,

ich habe folgendes Problem:

Ich versuche bei der manuellen Erstellung eines Formulars einen Timer zu übergeben:

Delphi-Quellcode:

procedure TdmMain.DataModuleCreate(Sender: TObject);
var
  mp: TMethodePionter;
begin
  fTiPostpone := TTimer.Create(self);
  fTiPostpone.Enabled := false;


  frmRem := TfrmRem.Create(fTiPostpone); //hier Erstellungsversuch
  frmRem.Show();
end;

// hier constructor

constructor TfrmRem.Create(var Timer: TTimer);
begin
  inherited Create(nil);

  fTiPostpone := Timer; // "fTiPostpone" ist hier eine private Variable des "frmRem".
end;

Ich bekomme in dem "inherited"-Abschnitt eine Exception "TTimer-Klasse konnte nicht gefunden werden" oder so ähnlich. Ich frage mich hierbei, warum er an dieser Stelle schon etwas mit dem Timer anfangen will, obwohl ich zuerst einmal das alte Create() aufrufe und dann den Timer-Kram mache...

Ich denke es handelt sich bei diesem Problem um eine Kleinigkeit, aber ich komme einfach nicht drauf :( .
Hat jemand eine Idee?

Grüße
razer91

[s.h.a.r.k]

Hm, hast du die Unit ExtCtrls unter uses eingebunden? Erscheint die Exception zur Laufzeit des Programms?

[razer91]

Zitat:

Zitat von s.h.a.r.k (Beitrag 1032492)

Hm, hast du die Unit ExtCtrls unter uses eingebunden? Erscheint die Exception zur Laufzeit des Programms?

Ja habe ich. Der Fehler tritt zur Laufzeit auf beim Erstellen des Formulars im "inherited" Abschnitt.

[himitsu]

Warum eigentlich VAR?
Du willst doch die externe Variable nicht verändern. :gruebel:

versuch's mal andersrum (falls es funktioniert und wenn man nun NIL als Timer übergibt, also keinen Timer, dann hätte man das Selbe Problem, wie vorher)

Delphi-Quellcode:

constructor TfrmRem.Create(Timer: TTimer);
begin
  fTiPostpone := Timer; 
  inherited Create(nil);
end;

Wie und wo ist denn fTiPostpone nun genau definiert und gibt es ein Property auf dieses Feld?
> Private, Public, Published, ...

[SirThornberry]

Bist du dir sicher mit der Fehlermeldung? Wird nicht eventuell bemängelt das die Ressource (dfm) für dein Formular nicht gefunden wird?

[Bernhard Geyer]

Dieses Konstrukt würde ich nicht so machen. Bei Formularen sollte man nicht den Konstruktor mit anderen Parametern überladen. Nimm dafür lieber ein Property.

Hast du denn überhaupt zu deinem Formular eine DFM? Falls nein: Du musst eine der Basismethoden überschreiben (AfterCreate oder so ähnlich) in der Versucht wird das DFM zu laden. TForm-Nachfolger erwarten im Normalfall eine DFM die geladen wird.

[razer91]

Das mit der DFM ist ein guter Hinweis... wenn ich zu Hause bin werde ich es gleich versuchen.

[razer91]

Also ich hab es mir noch mal angeguckt - und eine DFM ist in der Tat vorhanden.

@himitsu: der Timer soll auch noch erhalten bleiben, deshalb als var.

Ich habe deinen Vorschlag aufgegriffen und den Timer als Property im frmRem gesetzt. Allerdings mit der gleichen Fehlermeldung zur Laufzeit

"Klasse TTimer nicht gefunden". Wie gesagt, die Unit ExtCtrls ist in den uses (sonst würde Delphi ja gar nicht bauen).

Hat jemand noch eine Idee. Soll ich noch mehr Code posten? Sagt mir bitte bescheid. Bin gerade ein bisschen am Verzweifeln :(.

Gruß

[Bummi]

wenn Du verzeweifels schick mal etwas mehr Code, wenn Du willst auf per PN.

[razer91]

so weltklasse ist der Code nicht, dass er geheim bleiben müsste :D:

Main Datamodule:

Delphi-Quellcode:

unit DataModuleMain;

interface

uses
  SysUtils, Classes, ExtCtrls, FormMain;

type
  TdmMain = class(TDataModule)
    procedure DataModuleCreate(Sender: TObject);
  private
   frmRem: TfrmRem;
   procedure OnTimerTimeOut(Sender: TObject);
  public
  end;

var
  dmMain: TdmMain;
  gTiPostpone: TTimer;

implementation

{$R *.dfm}

type
  TMethodePionter = packed record
    pMethod: Pointer;
    pObject: TObject;
  end;

procedure TdmMain.DataModuleCreate(Sender: TObject);
var
  mp: TMethodePionter;
begin
  gTiPostpone := TTimer.Create(self);
  gTiPostpone.Enabled := false;

  mp.pMethod := @TdmMain.OnTimerTimeOut;
  mp.pObject := nil;
  gTiPostpone.OnTimer := TNotifyEvent(mp);

  frmRem := TfrmRem.Create(self);
  frmRem.PostPoneTimer := gTiPostpone;
  frmRem.Show();
end;

procedure TdmMain.OnTimerTimeOut(Sender: TObject);
begin
  gTiPostpone.Enabled := false;
  if not Assigned(frmRem) then
    frmRem := frmRem.Create(self);
  frmRem.PostPoneTimer := gTiPostpone;
  frmRem.Show();
end;

end.

und das ominöse frmRem ;)

Delphi-Quellcode:

unit FormRem;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls;

type
  TfrmRem = class(TForm)
    Label1: TLabel;
    Label2: TLabel;
    cbTimeChoice: TComboBox;
    btOpenOutlook: TButton;
    btPospone: TButton;
    procedure btOpenOutlookClick(Sender: TObject);
    procedure btPosponeClick(Sender: TObject);
  private
    fTiPostpone: TTimer;
    procedure SetTimerInterval(var Timer: TTimer; const nSecs, nMins, nHours : Cardinal);
  public
    property PostPoneTimer: TTimer read fTiPostpone write fTiPostpone;
  end;

Danke schon einmal :)!

[SirThornberry]

Zitat:

Zitat von Bummi (Beitrag 1032720)

wenn Du verzeweifels schick mal etwas mehr Code, wenn Du willst auf per PN.

Bitte nicht per PN. Das würde den Sinn eines Forums untergraben. Denn dann hat nur der fragende etwas davon und alle anderen die später das gleiche Problem haben fangen wieder von vorn hat.

[Bummi]

ich verstehe zwar den teil nicht ganz

Delphi-Quellcode:

  mp.pMethod := @TdmMain.OnTimerTimeOut;
  mp.pObject := nil;
  gTiPostpone.OnTimer := TNotifyEvent(mp);

und das ist böse

Delphi-Quellcode:

  if not Assigned(frmRem) then
    frmRem := frmRem.Create(self);

aber bei mir meckert der Compiler nicht an;

[razer91]

Zitat:

Zitat von Bummi (Beitrag 1032733)

ich verstehe zwar den teil nicht ganz

Delphi-Quellcode:

  mp.pMethod := @TdmMain.OnTimerTimeOut;
  mp.pObject := nil;
  gTiPostpone.OnTimer := TNotifyEvent(mp);

und das ist böse

Delphi-Quellcode:

  if not Assigned(frmRem) then
    frmRem := frmRem.Create(self);

aber bei mir meckert der Compiler nicht an;

1) warum ist das böse?^^
2) meckert er zur Laufzeit auch nicht?

[Bummi]

1.)
du hast Dich vertippt
if not Assigned(frmRem) then
frmRem := frmRem.Create(self);
statt
if not Assigned(frmRem) then
frmRem := TfrmRem.Create(self);

2.)
Tut twar nichts außer Fenster anzeigen, läut aber...

[Bummi]

es gibt noch eine Falle:
DataModuleMain;
private
frmRem: TfrmRem;


heißt wahrscheinlich (der Teil Code fehlte im Post) genauso wie

FormRem;
var
frmRem: TfrmRem;

hier kannst Du nie sagen welche der Variablen jetzt an welcher Stelle greift.

[razer91]

Auch die beiden letzten Tipps haben den Fehler nicht abstellen können.

@Bummi: Die Variable, die sich standardmäßig in dem frmRem befinden müsste hab ich gelöscht, um genau der Falle, die du angedeutet hast, vorzubeugen.

Noch weitere Vorschläge??

Gruß

[himitsu]

Zitat:

Zitat von razer91 (Beitrag 1032718)

@himitsu: der Timer soll auch noch erhalten bleiben, deshalb als var.

var nimmt man, wenn man was ändern will ... also wenn was unverändert "erhalten" bleiben soll, dann kein var

[Wormid]

Hallöchen,

abgesehen davon, dass sich mir der Sinn für dein Konstrukt nicht erschliesst und ich glaube, das du dich da in etwas verrannt hast, was du eventuell noch überdenken müsstest... um es ans Laufen zu bekommen, sind folgende Änderungen nötig:

Da der Timer in der unit FormRem nicht benutzt wird, fehlt er zur Laufzeit und muss daher mit RegisterClass registriert werden.

Delphi-Quellcode:

unit FormRem;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls;

type
  TfrmRem = class(TForm)
    // ...
  private
    fTiPostpone: TTimer;
  public
  end;

implementation

{$R *.dfm}

{ TTfrmRem }

{...}

initialization
  RegisterClass(TTimer);

end.

Der Kram mit dem MethodPointer etc... unnötig kompliziert, kann vereinfacht werden.

Delphi-Quellcode:

unit DataModuleMain;

interface

uses
  SysUtils, Classes, ExtCtrls, FormRem;

type
  TdmMain = class(TDataModule)
    procedure DataModuleCreate(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    frmRem: TfrmRem;
    procedure OnTimerTimeOut(Sender: TObject);
  end;

var
  dmMain: TdmMain;
  gTiPostpone: TTimer;

implementation

{$R *.dfm}

//type
//  TMethodePionter = packed record
//    pMethod: Pointer;
//    pObject: TObject;
//  end;

procedure TdmMain.DataModuleCreate(Sender: TObject);
//var
//  mp: TMethodePionter;
begin
  gTiPostpone := TTimer.Create(self);
  gTiPostpone.Enabled := false;

//  mp.pMethod := @OnTimerTimeOut;
//  mp.pObject := nil;
  gTiPostpone.OnTimer := OnTimerTimeOut;  // TNotifyEvent(mp);

  frmRem := TfrmRem.Create(self);
  frmRem.PostPoneTimer := gTiPostpone;
  frmRem.Show();
end;

procedure TdmMain.OnTimerTimeOut(Sender: TObject);
begin
  gTiPostpone.Enabled := false;
  if not Assigned(frmRem) then
    frmRem := TfrmRem.Create(self);  // <--- TfrmRem.Create !!!
  frmRem.PostPoneTimer := gTiPostpone;
  frmRem.Show();
end;

end.

So müsste es jetzt funktionieren... Viel Spaß damit!

MfG

Wormid

[himitsu]

RegisterClass ... Die Exception tritt auf, weil der DFM-Loader versucht einen Timer zu laden/erstellen, welchen er nicht kennt (automatisch kennt er immer nur Komponenten, beim Compilieren in der entsprechenden DFM-Resource enthalten waren)

RegisterClass behebt also nur das Symptom und Produziert nebenbei noch eine kleines Leck,
falls der DFM-Loader einen Timer erstellt, in diesem Feld ablegt und man danach dieses Feld (Variable) mit dem externen Timer überschreibt.
(der alte Timer wird dabei nicht gelöscht)


Es wäre also besser irgendwie dem DFM-Loader beizubringen, daß ihn dieses Feld nichts angeht.
Es darf also schonmal nicht als publisches deklariert sein, was es nicht ist ... also wie/wo/warum will der DFM-Loader dort einen TTimer laden?
Diesen Grund (die Ursache) sollte man abstellen.

[razer91]

Zitat:

Zitat von himitsu (Beitrag 1032760)

RegisterClass ... Die Exception tritt auf, weil der DFM-Loader versucht einen Timer zu laden/erstellen, welchen er nicht kennt (automatisch kennt er immer nur Komponenten, beim Compilieren in der entsprechenden DFM-Resource enthalten waren)

RegisterClass behebt also nur das Symptom und Produziert nebenbei noch eine kleines Leck,
falls der DFM-Loader einen Timer erstellt, in diesem Feld ablegt und man danach dieses Feld (Variable) mit dem externen Timer überschreibt.
(der alte Timer wird dabei nicht gelöscht)


Es wäre also besser irgendwie dem DFM-Loader beizubringen, daß ihn dieses Feld nichts angeht.
Es darf also schonmal nicht als publisches deklariert sein, was es nicht ist ... also wie/wo/warum will der DFM-Loader dort einen TTimer laden?
Diesen Grund (die Ursache) sollte man abstellen.

Ich habe die DFM überprüft und in der Tat, da flog noch ein Timer rum, der wohl nicht ordnungsgemäß aus der DFM entfernt worden ist, nachdem ich ihn eigentlich vom Form gelöscht hatte.

Naja kleiner Fehler große Wirkung und ein recht opulenter Thread :D. Danke noch mal an alle für ihre Vorschläge

Grüße

[razer91]

Thread noch richtig markieren ;)