HexEditor

[Jazzman_Marburg]

Werte Gemeinde!

Ich bin dabei eine kleine Anwendung zu schreiben, die Files nach bestimmten Kriterien untersuchen soll. Dazu würde ich dem User gern auch einen HexEditor zur Verfügung stellen. Nun ist mir auf Koders.com die freie Unit Hexeditor aufgefallen.
Hat jemand damit schon Erfahrung sammeln können?
Ich frage deshalb, weil ich die Unit nicht compilieren kann, weil der Compiler bei der Stelle:

Delphi-Quellcode:

ctEBCDICToISO : array [0..255] of Char = (
                          #0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,
                          #0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,
                          #0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,
                          #0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,
                          ' ',#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,#0 ,'.','<','(','+','',   // hier!

folgendes auswirft:

Delphi-Quellcode:

E2010 Inkompatible Typen: 'Char' und 'String'

Und das an einigen ähnlichen Stellen. (Ich frage mich, ob ich die Unit vielleicht im falschen Format gespeichert habe...)

Meine zweite Frage wäre dann, wie man das Ding zum Fliegen bringt -- leider kein Beispiel (oder ich habe es nicht gesehen) dabei.

Vielleicht hat das Ding ja schon jemand eingesetzt -- oder kennt einen besseren freien HexEditor (mit Source, nicht als Component, da ich nur TurboDelphi habe).

Vielen Dank & schönen Gruß
Jazzman

[jaenicke]

Der Fehler ist klar: An der Stelle steht ein leerer String. Ein Char wird aber erwartet, und ein Buchstabe kann entweder ein einbuchstabiger String sein oder ein Zeichen direkt (#). Aber eben kein String ohne Buchstabe. ;-)

Heißt: Einfach nen Leerzeichen rein und schon sollte es kompilieren. Ob das an der Stelle richtig ist, ist ne andere Frage. :mrgreen:

[Jazzman_Marburg]

:-D Super!

Das hat schon geholfen -- beim Download oder Speichern müssen da wohl ein paar Blanks flöten gegangen sein.

Vielen Dank!
Jazzman

[hathor]

Hier ist ein Programm, in dem diese Unit verwendet wird:
http://downloads.sourceforge.net/resbuilder/RB.zip

[Jazzman_Marburg]

Zitat:

Zitat von hathor

Hier ist ein Programm, in dem diese Unit verwendet wird:
http://downloads.sourceforge.net/resbuilder/RB.zip

Puuuh :shock:
Vielen Dank für den Hinweis -- aber geht es wohl auch eine Nummer kleiner? Auf ein Anwendungsbeispiel hatte ich tatsächlich gehofft -- aber bei diesen Beispiel brauche ich wohl Tage um zu verstehen, wie man den HexEditor im eigenen Programm verwendet.

Hat denn niemand bisher den HexEditor von Markus Stephany zum Laufen gebracht? Mein Problem ist, dass ich mit TurboDelphi keine Komponenten intsallieren kann -- ich aber die Sorucen von Markus Stephany heruntergeladen habe, und nun überfordert bin, den HexEditor in dieser Form zum Laufen zu bekommen. (Der Autor aber keine Fragen zu diesem Projekt wünscht.)

Wenn sich da vielleicht noch jemand fände, der mir die Bretter vor den Augen entfernt?

Auf der genannten Seite findest sich sogar ein Beispiel für einen HexViewer (genau das was ich suche) -- aber da wird auch auf die TMPHexEditorEx Komponente zugegriffen -- die ich ja so nicht gebrauchen kann.

In der Hoffnung, es findet sich noch ein Experte diesbezüglich
grüßt
Jazzman

[DeddyH]

Kannst Du die Komponente denn nicht einfach zur Laufzeit auf Dein Form klatschen?

[Jazzman_Marburg]

Zitat:

Zitat von DeddyH

Kannst Du die Komponente denn nicht einfach zur Laufzeit auf Dein Form klatschen?

:gruebel: Ähmm...
das verstehe ich nicht:
a) Komponenten klatsche ich doch nur zur Designzeit auf die Form, oder?!
b) Komponente ist grundsätzlich schlecht bei TurboDelphi, da nicht möglich.

Oder habe ich Deinen Hinweis missverstanden?


Danke & Gruß, Jazz

[DeddyH]

Natürlich ist das möglich, nur eben nicht zur Designtime. Es hält Dich aber niemand davon ab, die entsprechende Unit einzubinden und die Komponente zur Laufzeit dynamisch zu erzeugen.

[Jazzman_Marburg]

Hmmm,
also ich habe die beiden Units eingebunden:

Delphi-Quellcode:

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, MPHexEditor, MPHexEditorex;

...
VAR
  MyEditor1 := TMPHexEditorEx;

Beim OnCreate meiner Anwendung steht dann:

Delphi-Quellcode:

procedure TForm1.FormCreate(Sender: TObject);
begin
  MyEditor1.Create(Self);
end;

Nach einem F9 kommt aber die Exception:

Delphi-Quellcode:

EAccessViolation "Zugriffsverletzung bei Adresse...

Dachtest Du an so etwas?
Sehr verwirrend das.

Jazzman

[DeddyH]

Zitat:

Delphi-Quellcode:

MyEditor1.Create(Self);

Das sollte wohl eher

Delphi-Quellcode:

MyEditor1 := TMPHexEditorEx.Create(Self);

heißen ;)

[jaenicke]

Um es zu erklären: Sonst wird von dem nicht existenten Objekt in MyEditor1 die Methode Create aufgerufen. Da an der Adresse kein Zugriff möglich ist gibt es eine Schutzverletzung.

Die Deklaration von MyEditor1 hat aber nichts als globale Variable suchen. Das gehört in das Formular hinein...

Delphi-Quellcode:

TfrmYourForm = class(TForm)
...
private
  FMyEditor: TMPHexEditorEx;
public
end;

[DeddyH]

Ich hab mal schnell ein Beispiel mit einem dynamisch erzeugten Memo erstellt. Ich hoffe, das macht das Prinzip etwas klarer. Zur Designtime handelt es sich einfach nur um ein leeres Formular.

Delphi-Quellcode:

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls{für TMemo};

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    { Private-Deklarationen }
    FDynamicMemo: TMemo;
    procedure OnMemoClick(Sender: TObject);
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin
  //Erzeugen des Memos
  FDynamicMemo := TMemo.Create(nil);
  FDynamicMemo.Parent := self;
  //Setzen einiger Properties
  FDynamicMemo.Height := 80;
  FDynamicMemo.Align := alBottom;
  FDynamicMemo.Lines.Clear;
  FDynamicMemo.Lines.Add('Ich bin hier unten angewurzelt,');
  FDynamicMemo.Lines.Add('dass niemand aus dem Fenster purzelt.');
  //Zuweisung eines Event-Handlers
  FDynamicMemo.OnClick := OnMemoClick;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  //Freigeben des Memos
  FDynamicMemo.Free;
end;

procedure TForm1.OnMemoClick(Sender: TObject);
begin
  if Sender is TMemo then
    ShowMessage(TMemo(Sender).Lines.Text);
end;

end.

[Jazzman_Marburg]

Nagut, nagut :mrgreen:
die Deklaration ist nun die Form verschoben:

Delphi-Quellcode:

type
  TForm1 = class(TForm)
    Panel1: TPanel;
    procedure FormCreate(Sender: TObject);
  private
    { Private-Deklarationen }
    MyEditor1: TMPHexEditorEx;
  public
...

Deweiteren heisst es im OnCreste der Form1 nun richtigerweise:

Delphi-Quellcode:

  MyEditor1 := TMPHexEditorEx.Create(Self);

Aus dem mitgeliefertem Beispiel lese ich weiters, dass ein Assert folgt:

Delphi-Quellcode:

  procedure TForm1.FormCreate(Sender: TObject);
begin
  MyEditor1 := TMPHexEditorEx.Create(Self);
  Assert(MyEditor1 is TCustomGrid);

Soweit kein Fehler beim Compilieren, aber sobald ich versuche (wie im Beispiel) dem Editor eine Datei zu übergeben:

Delphi-Quellcode:

  procedure TForm1.FormCreate(Sender: TObject);
begin
  MyEditor1 := TMPHexEditorEx.Create(Self);
  Assert(MyEditor1 is TCustomGrid);

  MyEditor1.LoadFromFile('Test1.TXT');  // Exception!

fliegt mir das Projekt um die Ohren ('Test1.TXT' existiert):

Delphi-Quellcode:

  "EInvalidOperation: Element hat kein übergeordnetes Fenster"

Eine Idee, was ich da noch falsch mache?

(Vielen Dank für die bisherigen, wertvollen Hinweise!)
Jazzman

[DeddyH]

Du musst noch den Parent zuweisen (siehe mein Beispiel).

[Jazzman_Marburg]

Haaalt!

Letzter Beitrag hat sich erledigt.

Aus dem Beispiel von Detlef:
"Du musst noch den Parent zuweisen (siehe mein Beispiel)."

Dann hat es tatsächlich gekplappt!!!


Suuper!
Vielen, vielen Dank!

Jazzman

[jaenicke]

Dass es so klappt, ist aber Zufall, denn du hast vergessen den Pfad mit dazuzuschreiben:
http://www.delphi-library.de/viewtopic.php?p=499701

Aber ich vermute einmal das war ohnehin nur für den Test so.

[Jazzman_Marburg]

Abschlußkommentar

Zunächst großes Dankeschön an alle Mitwirkenden! Ohne diese Hilfe hätte ich es nicht hinbekommen.

Hier noch mal eine vollständige Zusammenfassung wie man den HexEditor von Markus Stephany zum fliegen bekommt (auch unter TurboDelphi!):

Benötigt werden:
MPDELVER.INC
MPHexEditor.RES
MPHexEditor.PAS
MPHexEditorEx.PAS und zusätzlich die GRIDS-Unit


Dann im Projekt:

Delphi-Quellcode:

unit U_Main;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, MPHexEditor, MPHexEditorex, ExtCtrls, Grids;

type
  TForm1 = class(TForm)
    procedure FormCreate(Sender: TObject);
  private
    { Private-Deklarationen }
    MyEditor1: TMPHexEditorEx;
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin

  MyEditor1 := TMPHexEditorEx.Create(Self);
  Assert(MyEditor1 is TCustomGrid);
  MyEditor1.Parent := self;
  MyEditor1.LoadFromFile('Test1.TXT');

end;

end.

Und schon klappts!
Vielleicht hilft es ja noch jemanden.

Also, schönen Sonntag noch weiters und vielen Dank.

Gruß
Jazzman