Custom compiler message beim Aufruf einer Methode möglich?

[Stevie]

Moin,

ist es möglich, beim Kompilieren eine eigene Compiler message auszugeben, wenn irgendwo im kompilierten Code eine bestimmte Methode aufgerufen wird? Ich möchte damit bei einer Singleton Implementierung verhindern, dass irgendwo der Konstruktor aufgerufen wird.
Ich hab {$MESSAGE WARN 'Instantiation of TSingleton not allowed'} in den constructor meiner TSingleton Klasse geschrieben, aber die wird immer angezeigt, egal ob ich irgendwo ein Objekt dieser Klasse instanziere oder nicht - irgendwie ja auch logisch ;)
Wäre prima, wenn beim Aufruf von TSingleton.Create irgendwo im Code sowas kommt, wie wenn man eine Klasse mit abstrakten Methoden instaziert (oder gar ein Fehler, der das Kompilieren ganz verhindert)

MfG

[himitsu]

nein

selbst wenn du diese Message in die Prozedur reinschreibst, wird sie immer beim Compilieren der Prozedur angezeigt ... ob diese dann verwendet/aufgerufen wird, ist dabei leider egal.

du kannst diese Methode maximal als Abstract definieren, dann kommst diese Abstract-Compiliermeldung, ansonsten kannst du zur Laufzeit einen Fehler werfen, wenn jemand diese Methode/Constructor aufruft.

[Corpsman]

Warum schreibst du nicht eine entsprechende Exception in den Create Part deiner Klasse ?

Ansonsten müsste der Compiler eigentlich eh schon eine Warnung bringen , wenn du versuchst eine Klasse mit Abstracten Methoden zu instantiieren...

[Stevie]

Zitat:

Zitat von himitsu

du kannst diese Methode maximal als Abstract definieren, dann kommst diese Abstract-Compiliermeldung, ansonsten kannst du zur Laufzeit einen Fehler werfen, wenn jemand diese Methode/Constructor aufruft.

Zitat:

Zitat von Corpsman

Warum schreibst du nicht eine entsprechende Exception in den Create Part deiner Klasse ?

Ansonsten müsste der Compiler eigentlich eh schon eine Warnung bringen , wenn du versuchst eine Klasse mit Abstracten Methoden zu instantiieren...

Genau das wollte ich ja vermeiden, die abstract warning ist mir nicht speziell genug und ein abstract error zur Laufzeit eher ungewünscht. Die Exception wäre die "Notlösung" gewesen, schade, dass es nicht mit compile error geht. :(

[himitsu]

PS: wir hatten hier schonmal was Ähnliches:
http://www.delphipraxis.net/internal...t.php?t=162021


nicht schön, aber selten ... und wenn man einfach mal hofft, daß der Programmierer ließt, bevor er schreibt

Delphi-Quellcode:

constructor Create(const Diese_Klasse_bitte_nicht_direkt_verwenden_oder_sowas);

Und eventuell doch noch einen "irren" :Typen hinten dranhängen, welchen man so dort nie verwendet,
dann hat man erstmal Probleme dieses zum Kompilieren zu bringen.

[mjustin]

Zitat:

Zitat von Stevie

Wäre prima, wenn beim Aufruf von TSingleton.Create irgendwo im Code sowas kommt, wie wenn man eine Klasse mit abstrakten Methoden instaziert (oder gar ein Fehler, der das Kompilieren ganz verhindert)

Ist der Konstruktor nicht "private"? Dann bekommt die Klasse auch nicht das Qualitätssiegel "Zertifiziertes Singleton" ;)

Viele Grüße,

[himitsu]

Zitat:

Zitat von mjustin

Ist der Konstruktor nicht "private"? Dann bekommt die Klasse auch nicht das Qualitätssiegel "Zertifiziertes Singleton" ;)

Das ist kein Problem, aber der "Standardkonstruktor" wäre immernoch erreichbar.

Delphi-Quellcode:

TObject = class
  // per standard public
  constructor Create;

[Stevie]

Zitat:

Zitat von mjustin

Ist der Konstruktor nicht "private"? Dann bekommt die Klasse auch nicht das Qualitätssiegel "Zertifiziertes Singleton" ;)

Wenn man die Sichtbarkeit in Delphi verringern könnte, wär mir schon so manches Gebastel erspart geblieben :wall:

[Medium]

Dann würde Delphi aber auch einem fundamentalen Mechanismus der OOP entgegen arbeiten ;)

[SubData]

Ich habe sowas mal für einen Destruktor gebraucht und bin zu folgender Lösung gekommen.

Delphi-Quellcode:

type
  TQueryObj = class(TQuery)
  private
   [...]
  public
   [...]
  published
    procedure Free; deprecated;
  end;

Delphi-Quellcode:

{$WARN SYMBOL_DEPRECATED OFF}
procedure TQueryObj.Free;
begin
  inherited;
end;
{$WARN SYMBOL_DEPRECATED ON}

Da das Objekt nicht freigegeben werden darf, sondern von einem QueryPool verwaltet wird, der auch für die Freigabe zuständig ist, wird so unterbunden, dass irgendwo direkt .Free aufgerufen wird. Zumindest gibt es dann eine Warnung.

Der Compilerschalter bewirkt in diesem Fall nur, dass die Methode selbst nicht auch schon im Quellcode angemeckert wird.

[himitsu]

Free ist nur Public und es wäre besser, wenn man das auch noch im Destructor prüft.
(Beispiel: siehe EOutOfMemory in der SysUtils)

Warnungen kann man ignorieren.


[edit]
OK, nicht Destructos, sondern FreeInstance.

Delphi-Quellcode:

uses SysConst, Dialogs;

procedure TForm1.FormCreate(Sender: TObject);
var E: EOutOfMemory;
begin
  E := EOutOfMemory.CreateRes(@SOutOfMemory);
  E.Free;
  ShowMessage('bin noch da: ' + E.Message);

  // und an das nötige private E.AllowFree:=True; kommt man nicht ran
end;

also am Einfachsten diese Beiden überschreiben.

Delphi-Quellcode:

class function NewInstance: TObject; virtual;
procedure FreeInstance; virtual;

in NewInstance prüfen ob es schon existiert und ansonsten eine Exception
und in FreeInstance prüfen ob es freigegeben werden darf

[Stevie]

Da ich den Ansatz mit class constructor und class property gewählt habe, kommt auch das Überschreiben von NewInstance und FreeInstance leider nicht in Frage, da niemals ein Objekt der Singleton Klasse selber erzeugt wird.

[himitsu]

OK, dann einfach nur NewInstance überschreiben, denn wenn da wirklich mal einer eine Instanz erzeugen will und dabei sämtliche Warnungen ignoriert, dann schmeißt du ihm darin einfach eine Exception entgegen. :zwinker:

dann ist das aber kein Singelton mehr.
Singelton = nur maximal eine Instanz der Klasse exisitert

[Stevie]

Zitat:

Zitat von himitsu

OK, dann einfach nur NewInstance überschreiben, denn wenn da wirklich mal einer eine Instanz erzeugen will und dabei sämtliche Warnungen ignoriert, dann schmeißt du ihm darin einfach eine Exception entgegen. :zwinker:

dann ist das aber kein Singelton mehr.
Singelton = nur maximal eine Instanz der Klasse exisitert

So hab ich das jetzt auch gelöst. Genauer gesagt, ist meine Klasse eher eine Art generischer Wrapper um aus einer anderen Klasse (diese darf natürlich dann nicht nach außen bekannt sein, damit man keine Instanz erzeugt) ein Singleton zu erzeugen. Die Idee ist mit durch diesen Artikel gekommen.

[himitsu]

Wenn die Klasse nach außen wirklich nicht sichtbar sein soll,
dann kannst du auch ganz böse sein und alles auf einen Record umstellen.
Von diesem kann man garantiert keine Instanz erstellen. :lol:

Delphi-Quellcode:

unit SingletonUnit;

interface

type
  {T}Singleton = record
    class procedure DoSomething;
  end;

implementation

type
  TInternalSingleton = class
    constructor Create;
    procedure DoSomething;
  end;

var FSingle: TInternalSingleton;

constructor TInternalSingleton.Create;
begin
  ...
end;

procedure TInternalSingleton.DoSomething;
begin
  ...
end;

class procedure TSingleton.DoSomething;
begin
  FSingle.DoSomething;
end;

initialization
  FSingle := TSingleton.Create;

finalization
  FSingel.Free;
end.

Wobei man hier auch teilweise komplett auf die interne Klasse verzichten könnte.

[Stevie]

Die Idee war eher folgende:

Delphi-Quellcode:

unit Singleton;

interface

type
  TSingleton<T: class, constructor> = class
  private
    class var FInstance: T;
    class constructor Create;
    class destructor Destroy;
  public
    class function NewInstance: TObject; override;
    class property Instance: T read FInstance;
  end;

implementation

uses
  SysUtils;

class constructor TSingleton<T>.Create;
begin
  FInstance := T.Create;
end;

class destructor TSingleton<T>.Destroy;
begin
  FInstance.Free;
end;

class function TSingleton<T>.NewInstance: TObject;
begin
  raise Exception.CreateFmt('Instantiation of TSingleton<%s> not allowed', [T.ClassName]);
end;

end.

In einer anderen unit wird dann z.B. TFooSingleton = class(TSingleton<TFoo>) deklariert und auch nur diese Klasse nach außen freigegeben. Auch die unit Singleton sollte nicht im uses benutzt werden, sondern nur die, wo die konkrete Singleton-Klasse definiert wurde (in dem Beispiel TFooSingleton).