Freigabe von Objekten in Objekten

[Ginko]

Hallo ich habe ein Objekt erstellt, dass ein Objekt erstellt, welches wiederum ein Objekt erstellt.
Nun passiert es bei der Freigabe des Innersten Objektes, das ich ein Speicherzugriffsfehler bekomme.
Dieser tritt auf wenn der Destructor des Innersten Objektes aufgerufen wird. Hier ist der Quelltext( die Stelle wo der Fehler autritt ist gekennzeichnet) :

Delphi-Quellcode:

unit Unit2;

interface

uses
  Classes, SysUtils, Variants, Math, Grids, Forms,  Dialogs, Controls,
  StdCtrls, Windows, Messages, Graphics, Unit3;

type
  TObjektMit2Objekten = class
  public
    Objekt1 : TObjekt1;
    constructor Create(ZuBenutzendesFormular : TWinControl);
    destructor Destroy;  override;
  end;


implementation


constructor TObjektMit2Objekten.Create(ZuBenutzendesFormular : TWinControl);
begin
  inherited Create;
  Objekt1 := TObjekt1.Create(ZuBenutzendesFormular,1);
  Objekt1 := TObjekt1.Create(ZuBenutzendesFormular,2);
end;

destructor TObjektMit2Objekten.destroy;
begin
  Objekt1.free;
  Inherited destroy;
end;


end.

Delphi-Quellcode:

unit Unit3;

interface

uses
  Classes, SysUtils, Variants, Math, Grids, Forms,  Dialogs, Controls,
  StdCtrls, Windows, Messages, Graphics;


type
  TObjekt2 = class(TEdit)
  public
    constructor Create(AOwner: TComponent); override;
  end;

  TObjekt1 = class(TStringGrid)
  public
    Objekt2 : TObjekt2;
    constructor Create(AOwner: TComponent; Anders : byte); reintroduce;
    destructor destroy; override;
  end;

implementation

constructor TObjekt1.Create(AOwner: TComponent; Anders : byte);
begin
  inherited Create(AOwner);
  Parent := AOwner as TWinControl;

  case Anders of
    1:
      begin
        Left := 450;
        Top := 150;
        DefaultColWidth := 30;
        DefaultRowHeight := 30;
        FixedCols   := 0;
        FixedRows   := 0;
        BorderStyle := bsSingle;
        ColCount    := 8;
        RowCount    := 1;
        Width := 253;
        Height := 32;
      end;

    2:
      begin
        Objekt2 := TObjekt2.Create(AOwner);
        Objekt2.Top := 200;
        Left := 450;
        Top := 200;
        DefaultColWidth := 30;
        DefaultRowHeight := 30;
        FixedCols   := 0;
        FixedRows   := 0;
        BorderStyle := bsSingle;
        ColCount    := 8;
        RowCount    := 1;
        Width := 253;
        Height := 32;
      end;
  end;
end;


destructor TObjekt1.destroy;
begin
  Objekt2.Free;                    //Fehler ??!!
  inherited destroy;
end;

constructor TObjekt2.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  Parent := TWinControl(AOwner);
  Left := 400;
  Width := 50;
  AutoSize := false;
  Height := 32;
  Font.Size := 16;
  Text := 'Objekt2';
end;


end.

[mleyen]

Tritt der Fehler noch auf, wenn du am Anfang der Konstruktors von TObjekt1 "Objekt2 := nil;" schreibst?


Edit:
ich seh grad, bei

Delphi-Quellcode:

  Objekt1 := TObjekt1.Create(ZuBenutzendesFormular,1); 
  Objekt1 := TObjekt1.Create(ZuBenutzendesFormular,2);

erzeugst du aber ein MemLeak, da dir die erste Referenz verloren geht.

[himitsu]

Delphi-Quellcode:

Objekt1 := TObjekt1.Create(ZuBenutzendesFormular,1);
Objekt1 := TObjekt1.Create(ZuBenutzendesFormular,2);

Eine Variable, aber 2 Objekte ... ergo, wwird das 1. nie freigegeben, da dessen Referenz durch das Zweite überschrieben wird !

der Owner (Besitzer) von Objekt 2 ist ja wohl das Objekt 1

Delphi-Quellcode:

Objekt2 := TObjekt2.Create(Self);

[Teekeks]

Hier dürfte der Fehler liegen:

Delphi-Quellcode:

 Objekt1 := TObjekt1.Create(ZuBenutzendesFormular,1);
  Objekt1 := TObjekt1.Create(ZuBenutzendesFormular,2);

Du willst dein eines Objekt 2x erzeugen, geht aber nicht ^^

Gruß Teekeks
Edit: arg, zu langsam, aber egal

[DeddyH]

Außerdem ist es nicht so günstig, das Objekt mit einem anderen Owner zu erzeugen und es dann doch selbst freizugeben.

@Teekeks: das geht schon, aber dann ist die erste Referenz nicht mehr erreichbar.

[Ginko]

Aso jetzt bin ich aber doch etwas verwirrt also wäre dann

Delphi-Quellcode:

Objekt1a := TObjekt1.Create(ZuBenutzendesFormular,1);
Objekt1b := TObjekt1.Create(ZuBenutzendesFormular,2);

richtig?

Was aber auch nicht zu gehen scheint...

[DeddyH]

Verwirrt bin ich auch. Was möchtest Du denn erreichen? Willst Du ein TObjekt1 erzeugen, dass je nach Stand von "Anders" wiederum ein TObjekt2 erzeugt?

[edit] Oder sollen das 2 unterschiedliche TObjekt1 sein? [/edit]

[Ginko]

Also ich will ein TObjektMit2Objekten erzeugen, dass je nach Stand von "Anders" ein TObjekt1 ohne einem TObjekt2 oder ein TObjekt1 mit einem TObjekt2 erzeugt.

[fajac]

genau; du brauchst für jede Objektinstanz, die du mit "Create" erzeugst, eine Referenz. Sonst kannst du sie später nicht mehr freigeben.

Der eigentliche Fehler liegt aber, glaube ich darin, dass du im Destruktor von TObjekt1 Objekt2 freigibst, obwohl es nirgends erzeugt wurde, zumindest dann, wenn TObjekt1 mit Anders=1 erzeugt wurde.

[DeddyH]

Wenn Objekt2 mit nil initialisiert ist, führt ein Free nicht zum Fehler.

[Ginko]

Ja dachte auch, dass .Free überprüft ob Objekt2 überhaupt erstellt ist.
Wie das mit der Referenz geht könnte mir vielleicht jemand erklären, wäre nett.

[mleyen]

Damit du die beiden von dir erzeugten Objekte voneinander unterscheiden kannst, brauchst du 2 Referenzen. (wie fajac schon erklärt hat)

Beispiel:

Delphi-Quellcode:

type 
  TObjektMit2Objekten = class 
  public 
    Objekt1 : TObjekt1; 
    Objekt2 : TObjekt1; // Zur Unterscheidung des 2ten Objekts nehmen wir diese Objekt-Referenz
    constructor Create(ZuBenutzendesFormular : TWinControl); 
    destructor Destroy;  override; 
  end;

[fajac]

Delphi-Quellcode:

var 
  ObjektReferenz : TObjektTyp;

begin
  ObjektReferenz = TObjektTyp.Create();

Objektreferenz stellt einen Pointer dar, der auf eine Instanz von TObjektTyp zeigt (d.h.: Objektvariablen sind immer Pointer).
Durch den Aufruf wird eine Instanz von TObjektTyp erzeugt und ihre Speicheradresse Objektreferenz zugewiesen.
Wenn man nun

Delphi-Quellcode:

  ObjektReferenz = TObjektTyp.Create();

ein zweitesmal aufruft, wird eine neue Instanz erstellt und ihre Adresse ObjektReferenz zugewiesen - wodurch die erste Adress-Referenz überschrieben wird. Du "weisst" dann nicht mehr, wo die Objektinstanz ist, obwohl sie noch im Speicher ist. Daher kannst du sie auch nicht mehr freigeben.

[Ginko]

Danke für die ausfürliche Erklärung aber das klappt leider auch nicht, obwohl es natürlich ein Fehler war das Objekt zwei mal mit dem selben Namen zu erzeugen :?


Hier die Verbesserung, die auch nicht funktioniert, der Rest wie oben:

Delphi-Quellcode:

unit Unit2;

interface

uses
  Classes, SysUtils, Variants, Math, Grids, Forms,  Dialogs, Controls,
  StdCtrls, Windows, Messages, Graphics, Unit3;

type
  TObjektMit2Objekten = class
  public
    Objekt1a : TObjekt1;
    Objekt1b : TObjekt1;
    constructor Create(ZuBenutzendesFormular : TWinControl);
    destructor Destroy;  override;
  end;


implementation


constructor TObjektMit2Objekten.Create(ZuBenutzendesFormular : TWinControl);
begin
  inherited Create;
  Objekt1a := TObjekt1.Create(ZuBenutzendesFormular,1);
  Objekt1b := TObjekt1.Create(ZuBenutzendesFormular,2);
end;

destructor TObjektMit2Objekten.destroy;
begin
  Objekt1a.free;
  Objekt1b.free;
  Inherited destroy;
end;


end.

[mleyen]

Hast du folgendes schon getestet?

Zitat:

Zitat von mleyen

Tritt der Fehler noch auf, wenn du am Anfang der Konstruktors von TObjekt1 "Objekt2 := nil;" schreibst?

Ansonsten zeig nochmal bitte den Code, wahrscheinlich ein kleiner Fehler, wie zB 2 mal den gleichen Destruktor mit .free aufgerufen.

Edit #1:
Ok, du warst schneller mit dem editieren als ich im posten. :)
Wenn ich zuhause bin jag das mal selber durch den Debugger, dann kann ich dir warscheinlich eher sagen woran es liegt. :pale:

Edit #2:
Welches Create() inheritest' du da eigentlich? hat TObject überhaupt eins?

[Ginko]

Ok danke dir.
Das mit dem inheritet weiß ich jetzt auch nicht das mach ich immer so....
PS: Wenn ich "Objekt2.Free" raushole geht es problemlos, wäre das sehr tragisch ? :shock:

[DeddyH]

Im Sinne der OOP wäre eine bessere Kapselung "schöner". Dasselbe dann auch in der anderen Unit, wobei ich mir denken könnte, dass der Fehler dann weg ist, da IIRC private Referenzfelder automatisch mit nil initialisiert werden.

Delphi-Quellcode:

unit Unit2;

interface

uses
  Classes, SysUtils, Variants, Math, Grids, Forms,  Dialogs, Controls,
  StdCtrls, Windows, Messages, Graphics, Unit3;

type
  TObjektMit2Objekten = class
  private
    FObjekt1a: TObjekt1;
    FObjekt1b: TObjekt1;
  public
    constructor Create(ZuBenutzendesFormular : TWinControl);
    destructor Destroy;  override;
    property Objekt1a : TObjekt1 read FObjekt1a;
    property Objekt1b : TObjekt1 read FObjekt1b;
  end;


implementation


constructor TObjektMit2Objekten.Create(ZuBenutzendesFormular : TWinControl);
begin
  inherited Create;
  FObjekt1a := TObjekt1.Create(ZuBenutzendesFormular,1);
  FObjekt1b := TObjekt1.Create(ZuBenutzendesFormular,2);
end;

destructor TObjektMit2Objekten.destroy;
begin
  FObjekt1a.free;
  FObjekt1b.free;
  Inherited destroy;
end;


end.

[himitsu]

Hatte jetzt einfach mal deinen Code aus Post #1 in ein Projekt kopiert und bei mir (in D7) trat kein Fehler auf.
(auch wenn das Problem mit der Objektreferenz drin ist)

auch mit berichtigtem Owner und den den Korrekturen bezüglich der Referenzen läuft alles einwandfrei

Delphi-Quellcode:

type
  TObjekt2 = class(TEdit)
  public
    constructor Create(AOwner: TComponent); override;
  end;

  TObjekt1 = class(TStringGrid)
  public
    Objekt2 : TObjekt2;
    constructor Create(AOwner: TComponent; Anders : byte); reintroduce;
    destructor destroy; override;
  end;

type
  TObjektMit2Objekten = class
  public
    Objekt1a, Objekt1b : TObjekt1;  //////////////////////
    constructor Create(ZuBenutzendesFormular : TWinControl);
    destructor Destroy;  override;
  end;

constructor TObjekt1.Create(AOwner: TComponent; Anders : byte);
begin
  inherited Create(AOwner);
  Parent := AOwner as TWinControl;

  case Anders of
    1:
      begin
        Left := 450;
        Top := 150;
        DefaultColWidth  := 30;
        DefaultRowHeight := 30;
        FixedCols   := 0;
        FixedRows   := 0;
        BorderStyle := bsSingle;
        ColCount    := 8;
        RowCount    := 1;
        Width       := 253;
        Height      := 32;
      end;
    2:
      begin
        Objekt2 := TObjekt2.Create(Self);  //////////////////////
        Objekt2.Top := 200;
        Left := 450;
        Top := 200;
        DefaultColWidth  := 30;
        DefaultRowHeight := 30;
        FixedCols   := 0;
        FixedRows   := 0;
        BorderStyle := bsSingle;
        ColCount    := 8;
        RowCount    := 1;
        Width       := 253;
        Height      := 32;
      end;
  end;
end;

destructor TObjekt1.destroy;
begin
  Objekt2.Free; 
  inherited destroy;
end;

constructor TObjekt2.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  Parent := TWinControl(AOwner);
  Left := 400;
  Width := 50;
  AutoSize := false;
  Height := 32;
  Font.Size := 16;
  Text := 'Objekt2';
end;

constructor TObjektMit2Objekten.Create(ZuBenutzendesFormular : TWinControl);
begin
  inherited Create;
  Objekt1a := TObjekt1.Create(ZuBenutzendesFormular, 1);  //////////////////////
  Objekt1b := TObjekt1.Create(ZuBenutzendesFormular, 2);  //////////////////////
end;

destructor TObjektMit2Objekten.destroy;
begin
  Objekt1a.free;  //////////////////////
  Objekt1b.free;  //////////////////////
  Inherited destroy;
end;

procedure TForm1.Button1Click(Sender: TObject);
var o: TObjektMit2Objekten;
begin
  o := TObjektMit2Objekten.Create(Self);
  o.Free;
end;

Zitat:

Edit #2:
Welches Create() inheritest' du da eigentlich? hat TObject überhaupt eins?

das ist egal ... wenn kein Vorgänger existert, dann irgnoriert es Delphi
es sit auch besser dieses immer mit reinzumachen (es sei denn man weiß ganze genau, daß es wirklich unnötig ist),
aber lieber einmal zuviel, als es wo anders mal zu vergessen,

also es ist wirklich einfacher es immer zu reinzuschreiben ... sicher ist sicher

[DeddyH]

Wenn ich nicht total daneben liege, fügt Delphi bei STRG-SHIFT-C das inherited selbst automatisch ein, das kann also nicht so falsch sein ;)

[Ginko]

Das mit der besseren Kapslung bringt leider auch nix.
himitsu dein Vorschlag läuft zwar ohne Fehler, allerdings wird das TEdit Feld, also Objekt2 nicht mehr auf dem Formblatt angezeigt.:(

[DeddyH]

Du musst auch den Parent für das Objekt2 setzen.

Delphi-Quellcode:

constructor TObjekt1.Create(AOwner: TComponent; Anders : byte);
begin
  inherited Create(AOwner);
  Parent := AOwner as TWinControl;
  case Anders of 

    ...

    2:
      begin
        Objekt2 := TObjekt2.Create(Self);  //////////////////////
        Objekt2.Parent := AOwner as TWinControl;
        ...

[Ginko]

:thumb: Danke das war es :hello: Der überaus bösartige Parent war wirklich schuld....

So klapptes:

Delphi-Quellcode:

constructor TObjekt1.Create(AOwner: TComponent; Anders : byte);
begin
  inherited Create(AOwner);
  case Anders of
    1:
      begin
        Parent := AOwner as TWinControl;////////////////
        Left := 450;
        Top := 150;
        DefaultColWidth := 30;
        DefaultRowHeight := 30;
        FixedCols   := 0;
        FixedRows   := 0;
        BorderStyle := bsSingle;
        ColCount    := 8;
        RowCount    := 1;
        Width := 253;
        Height := 32;
      end;

    2:
      begin
        Objekt2 := TObjekt2.Create(AOwner);
        Parent := AOwner as TWinControl;     ////////////////////!!!
        Objekt2.Top := 200;
        Left := 450;
        Top := 200;
        DefaultColWidth := 30;
        DefaultRowHeight := 30;
        FixedCols   := 0;
        FixedRows   := 0;
        BorderStyle := bsSingle;
        ColCount    := 8;
        RowCount    := 1;
        Width := 253;
        Height := 32;
      end;
  end;
end;

[DeddyH]

Ist der Speicherfehler denn jetzt auch behoben, oder hast Du nur das Free im Destruktor rausgeworfen und bekommst nun Memoryleaks?

[Ginko]

Nein ich habe das Objekt2.Free nicht rausgeworfen und der Speicherfehler ist weg.
Es lag scheinbar nur daran, dass ich den Parent jedesmal extra angeben muss. Warum ist mir aber nicht wirklich klar ....

[DeddyH]

Ööhhmm... hö :?: Aber egal, wenn es jetzt funktioniert, ist ja alles gut :-D