D7 falscher Compiler-Hinweis: Auf xxxx zugewiesener Wert ...

[p80286]

Hallo zusammen,

Ihr habt alle bestimmt schon die Meldung "Auf xxxx zugewiesener Wert wird niemals genutzt" gehabt. Ist ja auch nicht weiter schlimm, solange es bei dem Hinweis bleibt.
Wenn allerdings die entsprechenden Zeilen vom Compiler ignoriert werden, find ich das garnicht lustig. Insbesonders wenn der Hinweis auch noch falsch ist.

Delphi-Quellcode:

if fpos<=pufflen then begin
            setlength(pPosListrec^.Positions,pPosListrec^.Positions[0]+2);
            inc(pPosListrec^.Positions[0],1);
            pPosListrec^.Positions[pPosListrec^.Positions[0]]:=fpos+chkpos;
            if fpos>1 then begin         
              chkpos:=chkpos+fpos-1;
              move(buffer[fpos],buffer[1],gelesen+lpos-1-(fpos-1));
              move(UpCbuffer[fpos],UpCbuffer[1],gelesen+lpos-1-(fpos-1));
              pufflen:=pufflen-(gelesen+lpos-1-(fpos-1));{<------------------------hier gibt's mecker }
              if gelesen=lies then       { Dateiende noch nicht erreicht}
                blockread(edat,buffer[maxbuff-(fpos-2)],fpos-1,gelesen)
              else
                gelesen:=0;              { Dateiende erreicht}
              pufflen:=pufflen+gelesen;{<------------------------hier gibt's mecker }
            end;

Wie kann ich dem Compiler Seine Starrsinngkeit austreiben ( D7)?

Gruß
K-H

[DeddyH]

Steht der Code innerhalb einer Schleife? Ansonsten wäre die Meldung doch völlig korrekt.

[himitsu]

Also mein D7 kürzt hier nix weg. :gruebel:

Aber du kannst ja dennoch mal versuchen in dem betreffenden Codeabschnitt die Codeoptimierung abzuschalten:

{$O-}
oder
{$OPTIMIZATION OFF}

[hoika]

Hallo,

Delphi-Quellcode:

pufflen:=pufflen-(gelesen+lpos-1-(fpos-1));{<------------------------hier gibt's mecker }

-1 -(-1) = -1+1

Das könnte man zumindestens schon mal "wegkürzen"

Is das denn die einzige Warnung des Compilers ?
Vielleicht ist pufflen nicht initialisiert und wo wird sie nach deinem Code benutzt ??


Heiko

[DeddyH]

Verschwindet die Meldung, wenn man am Ende der Methode pufflen einmal ausgeben lässt?

[himitsu]

Wird pufflen nach diesen Zuweisungen (also nach diesem Code und somit in den uns verschwiegenen Codeteilen) überhaupt verwendet?

Wenn nicht, dann ist diese Aussage ja korrekt.

PS: Wieso mischen eigentlich so viele deutsche und engliche Namen? (z.B. buffer und gelesen)
PSS: buffer, maxbuff oder pufflen (PufferLength oder wie? )

[DeddyH]

@himi: Sag ich das nicht bereits die ganze Zeit? Du solltest auch mal lesen, was andere schreiben :tongue:

[p80286]

Danke für die Antworten.

1) das Kauderwelsch ist dem Alter der Anwendung und den verzweifelten Versuchen über Variablennamen das Problem in den Griff zu bekommen geschuldet.
2) pufflen wird genau einmal benötigt/gebraucht/abgefragt und zwar in der ersten Zeile! (ist ein Ausschnitt aus repeat..until)
und am Anfang der Schleife wird pufflen neu belegt.

@hoika
Die "ungekürzte" Version bleibt mir so lange erhalten bis das ich alles "sauber" habe. (ist sowas ähnliches wie list.count-1)

Auf die Idee mit {$OPTIMIZATION OFF} bin ich auch schon gekommen, aber wird der Code dann nicht elendig langsam?

Gruß
K-H

[Luckie]

Zitat:

Zitat von p80286

2) pufflen wird genau einmal benötigt/gebraucht/abgefragt und zwar in der ersten Zeile! (ist ein Ausschnitt aus repeat..until)
und am Anfang der Schleife wird pufflen neu belegt.

Dann poste doch ,mal den ganzen relevanten Code und nicht nur diesen Ausschnitt.

[himitsu]

{$OPTIMIZATION ...} wirkt sich nur auf den nachfolgenden Code aus
und sooo viel langsamer sollte es eh nicht werden.

Delphi-Quellcode:

optimiert
{$OPTIMIZATION OFF}
nicht optimiert
{$OPTIMIZATION ON}
optimiert

PS: Die Dateioperation (ReadBuffer) braucht so lange, daß ein paar schnelle Assemblerbefehle und ein paar zusätzlicher/unoptimiertere Speicherzugriffe garnicht auffallen.

[Luckie]

Aber wäre es nicht sinnvoll die Ursache zu beseitigen, anstatt an den Symptomen rumzudoktern? Der Compiler wird den Hinweis nicht umsonst generieren.

[p80286]

Auf besonderen Wunsch:

Delphi-Quellcode:

function Get_StringPosList(efile:f_str;suchstr:shortstring;casesensitive:boolean=true;useunicode:boolean=false):T_pPosListrec;
var
(* ***********************
 buffer überarbeiten!!!
 ****************************************** *)
  i              : integer;
  fPos           : longint;
  chkPos         : longint;
  iniok          : boolean;
  dname          : string;
  buffer         : array [1..maxbuff] of byte;
  Cbuffer        : array [1..maxbuff] of char absolute buffer;
  pufflen        : integer;
  lpos,
  lies,
  gelesen        : integer;
  UpCbuffer      : array [1..maxbuff] of char;
  UpCsuchstr     : shortstring;
  UniCsuchstr    : widestring;
  UpCUniCsuchstr : widestring;
  pPosListrec    : T_pPosListRec;
begin
  new(pPosListRec);
  pPosListrec^.Filename:=efile;
  setlength(pPosListrec^.Positions,1);
  pPosListrec^.Positions[0]:=0;
  chkPos :=0;
  UpCsuchstr    :=uppercase(suchstr);
  UniCsuchstr   :=suchstr;
  UpCUniCsuchstr:=UpCsuchstr;
  dname:=efile;
  filemode:=0;
//  count:=0;

  assign(edat,efile);
  {$I-}
  reset(edat,1);
  {$I+}
  if ioresult=0 then begin
    if casesensitive then begin
      if useunicode then
        iniok:=INITSUCHARR(@UniCsuchStr[1],length(UniCsuchstr)*2)
      else
        iniok:=INITSUCHARR(@SuchStr[1],length(SuchStr));
    end
    else begin
      if useunicode then
        iniok:=INITSUCHARR(@UpCUnicsuchstr[1],length(UpCUnicsuchstr)*2)
      else
        iniok:=INITSUCHARR(@UpCsuchstr[1],length(UpCsuchstr));
    end;
    if not iniok then begin
      FEHLER(9,' Initialisierungsfehler!');
      result:=pPosListrec;
      exit; {zurück zur Eingabe }
    end;

    lpos:=1;
    fpos:=-1;
    lies:=maxbuff;
    repeat
      blockread(edat,buffer[lpos],lies,gelesen);
      pufflen:=lpos-1+gelesen;
      if not casesensitive then
        for i:=lpos to lpos-1+gelesen do
          UpCbuffer[i]:=upcase(Cbuffer[i]);

      if (lpos-1+gelesen)>=length(such_str) then begin
        if casesensitive then begin
          if useunicode then
            fpos:=FINDEINARR(@buffer[1],lpos+gelesen-1,@UniCsuchstr[1],length(UniCsuchstr)*2)
          else
            fpos:=FINDEINARR(@buffer[1],lpos+gelesen-1,@such_str[1],length(such_str));
        end
        else begin
          if useunicode then
            fpos:=FINDEINARR(@UpCbuffer[1],lpos+gelesen-1,@UpCUniCsuchstr[1],length(UpCUniCsuchstr)*2)
          else
            fpos:=FINDEINARR(@UpCbuffer[1],lpos+gelesen-1,@UpCsuchstr[1],length(UpCsuchstr))
        end;

        if fpos=-1 then begin          {---------------------- nichts gefunden }
          move(buffer[lpos+gelesen-length(such_str)],buffer[1],byte(such_str[0]));
          move(UpCbuffer[lpos+gelesen-length(such_str)],UpCbuffer[1],byte(such_str[0]));
          lpos:=length(such_str)+1;
          lies:=maxbuff-length(such_str);
          chkPos:=chkPos+gelesen-lpos;
        end
        else begin   {-- gefunden ---------------------------}
          inc(fpos,1);                 { fpos gilt für 0-basierte arrays!}
          if fpos<=pufflen then begin
            setlength(pPosListrec^.Positions,pPosListrec^.Positions[0]+2);
            inc(pPosListrec^.Positions[0],1);
            pPosListrec^.Positions[pPosListrec^.Positions[0]]:=fpos+chkpos;
            if fpos>1 then begin         { für fpos=1 ist gibt es bei move einen Bereichsfehler und ist auch Blödsinn }
              chkpos:=chkpos+fpos-1;
              move(buffer[fpos],buffer[1],gelesen+lpos-1-(fpos-1));
              move(UpCbuffer[fpos],UpCbuffer[1],gelesen+lpos-1-(fpos-1));
              pufflen:=pufflen-(gelesen+lpos-1-(fpos-1));
              if gelesen=lies then       { Dateiende noch nicht erreicht}
                blockread(edat,buffer[maxbuff-(fpos-2)],fpos-1,gelesen)
              else
                gelesen:=0;              { Dateiende erreicht}
              pufflen:=pufflen+gelesen;
            end;
            {-- Der gefundene String steht auf pos1...}
            move(buffer[2],buffer[1],maxbuff-1);
            move(UpcBuffer[2],UpCbuffer[1],maxbuff-1);
            inc(Chkpos,1);
            lies:=1;
            lpos:=maxbuff-1;
            fpos:=0;
          end
          else
            fpos:=-1; { Abbruchbedingung }
        end;
      end;
    until eof(edat) and (fpos=-1) ;
    close(edat);
  end;
  result:=pPosListrec;
end;{-- Get_StringPosList -----------------------------------------------}

Und bitte nicht hauen, ich weis das es nicht schön ist, sonst hätt ich es auch nicht angepackt.

Gruß
K-H

Da fehlt noch was:

Delphi-Quellcode:

T_PosListrec= record
                   Filename : string[255];
                   Positions: array of Longint; {0 - Zähler,1..n Posdaten ; Longint dami Dateien>2Gig verarbeitbar sind }
                 end;
  T_pPoslistrec=^T_PosListrec;

[Luckie]

Vorschlag: Überarbeite die Routine mal. Zerleg sie in kleinere übersichtlicher Unterroutinen und benennen mal die Variablen besser.

[DeddyH]

Am Anfang der Schleife wird pufflen gesetzt.

Zitat:

Delphi-Quellcode:

pufflen:=lpos-1+gelesen;

Danach wird es zwar noch ein paar mal verändert, aber nicht verwertet, von daher stimmt die Meldung (sofern ich nichts übersehen habe).

[edit] Nochmal ein einfaches Beispiel:

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var i, ErrorVariable: integer;
begin
  i := 0;
  repeat
    ErrorVariable := 3;
    ShowMessage(IntToStr(ErrorVariable));
    ErrorVariable := ErrorVariable + 3; //hier kommt o.a. Meldung, was ja auch stimmt
    inc(i);
  until i > 4;
end;

Hier dagegen kommt keine Meldung:

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var i, ErrorVariable: integer;
begin
  i := 0;
  ErrorVariable := 3; //Initialisierung außerhalb der Schleife
  repeat
    ShowMessage(IntToStr(ErrorVariable));
    ErrorVariable := ErrorVariable + 3;
    inc(i);
  until i > 4;
end;

[/edit]

[p80286]

@DeddyH

das wars!
Die beiden Zeilen waren vollkommen überflüssig.

Was das Kauderwelsch angeht, ich gelobe Besserung

Vielen Dank nochmal an alle!

K-H

[DeddyH]

Manchmal hat der Compiler eben auch Recht, auch wenn man das selbst anders sieht :zwinker:

[Luckie]

Zitat:

Zitat von p80286

Die beiden Zeilen waren vollkommen überflüssig.

Und bevor wir das nächste mal den Compiler die Schuld in die Schuhe schieben, suchen wir erst mal den Fehler bei uns. ;)

[p80286]

Zitat:

Zitat von Luckie

Zitat:

Zitat von p80286

Die beiden Zeilen waren vollkommen überflüssig.

Und bevor wir das nächste mal den Compiler die Schuld in die Schuhe schieben, suchen wir erst mal den Fehler bei uns. ;)

Na dann ist hier demnächst nichts mehr los, weil alle debuggen, googlen, die Hilfe nutzen und jeden Fehler zuerst bei sich suchen.

Gruß
K-H

[himitsu]

Zitat:

Zitat von p80286

Na dann ist hier demnächst nichts mehr los, weil alle debuggen, googlen, die Hilfe nutzen und jeden Fehler zuerst bei sich suchen.

Alle werden es nie werden, denn es kommen ja immer wieder neue/unwissende User dazu.

Aber stell dir mal das Gegenteil vor. :stupid:
Alle machen garnichts mehr selber und fragen erstmal hier nach ... immer wieder in einem neuen Thread, damit/da man dann in der Flut der Threads nix mehr findet.

[Luckie]

Zitat:

Zitat von p80286

Na dann ist hier demnächst nichts mehr los, weil alle debuggen, googlen, die Hilfe nutzen und jeden Fehler zuerst bei sich suchen.

Habe ich irgendwo geschrieben, dass zur Fehlersuche nicht auch das Forum benutzt werden kann und auch Beiträge erstellt werden können? Aber er hat ja im Titel behauptet der Compiler würde ihm eine falsche Meldung ausgeben, was ja nicht der Fall war.